Adding metadata

3 files changed, 1 insertions, 117 deletions

diff --git a/www-servers/h2o/Manifest b/www-servers/h2o/Manifest
index 0e6f9afc2687..6c4cf7d2775b 100644
--- a/www-servers/h2o/Manifest
+++ b/www-servers/h2o/Manifest
@@ -1,2 +1 @@
-DIST h2o-2.3.0_pre20250130.tar.gz 30811885 BLAKE2B e40c59c9fc010412e613bd8059108f88b554131afd64a832c6e2db3ee0a9aa01b14451abee680d91b430a47550f32897dde367b86ee48397029d4b7890258e0e SHA512 3d855ed1571e11fb6b0ed3b0f85cd26a015448347423eb0b994f8803b23c73bf7b773b0d84b6a2b70f08c314496488ad02f358a2269478e86da18fc983c26ae1
 DIST h2o-2.3.0_pre20260415.tar.gz 30867198 BLAKE2B 89c4458c2b3ebebd97b8218bd8786cdd8051a1300090fc6a25cf69c0885004458e76ae6600efd76b993db8eb6716ddddf85668c77788f72e923ae38f00e62d05 SHA512 7dfd7bd381d731d3bc92d75a044bb601ae0d528608f7523a0600d2c472fd01e22c566c4d0e6b1379cb9a81657dba1830edb412f2e5714d32611cd341c590a91a
diff --git a/www-servers/h2o/h2o-2.3.0_pre20250130.ebuild b/www-servers/h2o/h2o-2.3.0_pre20250130.ebuild
deleted file mode 100644
index e0db717df84c..000000000000
--- a/www-servers/h2o/h2o-2.3.0_pre20250130.ebuild
+++ /dev/null
@@ -1,115 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="8"
-SSL_DEPS_SKIP=1
-USE_RUBY="ruby31 ruby32 ruby33"
-
-inherit cmake flag-o-matic ruby-single ssl-cert systemd toolchain-funcs vcs-snapshot
-
-EGIT_COMMIT="26b116e9536be8cf07036185e3edf9d721c9bac2"
-
-DESCRIPTION="H2O - the optimized HTTP/1, HTTP/2 server"
-HOMEPAGE="https://h2o.examp1e.net/"
-SRC_URI="https://github.com/${PN}/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="libh2o +mruby"
-
-RDEPEND="acct-group/h2o
-	acct-user/h2o
-	dev-lang/perl
-	dev-libs/openssl:0=
-	!sci-libs/libh2o
-	sys-libs/libcap
-	virtual/zlib:=
-	libh2o? (
-		app-arch/brotli
-		dev-libs/libuv
-	)"
-DEPEND="${RDEPEND}
-	mruby? (
-		${RUBY_DEPS}
-		|| (
-			dev-libs/onigmo
-			dev-libs/oniguruma
-		)
-	)"
-BDEPEND="virtual/pkgconfig
-	mruby? ( app-alternatives/yacc )"
-
-PATCHES=( "${FILESDIR}"/${PN}-2.3-mruby.patch )
-
-src_prepare() {
-	cmake_src_prepare
-
-	local ruby="ruby"
-	if use mruby; then
-		for ruby in ${RUBY_TARGETS_PREFERENCE}; do
-			if has_version dev-lang/ruby:${ruby:4:1}.${ruby:5}; then
-				break
-			fi
-			ruby=
-		done
-		[[ -z ${ruby} ]] && die "no suitable ruby version found"
-	fi
-
-	sed -i \
-		-e "/INSTALL/s:\(/doc/${PN}\) :\1/html :" \
-		-e "/INSTALL/s:\(/doc\)/${PN}:\1/${PF}:" \
-		-e "s: ruby: ${ruby}:" \
-		CMakeLists.txt
-
-	sed -i "s:pkg-config:$(tc-getPKG_CONFIG):g" deps/mruby/lib/mruby/gem.rb
-	tc-export CC
-	export LD="$(tc-getCC)"
-}
-
-src_configure() {
-	if use libh2o; then
-		# -Werror=strict-aliasing
-		# https://bugs.gentoo.org/967654
-		# https://github.com/h2o/h2o/issues/3541
-		#
-		# Fixed upstream in git, post 2.3.0-beta2
-		append-flags -fno-strict-aliasing
-		filter-lto
-	fi
-
-	local mycmakeargs=(
-		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc/${PN}
-		-DWITH_CCACHE=OFF
-		-DWITH_MRUBY=$(usex mruby)
-		-DWITHOUT_LIBS=$(usex !libh2o)
-		-DBUILD_SHARED_LIBS=$(usex libh2o)
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	keepdir /var/www/localhost/htdocs
-
-	insinto /etc/${PN}
-	doins "${FILESDIR}"/${PN}.conf
-
-	newinitd "${FILESDIR}"/${PN}.initd ${PN}
-	systemd_dounit "${FILESDIR}"/${PN}.service
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}"/${PN}.logrotate ${PN}
-
-	keepdir /var/log/${PN}
-	fowners ${PN}:${PN} /var/log/${PN}
-	fperms 0750 /var/log/${PN}
-}
-
-pkg_postinst() {
-	if [[ ! -f "${EROOT}"/etc/ssl/${PN}/server.key ]]; then
-		install_cert /etc/ssl/${PN}/server
-		chown ${PN}:${PN} "${EROOT}"/etc/ssl/${PN}/server.*
-	fi
-}
diff --git a/www-servers/h2o/h2o-2.3.0_pre20260415.ebuild b/www-servers/h2o/h2o-2.3.0_pre20260415.ebuild
index c9c1e0d43938..739d2ab23f8d 100644
--- a/www-servers/h2o/h2o-2.3.0_pre20260415.ebuild
+++ b/www-servers/h2o/h2o-2.3.0_pre20260415.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/${PN}/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.ta
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="libh2o +mruby"
 
 RDEPEND="acct-group/h2o