1 files changed, 54 insertions, 0 deletions
diff --git a/dev-java/libg/libg-7.2.3.ebuild b/dev-java/libg/libg-7.2.3.ebuild
new file mode 100644
index 000000000000..2c71a9e33fb2
--- /dev/null
+++ b/dev-java/libg/libg-7.2.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+# No tests, because
+# aQute.bnd.test.jupiter does not exist
+# org.assertj.core.api.junit.jupiter does not exist
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A library to be statically linked. Contains many small utilities"
+HOMEPAGE="https://bnd.bndtools.org/"
+SRC_URI="https://github.com/bndtools/bnd/archive/${PV/_rc/.RC}.tar.gz -> aQute.bnd-${PV}.tar.gz"
+S="${WORKDIR}/bnd-${PV/_rc/.RC}"
+
+LICENSE="Apache-2.0 EPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64"
+
+CP_DEPEND="
+	dev-java/osgi-cmpn:8
+	dev-java/slf4j-api:0
+"
+
+DEPEND="
+	${CP_DEPEND}
+	~dev-java/bnd-annotation-${PV}:0
+	dev-java/eclipse-jdt-annotation:0
+	>=virtual/jdk-17:*
+"
+
+# aQute.libg/src/aQute/libg/uri/URIUtil.java:161:
+# error: switch expressions are not supported in -source 11
+RDEPEND="
+	${CP_DEPEND}
+	dev-java/osgi-annotation:0
+	dev-java/osgi-core:0
+	>=virtual/jre-17:*
+"
+
+JAVA_AUTOMATIC_MODULE_NAME="aQute.libg"
+JAVA_CLASSPATH_EXTRA="
+	bnd-annotation
+	eclipse-jdt-annotation
+"
+JAVA_SRC_DIR="aQute.libg/src"
+
+src_install() {
+	java-pkg-simple_src_install
+	java-pkg_register-dependency osgi-core
+	java-pkg_register-dependency osgi-annotation
+}