Adding metadata

4 files changed, 327 insertions, 23 deletions

diff --git a/net-p2p/deluge/deluge-2.2.0-r2.ebuild b/net-p2p/deluge/deluge-2.2.0-r2.ebuild
new file mode 100644
index 000000000000..0e99f891dcc3
--- /dev/null
+++ b/net-p2p/deluge/deluge-2.2.0-r2.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 greadme systemd xdg
+
+DESCRIPTION="BitTorrent client with a client/server model"
+HOMEPAGE="https://deluge-torrent.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.deluge-torrent.org/${PN}"
+else
+	SRC_URI="http://download.deluge-torrent.org/source/$(ver_cut 1-2)/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="appindicator console gui libnotify sound webinterface"
+REQUIRED_USE="
+	appindicator? ( gui )
+	libnotify? ( gui )
+	sound? ( gui )
+"
+
+BDEPEND="
+	dev-util/intltool
+"
+
+RDEPEND="
+	acct-group/deluge
+	acct-user/deluge
+	net-libs/libtorrent-rasterbar:=[python,${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		gui? (
+			sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
+			dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		)
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pkg-resources[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+		dev-python/rencode[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		>=dev-python/twisted-17.1.0[ssl(-),${PYTHON_USEDEP}]
+		>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+		dev-python/mako[${PYTHON_USEDEP}]
+	')
+	appindicator? ( dev-libs/libayatana-appindicator )
+	gui? (
+		gnome-base/librsvg:2
+		libnotify? ( x11-libs/libnotify )
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-twisted )
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local args=(
+		-e 's|"new_release_check": True|"new_release_check": False|'
+		-e 's|"check_new_releases": True|"check_new_releases": False|'
+		-e 's|"show_new_releases": True|"show_new_releases": False|'
+	)
+	sed -i "${args[@]}" -- 'deluge/core/preferencesmanager.py' || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Upstream CI/CD skips these and they seem to intentionally segfault to collect core dumps...
+		deluge/plugins/Stats/deluge_stats/tests/test_stats.py
+		# Skipped upstream
+		deluge/tests/test_security.py
+		# Broken
+		deluge/tests/test_ui_entry.py
+		deluge/tests/test_webserver.py
+	)
+	local EPYTEST_DESELECT=(
+		# Skipped upstream
+		'deluge/plugins/WebUi/deluge_webui/tests/test_plugin_webui.py::TestWebUIPlugin::test_enable_webui'
+		'deluge/tests/test_torrent.py::TestTorrent::test_torrent_error_resume_data_unaltered'
+		'deluge/tests/test_tracker_icons.py::TestTrackerIcons::test_get_seo_svg_with_sni'
+		# never returns
+		'deluge/tests/test_ui_entry.py::TestConsoleScriptEntryWithDaemon'
+		# failing network(?)-related tests, even with sandbox disabled
+		'deluge/tests/test_common.py::TestCommon::test_is_interface'
+		# fails
+		'deluge/tests/test_core.py::TestCore::test_pause_torrents'
+		# fails because of network sandbox
+		'deluge/tests/test_core.py::TestCore::test_test_listen_port'
+		'deluge/tests/test_tracker_icons.py::TestTrackerIcons::test_get_deluge_png'
+		'deluge/tests/test_tracker_icons.py::TestTrackerIcons::test_get_google_ico'
+		'deluge/tests/test_tracker_icons.py::TestTrackerIcons::test_get_google_ico_hebrew'
+		'deluge/tests/test_tracker_icons.py::TestTrackerIcons::test_get_google_ico_with_redirect'
+		# segfaults with FEATURES="network-sandbox"
+		'deluge/tests/test_core.py::TestCore::test_pause_torrent'
+	)
+
+	epytest -m "not (todo or gtkui)" -v
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if ! use console ; then
+		rm -r "${D}/$(python_get_sitedir)/deluge/ui/console/" || die
+		rm "${ED}/usr/bin/deluge-console" || die
+		rm "${ED}/usr/share/man/man1/deluge-console.1" ||die
+	fi
+	if ! use gui ; then
+		rm -r "${D}/$(python_get_sitedir)/deluge/ui/gtk3/" || die
+		rm -r "${ED}/usr/share/icons/" || die
+		rm "${ED}/usr/bin/deluge-gtk" || die
+		rm "${ED}/usr/share/man/man1/deluge-gtk.1" || die
+	else
+		mkdir -p "${ED}/usr/share/applications/" || die
+		cp "${WORKDIR}/${P}/deluge/ui/data/share/applications/deluge.desktop" "${ED}/usr/share/applications/" || die
+		mkdir -p "${ED}/usr/share/metainfo" || die
+		cp "${WORKDIR}/${P}/deluge/ui/data/share/metainfo/deluge.metainfo.xml" "${ED}/usr/share/metainfo/" || die
+	fi
+
+	if use webinterface; then
+		newinitd "${FILESDIR}/deluge-web.init-2" deluge-web
+		newconfd "${FILESDIR}/deluge-web.conf" deluge-web
+		systemd_newunit "${FILESDIR}/deluge-web.service-4" deluge-web.service
+		systemd_install_serviced "${FILESDIR}/deluge-web.service.conf"
+	else
+		rm -r "${D}/$(python_get_sitedir)/deluge/ui/web/" || die
+		rm "${ED}/usr/bin/deluge-web" || die
+		rm "${ED}/usr/share/man/man1/deluge-web.1" || die
+	fi
+
+	newinitd "${FILESDIR}"/deluged.init-2 deluged
+	newconfd "${FILESDIR}"/deluged.conf-2 deluged
+	systemd_newunit "${FILESDIR}"/deluged.service-2 deluged.service
+	systemd_install_serviced "${FILESDIR}"/deluged.service.conf
+
+	python_optimize
+
+	greadme_stdin <<-EOF
+	To start only the daemon either run 'deluged' as user or modify
+	/etc/conf.d/deluged and run '/etc/init.d/deluged start' as root
+	if you use OpenRC or 'systemctl start deluged.service' if you use systemd.
+
+	Systemd unit files for deluged and deluge-web no longer source
+	/etc/conf.d/deluge* files. Environment variable customization now happens in
+	/etc/systemd/system/deluged.service.d/00gentoo.conf and
+	/etc/systemd/system/deluge-web.service.d/00gentoo.conf
+
+	For more information see https://deluge-torrent.org/faq/
+EOF
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	greadme_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	greadme_pkg_postinst
+}
diff --git a/net-p2p/deluge/deluge-9999.ebuild b/net-p2p/deluge/deluge-9999.ebuild
index fa4c3822566b..0e99f891dcc3 100644
--- a/net-p2p/deluge/deluge-9999.ebuild
+++ b/net-p2p/deluge/deluge-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -6,7 +6,7 @@ EAPI=8
 PYTHON_COMPAT=( python3_{10..14} )
 DISTUTILS_USE_PEP517=setuptools
 DISTUTILS_SINGLE_IMPL=1
-inherit distutils-r1 systemd xdg
+inherit distutils-r1 greadme systemd xdg
 
 DESCRIPTION="BitTorrent client with a client/server model"
 HOMEPAGE="https://deluge-torrent.org/"
@@ -39,22 +39,24 @@ RDEPEND="
 	$(python_gen_cond_dep '
 		gui? (
 			sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
-			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
 		)
 		dev-python/chardet[${PYTHON_USEDEP}]
 		dev-python/distro[${PYTHON_USEDEP}]
 		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pkg-resources[${PYTHON_USEDEP}]
 		dev-python/pyopenssl[${PYTHON_USEDEP}]
 		dev-python/pyxdg[${PYTHON_USEDEP}]
 		dev-python/rencode[${PYTHON_USEDEP}]
 		dev-python/setproctitle[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
 		>=dev-python/twisted-17.1.0[ssl(-),${PYTHON_USEDEP}]
 		>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
 		dev-python/mako[${PYTHON_USEDEP}]
 	')
 	appindicator? ( dev-libs/libayatana-appindicator )
 	gui? (
-		gnome-base/librsvg
+		gnome-base/librsvg:2
 		libnotify? ( x11-libs/libnotify )
 	)
 "
@@ -79,6 +81,9 @@ python_test() {
 		deluge/plugins/Stats/deluge_stats/tests/test_stats.py
 		# Skipped upstream
 		deluge/tests/test_security.py
+		# Broken
+		deluge/tests/test_ui_entry.py
+		deluge/tests/test_webserver.py
 	)
 	local EPYTEST_DESELECT=(
 		# Skipped upstream
@@ -140,27 +145,27 @@ python_install_all() {
 	systemd_install_serviced "${FILESDIR}"/deluged.service.conf
 
 	python_optimize
+
+	greadme_stdin <<-EOF
+	To start only the daemon either run 'deluged' as user or modify
+	/etc/conf.d/deluged and run '/etc/init.d/deluged start' as root
+	if you use OpenRC or 'systemctl start deluged.service' if you use systemd.
+
+	Systemd unit files for deluged and deluge-web no longer source
+	/etc/conf.d/deluge* files. Environment variable customization now happens in
+	/etc/systemd/system/deluged.service.d/00gentoo.conf and
+	/etc/systemd/system/deluge-web.service.d/00gentoo.conf
+
+	For more information see https://deluge-torrent.org/faq/
+EOF
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	greadme_pkg_preinst
 }
 
 pkg_postinst() {
 	xdg_pkg_postinst
-
-	elog
-	elog "If, after upgrading, deluge doesn't work please back up and then"
-	elog "remove your '~/.config/deluge' directory and try again"
-	elog
-	elog "To start the daemon either run 'deluged' as user"
-	elog "or modify /etc/conf.d/deluged and run"
-	elog "'/etc/init.d/deluged start' as root if you use OpenRC"
-	elog "or"
-	elog "'systemctl start deluged.service' as root if you use systemd"
-	elog "You can still use deluge the old way"
-	elog
-	elog "Systemd unit files for deluged and deluge-web no longer source"
-	elog "/etc/conf.d/deluge* files. Environment variable customization now"
-	elog "happens in /etc/systemd/system/deluged.service.d/00gentoo.conf"
-	elog "and /etc/systemd/system/deluge-web.service.d/00gentoo.conf"
-	elog
-	elog "For more information see https://dev.deluge-torrent.org/wiki/Faq"
-	elog
+	greadme_pkg_postinst
 }
diff --git a/net-p2p/syncthing/Manifest b/net-p2p/syncthing/Manifest
index de5c3cc6d5f1..ada6c923bee1 100644
--- a/net-p2p/syncthing/Manifest
+++ b/net-p2p/syncthing/Manifest
@@ -7,3 +7,5 @@ DIST syncthing-source-v2.0.15.tar.gz 62690897 BLAKE2B 532e5d56b27bdec444495fef46
 DIST syncthing-source-v2.0.15.tar.gz.asc 1391 BLAKE2B 7baf7edcaa3ab1b332d047c6b03b734a6ccd4ea9c4a778b08f5c89a1e5b917b48a3a8755f1c80c7a221b9351b38a61053b7e9cb6eb561ef2ba8189a2afb72657 SHA512 d62a11ca3c20910cd815160f0abc6080ad413ae96f7ab51c36f84b1f9b4e23bcf47fc9845af402d9967820352fa976580fb5e237c839b47f2382fdb71bfc75aa
 DIST syncthing-source-v2.0.16.tar.gz 62749079 BLAKE2B a9c5f3f7c26506e1997d0e28713fee30c31fec6d79c2e89405e6b3f5f4fb0834d23eb380ad87ac2752d91aea5208b1955e91e92a47dd2a53080bb4b54890e800 SHA512 e5556a56ffcbe1f2830f6225e3acb0e5b15d879704908d94f8fbb9e06a520e5233600f11da469e220a36a55a6e96c1a2a6b7d4c67b50a18136018d089051e6fd
 DIST syncthing-source-v2.0.16.tar.gz.asc 1391 BLAKE2B ae28c7037514065d63d784c3085c94e249626ad72b37b887dc9d49038ba3b89ec6be9884132ab5b19053d565e2da393ae71d850cd9515e6da983f29a75b47c90 SHA512 6821ac6ab15e5a9ca5f3944a2d4da20febaba1d9d41ee485492511a7cdf399e363e34fb44c94640e401e31befccace6a408f82891f55ded09406580923a41104
+DIST syncthing-source-v2.1.0.tar.gz 63030467 BLAKE2B a49e5eb507bd81483ff82d00d07de40b2b7df640190f3df98427ee41d96aa43eaacea34e8b9f37e5f1846044c2d4b25463048fe8b109b6b6b272c7f6be7074ab SHA512 ee6e14d9522e4d37063b90afcda20fc55dbd1a4a9faf7cd6fe34b9f7581a28572d8b8614e8821b5bfaca94c0a7456784f053f02878ac7872900a2752f19e3210
+DIST syncthing-source-v2.1.0.tar.gz.asc 1391 BLAKE2B 68c2835c37a78a123f4a04af0d04d3a0c8c7699532d8e38400ed535877d3b324ae2a220c70946c959d6c01f3a1c26425370acbe0a445bc2ce50892fc929af835 SHA512 c724d0cf5aab6dc27d72587ba3d51b2bb8932c88b65cdbe45a26b72210f2fd50ca37ba05d9a307035c963c15166595bcf36dacef3b6d11269dda70286720adba
diff --git a/net-p2p/syncthing/syncthing-2.1.0.ebuild b/net-p2p/syncthing/syncthing-2.1.0.ebuild
new file mode 100644
index 000000000000..73bfd5f459a9
--- /dev/null
+++ b/net-p2p/syncthing/syncthing-2.1.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit eapi9-ver desktop go-module systemd verify-sig xdg
+
+DESCRIPTION="Open Source Continuous File Synchronization"
+HOMEPAGE="https://syncthing.net https://github.com/syncthing/syncthing"
+SRC_URI="
+	https://github.com/${PN}/${PN}/releases/download/v${PV}/${PN}-source-v${PV}.tar.gz
+	verify-sig? (
+		https://github.com/${PN}/${PN}/releases/download/v${PV}/${PN}-source-v${PV}.tar.gz.asc
+	)
+"
+S="${WORKDIR}"/${PN}
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC0-1.0 ISC MIT Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="selinux tools"
+
+DEPEND="
+	dev-db/sqlite:3
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/syncthing
+	acct-user/syncthing
+	tools? (
+		>=acct-user/stdiscosrv-1
+		>=acct-user/strelaysrv-1
+	)
+	selinux? ( sec-policy/selinux-syncthing )
+"
+BDEPEND="
+	>=dev-lang/go-1.25.0
+	verify-sig? ( sec-keys/openpgp-keys-syncthing )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/syncthing.asc
+
+DOCS=( AUTHORS {GOALS,README}.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.4-TestIssue5063_timeout.patch
+	"${FILESDIR}"/${PN}-1.18.4-tool_users.patch
+	"${FILESDIR}"/${PN}-1.29.5-remove_race_in_tests.patch #955442
+)
+
+src_prepare() {
+	# Bug #679280
+	xdg_environment_reset
+
+	default
+
+	local srv
+	for srv in st{disco,relay}srv; do
+		sed -i \
+			's|^ExecStart=.*|ExecStart=/usr/libexec/${PN}/${srv}|' \
+			cmd/${srv}/etc/linux-systemd/${srv}.service || die
+	done;
+}
+
+src_compile() {
+	# https://github.com/mattn/go-sqlite3#linux
+	# -tags libsqlite3: use system sqlite3 instead of bundled
+	ego run build.go -version "v${PV}" -tags "libsqlite3" -no-upgrade -build-out=bin/ \
+		build $(usev tools all)
+}
+
+src_test() {
+	ego run build.go test
+}
+
+src_install() {
+	dobin bin/${PN}
+
+	doman man/*.[157]
+	einstalldocs
+
+	domenu etc/linux-desktop/${PN}-{start,ui}.desktop
+	local -i icon_size
+	for icon_size in 32 64 128 256 512; do
+		newicon -s ${icon_size} assets/logo-${icon_size}.png ${PN}.png
+	done
+	newicon -s scalable assets/logo-only.svg ${PN}.svg
+
+	systemd_dounit etc/linux-systemd/system/${PN}@.service
+	systemd_douserunit etc/linux-systemd/user/${PN}.service
+	newconfd "${FILESDIR}"/${PN}.confd-r2 ${PN}
+	newinitd "${FILESDIR}"/${PN}.initd-r5 ${PN}
+	exeinto /etc/user/init.d
+	newexe "${FILESDIR}"/syncthing.initd-user-r2 syncthing
+
+	keepdir /var/log/${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	insinto /etc/ufw/applications.d
+	doins etc/firewall-ufw/${PN}
+
+	if use tools; then
+		exeinto /usr/libexec/${PN}
+		insinto /etc/logrotate.d
+
+		local srv
+		for srv in st{disco,relay}srv; do
+			doexe bin/${srv}
+			systemd_dounit cmd/${srv}/etc/linux-systemd/${srv}.service
+			newconfd "${FILESDIR}"/${srv}.confd ${srv}
+			newinitd "${FILESDIR}"/${srv}.initd-r1 ${srv}
+
+			newins "${FILESDIR}"/${srv}.logrotate ${srv}
+		done
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ver_replacing -lt 2.0 ; then
+		elog "Major changes in 2.0:"
+		elog "https://github.com/syncthing/syncthing/blob/v${PV}/relnotes/v2.0.md"
+	fi
+}