Adding metadata

4 files changed, 120 insertions, 0 deletions

diff --git a/net-dns/libidn/Manifest b/net-dns/libidn/Manifest
new file mode 100644
index 000000000000..a074aa2740dc
--- /dev/null
+++ b/net-dns/libidn/Manifest
@@ -0,0 +1,2 @@
+DIST libidn-1.43.tar.gz 2535228 BLAKE2B 92aec3d66b58ec5a85a6959bacdce017cc11c94500bcedb58080f871cb3ec59e5400c6607b6304445787fedd2088b7a7b87a111e2b9eb5372524ebe2806a214b SHA512 a098d9c1df9d47181e7707a115dcfa12ba4b1aba68b1d070eff4f0578fd2e09b9c453457f83fc1a704726eac3a6f90e5a00772ab116affd07efe1e1ab9d5b0f1
+DIST libidn-1.43.tar.gz.sig 1223 BLAKE2B ad009aadf0a16a21a6a4697ab67da06a20f6ca68ee479fe425fa9747168e24cb53ab863d59939a66d31ca932386a89eb49bdd36bff56505b0d2973a73acc0183 SHA512 c161a89309b3cffa32d81cc2ce87d0f2e3dde5ab2bfa4fe5acdc2ee19650e6cca3f793744b8bf6fac23e121fb0460d4c55daccc5ef2ad65be2f5a33a630a7957
diff --git a/net-dns/libidn/files/50libidn-gentoo.el b/net-dns/libidn/files/50libidn-gentoo.el
new file mode 100644
index 000000000000..a70158961f79
--- /dev/null
+++ b/net-dns/libidn/files/50libidn-gentoo.el
@@ -0,0 +1,9 @@
+(add-to-list 'load-path "@SITELISP@")
+(autoload 'idna-to-ascii "idna"
+  "Returns an ASCII Compatible Encoding (ACE) of STR.")
+(autoload 'idna-to-unicode "idna"
+  "Returns a possibly multibyte string after decoding STR.")
+(autoload 'punycode-encode "punycode"
+  "Returns a Punycode encoding of STR.")
+(autoload 'punycode-decode "punycode"
+  "Returns a possibly multibyte string which is the punycode decoding of STR.")
diff --git a/net-dns/libidn/libidn-1.43.ebuild b/net-dns/libidn/libidn-1.43.ebuild
new file mode 100644
index 000000000000..375016e9cfad
--- /dev/null
+++ b/net-dns/libidn/libidn-1.43.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/libidn.asc
+inherit branding elisp-common libtool multilib-minimal verify-sig
+
+DESCRIPTION="Internationalized Domain Names (IDN) implementation"
+HOMEPAGE="https://www.gnu.org/software/libidn/"
+SRC_URI="
+	mirror://gnu/libidn/${P}.tar.gz
+	verify-sig? ( mirror://gnu/libidn/${P}.tar.gz.sig )
+"
+
+LICENSE="GPL-2 GPL-3 LGPL-3"
+SLOT="0/12"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="emacs nls"
+
+DEPEND="nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+	nls? ( >=sys-devel/gettext-0.17 )
+	verify-sig? ( >=sec-keys/openpgp-keys-libidn-20250414 )
+"
+
+DOCS=( AUTHORS ChangeLog FAQ NEWS README THANKS )
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	unreachable
+	static_assert
+)
+
+src_prepare() {
+	default
+
+	# For Solaris shared objects
+	elibtoolize
+}
+
+multilib_src_configure() {
+	# -fanalyzer substantially slows down the build and isn't useful for
+	# us. It's useful for upstream as it's static analysis, but it's not
+	# useful when just getting something built.
+	export gl_cv_warn_c__fanalyzer=no
+
+	local args=(
+		$(use_enable nls)
+		--disable-gcc-warnings
+		--disable-doc
+		--disable-gtk-doc
+		--disable-gtk-doc-html
+		--disable-gtk-doc-pdf
+		--disable-csharp
+		--disable-java
+		--disable-valgrind-tests
+		--with-lispdir="${EPREFIX}${SITELISP}/${PN}"
+	)
+
+	ECONF_SOURCE="${S}" econf "${args[@]}"
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi; then
+		use emacs && elisp-compile "${S}"/src/*.el
+	fi
+}
+
+multilib_src_install_all() {
+	if use emacs; then
+		# *.el are installed by the build system
+		elisp-install ${PN} "${S}"/src/*.elc
+		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
+	else
+		rm -r "${ED}"/usr/share/emacs || die
+	fi
+
+	einstalldocs
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/net-dns/libidn/metadata.xml b/net-dns/libidn/metadata.xml
new file mode 100644
index 000000000000..e50d483ef374
--- /dev/null
+++ b/net-dns/libidn/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>mgorny@gentoo.org</email>
+    <name>Michał Górny</name>
+  </maintainer>
+  <maintainer type="person">
+    <email>sam@gentoo.org</email>
+    <name>Sam James</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="cpe">cpe:/a:gnu:libidn</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>