3 files changed, 81 insertions, 2 deletions
diff --git a/dev-libs/libpqxx/Manifest b/dev-libs/libpqxx/Manifest
index c7e4685aa032..56d248f83f7d 100644
--- a/dev-libs/libpqxx/Manifest
+++ b/dev-libs/libpqxx/Manifest
@@ -1,2 +1,3 @@
 DIST libpqxx-7.1.2.tar.gz 693152 BLAKE2B da28d0041fc345eb7774eadf0a886e2a89692ac47d870120991aa97328a6be7d10e8cb2d6deb9e056dc7e05b04fd317d9d0fe4dcf8eab901114b27cd64bf4ff6 SHA512 a4a76c62f6115f5898e4c4bb1c6f095284bdb7ae6a1efa45add9efd422d2a8280d1698caa2469acbb087168208ae0fd8efa36c8735a8ce30e58853e27acd4161
 DIST libpqxx-7.2.1.tar.gz 691486 BLAKE2B ef1b12e436e33a26faa8f5acceef8d5ab1063b0618798fdf881fe38ab101da6d78989cc30c1e24f60fd81dd4f4034267e8b220b7b1d1932793028abf7e17c614 SHA512 baaa53f12aa87f512bbbe7494c915242cda8508b43414b79e6cd047dbd61902cbe54cb34af13d75bdccd70bdbafcaca155b4ccb426d8b831bd4df46e9a57e3a2
+DIST libpqxx-7.3.0.tar.gz 694012 BLAKE2B 35770599fcb3131081e08c18d96b753cc6d412c6ea8fddf5617df7da2035cf8ee3a031b7c14d592e0c9560e1e1074e633734337113ed0b3943e519aa44806307 SHA512 897af8e1c0ab12df745116e5387d3c31fb8800b6c599f49413ddcc67df7968fb1922c96896c818ce3f34d9649fb6c1d2ea59784f8765fb765481b156be44eaa2
diff --git a/dev-libs/libpqxx/libpqxx-7.2.1.ebuild b/dev-libs/libpqxx/libpqxx-7.2.1.ebuild
index 3ca142f65ec5..f23e71978646 100644
--- a/dev-libs/libpqxx/libpqxx-7.2.1.ebuild
+++ b/dev-libs/libpqxx/libpqxx-7.2.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -6,7 +6,7 @@ EAPI=7
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 inherit python-any-r1
 
-KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 ~sparc x86"
 
 DESCRIPTION="Standard front-end for writing C++ programs that use PostgreSQL"
 SRC_URI="https://github.com/jtv/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
diff --git a/dev-libs/libpqxx/libpqxx-7.3.0.ebuild b/dev-libs/libpqxx/libpqxx-7.3.0.ebuild
new file mode 100644
index 000000000000..3ca142f65ec5
--- /dev/null
+++ b/dev-libs/libpqxx/libpqxx-7.3.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit python-any-r1
+
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+DESCRIPTION="Standard front-end for writing C++ programs that use PostgreSQL"
+SRC_URI="https://github.com/jtv/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="https://pqxx.org/development/libpqxx/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc static-libs"
+
+RDEPEND="dev-db/postgresql:="
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	doc? (
+		app-doc/doxygen
+		app-text/xmlto
+	)
+"
+
+DOCS=( AUTHORS NEWS README{.md,-UPGRADE} )
+
+src_configure() {
+	econf \
+		--enable-shared \
+		$(use_enable doc documentation) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	einfo "The tests need a running PostgreSQL server and an existing database."
+	einfo "Test requires PGDATABASE and PGUSER to be set at a minimum. Optionally,"
+	einfo "set PGPORT and PGHOST. Define them at the command line or in:"
+	einfo "    ${EROOT}/etc/libpqxx_test_env"
+
+	if [[ -z $PGDATABASE || -z $PGUSER ]] ; then
+		if [[ -f ${EROOT}/etc/libpqxx_test_env ]] ; then
+			source "${EROOT}/etc/libpqxx_test_env"
+			[[ -n $PGDATABASE ]] && export PGDATABASE
+			[[ -n $PGHOST ]] && export PGHOST
+			[[ -n $PGPORT ]] && export PGPORT
+			[[ -n $PGUSER ]] && export PGUSER
+		fi
+	fi
+
+	if [[ -n $PGDATABASE && -n $PGUSER ]] ; then
+		local server_version
+		server_version=$(psql -Aqtc 'SELECT version();' 2> /dev/null)
+		if [[ $? = 0 ]] ; then
+			cd "${S}/test" || die
+			emake check
+		else
+			eerror "Is the server running?"
+			eerror "Verify role and database exist, and are permitted in pg_hba.conf for:"
+			eerror "    Role: ${PGUSER}"
+			eerror "    Database: ${PGDATABASE}"
+			die "Couldn't connect to server."
+		fi
+	else
+		eerror "PGDATABASE and PGUSER must be set to perform tests."
+		eerror "Skipping tests."
+	fi
+}
+
+src_install () {
+	use doc && HTML_DOCS=( doc/html/. )
+	default
+
+	if ! use static-libs; then
+		find "${D}" -name '*.la' -delete || die
+	fi
+}