Adding metadata

3 files changed, 97 insertions, 1 deletions

diff --git a/media-sound/cava/cava-1.0.0.ebuild b/media-sound/cava/cava-1.0.0.ebuild
index d507d99f80f5..692314fdd1c5 100644
--- a/media-sound/cava/cava-1.0.0.ebuild
+++ b/media-sound/cava/cava-1.0.0.ebuild
@@ -11,7 +11,7 @@ SRC_URI="https://github.com/karlstav/cava/releases/download/${PV}/${P}.tar.gz"
 
 LICENSE="MIT Unlicense"
 SLOT="0"
-KEYWORDS="amd64 x86"
+KEYWORDS="amd64 ~arm64 x86"
 IUSE="alsa jack +ncurses pipewire portaudio pulseaudio sdl sndio"
 
 RDEPEND="
diff --git a/media-sound/fooyin/Manifest b/media-sound/fooyin/Manifest
index a731f448b86e..c19cf73702ae 100644
--- a/media-sound/fooyin/Manifest
+++ b/media-sound/fooyin/Manifest
@@ -1,3 +1,4 @@
 DIST fooyin-0.12.1.tar.gz 4747608 BLAKE2B c465de0516ea5749ee4800feffd6a54f7271ab389dded92066e8c1a6a5af7b7664419fd3bce8132e8bbbc47264911e64fc98fc4ae189a1a42811ed190202d91b SHA512 ee85b2ada8cc3cf36fb636342a72446e9f5b0fcebb3b0d06fbe74f2c10daec9d88854c8bdd166f1385859a2f39f4e88f119dcf90d0b97366a5060906f9967a98
 DIST fooyin-0.12.2.tar.gz 4813616 BLAKE2B d78bb2cea12b910a185ca1bf59397bde785610ceccc572a04d09e06a50b260207f27e4c27fbbc025b36dce2f3a148eb30d84dae06f6e6e4fccd46bf916283531 SHA512 2bd373432a22b2e225374f60339f4d31b5f68e90234d67356071bdaf361c44cb796f4d2c8b556a5911e1caf3a8e8a1e03c9a0ed18b74c27237690fc488778152
 DIST fooyin-0.12.3.tar.gz 4864183 BLAKE2B b97a499944cb9c665975bad835c55249edfb3fa89293af278150d00786c9464d752011522c7c310429616bc0205b044c3d13d4a02db55f276e6c3c4d0a8a33dc SHA512 5dd5c5185c963d5448bbc891d397b318d854fc222afeb01618785bf0c823bfba4976329353c61415a5fb834530c7c6e6c221bb01ef1dfdc2671263ba16224879
+DIST fooyin-0.12.4.tar.gz 4868269 BLAKE2B f498107132cca3463a65592c4684934a97b6d870f763278e2bf3a91f5c045e6530efa3e1bacc5504a800e28cdc02b1ac54be6f727b45db7e4d28d4cd0b20fe23 SHA512 6373e5fd8dcbf6700d0a0fb2cca9ff523fd08820501cdf52cf9bf76dde9b4e778126143fd2727dc2007849c31bd8edaaaf3fc166532fab96d99b6a2a46806231
diff --git a/media-sound/fooyin/fooyin-0.12.4.ebuild b/media-sound/fooyin/fooyin-0.12.4.ebuild
new file mode 100644
index 000000000000..ea0d5ee9ce6b
--- /dev/null
+++ b/media-sound/fooyin/fooyin-0.12.4.ebuild
@@ -0,0 +1,95 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Play and manage your music with a powerful, highly customisable player"
+HOMEPAGE="https://www.fooyin.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fooyin/fooyin.git"
+else
+	SRC_URI="
+		https://github.com/fooyin/fooyin/archive/refs/tags/v${PV}.tar.gz
+			-> ${P}.tar.gz
+	"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE="alsa +archive gme openmpt +pipewire projectm pulseaudio +replaygain sdl sndfile soundtouch soxr test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	|| ( alsa pipewire pulseaudio sdl )
+"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/kdsingleapplication
+	dev-libs/qcoro[network]
+	dev-qt/qtbase:6[concurrent,dbus,gui,icu,network,opengl,sql,widgets]
+	dev-qt/qtimageformats:6
+	dev-qt/qtsvg:6
+	media-libs/taglib:=
+	media-video/ffmpeg:=
+	virtual/zlib:=
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive:= )
+	gme? ( media-libs/game-music-emu )
+	openmpt? ( media-libs/libopenmpt )
+	pipewire? ( media-video/pipewire:= )
+	projectm? (
+		media-libs/libprojectm:4=
+	)
+	pulseaudio? ( media-libs/libpulse )
+	replaygain? ( media-libs/libebur128:= )
+	sdl? ( media-libs/libsdl2 )
+	sndfile? ( media-libs/libsndfile )
+	soundtouch? ( media-libs/libsoundtouch:= )
+	soxr? ( media-libs/soxr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist,opengl]
+	test? (
+		dev-cpp/gtest
+		media-video/ffmpeg:=[opus]
+	)
+"
+
+src_prepare() {
+	sed -i CMakeLists.txt \
+		-e "s|/doc/${PN}|/doc/${PF}|g" \
+		|| die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_ALSA=$(usex alsa)
+		-DBUILD_CCACHE=OFF
+		-DBUILD_SENSITIVE_TESTING=OFF
+		-DBUILD_TESTING=$(usex test)
+		-DFETCH_PROJECTM=OFF
+		-DINSTALL_HEADERS=ON
+		$(cmake_use_find_package archive LibArchive)
+		$(cmake_use_find_package gme LIBGME)
+		$(cmake_use_find_package openmpt OpenMpt)
+		$(cmake_use_find_package pipewire PipeWire)
+		$(cmake_use_find_package projectm projectM4)
+		$(cmake_use_find_package pulseaudio PulseAudio)
+		$(cmake_use_find_package replaygain Ebur128)
+		$(cmake_use_find_package sdl SDL2)
+		$(cmake_use_find_package sndfile SndFile)
+		$(cmake_use_find_package soundtouch SoundTouch)
+		$(cmake_use_find_package soxr SoXR)
+	)
+
+	cmake_src_configure
+}