Updating liguros repov21.1.3

1 files changed, 54 insertions, 0 deletions

diff --git a/net-misc/spiped/spiped-1.6.1.ebuild b/net-misc/spiped/spiped-1.6.1.ebuild
new file mode 100644
index 000000000000..e3f8538c10d4
--- /dev/null
+++ b/net-misc/spiped/spiped-1.6.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="secure pipe daemon"
+HOMEPAGE="https://www.tarsnap.com/spiped.html"
+SRC_URI="http://www.tarsnap.com/${PN}/${P}.tgz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl"
+
+MY_PN="${PN/d/}"
+
+DEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )"
+
+# Blocker added due to #548126
+RDEPEND="
+	${DEPEND}
+	!net-mail/qlogtools"
+
+# Some tests fail.
+RESTRICT="test"
+
+src_compile() {
+	emake CC=$(tc-getCC) CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin "${MY_PN}/${MY_PN}"
+	dosbin "${PN}/${PN}"
+
+	doman "${MY_PN}/${MY_PN}.1" "${PN}/${PN}.1"
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+
+	dodir "etc/${PN}"
+}
+
+pkg_postinst() {
+	elog
+	elog "You will need to configure spiped via its"
+	elog "configuration file located in /etc/conf.d/."
+	elog
+	elog "Please have a look at this file prior to starting up spiped!"
+	elog
+}