3 files changed, 66 insertions, 0 deletions
diff --git a/dev-python/colour/Manifest b/dev-python/colour/Manifest
new file mode 100644
index 000000000000..137909571b6b
--- /dev/null
+++ b/dev-python/colour/Manifest
@@ -0,0 +1 @@
+DIST colour-0.1.5.tar.gz 24776 BLAKE2B 71e2b44c6379f73fa1a70781ae2559e37122e2db982d1f98ab5c4432b4e95a2c60d6489a88025499c36d288f3e9269e65caf9560d7772e2c1c050266c284816f SHA512 09a5160862bf10cd5f4a94e43c63d6f2a5db43bcaae0e9d8f66900113ec04471e22d0bec7412f0289c6f1e6871c1a544f5be36266aa8d6fd5ec274bd461d9df8
diff --git a/dev-python/colour/colour-0.1.5-r1.ebuild b/dev-python/colour/colour-0.1.5-r1.ebuild
new file mode 100644
index 000000000000..7d6b5359e5b8
--- /dev/null
+++ b/dev-python/colour/colour-0.1.5-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python color representations manipulation library"
+HOMEPAGE="
+	https://github.com/vaab/colour/
+	https://pypi.org/project/colour/
+"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~x86"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# Upstream uses dead & broken d2to1, just make a quick flit config
+	# to make it work.
+	cat > pyproject.toml <<-EOF
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "colour"
+		version = "${PV}"
+		description = "${DESCRIPTION}"
+	EOF
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --doctest-modules
+}
diff --git a/dev-python/colour/metadata.xml b/dev-python/colour/metadata.xml
new file mode 100644
index 000000000000..d5c90888b9f2
--- /dev/null
+++ b/dev-python/colour/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>xgqt@gentoo.org</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription>
+    Converts and manipulates common color representation (RGB, HSL, web, ...).
+    Full conversion between RGB, HSL, 6-digit hex, 3-digit hex, human color.
+    One object (Color) or bunch of single purpose function (rgb2hex, hsl2rgb
+    ...). Web format that use the smallest representation between 6-digit (e.g.
+    #fa3b2c), 3-digit (e.g. #fbb), fully spelled color (e.g. white), following
+    W3C color naming for compatible CSS or HTML color specifications. Smooth
+    intuitive color scale generation choosing N color gradients. Can pick
+    colors for you to identify objects of your application.
+  </longdescription>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>