Adding metadata

4 files changed, 0 insertions, 186 deletions

diff --git a/xfce-base/xfce4-session/Manifest b/xfce-base/xfce4-session/Manifest
deleted file mode 100644
index 7834c4d71863..000000000000
--- a/xfce-base/xfce4-session/Manifest
+++ /dev/null
@@ -1,2 +0,0 @@
-DIST xfce4-session-4.20.4.tar.bz2 1233844 BLAKE2B e49787a13f82bc06633fcb4d67c542a9ad48956511e403122bc63220b5bb9eba33eae0fbd0d11c8abb5a4f80cf10c61ffb3d31a5cd6cfd64893cf37540123c1f SHA512 35d5081b6bf36b00a4fa8dcf50417430193c6424034fa21b1bc14003ad925bcc94e2e683c9aa61193a36bc6e50d5fa52b5c4d33abb41bcd259695478509d86d9
-DIST xfce4-session-4.21.1.tar.xz 366692 BLAKE2B aeb180fe82ae0f1b874c64b2e5bbc0cbe45f9b032ab60625faad93bf6ae4e2fdde096e0b17d0689ddbfe81eb09eaa831b10a9971f93935fe137ddb15c91f9c5b SHA512 32e6ada77389849acd705dd319728af523f86ae62c23c8aa72adf48a18f7e61969c5000c772803dfce6ab67e9f10bdc30b3c6f21566370d0a99e44a590cba84a
diff --git a/xfce-base/xfce4-session/metadata.xml b/xfce-base/xfce4-session/metadata.xml
deleted file mode 100644
index 2b8ef06e9a39..000000000000
--- a/xfce-base/xfce4-session/metadata.xml
+++ /dev/null
@@ -1,8 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-  <maintainer type="project">
-    <email>xfce@gentoo.org</email>
-    <name>XFCE Team</name>
-  </maintainer>
-</pkgmetadata>
diff --git a/xfce-base/xfce4-session/xfce4-session-4.20.4.ebuild b/xfce-base/xfce4-session/xfce4-session-4.20.4.ebuild
deleted file mode 100644
index 6a520a765b2e..000000000000
--- a/xfce-base/xfce4-session/xfce4-session-4.20.4.ebuild
+++ /dev/null
@@ -1,90 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit xdg-utils
-
-DESCRIPTION="A session manager for the Xfce desktop environment"
-HOMEPAGE="
-	https://docs.xfce.org/xfce/xfce4-session/start
-	https://gitlab.xfce.org/xfce/xfce4-session
-"
-SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
-IUSE="X nls policykit wayland +xscreensaver"
-REQUIRED_USE="|| ( X wayland )"
-
-DEPEND="
-	>=dev-libs/glib-2.72.0
-	>=x11-libs/gtk+-3.24.0:3[X?,wayland?]
-	>=xfce-base/libxfce4util-4.19.2:=
-	>=xfce-base/libxfce4ui-4.18.4:=
-	>=xfce-base/libxfce4windowing-4.19.2:=
-	>=xfce-base/xfconf-4.18.0:=
-	policykit? ( >=sys-auth/polkit-0.102 )
-	wayland? (
-		>=gui-libs/gtk-layer-shell-0.7.0
-	)
-	X? (
-		>=x11-libs/libICE-1.0.10
-		>=x11-libs/libSM-1.2.3
-		>=x11-libs/libX11-1.6.7
-		>=x11-libs/libwnck-3.10.0:3
-	)
-"
-RDEPEND="
-	${DEPEND}
-	x11-apps/xrdb
-	nls? ( x11-misc/xdg-user-dirs )
-	X? (
-		x11-apps/iceauth
-	)
-	xscreensaver? (
-		|| (
-			xfce-extra/xfce4-screensaver
-			>=x11-misc/xscreensaver-5.26
-			x11-misc/light-locker
-		)
-	)
-"
-BDEPEND="
-	dev-libs/glib
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-"
-
-src_configure() {
-	local myconf=(
-		$(use_enable X x11)
-		$(use_enable policykit polkit)
-		$(use_enable wayland)
-		$(use_enable wayland gtk-layer-shell)
-		--with-xsession-prefix="${EPREFIX}"/usr
-		ICEAUTH="${EPREFIX}"/usr/bin/iceauth
-	)
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	default
-	find "${ED}" -name '*.la' -delete || die
-
-	exeinto /etc/X11/Sessions
-	newexe - Xfce4 <<-EOF
-		startxfce4
-	EOF
-	dosym Xfce4 /etc/X11/Sessions/Xfce
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}
diff --git a/xfce-base/xfce4-session/xfce4-session-4.21.1.ebuild b/xfce-base/xfce4-session/xfce4-session-4.21.1.ebuild
deleted file mode 100644
index 0ad06bf85069..000000000000
--- a/xfce-base/xfce4-session/xfce4-session-4.21.1.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit meson xdg-utils
-
-DESCRIPTION="A session manager for the Xfce desktop environment"
-HOMEPAGE="
-	https://docs.xfce.org/xfce/xfce4-session/start
-	https://gitlab.xfce.org/xfce/xfce4-session
-"
-SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.xz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
-IUSE="X nls policykit wayland +xscreensaver"
-REQUIRED_USE="|| ( X wayland )"
-
-DEPEND="
-	>=dev-libs/glib-2.72.0
-	>=x11-libs/gdk-pixbuf-2.42.8
-	>=x11-libs/gtk+-3.24.0:3[X?,wayland?]
-	>=xfce-base/libxfce4util-4.19.2:=
-	>=xfce-base/libxfce4ui-4.21.0:=
-	>=xfce-base/libxfce4windowing-4.19.2:=
-	>=xfce-base/xfconf-4.18.0:=
-	policykit? ( >=sys-auth/polkit-0.102 )
-	wayland? (
-		>=gui-libs/gtk-layer-shell-0.7.0
-	)
-	X? (
-		x11-apps/iceauth
-		>=x11-libs/libICE-1.0.10
-		>=x11-libs/libSM-1.2.3
-		>=x11-libs/libX11-1.6.7
-		>=x11-libs/libwnck-3.10.0:3
-	)
-"
-RDEPEND="
-	${DEPEND}
-	x11-apps/xrdb
-	nls? ( x11-misc/xdg-user-dirs )
-	xscreensaver? (
-		|| (
-			xfce-extra/xfce4-screensaver
-			>=x11-misc/xscreensaver-5.26
-			x11-misc/light-locker
-		)
-	)
-"
-BDEPEND="
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-"
-
-src_configure() {
-	local emesonargs=(
-		$(meson_feature X x11)
-		$(meson_feature wayland)
-		$(meson_feature wayland gtk-layer-shell)
-		$(meson_feature policykit polkit)
-		-Dxsession-prefix="${EPREFIX}"/usr
-		-Dwayland-session-prefix="${EPREFIX}"/usr
-	)
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	exeinto /etc/X11/Sessions
-	newexe - Xfce4 <<-EOF
-		startxfce4
-	EOF
-	dosym Xfce4 /etc/X11/Sessions/Xfce
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}