3 files changed, 110 insertions, 79 deletions
diff --git a/dev-lua/lua-zlib/lua-zlib-1.2-r100.ebuild b/dev-lua/lua-zlib/lua-zlib-1.2-r100.ebuild
new file mode 100644
index 000000000000..1fbf98752889
--- /dev/null
+++ b/dev-lua/lua-zlib/lua-zlib-1.2-r100.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit cmake lua
+
+DESCRIPTION="Simple streaming interface to zlib for Lua"
+HOMEPAGE="https://github.com/brimworks/lua-zlib"
+SRC_URI="https://github.com/brimworks/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	sys-libs/zlib
+	${LUA_DEPS}
+
+"
+DEPEND="${RDEPEND}"
+
+lua_src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_CMOD="$(lua_get_cmod_dir)"
+		-DUSE_LUA_VERSION="$(lua_get_version)"
+	)
+
+	if [[ ${ELUA} == luajit ]]; then
+		mycmakeargs+=( -DUSE_LUAJIT="ON" )
+	fi
+
+	cmake_src_configure
+}
+
+src_configure() {
+	lua_foreach_impl lua_src_configure
+}
+
+src_compile() {
+	lua_foreach_impl cmake_src_compile
+}
+
+src_install() {
+	lua_foreach_impl cmake_src_install
+}
diff --git a/dev-lua/luaevent/luaevent-0.4.6-r100.ebuild b/dev-lua/luaevent/luaevent-0.4.6-r100.ebuild
new file mode 100644
index 000000000000..73dc2a0ca236
--- /dev/null
+++ b/dev-lua/luaevent/luaevent-0.4.6-r100.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Binding of libevent for Lua"
+HOMEPAGE="https://luaforge.net/projects/luaevent"
+SRC_URI="https://github.com/harningt/luaevent/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	dev-libs/libevent:0=
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	local mysedargs=(
+		-e "'s/CFLAGS =/CFLAGS +=/'"
+		-e "'s/LDFLAGS =/LDFLAGS +=/'"
+		-e "'s:-I\$(LUA_INC_DIR):\$(LUA_INC_DIR):'"
+		-i Makefile
+	)
+
+	eval sed ${mysedargs[@]} || die
+}
+
+lua_src_compile() {
+	tc-export CC
+
+	emake LUA_INC_DIR="$(lua_get_CFLAGS)"
+}
+
+src_compile() {
+	lua_foreach_impl lua_src_compile
+}
+
+lua_src_install() {
+	local myemakeargs=(
+		DESTDIR="${ED}"
+		INSTALL_DIR_BIN="$(lua_get_cmod_dir)"
+		INSTALL_DIR_LUA="$(lua_get_lmod_dir)"
+		LUA_INC_DIR="$(lua_get_CFLAGS)"
+	)
+
+	emake ${myemakeargs[@]} install
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}
diff --git a/dev-lua/luv/luv-1.32.0.0-r100.ebuild b/dev-lua/luv/luv-1.32.0.0-r100.ebuild
deleted file mode 100644
index 793fb2104a09..000000000000
--- a/dev-lua/luv/luv-1.32.0.0-r100.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 2019-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-LUA_COMPAT=( lua5-{1..3} luajit )
-
-inherit cmake lua-single unpacker
-
-# e.g. MY_PV = a.b.c-d
-MY_PV="$(ver_rs 3 -)"
-MY_P="${PN}-${MY_PV}"
-
-DESCRIPTION="Bare libuv bindings for lua"
-HOMEPAGE="https://github.com/luvit/luv"
-
-LUA_COMPAT_PV="0.7"
-SRC_URI="
-	https://github.com/luvit/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/keplerproject/lua-compat-5.3/archive/v${LUA_COMPAT_PV}.tar.gz -> ${PN}-lua-compat-${LUA_COMPAT_PV}.tar.gz
-"
-
-LICENSE="Apache-2.0 MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-BDEPEND="virtual/pkgconfig"
-DEPEND="${LUA_DEPS}
-	>=dev-libs/libuv-1.32.0:="
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.32.0.0-cmake_lua_version.patch
-)
-
-S="${WORKDIR}/${MY_P}"
-
-src_prepare() {
-	# Fix libdir
-	# Match '/lib/' and '/lib"' without capturing / or ", replacing with libdir
-	sed -i -r "s/\/lib(\"|\/)/\/$(get_libdir)\1/g" CMakeLists.txt || die "Failed to sed CMakeLists.txt"
-	cmake_src_prepare
-}
-
-# TODO: try to make this multi-impl. Will need at least:
-#  - per-implementation install dirs for headers and the library
-#  - versioned .pc files (which may or may not break revdeps)
-src_configure() {
-	lua_compat_dir="${WORKDIR}/lua-compat-5.3-${LUA_COMPAT_PV}"
-
-	local mycmakeargs=(
-		-DBUILD_MODULE=OFF
-		-DLUA_BUILD_TYPE=System
-		-DLUA_COMPAT53_DIR="${lua_compat_dir}"
-		-DWITH_SHARED_LIBUV=ON
-	)
-	if [[ ${ELUA} == luajit ]]; then
-		mycmakeargs+=(
-			-DWITH_LUA_ENGINE=LuaJIT
-		)
-	else
-		mycmakeargs+=(
-			-DWITH_LUA_ENGINE=Lua
-			-DLUA_VERSION=$(ver_cut 1-2 $(lua_get_version))
-		)
-	fi
-
-	cmake_src_configure
-}
-
-src_test() {
-	# We need to copy the library back so that the tests see it
-	ln -s "${BUILD_DIR}/libluv.so" "./luv.so" || die "Failed to symlink library for tests"
-	${ELUA} "tests/run.lua" || die "Tests failed"
-}