3 files changed, 69 insertions, 0 deletions
diff --git a/dev-python/docker/Manifest b/dev-python/docker/Manifest
new file mode 100644
index 000000000000..1e77cd1696ad
--- /dev/null
+++ b/dev-python/docker/Manifest
@@ -0,0 +1 @@
+DIST docker-py-7.1.0.gh.tar.gz 253282 BLAKE2B 82eba285c1ea61956005dd0a9bfb66864fd30119a4b4c384d0d4350edeb331004d66bcdba6f20ec56ff48590b4a29a7b0fb07c6db6ecadfe96830337c37a535a SHA512 3dd73f2c3f3e92863496ef8277f481e64484e0e85a64dffe4e3287836823e4b118a5c8e73b2540e7188a0b755cd3f237ccc868a5bfb81d3bff1142fbb33755cb
diff --git a/dev-python/docker/docker-7.1.0.ebuild b/dev-python/docker/docker-7.1.0.ebuild
new file mode 100644
index 000000000000..5fd21c9c5e31
--- /dev/null
+++ b/dev-python/docker/docker-7.1.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P=docker-py-${PV}
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="
+	https://github.com/docker/docker-py/
+	https://pypi.org/project/docker/
+"
+SRC_URI="
+	https://github.com/docker/docker-py/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
+
+RDEPEND="
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/paramiko-2.4.3[${PYTHON_USEDEP}]
+		>=dev-python/websocket-client-1.3.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/myst-parser'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local -x TZ=UTC
+	epytest tests/unit
+}
diff --git a/dev-python/docker/metadata.xml b/dev-python/docker/metadata.xml
new file mode 100644
index 000000000000..5da5c3334011
--- /dev/null
+++ b/dev-python/docker/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+  </maintainer>
+  <stabilize-allarches />
+  <upstream>
+    <bugs-to>https://github.com/docker/docker-py/issues</bugs-to>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>