Checkpoint dirty output before beosrepo update

2 files changed, 125 insertions, 0 deletions

diff --git a/sys-block/hpssacli/hpssacli-2.40.13.0-r2.ebuild b/sys-block/hpssacli/hpssacli-2.40.13.0-r2.ebuild
new file mode 100644
index 000000000000..b52f1d77c8a2
--- /dev/null
+++ b/sys-block/hpssacli/hpssacli-2.40.13.0-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pax-utils rpm
+
+MY_PV=$(ver_rs 2 '-')
+
+DESCRIPTION="HPE Smart Storage Administrator (HPE SSA) CLI (HPSSACLI, formerly HPACUCLI)"
+HOMEPAGE="http://h20564.www2.hpe.com/hpsc/swd/public/detail?swItemId=MTX_04bffb688a73438598fef81ddd"
+SRC_URI="
+	amd64? ( https://downloads.linux.hpe.com/SDR/repo/spp/RHEL/6/x86_64/current/${PN}-${MY_PV}.x86_64.rpm )
+	x86? ( https://downloads.linux.hpe.com/SDR/repo/spp/RHEL/6/i686/current/${PN}-${MY_PV}.i386.rpm )"
+
+LICENSE="hpe"
+SLOT="0"
+KEYWORDS="-* amd64 x86"
+RESTRICT="mirror bindist"
+
+RDEPEND="elibc_glibc? ( >sys-libs/glibc-2.14 )
+	>=sys-libs/libunwind-0.99
+	>=sys-process/procps-3.3.6"
+
+DOCS=( license.txt readme.txt )
+
+MY_HPSSACLI_BASEDIR="/opt/hp/hpssacli"
+
+QA_PREBUILT="${MY_HPSSACLI_BASEDIR:1}/hpssa*.bin"
+QA_EXECSTACK="${MY_HPSSACLI_BASEDIR:1}/hpssa*.bin"
+
+src_unpack() {
+	rpm_src_unpack
+
+	mkdir "${S}" || die "Failed to create '${S}'"
+}
+
+src_prepare() {
+	default
+
+	# Create a clean $S
+	mv "${WORKDIR}"/opt/hp/hpssacli/bld/hpss* "${S}" || die "Failed to to copy 'hpss*' related files"
+	mv "${S}"/hpssacli.license "${S}"/license.txt || die "Renaming hpssacli.license failed!"
+	mv "${S}"/hpssacli*.txt "${S}"/readme.txt || die "Renaming hpssacli*.txt failed!"
+	rm -rf "${WORKDIR}"/opt || die "Failed to cleanup '${WORKDIR}/opt'"
+	rm -rf "${WORKDIR}"/usr || die "Failed to cleanup '${WORKDIR}/usr'"
+}
+
+src_install() {
+	newsbin "${FILESDIR}"/"${PN}-wrapper" ${PN}
+	dosym ${PN} /usr/sbin/hpssascripting
+
+	exeinto "${MY_HPSSACLI_BASEDIR}"
+	for bin in "${S}"/hpssa{cli,scripting}; do
+		local basename=$(basename "${bin}")
+		newexe "${bin}" ${basename}.bin
+	done
+
+	dodoc "${DOCS[@]}"
+
+	pax-mark m "${D}${HPSSACLI_BASEDIR}"/*.bin
+}
diff --git a/sys-block/hpssacli/hpssacli-3.40.3.0-r1.ebuild b/sys-block/hpssacli/hpssacli-3.40.3.0-r1.ebuild
new file mode 100644
index 000000000000..1ec8e9744d5c
--- /dev/null
+++ b/sys-block/hpssacli/hpssacli-3.40.3.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pax-utils rpm
+
+MY_PV=$(ver_rs 2 '-')
+
+DESCRIPTION="HPE Smart Storage Administrator (HPE SSA) CLI (HPSSACLI, formerly HPACUCLI)"
+HOMEPAGE="https://support.hpe.com/hpsc/swd/public/detail?swItemId=MTX_688838b13b194c7abe1aa98584"
+SRC_URI="https://downloads.linux.hpe.com/SDR/repo/spp/2019.03.0/packages/ssacli-${MY_PV}.x86_64.rpm"
+
+LICENSE="hpe"
+SLOT="0"
+KEYWORDS="-* amd64"
+RESTRICT="mirror bindist"
+
+RDEPEND="
+	elibc_glibc? ( sys-libs/glibc )
+	sys-libs/libunwind
+	sys-process/procps"
+
+DOCS=( license.txt readme.txt )
+
+MY_HPSSACLI_BASEDIR="/opt/hp/hpssacli"
+
+QA_PREBUILT="${MY_HPSSACLI_BASEDIR:1}/hpssa*.bin"
+QA_EXECSTACK="${MY_HPSSACLI_BASEDIR:1}/hpssa*.bin"
+
+src_unpack() {
+	rpm_src_unpack
+
+	mkdir "${S}" || die "Failed to create '${S}'"
+}
+
+src_prepare() {
+	default
+
+	# Create a clean $S
+	mv "${WORKDIR}"/opt/smartstorageadmin/ssacli/bin/ssa* "${S}" || die "Failed to to copy 'ssa*' related files"
+	mv "${S}"/ssacli "${S}"/hpssacli || die "Renaming ssacli failed!"
+	mv "${S}"/ssascripting "${S}"/hpssascripting || die "Renaming ssascripting failed!"
+	mv "${S}"/ssacli.license "${S}"/license.txt || die "Renaming ssacli.license failed!"
+	mv "${S}"/ssacli*.txt "${S}"/readme.txt || die "Renaming ssacli*.txt failed!"
+	rm -r "${WORKDIR}"/opt || die "Failed to cleanup '${WORKDIR}/opt'"
+	rm -r "${WORKDIR}"/usr || die "Failed to cleanup '${WORKDIR}/usr'"
+}
+
+src_install() {
+	newsbin "${FILESDIR}"/"${PN}-wrapper" ${PN}
+	dosym ${PN} /usr/sbin/hpssascripting
+
+	exeinto "${MY_HPSSACLI_BASEDIR}"
+	for bin in "${S}"/hpssa{cli,scripting}; do
+		local basename=$(basename "${bin}")
+		newexe "${bin}" ${basename}.bin
+	done
+
+	dodoc "${DOCS[@]}"
+
+	pax-mark m "${D}${HPSSACLI_BASEDIR}"/*.bin
+}