Adding metadata

3 files changed, 0 insertions, 97 deletions

diff --git a/media-libs/lilv/Manifest b/media-libs/lilv/Manifest
deleted file mode 100644
index 6ac24e640c22..000000000000
--- a/media-libs/lilv/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST lilv-0.24.26.tar.xz 106044 BLAKE2B 23b7a029fd40099420e9e8de222b2534b124a93f899c03c5ada27673fc47431c95866d7d4bc5f34b80110b5142e6564e95390fd56d686ac9958ad8bf71ca6033 SHA512 3d360d63391554f62d1dd44b9ba0fc28e4ccde9640da1e28ef3f127c23c9f03974b66c5bbb83f022f18810284a0e25060127d580ca2fad6213fe88920618c2ae
diff --git a/media-libs/lilv/lilv-0.24.26-r1.ebuild b/media-libs/lilv/lilv-0.24.26-r1.ebuild
deleted file mode 100644
index 77876475267d..000000000000
--- a/media-libs/lilv/lilv-0.24.26-r1.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{13..14} )
-PYTHON_REQ_USE='threads(+)'
-
-inherit meson-multilib python-single-r1
-
-DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
-HOMEPAGE="https://drobilla.net/software/lilv.html"
-SRC_URI="https://download.drobilla.net/${P}.tar.xz"
-
-LICENSE="ISC"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
-IUSE="doc python test tools"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	virtual/pkgconfig
-	doc? (
-		app-text/doxygen
-		dev-python/sphinx
-		dev-python/sphinx-lv2-theme
-		dev-python/sphinxygen
-	)
-"
-# Take care on bumps to check minimum versions!
-RDEPEND="
-	python? ( ${PYTHON_DEPS} )
-	>=dev-libs/serd-0.30.10[${MULTILIB_USEDEP}]
-	>=dev-libs/sord-0.16.16[${MULTILIB_USEDEP}]
-	>=dev-libs/zix-0.6.0[${MULTILIB_USEDEP}]
-	media-libs/libsndfile
-	>=media-libs/lv2-1.18.2[${MULTILIB_USEDEP}]
-	>=media-libs/sratom-0.6.10[${MULTILIB_USEDEP}]
-"
-DEPEND="${RDEPEND}"
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# fix doc installation path
-	sed -iE "s/versioned_name/'${PF}'/g" doc/html/meson.build doc/singlehtml/meson.build || die
-}
-
-multilib_src_configure() {
-	local emesonargs=(
-		$(meson_native_use_feature doc docs)
-		$(meson_feature python bindings_py)
-		$(meson_feature test tests)
-		$(meson_feature tools)
-	)
-
-	meson_src_configure
-}
-
-multilib_src_install() {
-	meson_src_install
-	use python && python_optimize
-}
-
-multilib_src_install_all() {
-	local DOCS=( AUTHORS NEWS README.md )
-	einstalldocs
-
-	newenvd - 60lv2 <<-EOF
-		LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2
-	EOF
-}
diff --git a/media-libs/lilv/metadata.xml b/media-libs/lilv/metadata.xml
deleted file mode 100644
index 0e474c5e46a8..000000000000
--- a/media-libs/lilv/metadata.xml
+++ /dev/null
@@ -1,19 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="project">
-		<email>proaudio@gentoo.org</email>
-		<name>Gentoo ProAudio Project</name>
-	</maintainer>
-	<longdescription lang="en">
-		Lilv is a library to make the use of LV2 plugins as simple as possible for applications.
-		Lilv is the successor to SLV2, rewritten to be significantly faster and have minimal dependencies.
-	</longdescription>
-	<use>
-		<flag name="tools">Build command line utilities</flag>
-	</use>
-	<upstream>
-		<remote-id type="github">lv2/lilv</remote-id>
-		<remote-id type="gitlab">lv2/lilv</remote-id>
-	</upstream>
-</pkgmetadata>