Adding metadata

5 files changed, 255 insertions, 23 deletions

diff --git a/media-video/ffmpeg-chromium/Manifest b/media-video/ffmpeg-chromium/Manifest
index a08feead42b7..e50d6711823e 100644
--- a/media-video/ffmpeg-chromium/Manifest
+++ b/media-video/ffmpeg-chromium/Manifest
@@ -9,3 +9,4 @@ DIST ffmpeg-chromium-145.tar.xz 11119344 BLAKE2B d6ca614edc549c69b9cbf881cf34099
 DIST ffmpeg-chromium-146.tar.xz 11133040 BLAKE2B e4c5dd4865272b09377257432e35f34ddc0f4325432184ec614d05b3c9df65509ac10056166ef0a4342389acf22044036e52acb3fa9191c8f4ac30722d98708f SHA512 5b1f07dc2f6e25581a675d64b1f88aae3f01266ed18a90e671e0787d8023bec009b66894683e5da4f4779dd51584650f33d8a6cb57fba616843494e89a60af09
 DIST ffmpeg-chromium-147.tar.xz 11137344 BLAKE2B bf8339417bb8eed2efff2effeb702231461e9d4b22a7eaa41c929c2e44e4e42db6bdbae6d89f0726dfce623fa029c3949ce7d50d5f81bf72f84a8755f277af0a SHA512 2af6888a0c20c3717fba8aa7e813ae2675d0ce14a60b4ba3fd6dd317f4db71271daf3751eab50b7c165c829ab81b81567d602e7f79ab9e1fc5413c3731b82855
 DIST ffmpeg-chromium-148.tar.xz 11142936 BLAKE2B c332d6e02fdf40edfb287352110e5f746025ddc783b802b750badd99385ab80867ec38367f794a26395796fdddd7468a6ec06663fdddf48d0f2fe72094b59883 SHA512 d108defc08bf9b41c068714ee90cd0334e8680be20ee11142635d6c41fff889da901dbc3422a22ef014ecfceef7dccfa7cb557a765508392a522e9566baabe5e
+DIST ffmpeg-chromium-149.tar.xz 11205008 BLAKE2B 335db3d049d8619a794b344d47d2863681b53dd498b94c67b08bab66ea7bab1eb3c03e5c8f73515c538dcf49af8c7f642124076fb44ce77659d1ff5db966885b SHA512 6aa5b8d6b5f3190d7165ebddaa63142d5eaa1e0bfe1f222add6aab34e05a58c4c89c3d1d042e364eb20a19c88c560d5d2c3b858ec425d174628ba3769ff2b844
diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-149.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-149.ebuild
new file mode 100644
index 000000000000..d9bd135570df
--- /dev/null
+++ b/media-video/ffmpeg-chromium/ffmpeg-chromium-149.ebuild
@@ -0,0 +1,241 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+COMMIT=b5e18fb9da84e26ceef30d4e4886696bf59337c0
+DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
+HOMEPAGE="https://ffmpeg.org/"
+SRC_URI="https://deps.gentoo.zip/media-video/${P}.tar.xz"
+
+LICENSE="
+	!gpl? ( LGPL-2.1 )
+	gpl? ( GPL-2 )
+"
+SLOT="${PV}"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64"
+
+# Options to use as use_enable in the foo[:bar] form.
+# This will feed configure with $(use_enable foo bar)
+# or $(use_enable foo foo) if no :bar is set.
+# foo is added to IUSE.
+FFMPEG_FLAG_MAP=(
+		cpudetection:runtime-cpudetect debug
+		+gpl
+		vaapi vdpau vulkan
+		nvenc:ffnvcodec
+		# Threads; we only support pthread for now but ffmpeg supports more
+		+threads:pthreads
+)
+
+IUSE="
+	${FFMPEG_FLAG_MAP[@]%:*}
+"
+
+# Strings for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+ARM_CPU_FEATURES=(
+	cpu_flags_arm_thumb:armv5te
+	cpu_flags_arm_v6:armv6
+	cpu_flags_arm_thumb2:armv6t2
+	cpu_flags_arm_neon:neon
+	cpu_flags_arm_vfp:vfp
+	cpu_flags_arm_vfpv3:vfpv3
+	cpu_flags_arm_v8:armv8
+	cpu_flags_arm_asimddp:dotprod
+	cpu_flags_arm_i8mm:i8mm
+)
+ARM_CPU_REQUIRED_USE="
+	arm64? ( cpu_flags_arm_v8 )
+	cpu_flags_arm_v8? ( cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
+	cpu_flags_arm_neon? (
+		cpu_flags_arm_vfp
+		arm? ( cpu_flags_arm_thumb2 )
+	)
+	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
+	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
+	cpu_flags_arm_v6? (
+		arm? ( cpu_flags_arm_thumb )
+	)
+"
+X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx
+					   mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
+X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
+X86_CPU_REQUIRED_USE="
+	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
+	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
+	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
+	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
+	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
+	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
+	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
+	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
+	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
+	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
+	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
+"
+
+CPU_FEATURES_MAP=(
+	${ARM_CPU_FEATURES[@]}
+	${X86_CPU_FEATURES[@]}
+)
+IUSE="${IUSE}
+	${CPU_FEATURES_MAP[@]%:*}"
+
+CPU_REQUIRED_USE="
+	${ARM_CPU_REQUIRED_USE}
+	${X86_CPU_REQUIRED_USE}
+"
+
+RDEPEND="
+	>=media-libs/opus-1.0.2-r2
+	vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
+	nvenc? ( >=media-libs/nv-codec-headers-11.1.5.3 )
+	vdpau? ( >=x11-libs/libvdpau-0.7 )
+	vulkan? ( >=media-libs/vulkan-loader-1.3.277:= )
+"
+
+DEPEND="${RDEPEND}
+	vulkan? ( >=dev-util/vulkan-headers-1.3.277 )
+"
+BDEPEND="
+	>=dev-build/make-3.81
+	virtual/pkgconfig
+	cpu_flags_x86_mmx? ( >=dev-lang/nasm-2.13 )
+"
+
+REQUIRED_USE="
+	vulkan? ( threads )
+	${CPU_REQUIRED_USE}"
+RESTRICT="
+	test
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-138-configure-enable-libopus.patch
+	"${FILESDIR}"/chromium.patch
+)
+
+src_prepare() {
+	export revision=git-N-g${COMMIT:0:10}
+	default
+
+	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
+}
+
+src_configure() {
+	local myconf=( )
+
+	# Bug #918997. Will probably be fixed upstream in the next release.
+	use vulkan && append-ldflags -Wl,-z,muldefs
+
+	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
+
+	for i in "${ffuse[@]#+}" ; do
+		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
+	done
+
+	# CPU features
+	for i in "${CPU_FEATURES_MAP[@]}" ; do
+		use ${i%:*} || myconf+=( --disable-${i#*:} )
+	done
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag mcpu) $(get-flag march) ; do
+		[[ ${i} = native ]] && i="host" # bug #273421
+		if use arm64; then # 830165 - 'host' explicitly not supported on arm64
+			[[ ${i} != host ]] && myconf+=( --cpu=${i} )
+		else
+			myconf+=( --cpu=${i} )
+		fi
+		break
+	done
+
+	# LTO support, bug #566282, bug #754654, bug #772854
+	if [[ ${ABI} != x86 ]] && tc-is-lto; then
+		# Respect -flto value, e.g -flto=thin
+		local v="$(get-flag flto)"
+		[[ -n ${v} ]] && myconf+=( "--enable-lto=${v}" ) || myconf+=( "--enable-lto" )
+	fi
+	filter-lto
+
+	# Mandatory configuration
+	myconf=(
+		--disable-stripping
+		# This is only for hardcoded cflags; those are used in configure checks that may
+		# interfere with proper detections, bug #671746 and bug #645778
+		# We use optflags, so that overrides them anyway.
+		--disable-optimizations
+		--disable-libcelt # bug #664158
+		"${myconf[@]}"
+	)
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
+		case ${CHOST} in
+			*mingw32*)
+				myconf+=( --target-os=mingw32 )
+				;;
+			*linux*)
+				myconf+=( --target-os=linux )
+				;;
+		esac
+	fi
+
+	# Use --extra-libs if needed for LIBS
+	set -- "${S}/configure" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--nm="$(tc-getNM)" \
+		--strip="$(tc-getSTRIP)" \
+		--ranlib="$(tc-getRANLIB)" \
+		--pkg-config="$(tc-getPKG_CONFIG)" \
+		--optflags="${CFLAGS}" \
+		--extra-cflags="-DCHROMIUM_NO_LOGGING" \
+		--disable-all \
+		--disable-autodetect \
+		--disable-error-resilience \
+		--disable-everything \
+		--disable-faan \
+		--disable-iamf \
+		--disable-iconv \
+		--disable-network \
+		--enable-avcodec \
+		--enable-avformat \
+		--enable-avutil \
+		--enable-libopus \
+		--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,vorbis \
+		--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
+		--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp9 \
+		--enable-pic \
+		--enable-static \
+		"${myconf[@]}" \
+		${EXTRA_FFMPEG_CONF}
+
+	echo "${@}"
+	"${@}" || die
+}
+
+src_compile() {
+	emake V=1 libffmpeg
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" install-libffmpeg
+}
diff --git a/media-video/gaupol/Manifest b/media-video/gaupol/Manifest
index 429dd1810f72..1b648206aea7 100644
--- a/media-video/gaupol/Manifest
+++ b/media-video/gaupol/Manifest
@@ -1 +1,2 @@
 DIST gaupol-1.15.tar.gz 593412 BLAKE2B af21c3fac16a9e6a861ba93679f59134b68ab780812115048646b74a6524e230bb02a62454e8a42bdc436dfd08441f3e103a04b112c9d721e12d291e5e8cfbc7 SHA512 899dac0a8827e7b1b61ac9745f5fb39376eed1e4ccf928c3442350f6d8bb27f743923e1d321f1215f422b6e1d1d4e13cfe56adc2b4c358f22f6647a642726889
+DIST gaupol-1.16.tar.gz 594322 BLAKE2B 5a335504a9fde907faee2ec6a8a4b562004d8be68cf8936fa74ab69bbd518c1972892709cd8eb9abb9cde2051ee873c15dfc495624dd11d389c2f52300668c90 SHA512 d590094d796f6d47e78da939f6098b78b77dbbfb8e9e518bd93807c86caae7abb528991a2688df7c009ed743267af70b3aa1506c8dd63408fa1939a119e786b1
diff --git a/media-video/gaupol/gaupol-1.15-r1.ebuild b/media-video/gaupol/gaupol-1.16.ebuild
index bda44744b0e5..2f312fd45dfe 100644
--- a/media-video/gaupol/gaupol-1.15-r1.ebuild
+++ b/media-video/gaupol/gaupol-1.16.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -8,40 +8,40 @@ PYTHON_COMPAT=( python3_{10..14} )
 
 inherit distutils-r1 optfeature virtualx xdg-utils
 
-DESCRIPTION="A subtitle editor for text-based subtitles"
+DESCRIPTION="Editor for text-based subtitle files"
 HOMEPAGE="https://github.com/otsaloma/gaupol"
 SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="amd64 arm64 x86"
+KEYWORDS="~amd64 ~arm64 ~x86"
 
 RDEPEND="
 	app-text/iso-codes
 	dev-python/charset-normalizer[${PYTHON_USEDEP}]
-	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
 	x11-libs/gtk+:3[introspection]
 "
 BDEPEND="
 	sys-devel/gettext
 	test? (
 		app-dicts/myspell-en
+		app-text/gspell[introspection]
 		|| (
 			app-text/enchant[hunspell]
 			>=app-text/enchant-2.2.8[nuspell]
 		)
-		app-text/gspell[introspection]
 	)
 "
 
-distutils_enable_tests pytest
-
-DOCS=( AUTHORS.md NEWS.md README.md README.aeidon.md )
+DOCS=( {AUTHORS,NEWS,README{,.aeidon}}.md )
 
 PATCHES=(
-	"${FILESDIR}/${PN}-1.12-fix-prefix.patch"
+	"${FILESDIR}"/${PN}-1.12-fix-prefix.patch
 )
 
+distutils_enable_tests pytest
+
 python_test() {
 	virtx epytest
 }
@@ -53,11 +53,11 @@ pkg_postinst() {
 	# To check which GStreamer plugins are required (vaapisink is mentioned in the code but it is not used):
 	# plugins=$(qlist -e gaupol | xargs grep -ho 'Gst.ElementFactory.*' | cut -d'"' -f2 | sort -u | grep -vFx vaapisink)
 	# xargs -n1 gst-inspect-1.0 <<< "$plugins" | awk '/Filename/ {print $2}' | sort -u | xargs qfile
-	optfeature "integrated video player support" \
+	optfeature "built-in video player" \
 		"media-libs/gstreamer[introspection] media-libs/gst-plugins-base[pango] media-plugins/gst-plugins-gtk"
-	optfeature "external video previewing support" "media-video/mpv" "media-video/mplayer" "media-video/vlc"
+	optfeature "external video player" media-video/mpv media-video/mplayer media-video/vlc
 
-	optfeature "spellchecking support" "app-text/gspell[introspection]"
+	optfeature "spellchecking (does not include dictionaries)" "app-text/gspell[introspection]"
 	# To list dictionaries supported by gaupol:
 	# python3 -c 'import aeidon; print(*aeidon.SpellChecker.list_languages(), sep="\n")'
 	optfeature "spellchecking with app-dicts/myspell-* dictionaries using the nuspell backend" \
diff --git a/media-video/vdr/files/channel_alternative.conf b/media-video/vdr/files/channel_alternative.conf
deleted file mode 100644
index fb9088f0c439..000000000000
--- a/media-video/vdr/files/channel_alternative.conf
+++ /dev/null
@@ -1,11 +0,0 @@
-# Alternative channel configuration file
-#
-# Syntax:  original channel id;alternative channel id
-# Example: C-62499-10007-12003;C-0-196-14
-#          this means, if channel C-62499-10007-12003 is
-#          not available for a recording, vdr will try to
-#          use channel C-0-196-14
-#
-# lines beginning with '#' are ignored
-#
-