Updating liguros repo

3 files changed, 96 insertions, 0 deletions

diff --git a/media-sound/alsaplayer/Manifest b/media-sound/alsaplayer/Manifest
new file mode 100644
index 000000000000..b57e60ab662e
--- /dev/null
+++ b/media-sound/alsaplayer/Manifest
@@ -0,0 +1 @@
+DIST alsaplayer-0.99.81.tar.bz2 806906 BLAKE2B 6b37aaa65f6426a43483c3fa7e077ca89ce553655587e0f44ac61ade5d4f5467a304e18ef0142336b0cc94311498ccaa16d9ed2d6eb8109474626c6d1a4ca97d SHA512 6723b36837d01f14645bb1d43ec7c54c85e8afed9b020f56dc81b4de64b74e4da2504507fe83954c7b26817e90510c585d09e759fc11e731d4d27e86f3932650
diff --git a/media-sound/alsaplayer/alsaplayer-0.99.81-r1.ebuild b/media-sound/alsaplayer/alsaplayer-0.99.81-r1.ebuild
new file mode 100644
index 000000000000..54627dd53847
--- /dev/null
+++ b/media-sound/alsaplayer/alsaplayer-0.99.81-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools desktop
+
+DESCRIPTION="A heavily multi-threaded pluggable audio player"
+HOMEPAGE="http://www.alsaplayer.org/"
+SRC_URI="http://www.alsaplayer.org/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~mips ~ppc ~sparc x86"
+IUSE="+alsa audiofile doc flac gtk id3tag jack mad mikmod nas nls ogg opengl oss vorbis xosd"
+
+RDEPEND="
+	media-libs/libsndfile:=
+	sys-libs/zlib:=
+	alsa? ( media-libs/alsa-lib )
+	audiofile? ( media-libs/audiofile )
+	flac? ( media-libs/flac )
+	gtk? ( >=x11-libs/gtk+-2.10:2 )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( virtual/jack )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	nas? ( media-libs/nas )
+	ogg? ( media-libs/libogg )
+	opengl? ( virtual/opengl )
+	vorbis? ( media-libs/libvorbis )
+	xosd? ( x11-libs/xosd )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )
+	oss? ( virtual/os-headers )"
+REQUIRED_USE="|| ( alsa jack nas oss )"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's:AM_CFLAGS = $(AM_CXXFLAGS)::' \
+		output/jack/Makefile.am || die
+
+	sed -i \
+		-e 's:-O2 -funroll-loops -finline-functions -ffast-math::' \
+		configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	export ac_cv_prog_HAVE_DOXYGEN=$(usex doc true false)
+	export ac_cv_lib_xosd_xosd_create=$(usex xosd)
+
+	econf \
+		--disable-esd \
+		$(use_enable nls) \
+		$(use_enable opengl) \
+		$(use_enable mikmod) \
+		$(use_enable vorbis oggvorbis) \
+		$(use_enable audiofile) \
+		$(use_enable flac) \
+		$(use_enable mad) \
+		$(use_enable id3tag) \
+		$(use_enable gtk systray) \
+		$(use_enable jack) \
+		$(use_enable alsa) \
+		$(use_enable oss) \
+		$(use_enable gtk gtk2) \
+		$(use_enable nas)
+}
+
+src_install() {
+	default
+	dodoc docs/*.txt
+
+	newicon interface/gtk2/pixmaps/logo.xpm ${PN}.xpm
+
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/media-sound/alsaplayer/metadata.xml b/media-sound/alsaplayer/metadata.xml
new file mode 100644
index 000000000000..9bd185365292
--- /dev/null
+++ b/media-sound/alsaplayer/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>sound@gentoo.org</email>
+		<name>Gentoo Sound project</name>
+	</maintainer>
+	<use>
+		<flag name="id3tag">Enables ID3 tagging with id3tag library</flag>
+	</use>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>