Adding metadata

4 files changed, 200 insertions, 0 deletions

diff --git a/media-libs/harfbuzz/Manifest b/media-libs/harfbuzz/Manifest
new file mode 100644
index 000000000000..1aeb9709b1d6
--- /dev/null
+++ b/media-libs/harfbuzz/Manifest
@@ -0,0 +1 @@
+DIST harfbuzz-12.3.2.tar.xz 19282952 BLAKE2B 13371f7717eb33c6c1abee376a98c1b25d1205a51c8f7fab05f84fac9a2fd26d7d1f3480fe017760dbec45c0a6707c3b22673f0382835644461f2dc1ed04387e SHA512 2bb907d206edb93a9fb0856dc2e767d491f79f20cd8e8eeeb65f284f10b67ca9ae16b6a8e72ebbfedfeaa0199af7c12dbe675eb08b7c1fb61d2f5ca1fa406782
diff --git a/media-libs/harfbuzz/harfbuzz-12.3.2.ebuild b/media-libs/harfbuzz/harfbuzz-12.3.2.ebuild
new file mode 100644
index 000000000000..0757b616922f
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-12.3.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit flag-o-matic meson-multilib python-any-r1 xdg-utils
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="https://harfbuzz.github.io/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/harfbuzz/harfbuzz.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/harfbuzz/harfbuzz/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="Old-MIT ISC icu"
+# 0.9.18 introduced the harfbuzz-icu split; bug #472416
+# 3.0.0 dropped some unstable APIs; bug #813705
+# 6.0.0 changed libharfbuzz-subset.so ABI
+SLOT="0/6.0.0"
+
+IUSE="+cairo debug doc experimental +glib +graphite icu +introspection test +truetype"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:=[${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}] )
+	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-apps/help2man
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-util/glib-utils )
+"
+
+src_prepare() {
+	default
+
+	xdg_environment_reset
+
+	# bug #790359
+	filter-flags -fexceptions -fthreadsafe-statics
+
+	if ! use debug ; then
+		append-cppflags -DHB_NDEBUG
+	fi
+}
+
+multilib_src_configure() {
+	# harfbuzz-gobject only used for introspection, bug #535852
+	local emesonargs=(
+		-Dcoretext=disabled
+		-Dchafa=disabled
+		-Dfontations=disabled
+		-Dwasm=disabled
+
+		$(meson_feature cairo)
+		$(meson_feature glib)
+		$(meson_feature graphite graphite2)
+		$(meson_feature icu)
+		$(meson_feature introspection gobject)
+		$(meson_feature test tests)
+		$(meson_feature truetype freetype)
+
+		$(meson_native_use_feature doc docs)
+		$(meson_native_use_feature introspection)
+		# Breaks building tests..
+		#$(meson_native_use_feature utilities)
+
+		$(meson_use experimental experimental_api)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# harfbuzz:src / check-static-inits times out on hppa
+	meson_src_test --timeout-multiplier 5
+}
diff --git a/media-libs/harfbuzz/harfbuzz-9999.ebuild b/media-libs/harfbuzz/harfbuzz-9999.ebuild
new file mode 100644
index 000000000000..e94a7fa3b342
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-9999.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit flag-o-matic meson-multilib python-any-r1 xdg-utils
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="https://harfbuzz.github.io/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/harfbuzz/harfbuzz.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/harfbuzz/harfbuzz/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="Old-MIT ISC icu"
+# 0.9.18 introduced the harfbuzz-icu split; bug #472416
+# 3.0.0 dropped some unstable APIs; bug #813705
+# 6.0.0 changed libharfbuzz-subset.so ABI
+SLOT="0/6.0.0"
+
+IUSE="+cairo debug doc experimental +glib +graphite icu +introspection test +truetype"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:=[${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}] )
+	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-apps/help2man
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-util/glib-utils )
+"
+
+src_prepare() {
+	default
+
+	xdg_environment_reset
+
+	# bug #790359
+	filter-flags -fexceptions -fthreadsafe-statics
+
+	if ! use debug ; then
+		append-cppflags -DHB_NDEBUG
+	fi
+}
+
+multilib_src_configure() {
+	# harfbuzz-gobject only used for introspection, bug #535852
+	local emesonargs=(
+		-Dcoretext=disabled
+		-Dchafa=disabled
+		-Dfontations=disabled
+		-Dwasm=disabled
+
+		$(meson_feature cairo)
+		$(meson_feature glib)
+		$(meson_feature graphite graphite2)
+		$(meson_feature icu)
+		$(meson_feature introspection gobject)
+		$(meson_feature test tests)
+		$(meson_feature truetype freetype)
+
+		$(meson_native_use_feature doc docs)
+		$(meson_native_use_feature introspection)
+		# Breaks building tests..
+		#$(meson_native_use_feature utilities)
+
+		$(meson_use experimental experimental_api)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# harfbuzz:src / check-static-inits times out on hppa
+	meson_src_test --timeout-multiplier 5
+}
diff --git a/media-libs/harfbuzz/metadata.xml b/media-libs/harfbuzz/metadata.xml
new file mode 100644
index 000000000000..75a74263574a
--- /dev/null
+++ b/media-libs/harfbuzz/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>office@gentoo.org</email>
+    <name>Gentoo Office project</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="cpe">cpe:/a:harfbuzz_project:harfbuzz</remote-id>
+  </upstream>
+  <use>
+    <flag name="experimental">Enable experimental APIs</flag>
+    <flag name="glib">Enable <pkg>dev-libs/glib</pkg> unicode functions</flag>
+    <flag name="graphite">Enable <pkg>media-gfx/graphite2</pkg> complementary shaper</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>