4 files changed, 96 insertions, 5 deletions
diff --git a/dev-java/asm/Manifest b/dev-java/asm/Manifest
index d1f433cd189e..0d968b7a0477 100644
--- a/dev-java/asm/Manifest
+++ b/dev-java/asm/Manifest
@@ -1,3 +1,4 @@
-DIST asm-ASM_4_0.tar.gz 14789505 BLAKE2B 62b49d904f1ef2d32379f4f5d644cdc274b30f292ee4f64ad02be7d2226a90965f7b12421700e79dcd1e67a46e6a8543d5e353486a1577313616688ddc57f3b3 SHA512 e654623a882d9fe414e71861183f64840f7b6629231864872497d4bf9274e8ac05e05496593fa54a90d8c6a2e6d701b9a6f3876df611637f7d2079c5519def1e
-DIST asm-ASM_5_1.tar.gz 16258842 BLAKE2B bd7d717cdfa6ff652c96b88d7b7d33fae614acba390c256ea72ecfbb3edc48382621a076dedf9b8728fdb1d0961cda943f165f99de840824b766c9af45a49339 SHA512 4bb32ce6eba267928261238f8f13cd2365ab374780039ad1df31698cd791645a370aca58c44270ec05f8377d6aa0a0d00f9f3890961cbd32a10cbd2e79e2d518
+DIST asm-ASM_4_0.tar.bz2 14706135 BLAKE2B 20bed2b10b6107e9af74dafd8f7c9db93be1c26e073a8f7d8b25a94b99a1e89659dd03ed9094c4a56fe8a9b8d206b00e3db35eb4074e16396292d2fe75c2bb41 SHA512 046b36fe664a58e65daca2e3820f431436f27242fb548723ec02e829637f4d27d3329edd5014d3c84855d827a2fb2a87107043951a83f4fee2e83d89bb0ba74d
+DIST asm-ASM_5_1.tar.bz2 16191369 BLAKE2B 30e0f97fe200f09c78b3ba743ad70f25715b411d5e0be330234d97dec98b997db78736b5e005fdac8ed5339c553783a4e12386c34cb2c5a45bd8d8b42d7e8465 SHA512 6e73fe0787cfa974c598be44b5d735bbd6cba88f64db24169ec481281aea2169bce65fb08a677aa99f0d71f876a204c86432d2a4a79e85cc5286eb2ccf7617d7
 DIST asm-ASM_9_3.tar.gz 1666740 BLAKE2B 6905233f666159f861dda68a855e8f5632817b0627c2006d3a8e61340cd4afca9310860dd1eff46173ca7356583e6c44027e674f7e17eacaaf0dbcc24b92198e SHA512 401a4dd7c2638bbad940ca92c42b7ec6f44e1d19c407bba3cd6a081e0b51969cf62a0fbcc407ef4889d3c7d6c7b9893e77642c058f812e9d10b9d67c5215be42
+DIST asm-ASM_9_4.tar.bz2 1380417 BLAKE2B 612fc6669294f2926ec77522f642f2878a96a9c977579ceda9feb955041ff53fa698c75b26c27bae478a41dca59357d9cf824263df39d60ea5c6722e5f0efc75 SHA512 a59268808ac54a238bd6e117eb0164d28c5c3572c12d7ad42c2f3dbd32714c03056f330255756511db4f1ede8d66bf32c7347128b8ec179beba11cca27927687
diff --git a/dev-java/asm/asm-5.1-r1.ebuild b/dev-java/asm/asm-5.1-r1.ebuild
index ff2f2f95764b..c4beac9c0ac2 100644
--- a/dev-java/asm/asm-5.1-r1.ebuild
+++ b/dev-java/asm/asm-5.1-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -10,7 +10,7 @@ inherit java-pkg-2 java-ant-2
 DESCRIPTION="Bytecode manipulation framework for Java"
 HOMEPAGE="https://asm.ow2.io"
 MY_P="ASM_${PV//./_}"
-SRC_URI="https://gitlab.ow2.org/asm/asm/-/archive/${MY_P}/asm-${MY_P}.tar.gz https://gitlab.ow2.org/asm/asm/-/archive/ASM_4_0/asm-ASM_4_0.tar.gz"
+SRC_URI="https://gitlab.ow2.org/asm/asm/-/archive/${MY_P}/asm-${MY_P}.tar.bz2 https://gitlab.ow2.org/asm/asm/-/archive/ASM_4_0/asm-ASM_4_0.tar.bz2"
 
 LICENSE="BSD"
 SLOT="4"
diff --git a/dev-java/asm/asm-9.4.ebuild b/dev-java/asm/asm-9.4.ebuild
new file mode 100644
index 000000000000..872b14d0208c
--- /dev/null
+++ b/dev-java/asm/asm-9.4.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# No tests because:
+# package org.junit.jupiter.api does not exist
+# package org.junit.jupiter.params does not exist
+JAVA_PKG_IUSE="doc source"
+MAVEN_PROVIDES="org.ow2.asm:asm-bom:9.4 org.ow2.asm:asm:9.4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Bytecode manipulation framework for Java"
+HOMEPAGE="https://asm.ow2.io"
+MY_P="ASM_${PV//./_}"
+SRC_URI="https://gitlab.ow2.org/asm/asm/-/archive/${MY_P}/asm-${MY_P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="9"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~x64-macos"
+
+DEPEND=">=virtual/jdk-11:*"
+RDEPEND=">=virtual/jre-1.8:*"
+
+ASM_MODULES=( "asm" "asm-tree" "asm-analysis" "asm-commons" "asm-util" )
+
+S="${WORKDIR}/asm-${MY_P}"
+
+src_prepare() {
+	default
+	local module
+	touch "${T}/asm.module" || die
+	for module in "${ASM_MODULES[@]}"; do
+		module=${module/-/.}
+		cat > ${module/./-}/src/main/java/module-info.java <<-EOF || die
+			open module org.objectweb.${module/analysis/tree.analysis} {
+				$(cat ${T}/asm.module)
+				requires java.base;
+				exports org.objectweb.${module/analysis/tree.analysis};
+			}
+		EOF
+		echo "requires transitive org.objectweb.${module/analysis/tree.analysis};" \
+			>> "${T}/asm.module" || die
+	done
+	sed -e '/^$/d' \
+		-e '/asm;/p;s:\(asm\)\(;\):\1.signature\2:' \
+		-i  asm/src/main/java/module-info.java || die
+	sed -e '/analysis/d' \
+		-i  asm-commons/src/main/java/module-info.java || die
+	sed -e '/commons/d' \
+		-i  asm-util/src/main/java/module-info.java || die
+}
+
+src_compile() {
+	local module
+	for module in "${ASM_MODULES[@]}"; do
+		einfo "Compiling $module"
+		JAVA_JAR_FILENAME="$module.jar"
+		JAVA_SRC_DIR="$module/src/main/java"
+		java-pkg-simple_src_compile
+		JAVA_GENTOO_CLASSPATH_EXTRA+=":$module.jar"
+		rm -r target || die
+	done
+
+	if use doc; then
+		einfo "Compiling javadocs"
+		JAVA_JAR_FILENAME="ignoreme.jar"
+		JAVA_SRC_DIR=()
+		for module in "${ASM_MODULES[@]}"; do
+			rm "$module/src/main/java/module-info.java" || die
+			JAVA_SRC_DIR+=("$module/src/main/java")
+		done
+		java-pkg-simple_src_compile
+	fi
+}
+
+src_install() {
+	local module
+	for module in "${ASM_MODULES[@]}"; do
+		java-pkg_dojar $module.jar
+		if use source; then
+			java-pkg_dosrc "$module/src/main/java/*"
+		fi
+	done
+	if use doc; then
+		java-pkg_dojavadoc target/api
+	fi
+	default
+}
diff --git a/dev-java/asm/metadata.xml b/dev-java/asm/metadata.xml
index 7dc0071e9fc7..7bfaff1ebb0b 100644
--- a/dev-java/asm/metadata.xml
+++ b/dev-java/asm/metadata.xml
@@ -24,7 +24,7 @@
 	possible.
 	</longdescription>
  <upstream>
-  <bugs-to>https://gitlab.ow2.org/asm/asm/issues</bugs-to>
+  <bugs-to>https://gitlab.ow2.org/asm/asm/-/issues</bugs-to>
   <doc>https://asm.ow2.io/documentation.html</doc>
  </upstream>
  <origin>gentoo-staging</origin>