Adding metadata

4 files changed, 169 insertions, 0 deletions

diff --git a/x11-misc/autorandr/Manifest b/x11-misc/autorandr/Manifest
new file mode 100644
index 000000000000..ccdf23bfa8df
--- /dev/null
+++ b/x11-misc/autorandr/Manifest
@@ -0,0 +1 @@
+DIST autorandr-1.15.tar.gz 49352 BLAKE2B b7200eb7a77230076f1a9f8b1a21be883ae363cc41cff7f1191e034359cc8ebb52e9dd19dd5f2e415a34b9a3a89fda3d0d43a946b2f3401de0d279fb9d5ba1a2 SHA512 2837348b755f5c4b30ad2b68e191e1969a467401cf32dda495dd19867e391f8b8b4a9c0b4958ef33f75c71aace46686995e27bab805e1e40cc4a1af44e9f0405
diff --git a/x11-misc/autorandr/autorandr-1.15-r2.ebuild b/x11-misc/autorandr/autorandr-1.15-r2.ebuild
new file mode 100644
index 000000000000..438aa99c6a30
--- /dev/null
+++ b/x11-misc/autorandr/autorandr-1.15-r2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 shell-completion systemd udev
+
+if [[ "${PV}" = "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/phillipberndt/${PN}.git"
+else
+	SRC_URI="https://github.com/phillipberndt/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64"
+fi
+
+DESCRIPTION="Automatically select a display configuration based on connected devices"
+HOMEPAGE="https://github.com/phillipberndt/autorandr"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="launcher systemd udev"
+
+RDEPEND="
+	x11-apps/xrandr
+	launcher? ( x11-libs/libxcb )
+	udev? ( virtual/udev )
+"
+DEPEND="${RDEPEND}"
+# desktop-file-util: uses desktop-file-edit in Makefile
+BDEPEND="
+	dev-util/desktop-file-utils
+	virtual/pkgconfig
+"
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if use launcher; then
+		emake contrib/autorandr_launcher/autorandr-launcher
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman autorandr.1
+
+	local targets=(
+		autostart_config
+		bash_completion
+		$(usev launcher)
+		$(usev systemd)
+		$(usev udev)
+	)
+
+	emake DESTDIR="${D}" \
+		  BASH_COMPLETIONS_DIR="$(get_bashcompdir)" \
+		  SYSTEMD_UNIT_DIR=$(usex systemd "$(systemd_get_systemunitdir)" "") \
+		  UDEV_RULES_DIR="$(get_udevdir)"/rules.d \
+		  $(printf "install_%s " "${targets[@]}")
+
+	dozshcomp contrib/zsh_completion/_${PN}
+}
+
+pkg_postinst() {
+	if use udev; then
+		udev_reload
+	fi
+}
+
+pkg_postrm() {
+	if use udev; then
+		udev_reload
+	fi
+}
diff --git a/x11-misc/autorandr/autorandr-9999.ebuild b/x11-misc/autorandr/autorandr-9999.ebuild
new file mode 100644
index 000000000000..c9a767f55a53
--- /dev/null
+++ b/x11-misc/autorandr/autorandr-9999.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 shell-completion systemd udev
+
+if [[ "${PV}" = "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/phillipberndt/${PN}.git"
+else
+	SRC_URI="https://github.com/phillipberndt/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Automatically select a display configuration based on connected devices"
+HOMEPAGE="https://github.com/phillipberndt/autorandr"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="launcher systemd udev"
+
+RDEPEND="
+	x11-apps/xrandr
+	launcher? ( x11-libs/libxcb )
+	udev? ( virtual/udev )
+"
+DEPEND="${RDEPEND}"
+# desktop-file-util: uses desktop-file-edit in Makefile
+BDEPEND="
+	dev-util/desktop-file-utils
+	virtual/pkgconfig
+"
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if use launcher; then
+		emake contrib/autorandr_launcher/autorandr-launcher
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman autorandr.1
+
+	local targets=(
+		autostart_config
+		bash_completion
+		$(usev launcher)
+		$(usev systemd)
+		$(usev udev)
+	)
+
+	emake DESTDIR="${D}" \
+		  BASH_COMPLETIONS_DIR="$(get_bashcompdir)" \
+		  SYSTEMD_UNIT_DIR=$(usex systemd "$(systemd_get_systemunitdir)" "") \
+		  UDEV_RULES_DIR="$(get_udevdir)"/rules.d \
+		  $(printf "install_%s " "${targets[@]}")
+
+	dozshcomp contrib/zsh_completion/_${PN}
+}
+
+pkg_postinst() {
+	if use udev; then
+		udev_reload
+	fi
+}
+
+pkg_postrm() {
+	if use udev; then
+		udev_reload
+	fi
+}
diff --git a/x11-misc/autorandr/metadata.xml b/x11-misc/autorandr/metadata.xml
new file mode 100644
index 000000000000..19f2dc6d246f
--- /dev/null
+++ b/x11-misc/autorandr/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>flow@gentoo.org</email>
+    <name>Florian Schmaus</name>
+  </maintainer>
+  <use>
+    <flag name="launcher">Install the launcher, i.e., an alternative to the udev/systemd hooks</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>