Adding metadata

8 files changed, 256 insertions, 125 deletions

diff --git a/sys-power/switcheroo-control/Manifest b/sys-power/switcheroo-control/Manifest
index c1a9404763de..7b9e560cf9b5 100644
--- a/sys-power/switcheroo-control/Manifest
+++ b/sys-power/switcheroo-control/Manifest
@@ -1,2 +1 @@
-DIST switcheroo-control-2.6.tar.xz 29996 BLAKE2B 98204a1d0f3b92cc2b98ad9f382313aed4da5877ac6be607c48ee9386bd25087301e249907a7e1385eea357f0a3ce5fb2936fac688923dfa3555a9870f0d2e58 SHA512 ac8867a839ae958676f5c5c7bb4c25cbbcf70eb35a696bb3d80b388c31a9722e75311c041c4c60b8f1d00f405af97dd9173e99780a2be3c621ac759c4986a2d2
 DIST switcheroo-control-3.0.tar.xz 33380 BLAKE2B 3d69968383b34f624ec0068bd986cb2b0be408d5617af350b128c0583511e3bfe7618e49826308ef87ef19b6cf681c41e786d9ab5fdd3cd1b868be5dd409ee18 SHA512 f2b3df3f0254a13f2e046269b612f90d15c4f6ce22f9e6463b156a03de271d30519fed9002f7faae76ca84a5e6001550d8003901d5a228694375ae56a640ad61
diff --git a/sys-power/switcheroo-control/switcheroo-control-2.6-r2.ebuild b/sys-power/switcheroo-control/switcheroo-control-2.6-r2.ebuild
deleted file mode 100644
index a4f11cca3116..000000000000
--- a/sys-power/switcheroo-control/switcheroo-control-2.6-r2.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 2021-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit meson python-single-r1 systemd
-
-DESCRIPTION="D-Bus service to check the availability of dual-GPU"
-HOMEPAGE="https://gitlab.freedesktop.org/hadess/switcheroo-control/"
-SRC_URI="https://gitlab.freedesktop.org/hadess/switcheroo-control/uploads/86ea54ac7ddb901b6bf6e915209151f8/${P}.tar.xz"
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="gtk-doc selinux test"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv x86"
-
-RDEPEND="${PYTHON_DEPS}
-	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
-	>=dev-libs/glib-2.56.0:2
-	>=dev-libs/libgudev-232:=
-	selinux? ( sec-policy/selinux-switcheroo )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
-	>=dev-util/gdbus-codegen-2.80.5-r1
-	gtk-doc? ( dev-util/gtk-doc )
-	test? (
-		$(python_gen_cond_dep 'dev-python/python-dbusmock[${PYTHON_USEDEP}]')
-		dev-util/umockdev
-	)
-"
-
-RESTRICT="!test? ( test )"
-
-python_check_deps() {
-	if use test; then
-		python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]" &&
-		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
-	else
-		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
-	fi
-}
-
-src_configure() {
-	local emesonargs=(
-		-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
-		$(meson_use gtk-doc gtk_doc)
-		$(meson_use test tests)
-	)
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-	python_fix_shebang "${ED}"/usr/bin/switcherooctl
-	newinitd "${FILESDIR}"/${PN}-init.d ${PN}
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		elog "You need to enable the service:"
-		if systemd_is_booted; then
-			elog "# systemctl enable ${PN}"
-		else
-			elog "# rc-update add ${PN} default"
-		fi
-	fi
-}
diff --git a/sys-power/switcheroo-control/switcheroo-control-3.0.ebuild b/sys-power/switcheroo-control/switcheroo-control-3.0.ebuild
index b63f23410669..b03d1f74727d 100644
--- a/sys-power/switcheroo-control/switcheroo-control-3.0.ebuild
+++ b/sys-power/switcheroo-control/switcheroo-control-3.0.ebuild
@@ -59,6 +59,8 @@ src_configure() {
 		-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
 		$(meson_use gtk-doc gtk_doc)
 		$(meson_use test tests)
+		$(meson_feature video_cards_amdgpu libdrm_amdgpu)
+		$(meson_feature video_cards_nouveau libdrm_nouveau)
 	)
 	meson_src_configure
 }
diff --git a/sys-power/thermald/thermald-2.5.11.ebuild b/sys-power/thermald/thermald-2.5.11.ebuild
index 582ca1a3ca74..450ab7970306 100644
--- a/sys-power/thermald/thermald-2.5.11.ebuild
+++ b/sys-power/thermald/thermald-2.5.11.ebuild
@@ -12,7 +12,7 @@ S=${WORKDIR}/thermal_daemon-${PV}
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 RDEPEND="
 	dev-libs/glib:=
diff --git a/sys-power/tlp/Manifest b/sys-power/tlp/Manifest
index 99e73e53b141..60129fc86464 100644
--- a/sys-power/tlp/Manifest
+++ b/sys-power/tlp/Manifest
@@ -1,2 +1,2 @@
-DIST tlp-1.8.0.tar.gz 172154 BLAKE2B 843951699bab3237e3f3869393fe9890088da950101c13351e175287734871e1a72e368264b775a3f1c128fe8ae3225db1e4b6fac9fb72260a59a02028f48647 SHA512 d1c133faf2c7870b66a363ff84e5e0fafc6be2e36b5440336e3f4c45e68a9a8b7524f697af7a509cf724e21c3a43f976f9814e627531148e9ddaff267564d3c7
+DIST tlp-1.10.1.tar.gz 217945 BLAKE2B 604ab1e5ef99ca944511be47b4999eb1b4efc40e04520632f3a07eb2547cd2a9d7f833211d35641bf1506f3e70d1245616bb59af71d65e4f0f399ac7181cc7fa SHA512 ee3ae1d32fe436c25f8a9a4fe14d049989708faf72318c01f651c7245f6bfd62b86c3f149ca236871bb7a1182728cc859188ddc0a798601db1543e99f709850e
 DIST tlp-1.9.1.tar.gz 210993 BLAKE2B b6ab4a81852ace750cd6ef49b1fb595b85a9f9cafcf8da3f79dfbc0cbe09af62da9a1777e3b70ac03695a59cd45369ca11c1aa00e3a824a92683b5e652df4633 SHA512 9abb0e3fdfc99de0f3c11ee473064663d9baedb1181d2c13c7dd58362c8bbb269108157600f1f674aeb49cf9776cfdf366352cb59ac649e5093e2b843f88debf
diff --git a/sys-power/tlp/tlp-1.10.1.ebuild b/sys-power/tlp/tlp-1.10.1.ebuild
new file mode 100644
index 000000000000..57f63952f238
--- /dev/null
+++ b/sys-power/tlp/tlp-1.10.1.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit udev optfeature python-single-r1
+
+DESCRIPTION="Optimize laptop battery life"
+HOMEPAGE="https://linrunner.de/tlp/"
+SRC_URI="https://github.com/linrunner/TLP/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/TLP-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+REQUIRED_USE="ppd? ( ${PYTHON_REQUIRED_USE} )"
+
+IUSE="
+	+ppd
+	+rdw
+"
+
+# NOTE(JayF): Upstream dep list in human-readable format:
+#             https://linrunner.de/tlp/developers/dependencies.html
+# NOTE(JayF): Blockers for these are not ideal, however all three
+#             of these packages implement the same service on dbus
+#             and have conflicting files as a result. Long-term
+#             there likely needs to be a better solution. See
+#             https://bugs.gentoo.org/967823.
+RDEPEND="
+	dev-lang/perl
+	net-wireless/iw
+	sys-apps/hdparm
+	sys-apps/pciutils
+	sys-apps/usbutils
+	virtual/udev
+	ppd? (
+		!sys-apps/tuned[ppd]
+		!sys-power/power-profiles-daemon
+		$(python_gen_cond_dep 'dev-python/dbus-python[${PYTHON_USEDEP}]')
+		$(python_gen_cond_dep 'dev-python/pygobject[${PYTHON_USEDEP}]')
+		${PYTHON_DEPS}
+	)
+	rdw? ( net-misc/networkmanager )
+"
+DEPEND="${RDEPEND}"
+DOCS=( changelog README.rst )
+
+src_prepare() {
+	# Add support for a PREFIX variable in the Makefile
+	sed -e '/^TLP_[A-Z_]\+ \+?= \//s|/|$(TLP_PREFIX)/|' \
+		-i Makefile || die
+
+	default
+}
+
+src_compile() {
+	# NOTE(JayF): TLP_WITH_ELOGIND/TLP_WITH_SYSTEMD are both only installing
+	#             small init/config files.
+	EMAKEARGS=(
+		TLP_PREFIX="${EPREFIX}"
+		TLP_ULIB="${EPREFIX}$(get_udevdir)"
+		TLP_NO_INIT=1
+		TLP_WITH_ELOGIND=1
+		TLP_WITH_SYSTEMD=1
+	)
+
+	emake "${EMAKEARGS[@]}"
+}
+
+src_install() {
+	local myemakeargs=(
+		"${EMAKEARGS[@]}"
+		DESTDIR="${D}"
+		install-tlp install-man-tlp
+	)
+
+	use ppd && myemakeargs+=(
+		install-pd
+		install-man-pd
+	)
+
+	use rdw && myemakeargs+=(
+		install-rdw
+		install-man-rdw
+	)
+
+	emake "${myemakeargs[@]}"
+
+	fperms 444 /usr/share/tlp/defaults.conf # manpage says this file should not be edited
+	newinitd "${FILESDIR}/tlp.init" tlp
+	newinitd "${FILESDIR}/tlp-pd.init" tlp-pd
+	keepdir /var/lib/tlp # created by Makefile, probably important
+	einstalldocs
+}
+
+pkg_postinst() {
+	udev_reload
+
+	optfeature "disable Wake-on-LAN" sys-apps/ethtool
+	optfeature "see disk drive health info in tlp-stat" sys-apps/smartmontools
+	optfeature "Sleep hooks" sys-auth/elogind sys-apps/systemd
+	optfeature "Battery functions for ThinkPads prior to the Sandy Bridge generation (2011)" app-laptop/tp_smapi
+
+	if has_version "sys-apps/tuned"; then
+		ewarn
+		ewarn "sys-apps/tuned is installed, but is "
+		ewarn "documented by upstream sys-power/tlp to be conficting. "
+		ewarn "For best results, uninstall one of these packages."
+		ewarn
+	fi
+
+	if has_version "app-laptop/laptop-mode-tools"; then
+		ewarn
+		ewarn "app-laptop/laptop-mode-tools is installed, but is "
+		ewarn "documented by upstream sys-power/tlp to be conficting. "
+		ewarn "For best results, uninstall one of these packages."
+		ewarn
+	fi
+}
+
+pkg_postrm() {
+	udev_reload
+}
diff --git a/sys-power/tlp/tlp-1.8.0-r1.ebuild b/sys-power/tlp/tlp-1.8.0-r1.ebuild
deleted file mode 100644
index 4c3ac97819fc..000000000000
--- a/sys-power/tlp/tlp-1.8.0-r1.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit udev optfeature
-
-DESCRIPTION="Optimize laptop battery life"
-HOMEPAGE="https://linrunner.de/tlp/"
-SRC_URI="https://github.com/linrunner/TLP/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/TLP-${PV}"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64"
-
-RDEPEND="
-	dev-lang/perl
-	virtual/udev
-"
-
-src_install() {
-	# NOTE(JayF): TLP_WITH_ELOGIND/TLP_WITH_SYSTEMD are both only installing
-	#             small init/config files.
-	local myemakeargs=(
-		DESTDIR="${D}"
-		TLP_NO_INIT=1
-		TLP_ELOD=/usr/lib/elogind/system-sleep
-		TLP_WITH_ELOGIND=1
-		TLP_WITH_SYSTEMD=1
-		install install-man
-	)
-	emake "${myemakeargs[@]}"
-
-	fperms 444 /usr/share/tlp/defaults.conf # manpage says this file should not be edited
-	newinitd "${FILESDIR}/tlp.init" tlp
-	keepdir /var/lib/tlp # created by Makefile, probably important
-}
-
-pkg_postinst() {
-	udev_reload
-
-	optfeature "disable Wake-on-LAN" sys-apps/ethtool
-	optfeature "see disk drive health info in tlp-stat" sys-apps/smartmontools
-	optfeature "Sleep hooks" sys-auth/elogind sys-apps/systemd
-}
-
-pkg_postrm() {
-	udev_reload
-}
diff --git a/sys-power/tlp/tlp-1.9.1-r1.ebuild b/sys-power/tlp/tlp-1.9.1-r1.ebuild
new file mode 100644
index 000000000000..57f63952f238
--- /dev/null
+++ b/sys-power/tlp/tlp-1.9.1-r1.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit udev optfeature python-single-r1
+
+DESCRIPTION="Optimize laptop battery life"
+HOMEPAGE="https://linrunner.de/tlp/"
+SRC_URI="https://github.com/linrunner/TLP/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/TLP-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+REQUIRED_USE="ppd? ( ${PYTHON_REQUIRED_USE} )"
+
+IUSE="
+	+ppd
+	+rdw
+"
+
+# NOTE(JayF): Upstream dep list in human-readable format:
+#             https://linrunner.de/tlp/developers/dependencies.html
+# NOTE(JayF): Blockers for these are not ideal, however all three
+#             of these packages implement the same service on dbus
+#             and have conflicting files as a result. Long-term
+#             there likely needs to be a better solution. See
+#             https://bugs.gentoo.org/967823.
+RDEPEND="
+	dev-lang/perl
+	net-wireless/iw
+	sys-apps/hdparm
+	sys-apps/pciutils
+	sys-apps/usbutils
+	virtual/udev
+	ppd? (
+		!sys-apps/tuned[ppd]
+		!sys-power/power-profiles-daemon
+		$(python_gen_cond_dep 'dev-python/dbus-python[${PYTHON_USEDEP}]')
+		$(python_gen_cond_dep 'dev-python/pygobject[${PYTHON_USEDEP}]')
+		${PYTHON_DEPS}
+	)
+	rdw? ( net-misc/networkmanager )
+"
+DEPEND="${RDEPEND}"
+DOCS=( changelog README.rst )
+
+src_prepare() {
+	# Add support for a PREFIX variable in the Makefile
+	sed -e '/^TLP_[A-Z_]\+ \+?= \//s|/|$(TLP_PREFIX)/|' \
+		-i Makefile || die
+
+	default
+}
+
+src_compile() {
+	# NOTE(JayF): TLP_WITH_ELOGIND/TLP_WITH_SYSTEMD are both only installing
+	#             small init/config files.
+	EMAKEARGS=(
+		TLP_PREFIX="${EPREFIX}"
+		TLP_ULIB="${EPREFIX}$(get_udevdir)"
+		TLP_NO_INIT=1
+		TLP_WITH_ELOGIND=1
+		TLP_WITH_SYSTEMD=1
+	)
+
+	emake "${EMAKEARGS[@]}"
+}
+
+src_install() {
+	local myemakeargs=(
+		"${EMAKEARGS[@]}"
+		DESTDIR="${D}"
+		install-tlp install-man-tlp
+	)
+
+	use ppd && myemakeargs+=(
+		install-pd
+		install-man-pd
+	)
+
+	use rdw && myemakeargs+=(
+		install-rdw
+		install-man-rdw
+	)
+
+	emake "${myemakeargs[@]}"
+
+	fperms 444 /usr/share/tlp/defaults.conf # manpage says this file should not be edited
+	newinitd "${FILESDIR}/tlp.init" tlp
+	newinitd "${FILESDIR}/tlp-pd.init" tlp-pd
+	keepdir /var/lib/tlp # created by Makefile, probably important
+	einstalldocs
+}
+
+pkg_postinst() {
+	udev_reload
+
+	optfeature "disable Wake-on-LAN" sys-apps/ethtool
+	optfeature "see disk drive health info in tlp-stat" sys-apps/smartmontools
+	optfeature "Sleep hooks" sys-auth/elogind sys-apps/systemd
+	optfeature "Battery functions for ThinkPads prior to the Sandy Bridge generation (2011)" app-laptop/tp_smapi
+
+	if has_version "sys-apps/tuned"; then
+		ewarn
+		ewarn "sys-apps/tuned is installed, but is "
+		ewarn "documented by upstream sys-power/tlp to be conficting. "
+		ewarn "For best results, uninstall one of these packages."
+		ewarn
+	fi
+
+	if has_version "app-laptop/laptop-mode-tools"; then
+		ewarn
+		ewarn "app-laptop/laptop-mode-tools is installed, but is "
+		ewarn "documented by upstream sys-power/tlp to be conficting. "
+		ewarn "For best results, uninstall one of these packages."
+		ewarn
+	fi
+}
+
+pkg_postrm() {
+	udev_reload
+}