Adding metadata

4 files changed, 268 insertions, 0 deletions

diff --git a/media-libs/libjxl/Manifest b/media-libs/libjxl/Manifest
new file mode 100644
index 000000000000..3cee64b58910
--- /dev/null
+++ b/media-libs/libjxl/Manifest
@@ -0,0 +1,2 @@
+DIST libjxl-0.11.2.tar.gz 1882762 BLAKE2B 86735fb986eb8a6e6f8c527e3288b6a01a41c458eeabe090dff1ef14a0f907a424dac064c92c26d634d0680d9a4e38054b7dab0a7dcb43e97b774332caf19a88 SHA512 a7e1f7d060b358f4382e84367d66aa2850aef3b4524a0fdfe3f22dd258fb9e35dda7540f859d8bf4c32f31c61a7a03db677f4490a9f472cd25869a9d00797336
+DIST libjxl-testdata-ff8d743aaba05b3014f17e5475e576242fa979fc.tar.gz 69105882 BLAKE2B a80fce437b810e7b99b4c7bd106ec7eba01a1eeddc90e1b82cb8d75f3ca194c357ef8e7b7e1e9da65aa39dc2cd11d32cb6de8558188c5258c7446d58787603ff SHA512 0d237e706fd8d001a9cb245b685e8e39085416daedec019c348ccc64cf15a34cecdb0c245f94f57507f5934e487ee5157f51f59bb6a000f5899862c582336384
diff --git a/media-libs/libjxl/libjxl-0.11.2.ebuild b/media-libs/libjxl/libjxl-0.11.2.ebuild
new file mode 100644
index 000000000000..f74144dd8745
--- /dev/null
+++ b/media-libs/libjxl/libjxl-0.11.2.ebuild
@@ -0,0 +1,121 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib gnome2-utils
+
+# This changes frequently.  Please check the testdata submodule when bumping.
+TESTDATA_COMMIT="ff8d743aaba05b3014f17e5475e576242fa979fc"
+DESCRIPTION="JPEG XL image format reference implementation"
+HOMEPAGE="https://github.com/libjxl/libjxl/"
+SRC_URI="
+	https://github.com/libjxl/libjxl/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+	test? (
+		https://github.com/libjxl/testdata/archive/${TESTDATA_COMMIT}.tar.gz
+			-> ${PN}-testdata-${TESTDATA_COMMIT}.tar.gz
+	)
+"
+
+LICENSE="BSD"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc64 ~riscv ~sparc x86"
+IUSE="+gdk-pixbuf gif jpeg openexr +png test"
+REQUIRED_USE="test? ( png )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/brotli:=[${MULTILIB_USEDEP}]
+	>=dev-cpp/highway-1.0.7[${MULTILIB_USEDEP}]
+	>=media-libs/lcms-2.13:2[${MULTILIB_USEDEP}]
+	gdk-pixbuf? (
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf:2
+	)
+	gif? ( media-libs/giflib:=[${MULTILIB_USEDEP}] )
+	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
+	openexr? ( media-libs/openexr:= )
+	png? ( media-libs/libpng:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	${DEPEND}
+	>=x11-misc/shared-mime-info-2.2
+"
+DEPEND+="
+	test? (
+		dev-cpp/gtest[${MULTILIB_USEDEP}]
+		>=dev-cpp/highway-1.0.7[${MULTILIB_USEDEP},test]
+	)
+"
+BDEPEND="
+	test? ( x11-misc/xdg-utils )
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DJPEGXL_ENABLE_BENCHMARK=OFF
+		-DJPEGXL_ENABLE_COVERAGE=OFF
+		-DJPEGXL_ENABLE_FUZZERS=OFF
+		-DJPEGXL_ENABLE_SJPEG=OFF
+		-DJPEGXL_WARNINGS_AS_ERRORS=OFF
+
+		-DCMAKE_DISABLE_FIND_PACKAGE_GIF=$(usex !gif)
+		-DCMAKE_DISABLE_FIND_PACKAGE_JPEG=$(usex !jpeg)
+		-DCMAKE_DISABLE_FIND_PACKAGE_PNG=$(usex !png)
+
+		-DJPEGXL_ENABLE_SKCMS=OFF
+		-DJPEGXL_ENABLE_VIEWERS=OFF
+		-DJPEGXL_FORCE_SYSTEM_BROTLI=ON
+		-DJPEGXL_FORCE_SYSTEM_GTEST=ON
+		-DJPEGXL_FORCE_SYSTEM_HWY=ON
+		-DJPEGXL_FORCE_SYSTEM_LCMS2=ON
+		-DJPEGXL_ENABLE_DOXYGEN=OFF
+		-DJPEGXL_ENABLE_MANPAGES=OFF
+		-DJPEGXL_ENABLE_JNI=OFF
+		-DJPEGXL_ENABLE_JPEGLI=OFF
+		-DJPEGXL_ENABLE_JPEGLI_LIBJPEG=OFF
+		-DJPEGXL_ENABLE_TCMALLOC=OFF
+		-DJPEGXL_ENABLE_EXAMPLES=OFF
+		-DBUILD_TESTING=$(usex test ON OFF)
+	)
+
+	if use test; then
+		mycmakeargs+=(
+			-DJPEGXL_TEST_DATA_PATH="${WORKDIR}/testdata-${TESTDATA_COMMIT}"
+		)
+	fi
+
+	if multilib_is_native_abi; then
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=ON
+			-DJPEGXL_ENABLE_OPENEXR=$(usex openexr)
+			-DJPEGXL_ENABLE_PLUGINS=ON
+			-DJPEGXL_ENABLE_PLUGIN_GDKPIXBUF=$(usex gdk-pixbuf)
+			-DJPEGXL_ENABLE_PLUGIN_GIMP210=OFF
+			-DJPEGXL_ENABLE_PLUGIN_MIME=OFF
+		)
+	else
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=OFF
+			-DJPEGXL_ENABLE_OPENEXR=OFF
+			-DJPEGXL_ENABLE_PLUGINS=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+
+	find "${ED}" -name '*.a' -delete || die
+}
+
+pkg_postinst() {
+	use gdk-pixbuf && multilib_foreach_abi gnome2_gdk_pixbuf_update
+}
+
+pkg_postrm() {
+	use gdk-pixbuf && multilib_foreach_abi gnome2_gdk_pixbuf_update
+}
diff --git a/media-libs/libjxl/libjxl-9999.ebuild b/media-libs/libjxl/libjxl-9999.ebuild
new file mode 100644
index 000000000000..6dfdc16d3787
--- /dev/null
+++ b/media-libs/libjxl/libjxl-9999.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib git-r3 gnome2-utils
+
+DESCRIPTION="JPEG XL image format reference implementation"
+HOMEPAGE="https://github.com/libjxl/libjxl/"
+
+EGIT_REPO_URI="https://github.com/libjxl/libjxl.git"
+EGIT_SUBMODULES=(
+	third_party/skcms
+	third_party/testdata
+)
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="+gdk-pixbuf gif jpeg openexr +png test"
+REQUIRED_USE="test? ( png )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/brotli:=[${MULTILIB_USEDEP}]
+	>=dev-cpp/highway-1.0.7[${MULTILIB_USEDEP}]
+	>=media-libs/lcms-2.13:2[${MULTILIB_USEDEP}]
+	gdk-pixbuf? (
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf:2
+	)
+	gif? ( media-libs/giflib:=[${MULTILIB_USEDEP}] )
+	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
+	openexr? ( media-libs/openexr:= )
+	png? ( media-libs/libpng:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	${DEPEND}
+	>=x11-misc/shared-mime-info-2.2
+"
+DEPEND+="
+	test? ( dev-cpp/gtest[${MULTILIB_USEDEP}] )
+"
+BDEPEND="
+	test? ( x11-misc/xdg-utils )
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DJPEGXL_ENABLE_BENCHMARK=OFF
+		-DJPEGXL_ENABLE_COVERAGE=OFF
+		-DJPEGXL_ENABLE_FUZZERS=OFF
+		-DJPEGXL_ENABLE_SJPEG=OFF
+		-DJPEGXL_WARNINGS_AS_ERRORS=OFF
+
+		-DCMAKE_DISABLE_FIND_PACKAGE_GIF=$(usex !gif)
+		-DCMAKE_DISABLE_FIND_PACKAGE_JPEG=$(usex !jpeg)
+		-DCMAKE_DISABLE_FIND_PACKAGE_PNG=$(usex !png)
+
+		-DJPEGXL_ENABLE_SKCMS=OFF
+		-DJPEGXL_ENABLE_VIEWERS=OFF
+		-DJPEGXL_FORCE_SYSTEM_BROTLI=ON
+		-DJPEGXL_FORCE_SYSTEM_GTEST=ON
+		-DJPEGXL_FORCE_SYSTEM_HWY=ON
+		-DJPEGXL_FORCE_SYSTEM_LCMS2=ON
+		-DJPEGXL_ENABLE_DOXYGEN=OFF
+		-DJPEGXL_ENABLE_MANPAGES=OFF
+		-DJPEGXL_ENABLE_JNI=OFF
+		-DJPEGXL_ENABLE_JPEGLI=OFF
+		-DJPEGXL_ENABLE_JPEGLI_LIBJPEG=OFF
+		-DJPEGXL_ENABLE_TCMALLOC=OFF
+		-DJPEGXL_ENABLE_EXAMPLES=OFF
+		-DBUILD_TESTING=$(usex test ON OFF)
+	)
+
+	if use test; then
+		mycmakeargs+=(
+			-DJPEGXL_TEST_DATA_PATH="${WORKDIR}/testdata-${TESTDATA_COMMIT}"
+		)
+	fi
+
+	if multilib_is_native_abi; then
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=ON
+			-DJPEGXL_ENABLE_OPENEXR=$(usex openexr)
+			-DJPEGXL_ENABLE_PLUGINS=ON
+			-DJPEGXL_ENABLE_PLUGIN_GDKPIXBUF=$(usex gdk-pixbuf)
+			-DJPEGXL_ENABLE_PLUGIN_GIMP210=OFF
+			-DJPEGXL_ENABLE_PLUGIN_MIME=OFF
+		)
+	else
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=OFF
+			-DJPEGXL_ENABLE_OPENEXR=OFF
+			-DJPEGXL_ENABLE_PLUGINS=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+
+	find "${ED}" -name '*.a' -delete || die
+}
+
+pkg_postinst() {
+	use gdk-pixbuf && multilib_foreach_abi gnome2_gdk_pixbuf_update
+}
+
+pkg_postrm() {
+	use gdk-pixbuf && multilib_foreach_abi gnome2_gdk_pixbuf_update
+}
diff --git a/media-libs/libjxl/metadata.xml b/media-libs/libjxl/metadata.xml
new file mode 100644
index 000000000000..af845deccff3
--- /dev/null
+++ b/media-libs/libjxl/metadata.xml
@@ -0,0 +1,32 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>dnovomesky@gmail.com</email>
+    <name>Daniel Novomesky</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <maintainer type="person">
+    <email>mgorny@gentoo.org</email>
+    <name>Michał Górny</name>
+  </maintainer>
+  <longdescription>
+    JPEG XL reference implementation
+    (encoder and decoder), called libjxl.
+    Contains command line utilities: cjxl, djxl, jxlinfo.
+  </longdescription>
+  <use>
+    <flag name="jpeg">
+      Enable full support for JPEG images.  When disabled, only
+      lossless conversion between JPEG and JPEG-XL is supported.
+    </flag>
+    <flag name="gdk-pixbuf">Build a gdk-pixbuf loader.</flag>
+  </use>
+  <upstream>
+    <remote-id type="cpe">cpe:/a:libjxl_project:libjxl</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>