Adding metadata

5 files changed, 0 insertions, 417 deletions

diff --git a/net-print/cups-pdf/Manifest b/net-print/cups-pdf/Manifest
index 274bac244452..f0271ef19341 100644
--- a/net-print/cups-pdf/Manifest
+++ b/net-print/cups-pdf/Manifest
@@ -1,3 +1 @@
-DIST cups-pdf_3.0.1.tar.gz 29754 BLAKE2B f964358c5e465447e703848a697f6c801624a1836e2a0a4026c507c66048cf4bef92327508598ec7e9a356d4f57894a6b610e55b7a9a34e942cf2b88c6c55b85 SHA512 a06580f3056dddbb883c8db0c71b37b883482ae1ac8aa9bcfd85e679c4dcb44278006b7110d2988173d0eeb05b0f19fb39081fad49bf26839235e97fbe27a818
-DIST cups-pdf_3.0.2.tar.gz 32776 BLAKE2B b5a869571cda9197f67ad3a59292c4680c629c91b0440ef5042705751826f7b9877aaccc33d555a85ce225d25d66f6f806473c856621f78e5b6afe9ad496c084 SHA512 e400a12da4b6cdfd9e77bf03e3a4e87f3512a01e5272d94e58ddf51b3cab54d8978c43c8bfd9490e4c7456523662df522ef783aa723332d32b657b6448320618
 DIST cups-pdf_3.0.3.tar.gz 36473 BLAKE2B 211da7231e55da2c60cd9032e486d4c2a12a19a2a49dc5c62ee54a36b614680de91d4d6a20ebec15c90ce31673f3a19dccadb47dd6d99d0e3c56e6e78f177cb9 SHA512 1005ff656d6465db73998dde0bff913249f90b944a2e762a98c5d2b66c1c0d1d0f03060f38199327a9c1a1408453ee764a0d54d71bdcb353b9dfb8a3911c7816
diff --git a/net-print/cups-pdf/cups-pdf-3.0.1-r3.ebuild b/net-print/cups-pdf/cups-pdf-3.0.1-r3.ebuild
deleted file mode 100644
index ed52b55cd752..000000000000
--- a/net-print/cups-pdf/cups-pdf-3.0.1-r3.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit toolchain-funcs
-
-DESCRIPTION="Provides a virtual printer for CUPS to produce PDF files"
-HOMEPAGE="https://www.cups-pdf.de/"
-SRC_URI="https://www.cups-pdf.de/src/${PN}_${PV/_}.tar.gz"
-S=${WORKDIR}/${PN}-${PV/_}
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ppc ~ppc64 x86"
-IUSE="+ppds"
-
-DEPEND="net-print/cups"
-RDEPEND="${DEPEND}
-	>=app-text/ghostscript-gpl-9.54"
-
-PATCHES=( "${FILESDIR}"/${PN}-3.0.1-ghostscript-gpl-9.54-compat.patch )
-
-src_configure() {
-	tc-export CC
-}
-
-src_compile() {
-	LDLIBS="-lcups" emake -C src ${PN}
-}
-
-src_install() {
-	exeinto /usr/libexec/cups/backend
-	exeopts -m0700
-	doexe src/cups-pdf
-
-	insinto /etc/cups
-	doins extra/cups-pdf.conf
-
-	insinto /usr/share/cups/model
-	if use ppds; then
-		doins extra/CUPS-PDF_opt.ppd
-	else
-		doins extra/CUPS-PDF_noopt.ppd
-	fi
-
-	einstalldocs
-}
diff --git a/net-print/cups-pdf/cups-pdf-3.0.2.ebuild b/net-print/cups-pdf/cups-pdf-3.0.2.ebuild
deleted file mode 100644
index 82c73b273003..000000000000
--- a/net-print/cups-pdf/cups-pdf-3.0.2.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit toolchain-funcs
-
-DESCRIPTION="Provides a virtual printer for CUPS to produce PDF files"
-HOMEPAGE="https://www.cups-pdf.de/"
-SRC_URI="https://www.cups-pdf.de/src/${PN}_${PV/_}.tar.gz"
-S=${WORKDIR}/${PN}-${PV/_}
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ppc ~ppc64 x86"
-IUSE="+ppds"
-
-DEPEND="net-print/cups"
-RDEPEND="
-	${DEPEND}
-	>=app-text/ghostscript-gpl-9.54
-"
-
-src_configure() {
-	tc-export CC
-}
-
-src_compile() {
-	LDLIBS="-lcups" emake -C src ${PN}
-}
-
-src_install() {
-	exeinto /usr/libexec/cups/backend
-	exeopts -m0700
-	doexe src/cups-pdf
-
-	insinto /etc/cups
-	doins extra/cups-pdf.conf
-
-	insinto /usr/share/cups/model
-	if use ppds; then
-		doins extra/CUPS-PDF_opt.ppd
-	else
-		doins extra/CUPS-PDF_noopt.ppd
-	fi
-
-	einstalldocs
-}
diff --git a/net-print/cups/Manifest b/net-print/cups/Manifest
index a25585d7ac5e..132feaf14a79 100644
--- a/net-print/cups/Manifest
+++ b/net-print/cups/Manifest
@@ -1,2 +1 @@
-DIST cups-2.4.16-source.tar.gz 8159166 BLAKE2B db7e9ea3c14794e54b92b18fcb8eb4a9b643ae9a77da864b2858fa0a72439c84be5484515b51b1c43f0a486e2b91a8565b7b835badcce9caef198fbdd3a0e0f8 SHA512 ee0d2afdba7b713c8249912dd738c4fa87efb6f7cdb0a48a48be299d03ae4b1a02773418d6ffc4f7c5731bbae2c859bcc39695f9b93cc422ec6124b7ba179734
 DIST cups-2.4.19-source.tar.gz 7950335 BLAKE2B 6c6a4c5b15e1ed4ae10abb21c9f4c6a4820df3f2289b478510579a455d3ceb82c6bac850765f05d6671588fdbfed1942e6e84e9a12c4547daa89a740bf3c3419 SHA512 3d7f7bd448afc54011e98cc3f6a6cfe704bdae58a1e0cdde19f95ed0b4956b518c6e0a64277c99daa38b26d3ddf23033a4135cc21c3e5d7602731789024fa287
diff --git a/net-print/cups/cups-2.4.16.ebuild b/net-print/cups/cups-2.4.16.ebuild
deleted file mode 100644
index d62e2a09231e..000000000000
--- a/net-print/cups/cups-2.4.16.ebuild
+++ /dev/null
@@ -1,318 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools eapi9-ver linux-info xdg multilib-minimal optfeature pam toolchain-funcs
-
-MY_PV="${PV/_beta/b}"
-MY_PV="${MY_PV/_rc/rc}"
-MY_PV="${MY_PV/_p/op}"
-MY_P="${PN}-${MY_PV}"
-
-if [[ ${PV} == *9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/OpenPrinting/cups.git"
-	[[ ${PV} != 9999 ]] && EGIT_BRANCH=branch-${PV/.9999}
-else
-	SRC_URI="https://github.com/OpenPrinting/cups/releases/download/v${MY_PV}/cups-${MY_PV}-source.tar.gz"
-	if [[ ${PV} != *_beta* && ${PV} != *_rc* ]] ; then
-		KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
-	fi
-fi
-
-DESCRIPTION="The Common Unix Printing System"
-HOMEPAGE="https://www.cups.org/ https://github.com/OpenPrinting/cups"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-IUSE="acl dbus debug kerberos openssl pam selinux static-libs systemd test usb X xinetd zeroconf"
-
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	acct-group/lp
-	acct-group/lpadmin
-	virtual/pkgconfig
-"
-COMMON_DEPEND="
-	app-text/libpaper:=
-	virtual/zlib:=
-	acl? (
-		kernel_linux? (
-			sys-apps/acl
-		)
-	)
-	dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
-	kerberos? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
-	pam? ( sys-libs/pam )
-	!pam? ( virtual/libcrypt:= )
-	!openssl? ( >=net-libs/gnutls-2.12.23-r6:=[${MULTILIB_USEDEP}] )
-	openssl? ( dev-libs/openssl:=[${MULTILIB_USEDEP}] )
-	systemd? ( sys-apps/systemd )
-	usb? ( virtual/libusb:1 )
-	X? ( x11-misc/xdg-utils )
-	xinetd? ( sys-apps/xinetd )
-	zeroconf? ( >=net-dns/avahi-0.6.31-r2[dbus,${MULTILIB_USEDEP}] )
-"
-# if libcupsfilters is installed, more tests are run. They fail without at least one of the two formats enabled.
-DEPEND="
-	${COMMON_DEPEND}
-	test? ( || ( net-print/libcupsfilters[jpeg] net-print/libcupsfilters[png] ) )
-"
-RDEPEND="
-	${COMMON_DEPEND}
-	acct-group/lp
-	acct-group/lpadmin
-	selinux? ( sec-policy/selinux-cups )
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.4.1-nostrip.patch"
-	"${FILESDIR}/${PN}-2.4.1-user-AR.patch"
-)
-
-MULTILIB_CHOST_TOOLS=(
-	/usr/bin/cups-config
-)
-
-pkg_setup() {
-	if use kernel_linux; then
-		linux-info_pkg_setup
-		if  ! linux_config_exists; then
-			ewarn "Can't check the linux kernel configuration."
-			ewarn "You might have some incompatible options enabled."
-		else
-			# Recheck that we don't have usblp to collide with libusb; this should now work in most cases (bug #501122)
-			if use usb; then
-				if linux_chkconfig_present USB_PRINTER; then
-					elog "Your USB printers will be managed via libusb. In case you run into problems, "
-					elog "please try disabling USB_PRINTER support in your kernel or blacklisting the"
-					elog "usblp kernel module."
-					elog "Alternatively, just disable the usb useflag for cups (your printer will still work)."
-				fi
-			else
-				if ! linux_chkconfig_present USB_PRINTER; then
-					ewarn "If you plan to use USB printers you should enable the USB_PRINTER"
-					ewarn "support in your kernel."
-					ewarn "Please enable it:"
-					ewarn "    CONFIG_USB_PRINTER=y"
-					ewarn "in /usr/src/linux/.config or"
-					ewarn "    Device Drivers --->"
-					ewarn "        USB support  --->"
-					ewarn "            [*] USB Printer support"
-					ewarn "Alternatively, enable the usb useflag for cups and use the libusb code."
-				fi
-			fi
-		fi
-	fi
-}
-
-src_prepare() {
-	default
-
-	# Remove ".SILENT" rule for verbose output (bug #524338).
-	sed 's#^.SILENT:##g' -i Makedefs.in || die
-
-	# Remove redefinition of _FORTIFY_SOURCE (bug #907683)
-	sed 's#-D_FORTIFY_SOURCE=3##g' -i config-scripts/cups-compiler.m4 || die
-
-	AT_M4DIR="config-scripts" eautoreconf
-
-	# Custom Makefiles
-	multilib_copy_sources
-}
-
-multilib_src_configure() {
-	export DSOFLAGS="${LDFLAGS}"
-
-	# Explicitly specify compiler wrt bug #524340
-	#
-	# Need to override KRB5CONFIG for proper flags
-	# https://github.com/apple/cups/issues/4423
-	local myeconfargs=(
-		CC="$(tc-getCC)"
-		CXX="$(tc-getCXX)"
-		KRB5CONFIG="${EPREFIX}"/usr/bin/${CHOST}-krb5-config
-		--libdir="${EPREFIX}"/usr/$(get_libdir)
-		--localstatedir="${EPREFIX}"/var
-		# Follow Fedora permission setting
-		--with-cupsd-file-perm=0755
-		--with-exe-file-perm=755
-		--with-log-file-perm=0640
-		# Used by Debian, also prevents printers from getting
-		# disabled and users not knowing how to re-enable them
-		--with-error-policy=retry-job
-		# Used in Debian and Fedora
-		--enable-sync-on-close
-		#
-		--with-rundir="${EPREFIX}"/run/cups
-		--with-pkgconfpath="${EPREFIX}"/usr/$(get_libdir)/pkgconfig
-		--with-cups-user=lp
-		--with-cups-group=lp
-		--with-docdir="${EPREFIX}"/usr/share/cups/html
-		# See bug #863221 for adding root
-		--with-system-groups="root lpadmin"
-		--with-xinetd="${EPREFIX}"/etc/xinetd.d
-		$(multilib_native_use_enable acl)
-		$(use_enable dbus)
-		$(use_enable debug)
-		$(use_enable debug debug-guards)
-		$(use_enable debug debug-printfs)
-		$(use_enable kerberos gssapi)
-		$(multilib_native_use_enable pam)
-		$(use_enable static-libs static)
-		--with-tls=$(usex openssl openssl gnutls)
-		$(use_with systemd ondemand systemd)
-		$(multilib_native_use_enable usb libusb)
-		$(use_with zeroconf dnssd avahi)
-		$(multilib_is_native_abi && echo --enable-libpaper || echo --disable-libpaper)
-	)
-
-	# Handle empty LINGUAS properly, bug #771162
-	if [[ -n "${LINGUAS+x}" ]] ; then
-		myeconfargs+=(
-			--with-languages="${LINGUAS}"
-		)
-	fi
-
-	if tc-is-static-only; then
-		myeconfargs+=(
-			--disable-shared
-		)
-	fi
-
-	# Install in /usr/libexec always, instead of using /usr/lib/cups, as that
-	# makes more sense when facing multilib support.
-	sed -i -e 's:CUPS_SERVERBIN="$exec_prefix/lib/cups":CUPS_SERVERBIN="$exec_prefix/libexec/cups":g' configure ||die
-
-	econf "${myeconfargs[@]}"
-
-	sed -i -e "s:SERVERBIN.*:SERVERBIN = \"\$\(BUILDROOT\)${EPREFIX}/usr/libexec/cups\":" Makedefs || die
-	sed -i -e "s:#define CUPS_SERVERBIN.*:#define CUPS_SERVERBIN \"${EPREFIX}/usr/libexec/cups\":" config.h || die
-	sed -i -e "s:cups_serverbin=.*:cups_serverbin=\"${EPREFIX}/usr/libexec/cups\":" cups-config || die
-
-	# Additional path corrections needed for prefix, see bug #597728
-	sed \
-		-e "s:ICONDIR.*:ICONDIR = ${EPREFIX}/usr/share/icons:" \
-		-e "s:INITDIR.*:INITDIR = ${EPREFIX}/etc:" \
-		-e "s:DBUSDIR.*:DBUSDIR = ${EPREFIX}/etc/dbus-1:" \
-		-e "s:MENUDIR.*:MENUDIR = ${EPREFIX}/usr/share/applications:" \
-		-i Makedefs || die
-}
-
-multilib_src_compile() {
-	if multilib_is_native_abi; then
-		default
-	else
-		emake libs
-	fi
-}
-
-multilib_src_test() {
-	# We only build some of CUPS for multilib, so can't run the tests.
-	if multilib_is_native_abi; then
-		# Avoid using /tmp
-		export CUPS_TESTBASE="${T}"/cups-tests
-
-		mkdir "${T}"/cups-tests || die
-
-		# avoid building *and running* test binaries in src_compile
-		# https://github.com/OpenPrinting/cups/commit/b1d42061e9286f50eefc851ed906d17c6e80c4b0
-		emake UNITTESTS=unittests
-		default
-	fi
-}
-
-multilib_src_install() {
-	if multilib_is_native_abi; then
-		emake BUILDROOT="${D}" install
-	else
-		emake BUILDROOT="${D}" install-libs install-headers
-
-		# Manually install pkgconfig file to avoid tangling with duplicate file behavior
-		insinto /usr/$(get_libdir)/pkgconfig
-		doins cups.pc
-
-		dobin cups-config
-	fi
-}
-
-multilib_src_install_all() {
-	dodoc {CHANGES,CREDITS,README}.md
-
-	# Move the default config file to docs
-	dodoc "${ED}"/etc/cups/cupsd.conf.default
-	rm "${ED}"/etc/cups/cupsd.conf.default || die
-
-	# Clean out cups init scripts
-	rm -r "${ED}"/etc/{init.d/cups,rc*} || die
-
-	# Install our init script
-	local neededservices=(
-		$(usex zeroconf avahi-daemon '')
-		$(usex dbus dbus '')
-	)
-	[[ -n ${neededservices[@]} ]] && neededservices="need ${neededservices[@]}"
-	cp "${FILESDIR}"/cupsd.init.d-r4 "${T}"/cupsd || die
-	sed -i -e "s/@neededservices@/${neededservices}/" "${T}"/cupsd || die
-	doinitd "${T}"/cupsd
-
-	if use pam ; then
-		rm "${ED}"/etc/pam.d/${PN} || die
-		pamd_mimic_system cups auth account
-	fi
-
-	if use xinetd ; then
-		# Correct path
-		sed -i -e "s:server = .*:server = /usr/libexec/cups/daemon/cups-lpd:" \
-			"${ED}"/etc/xinetd.d/cups-lpd || die
-		# It is safer to disable this by default, bug #137130
-		grep -w 'disable' "${ED}"/etc/xinetd.d/cups-lpd || \
-			{ sed -i -e "s:}:\tdisable = yes\n}:" "${ED}"/etc/xinetd.d/cups-lpd || die ; }
-		# Write permission for file owner (root), bug #296221
-		fperms u+w /etc/xinetd.d/cups-lpd
-	else
-		# Always configure with --with-xinetd= and clean up later,
-		# bug #525604
-		rm -r "${ED}"/etc/xinetd.d || die
-	fi
-
-	keepdir /etc/cups/{interfaces,ppd,ssl}
-
-	if ! use X ; then
-		rm -r "${ED}"/usr/share/applications || die
-	fi
-
-	# Create /etc/cups/client.conf, bug #196967 and bug #266678
-	echo "ServerName ${EPREFIX}/run/cups/cups.sock" >> "${ED}"/etc/cups/client.conf
-
-	# The following file is now provided by cups-filter:
-	rm -r "${ED}"/usr/share/cups/banners || die
-
-	# The following are created by the init script
-	rm -r "${ED}"/var/cache || die
-	rm -r "${ED}"/run || die
-
-	keepdir /usr/libexec/cups/driver /usr/share/cups/{model,profiles} /var/log/cups /var/spool/cups/tmp
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if ver_replacing -lt 2.2.2-r2 ; then
-		ewarn "The cupsd init script switched to using pidfiles. Shutting down"
-		ewarn "cupsd will fail the next time. To fix this, please run once as root"
-		ewarn "   killall cupsd ; /etc/init.d/cupsd zap ; /etc/init.d/cupsd start"
-	fi
-
-	if [[ -n ${REPLACING_VERSIONS} ]]; then
-		elog
-		elog "For information about installing a printer and general cups setup"
-		elog "take a look at: https://wiki.gentoo.org/wiki/Printing"
-	fi
-
-	optfeature_header "CUPS may need installing the following for certain features to work:"
-	use zeroconf && optfeature "local hostname resolution using a hostname.local naming scheme" sys-auth/nss-mdns
-}