Adding metadata

2 files changed, 82 insertions, 0 deletions

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index dc19c3c73849..118cfd3e92bc 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-remote-desktop-48.2.tar.xz 343308 BLAKE2B bf36d9f60fd4f4ffccd2118d1beeb8511147983ab2bd338a4008da0eb113a97930bbe4b58ac681e7f059f10e633c3687119c5999e6704f79732870ccb6456cc5 SHA512 345e74971eaa319af543b47f9353a643d901f0e5aaa8f60a85df21f624d7d413bc34bfaa8ee4c92b4934f8ccedd940658e0fff8f6f616c30262143def9610e3a
 DIST gnome-remote-desktop-49.2.tar.xz 359888 BLAKE2B 626a133c6d961ab9938db803a7711a01e2870a9b6eaa26b6f194f05ca300916d5d79d5f487511163a65e9c510b9367ead5a8e4142aec758f0bb09e1080b8f164 SHA512 b678ee125e1b5f6d58e85f57a332cf02ee6b5dee654469e66f496f9467e6512a701a3e37a9580562e0b064320380d2df4ca6b15e20bd35b1605b4bd9de73827c
+DIST gnome-remote-desktop-49.3.tar.xz 362172 BLAKE2B 1c07822d8e678b0391317807c74eec3a421516db8d1375e3710edb1c84d26a0e7cd2eedfe9587ab5a484b7c18112538352ae3cf0c0cca53823dee12ce693e34e SHA512 66beb510c41f7dc35d2e820d27c5f1494e187b46f53c2cd1b373e82c266019f39af4f807ed5ffe4f6c57bbd842cf58ec6f46abe66db38accc8b162592cee0d59
diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-49.3.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-49.3.ebuild
new file mode 100644
index 000000000000..d64dc5484a85
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-49.3.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd tmpfiles xdg
+
+DESCRIPTION="Remote desktop server which allows you to connect to your machine remotely"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong"
+IUSE="doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.75:2
+	>=dev-libs/libei-1.3.901
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-1.2.0:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-3.15.0:=[server]
+		>=sys-fs/fuse-3.9.1:3=
+		media-libs/libva
+		>=sys-auth/polkit-122
+		>=dev-util/vulkan-headers-1.2.0
+		media-libs/shaderc
+		dev-util/spirv-tools
+		>=x11-libs/libxkbcommon-1.0.0
+		media-libs/fdk-aac:=
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	acct-user/gnome-remote-desktop
+	acct-group/gnome-remote-desktop
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	>=dev-build/meson-1.4.0
+	dev-libs/glib
+	>=dev-util/gdbus-codegen-2.80.5-r1
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		-Dtests=false  # Tests run xvfb-run directly
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}-tmpfiles.conf"
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}