Adding metadata

5 files changed, 100 insertions, 70 deletions

diff --git a/games-emulation/dosbox-staging/Manifest b/games-emulation/dosbox-staging/Manifest
index 1ba80b463b83..80251d92a7d6 100644
--- a/games-emulation/dosbox-staging/Manifest
+++ b/games-emulation/dosbox-staging/Manifest
@@ -1 +1,3 @@
+DIST Nuked-SC55-CLAP-0.11.0.tar.gz 143699 BLAKE2B 646bdc10efb7e350bf9229b400303500d7e1a66b389c79a1422e249f9e746b34f6396ae380eb3b1ad9a632445951dd4acb1ce82048157c6deb8549ab1c407f0b SHA512 5ffe259792685361dd140b02a12b5c3e0e707f980a2cf25701a8a5e267963fd5a207bce7330213580717e5bc08c733e11b581de7f1313425707777cc46e17d3a
 DIST dosbox-staging-0.82.2.tar.gz 6691414 BLAKE2B d37be59d5817058fab3252377dd8103d8a89364ac27025680eaaba9741c603ca6f4e91d3b3f6b1ec21ee8a5904a04a587d367ab9274ad8f4c809e4fe7e1d13dc SHA512 09dfd20f3a749e141a3eca41bd4556fdcb33df864a908710fb6f6163dbdab4f427c2738354c089cea53af0ae8f7cd3f526ad9939e5e562abb9c9705a443c3c5d
+DIST dosbox-staging-0.83.0.tar.gz 9584499 BLAKE2B 8643daa6907a7fb1cc35d8bff1603f053b1099b669c705ff1b101b1d913cb3d3d13a0defd40d7e107440c3658e18e4525bbd6297546d65ba37767e209d80d38b SHA512 f7ed2fab3db23a24b2f3c3199c81402a2b6f4f648ba1f9338ad8718a069079f4ccbc7af8a0b4e454bd445c8b2f976db69517c01474d297a4807894d46925819e
diff --git a/games-emulation/dosbox-staging/dosbox-staging-0.82.2-r1.ebuild b/games-emulation/dosbox-staging/dosbox-staging-0.82.2-r1.ebuild
deleted file mode 100644
index cf5f1d50f85f..000000000000
--- a/games-emulation/dosbox-staging/dosbox-staging-0.82.2-r1.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 2020-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-inherit meson xdg
-
-DESCRIPTION="Modernized DOSBox soft-fork"
-HOMEPAGE="https://dosbox-staging.github.io/"
-SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-IUSE="+alsa debug dynrec +fluidsynth mt-32 network opengl slirp test"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="alsa? ( media-libs/alsa-lib )
-	debug? ( sys-libs/ncurses:0= )
-	fluidsynth? (
-		media-sound/fluid-soundfont
-		media-sound/fluidsynth
-	)
-	mt-32? ( media-libs/munt-mt32emu )
-	network? ( media-libs/sdl2-net )
-	opengl? ( virtual/opengl )
-	slirp? ( net-libs/libslirp )
-	media-libs/iir1
-	media-libs/libpng:0=
-	media-libs/libsdl2[joystick,opengl?,video,X]
-	media-libs/opusfile
-	media-libs/speexdsp
-	virtual/zlib:=
-	sys-libs/zlib-ng:=
-	!games-emulation/dosbox"
-DEPEND="${RDEPEND}"
-BDEPEND="test? ( dev-cpp/gtest )"
-
-DOCS=( AUTHORS README THANKS )
-
-src_prepare() {
-	default
-
-	# We do not have default.sf2, use actual name from fluid-soundfont
-	sed -e "s/default.sf2/FluidR3_GM.sf2/" \
-		-i src/midi/midi_fluidsynth.cpp || die
-
-	# Disable license and docs install (handled by ebuild)
-	sed -e "/licenses_dir\|doc_dir/d" -i meson.build || die
-}
-
-src_configure() {
-	# xinput2 comes with libsdl2[X]
-	local emesonargs=(
-		-Duse_xinput2=true
-		-Duse_zlib_ng=native
-		$(meson_use alsa use_alsa)
-		$(meson_use debug)
-		-Ddynamic_core=$(usex dynrec dynrec dyn-x86)
-		$(meson_use fluidsynth use_fluidsynth)
-		$(meson_use mt-32 use_mt32emu)
-		$(meson_use network use_sdl2_net)
-		$(meson_use opengl use_opengl)
-		$(meson_use slirp use_slirp)
-		$(meson_feature test unit_tests)
-	)
-	meson_src_configure
-}
diff --git a/games-emulation/dosbox-staging/dosbox-staging-0.83.0.ebuild b/games-emulation/dosbox-staging/dosbox-staging-0.83.0.ebuild
new file mode 100644
index 000000000000..94a10835d6f3
--- /dev/null
+++ b/games-emulation/dosbox-staging/dosbox-staging-0.83.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 2020-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+# Nuked SC-55 CLAP audio plugin
+SC55PV=0.11.0
+SC55_S="${WORKDIR}/Nuked-SC55-CLAP-${SC55PV}"
+SC55_BUILD_DIR="${SC55_S}_build"
+
+DESCRIPTION="Modernized DOSBox soft-fork"
+HOMEPAGE="https://dosbox-staging.github.io/"
+SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	sc55? (
+		https://github.com/johnnovak/Nuked-SC55-CLAP/archive/refs/tags/v${SC55PV}.tar.gz
+			-> Nuked-SC55-CLAP-${SC55PV}.tar.gz
+	)"
+
+LICENSE="GPL-2+ sc55? ( XMAME )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="debug dynrec mt-32 opengl +sc55 slirp test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="debug? ( sys-libs/ncurses:0= )
+	mt-32? ( media-libs/munt-mt32emu )
+	opengl? ( virtual/opengl )
+	slirp? ( net-libs/libslirp )
+	dev-cpp/asio
+	media-libs/alsa-lib
+	media-libs/iir1
+	media-libs/libpng:0=
+	media-libs/libsdl2[alsa,joystick,opengl?,sound,video,X]
+	media-libs/opusfile
+	media-libs/speexdsp
+	media-sound/fluid-soundfont
+	media-sound/fluidsynth
+	virtual/zlib:=
+	sys-libs/zlib-ng:=
+	!games-emulation/dosbox"
+DEPEND="${RDEPEND}"
+BDEPEND="test? ( dev-cpp/gtest )
+	sc55? ( virtual/pkgconfig )"
+
+DOCS=( README.md docs/AUTHORS )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# We do not have default.sf2, use actual name from fluid-soundfont
+	sed -e "s/default.sf2/FluidR3_GM.sf2/" \
+		-i src/midi/fluidsynth.cpp || die
+
+	# Disable license install
+	# Fix install path
+	sed -e '/install(.*license/I,/)/d' \
+		-e 's#${RESOURCE_COPY_PATH}#\0/#' \
+		-i cmake/add_install_rules.cmake || die
+
+	use sc55 && CMAKE_USE_DIR="${SC55_S}" BUILD_DIR="${SC55_BUILD_DIR}" cmake_prepare
+}
+
+src_configure() {
+	if use sc55; then
+		CMAKE_USE_DIR="${SC55_S}" BUILD_DIR="${SC55_BUILD_DIR}" cmake_src_configure
+	fi
+
+	# alsa is needed already by libsdl2[alsa,sound]
+	# xinput2 comes with libsdl2[X]
+	local mycmakeargs=(
+		-DUSE_SYSTEM_LIBS=ON
+		-DOPT_XINPUT=ON
+		-DOPT_DEBUGGER=$(usex debug)
+		-DOPT_FORCE_DYNREC=$(usex dynrec)
+		-DOPT_MT32EMU=$(usex mt-32)
+		-DOPT_OPENGL=$(usex opengl)
+		-DOPT_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	use sc55 && CMAKE_USE_DIR="${SC55_S}" BUILD_DIR="${SC55_BUILD_DIR}" cmake_src_compile
+	cmake_src_compile
+}
+
+src_install() {
+	if use sc55; then
+		insinto /usr/share/dosbox-staging/plugins
+		doins "${SC55_BUILD_DIR}/Nuked-SC55.clap"
+	fi
+	cmake_src_install
+}
diff --git a/games-emulation/dosbox-staging/metadata.xml b/games-emulation/dosbox-staging/metadata.xml
index 0eeb7c29388c..015392a9f3a3 100644
--- a/games-emulation/dosbox-staging/metadata.xml
+++ b/games-emulation/dosbox-staging/metadata.xml
@@ -10,6 +10,7 @@
     <flag name="fluidsynth">Use <pkg>media-sound/fluidsynth</pkg> for MIDI emulation</flag>
     <flag name="mt-32">Use <pkg>media-libs/munt-mt32emu</pkg> for MT-32 emulation</flag>
     <flag name="network">Enable networking features (modem, ipx)</flag>
+    <flag name="sc55">Build and install the plugin for SC-55 MIDI emulation</flag>
     <flag name="slirp">Enable Ethernet emulation using <pkg>net-libs/libslirp</pkg>
     </flag>
   </use>
diff --git a/games-emulation/eden/eden-9999.ebuild b/games-emulation/eden/eden-9999.ebuild
index 32e65beb8015..adb2fd2b4657 100644
--- a/games-emulation/eden/eden-9999.ebuild
+++ b/games-emulation/eden/eden-9999.ebuild
@@ -51,8 +51,7 @@ RDEPEND="
 	media-gfx/renderdoc
 	media-libs/libsdl3[udev]
 	media-libs/libva
-	media-libs/opus
-	media-video/ffmpeg
+	media-video/ffmpeg[opus]
 	net-libs/enet
 	net-libs/mbedtls:3
 	virtual/zlib:=