4 files changed, 142 insertions, 0 deletions
diff --git a/dev-python/doit/Manifest b/dev-python/doit/Manifest
new file mode 100644
index 000000000000..ccf358799987
--- /dev/null
+++ b/dev-python/doit/Manifest
@@ -0,0 +1,2 @@
+DIST doit-0.36.0.tar.gz 1448096 BLAKE2B 15558a39ccac031ddf3a429aa585bc6e1d49c2e7572df29979ca66d1025fa5d7a917f6cc5bcfd21f2749e4ed7e7885b0865ec67b6fa32817e1518d47da9ead97 SHA512 d4caa31701755c7f59213dde0f89fd3616c0c01b7f06245cbfd9f1a315d503e62f3556c3b86685cd0ebfcffcc9cae0987ca150f037aa7b3cd960439a1191be42
+DIST doit-0.37.0.tar.gz 1450967 BLAKE2B 7bd0d29f9f74273955ab4e2b25b553deb01e00455dd0d5b4072accd0549cf774c679fed15ce65688db3f71f94552eb82c61b6789fe1b2cd0cb3d051a8e8c69c6 SHA512 de7cc6b0a3d5afae53b9a4fdf2debaebf454094dc5be992b58f181d7e22895fe88996d0aed3d4e4f70df45d4afb38b19de7144b3387736bba81af9177414b392
diff --git a/dev-python/doit/doit-0.36.0-r2.ebuild b/dev-python/doit/doit-0.36.0-r2.ebuild
new file mode 100644
index 000000000000..a109fa4d8ea2
--- /dev/null
+++ b/dev-python/doit/doit-0.36.0-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Automation tool"
+HOMEPAGE="
+	https://pydoit.org/
+	https://github.com/pydoit/doit/
+	https://pypi.org/project/doit/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~riscv x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		|| (
+			dev-python/tomli[${PYTHON_USEDEP}]
+			dev-python/tomlkit[${PYTHON_USEDEP}]
+		)
+	' 3.10)
+"
+PDEPEND="
+	>=dev-python/doit-py-0.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${PDEPEND}
+		$(python_gen_impl_dep sqlite)
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc \
+	dev-python/sphinx-rtd-theme
+
+EPYTEST_DESELECT=(
+	# test failing due to impact on PATH run in a sandbox
+	tests/test_cmd_strace.py::TestCmdStrace::test_dep # #836164
+	tests/test_cmd_strace.py::TestCmdStrace::test_target
+)
+
+src_prepare() {
+	# Replace custom theme with builtin for documentation
+	sed -e '/html_theme/s/press/sphinx_rtd_theme/' -i doc/conf.py || die
+	# Remove non-exist modules for doc generation (#832754)
+	sed \
+		-e '/sphinx_sitemap/d' \
+		-e '/sphinx_reredirects/d' \
+		-i doc/conf.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp bash_completion_doit ${PN}
+	insinto /usr/share/zsh/site-functions
+	newins zsh_completion_doit _${PN}
+}
diff --git a/dev-python/doit/doit-0.37.0.ebuild b/dev-python/doit/doit-0.37.0.ebuild
new file mode 100644
index 000000000000..e57647cad2b1
--- /dev/null
+++ b/dev-python/doit/doit-0.37.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Automation tool"
+HOMEPAGE="
+	https://pydoit.org/
+	https://github.com/pydoit/doit/
+	https://pypi.org/project/doit/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~riscv x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx doc dev-python/furo
+
+src_prepare() {
+	# Remove non-exist modules for doc generation (#832754)
+	sed \
+		-e '/sphinx_sitemap/d' \
+		-e '/sphinx_reredirects/d' \
+		-i doc/conf.py || die
+
+	# Disable xdist to avoid issues if pytest-xdist is installed.
+	sed \
+		-e 's/from xdist import plugin/raise ImportError()/' \
+		-i tests/conftest.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp bash_completion_doit ${PN}
+	newzshcomp zsh_completion_doit _${PN}
+}
diff --git a/dev-python/doit/metadata.xml b/dev-python/doit/metadata.xml
new file mode 100644
index 000000000000..90530b367b86
--- /dev/null
+++ b/dev-python/doit/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>azamat.hackimov@gmail.com</email>
+    <name>Azamat H. Hackimov</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>