1 files changed, 61 insertions, 0 deletions
diff --git a/dev-cpp/glibmm/glibmm-2.88.1.ebuild b/dev-cpp/glibmm/glibmm-2.88.1.ebuild
new file mode 100644
index 000000000000..9a26cdbf17ef
--- /dev/null
+++ b/dev-cpp/glibmm/glibmm-2.88.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{13..14} )
+inherit flag-o-matic gnome.org meson-multilib python-any-r1
+
+DESCRIPTION="C++ interface for glib2"
+HOMEPAGE="https://gnome.pages.gitlab.gnome.org/glibmm/"
+
+LICENSE="LGPL-2.1+"
+SLOT="2.68"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk-doc debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.87.3:2[${MULTILIB_USEDEP}]
+	dev-libs/libsigc++:3[gtk-doc?,${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-cpp/mm-common
+	virtual/pkgconfig
+	gtk-doc? (
+		app-text/doxygen[dot]
+		dev-lang/perl
+		dev-libs/libxslt
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.88.1-const-whoops.patch
+)
+
+src_prepare() {
+	default
+
+	# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
+	sed -i -e '/giomm_tls_client/d' tests/meson.build || die
+
+	if ! use test; then
+		sed -i -e "/^subdir('tests')/d" meson.build || die
+	fi
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dwarnings=min
+		-Dbuild-deprecated-api=true
+		$(meson_native_use_bool gtk-doc build-documentation)
+		$(meson_use debug debug-refcounting)
+		-Dbuild-examples=false
+		-Dbuild-mmgir=false
+
+		# XXX: Drop this once https://gitlab.gnome.org/GNOME/glibmm/-/merge_requests/77 is in a release
+		-Dmaintainer-mode=true
+	)
+	meson_src_configure
+}