4 files changed, 130 insertions, 0 deletions
diff --git a/dev-python/cmd2/Manifest b/dev-python/cmd2/Manifest
new file mode 100644
index 000000000000..869f75b8bb93
--- /dev/null
+++ b/dev-python/cmd2/Manifest
@@ -0,0 +1,2 @@
+DIST cmd2-2.6.2.tar.gz 592373 BLAKE2B 917ecd684c60c0a6c1b273ef52fa1e317f71522dfd6fc8a9d2c1ee7fa28788b734c6536a9481ac56ef8409002f503837ae51191478a68e364c4780e9feb4b8e8 SHA512 75531dca561427eef259765a55c6385401edd8bc9d5c4cf08ab97e53e118334be932ee5c59f9e1fcd529a7a5f7416e654ee1d618d91623068ef21bcc66dcfdd7
+DIST cmd2-3.5.1.tar.gz 707325 BLAKE2B 5fd287a1a984c425cc7fdb3ef6c1f709b4af470b3280e715bcbad8200b52d5f8d698716eb540a9c9603ed090e2394b3aac319aaf80afc652459c127d968020bc SHA512 30414090390c1087173d2a259b5af2dc12228ab16892ea8617ec4168882565ebeef7e76a2c86b6e614fe45e3e454f74c49b633358b5da84d57365e7e70432054
diff --git a/dev-python/cmd2/cmd2-2.6.2.ebuild b/dev-python/cmd2/cmd2-2.6.2.ebuild
new file mode 100644
index 000000000000..40448f2557a4
--- /dev/null
+++ b/dev-python/cmd2/cmd2-2.6.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature virtualx pypi
+
+DESCRIPTION="Extra features for standard library's cmd module"
+HOMEPAGE="
+	https://github.com/python-cmd2/cmd2/
+	https://pypi.org/project/cmd2/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~mips ~ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	>=dev-python/pyperclip-1.8[${PYTHON_USEDEP}]
+	>=dev-python/wcwidth-0.2.10[${PYTHON_USEDEP}]
+"
+# pyperclip uses clipboard backends in the following preference order:
+# pygtk, xclip, xsel, klipper, qtpy, pyqt5, pyqt4.
+# klipper is known to be broken in Xvfb, and therefore causes test
+# failures.  to avoid them, we must ensure that one of the backends
+# preferred to it is available (i.e. xclip or xsel).
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		|| (
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures} )
+distutils_enable_tests pytest
+
+src_test() {
+	# tests rely on very specific text wrapping...
+	local -x COLUMNS=80
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# TODO: tests_isolated?
+	nonfatal epytest -o addopts= --reruns=5 tests || die
+}
+
+pkg_postinst() {
+	optfeature "IPython shell integration" dev-python/ipython
+}
diff --git a/dev-python/cmd2/cmd2-3.5.1.ebuild b/dev-python/cmd2/cmd2-3.5.1.ebuild
new file mode 100644
index 000000000000..fcf23fa32641
--- /dev/null
+++ b/dev-python/cmd2/cmd2-3.5.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature virtualx pypi
+
+DESCRIPTION="Extra features for standard library's cmd module"
+HOMEPAGE="
+	https://github.com/python-cmd2/cmd2/
+	https://pypi.org/project/cmd2/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~mips ~ppc64 ~riscv ~s390 x86"
+
+RDEPEND="
+	>=dev-python/pyperclip-1.8.2[${PYTHON_USEDEP}]
+	>=dev-python/rich-15.0.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-argparse-1.7.2[${PYTHON_USEDEP}]
+"
+# pyperclip uses clipboard backends in the following preference order:
+# pygtk, xclip, xsel, klipper, qtpy, pyqt5, pyqt4.
+# klipper is known to be broken in Xvfb, and therefore causes test
+# failures.  to avoid them, we must ensure that one of the backends
+# preferred to it is available (i.e. xclip or xsel).
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		|| (
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+EPYTEST_RERUNS=5
+distutils_enable_tests pytest
+
+src_test() {
+	# tests rely on very specific text wrapping...
+	local -x COLUMNS=80
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# TODO: tests_isolated?
+	nonfatal epytest -o addopts= tests || die
+}
+
+pkg_postinst() {
+	optfeature "IPython shell integration" dev-python/ipython
+}
diff --git a/dev-python/cmd2/metadata.xml b/dev-python/cmd2/metadata.xml
new file mode 100644
index 000000000000..b14f51ca55ab
--- /dev/null
+++ b/dev-python/cmd2/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>prometheanfire@gentoo.org</email>
+    <name>Matthew Thode</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>