Adding metadata

8 files changed, 188 insertions, 6 deletions

diff --git a/gui-libs/gtk4-layer-shell/Manifest b/gui-libs/gtk4-layer-shell/Manifest
index 0125604f844f..1f779ad6e8aa 100644
--- a/gui-libs/gtk4-layer-shell/Manifest
+++ b/gui-libs/gtk4-layer-shell/Manifest
@@ -1 +1,2 @@
 DIST gtk4-layer-shell-1.1.1.tar.gz 70227 BLAKE2B f90e6456b4d793609183127f4e4137363f2ef1f3527c7e405dd41ec17ffed4407dc1566dca1f5336cea6cab8541bcad9bcca81f8297abd2a34bd3f03f1fd8089 SHA512 5c47e1df308fe9ee53bc16458209b845854307fd1d939a0342568f3a1a22bc2b40b8d817642c69a81be4c2d291495b1f900c084276c605952eead103b3cb6a02
+DIST gtk4-layer-shell-1.3.0.tar.gz 79405 BLAKE2B e65fc7ff36f9210e0b16f9e606f5c62ac89b8c95ca1fb3eda7754f46d1e604e0d4bc954e13e47fe90572e945ea2ed277de863c1006532c3023f74ffd9a36f99d SHA512 dab8350caa6713406e4dd8a3f701f1ed1fb287913d96d697f7c3875efd27b24a504e01010c2e1cf90d45241ef3e1efa5dc678c69182946f0abf7010648700eff
diff --git a/gui-libs/gtk4-layer-shell/gtk4-layer-shell-1.3.0.ebuild b/gui-libs/gtk4-layer-shell/gtk4-layer-shell-1.3.0.ebuild
new file mode 100644
index 000000000000..344be9e57982
--- /dev/null
+++ b/gui-libs/gtk4-layer-shell/gtk4-layer-shell-1.3.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+inherit meson python-any-r1 vala
+
+DESCRIPTION="A library for using the Layer Shell Wayland protocol with GTK4"
+HOMEPAGE="https://github.com/wmww/gtk4-layer-shell"
+SRC_URI="https://github.com/wmww/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="doc examples introspection +smoke-tests test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/wayland-1.10.0
+	>=gui-libs/gtk-4.10.5:4[wayland]
+	dev-libs/glib:2
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.16
+	>=dev-util/wayland-scanner-1.10.0
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
+	doc? ( dev-util/gtk-doc )
+	vala? ( dev-lang/vala[vapigen(+)] )
+	test? (
+		${PYTHON_DEPS}
+		examples? (
+			smoke-tests? (
+				dev-lang/luajit
+				dev-lua/lgi
+			)
+		)
+	)
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	if use vala; then
+		vala_setup
+	else
+		# Disable the vala smoke test if not built with vala
+		sed '/test-vala-example/d' -i test/smoke-tests/meson.build || die
+		rm test/smoke-tests/test-vala-example.py || die
+	fi
+
+	default
+
+	use test && python_fix_shebang "${S}"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use examples)
+		$(meson_use doc docs)
+		$(meson_use test tests)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	if use test && use examples; then
+		emesonargs+=( $(meson_use smoke-tests) )
+	else
+		emesonargs+=( -Dsmoke-tests=false )
+	fi
+	meson_src_configure
+}
diff --git a/gui-libs/wayfire-plugins-extra/Manifest b/gui-libs/wayfire-plugins-extra/Manifest
index 538d37c6b7a3..e3c06472665e 100644
--- a/gui-libs/wayfire-plugins-extra/Manifest
+++ b/gui-libs/wayfire-plugins-extra/Manifest
@@ -1 +1,2 @@
 DIST wayfire-plugins-extra-0.10.0.tar.xz 96584 BLAKE2B 18cf7da7dff2be95cdbd104789f8bed0675aed05295ebacefd24503bad5abba84e0ed0b873de97dbf7916dc8607ab7ad41f2ac03b3b2ed2708beaa7b7eb14905 SHA512 96a8e82790dad59d67989073332f248806c71bf3fe1d491a098880aae9389bf06243e5a7e7ea5271a1a262bea6b94a04260f105baf3de3f03695d4533f4c56b2
+DIST wayfire-plugins-extra-0.11.0_pre20260801.tar.gz 87551 BLAKE2B 0b7ca39de73950ea69ef1551620e96c1da7d8d606cf44e20067481a3dc377d959efc0444f68ae80f00fe4068c917de2d32d971dea1be70999b48062cf51ea445 SHA512 4542ff4263f74204e5f46ed9d840d142818ccc6849842906a238bb04b4cce6c0be284c6dc6c934efd834f3936a53d06af6dea9780e9d26b91267f9956bc6290f
diff --git a/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-0.11.0_pre20260801.ebuild b/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-0.11.0_pre20260801.ebuild
new file mode 100644
index 000000000000..e305fff1e15b
--- /dev/null
+++ b/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-0.11.0_pre20260801.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2019-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="extra plugins for wayfire"
+HOMEPAGE="https://github.com/WayfireWM/wayfire-plugins-extra"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/WayfireWM/wayfire-plugins-extra.git"
+	SLOT="0/0.12"
+else
+	COMMIT=4290ddf13bfadb344d45cb25c47f7825bbdc8a30
+	SRC_URI="https://github.com/WayfireWM/wayfire-plugins-extra/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${COMMIT}
+	KEYWORDS="~amd64 ~arm64"
+	SLOT="0/$(ver_cut 1-2)"
+fi
+
+LICENSE="MIT"
+
+# no tests
+RESTRICT="test"
+
+WAYFIRE_REVDEP="
+	dev-libs/glib:2
+	dev-libs/libsigc++:2
+	gui-libs/wf-config:=
+	gui-libs/wlroots:0.20
+	x11-libs/cairo
+"
+
+DEPEND="
+	${WAYFIRE_REVDEP}
+	dev-cpp/glibmm:2
+	dev-libs/boost
+	dev-libs/libevdev
+	dev-libs/wayland
+	>=gui-wm/wayfire-0.11:*
+	media-libs/glm
+	media-libs/libglvnd
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.12
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	virtual/pkgconfig
+"
diff --git a/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-9999.ebuild b/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-9999.ebuild
index c2940b9adf01..1e306f3a1e7a 100644
--- a/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-9999.ebuild
+++ b/gui-libs/wayfire-plugins-extra/wayfire-plugins-extra-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2019-2025 Gentoo Authors
+# Copyright 2019-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -11,7 +11,7 @@ HOMEPAGE="https://github.com/WayfireWM/wayfire-plugins-extra"
 if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/WayfireWM/wayfire-plugins-extra.git"
-	SLOT="0/0.11"
+	SLOT="0/0.12"
 else
 	SRC_URI="https://github.com/WayfireWM/wayfire-plugins-extra/releases/download/v${PV}/${P}.tar.xz"
 	KEYWORDS="~amd64 ~arm64"
@@ -27,7 +27,7 @@ WAYFIRE_REVDEP="
 	dev-libs/glib:2
 	dev-libs/libsigc++:2
 	gui-libs/wf-config:=
-	gui-libs/wlroots:0.19
+	gui-libs/wlroots:0.20
 	x11-libs/cairo
 "
 
@@ -37,11 +37,14 @@ DEPEND="
 	dev-libs/boost
 	dev-libs/libevdev
 	dev-libs/wayland
-	gui-wm/wayfire:${SLOT}
+	>=gui-wm/wayfire-0.11:*
+	media-libs/glm
+	media-libs/libglvnd
 "
 RDEPEND="${DEPEND}"
 BDEPEND="
 	>=dev-libs/wayland-protocols-1.12
 	dev-util/wayland-scanner
+	sys-devel/gettext
 	virtual/pkgconfig
 "
diff --git a/gui-libs/wf-config/Manifest b/gui-libs/wf-config/Manifest
index 4338e19f6d43..9ec08bdc6ebe 100644
--- a/gui-libs/wf-config/Manifest
+++ b/gui-libs/wf-config/Manifest
@@ -1 +1,2 @@
 DIST wf-config-0.10.0.tar.xz 43684 BLAKE2B e7d80f8f73956a68206a504524463bb357d89376faf044b17731a7584b481acf008814f405a0415965abde12d79ef7ca4cb1788780e979e80d3d9c65a80de229 SHA512 c75eb9188a361cc6f59d5c2142600337c71b05c5175ac8a2d8040c4fce4036d0ceb85ed87023d2db0704b55364aa88779510a757c225ba839faa0b751e03ed9f
+DIST wf-config-0.11.0.tar.xz 45268 BLAKE2B 48401f133a914d2158952997354325bff1033e35863c060ed8015a0be6a2183f2e55f95f9199383ef8493bc71715583d597bb0b4332f953048889dbc116158e6 SHA512 0ce0f646bf313ea50eea2cf38859b372408d78023f733b99fad24b1dd5149bdb2b92702295865359938ba35384a55ad9e995f7a61f4fa5ad090dcee918dec6ff
diff --git a/gui-libs/wf-config/wf-config-0.11.0.ebuild b/gui-libs/wf-config/wf-config-0.11.0.ebuild
new file mode 100644
index 000000000000..5778f77f80f2
--- /dev/null
+++ b/gui-libs/wf-config/wf-config-0.11.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2019-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="library for managing wayfire configuration files"
+HOMEPAGE="https://github.com/WayfireWM/wf-config"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/WayfireWM/wf-config.git"
+	SLOT="0/0.12"
+else
+	SRC_URI="https://github.com/WayfireWM/wf-config/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+	SLOT="0/$(ver_cut 1-2)"
+fi
+
+LICENSE="MIT"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/libevdev
+	dev-libs/libxml2:=
+	media-libs/glm
+"
+RDEPEND="
+	${DEPEND}
+	!gui-wm/wayfire:0/0.9
+"
+BDEPEND="
+	dev-libs/wayland-protocols
+	virtual/pkgconfig
+	test? ( dev-cpp/doctest )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test tests)
+		-Dlocale_test=false # requires de_DE locale to be installed
+	)
+
+	meson_src_configure
+}
diff --git a/gui-libs/wf-config/wf-config-9999.ebuild b/gui-libs/wf-config/wf-config-9999.ebuild
index baf979471136..5778f77f80f2 100644
--- a/gui-libs/wf-config/wf-config-9999.ebuild
+++ b/gui-libs/wf-config/wf-config-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2019-2025 Gentoo Authors
+# Copyright 2019-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -11,7 +11,7 @@ HOMEPAGE="https://github.com/WayfireWM/wf-config"
 if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/WayfireWM/wf-config.git"
-	SLOT="0/0.11"
+	SLOT="0/0.12"
 else
 	SRC_URI="https://github.com/WayfireWM/wf-config/releases/download/v${PV}/${P}.tar.xz"
 	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"