Adding metadata

3 files changed, 67 insertions, 3 deletions

diff --git a/dev-vcs/python-gitlab/Manifest b/dev-vcs/python-gitlab/Manifest
index 86fe4c694f1f..1fdf0a0e6e85 100644
--- a/dev-vcs/python-gitlab/Manifest
+++ b/dev-vcs/python-gitlab/Manifest
@@ -1,2 +1,3 @@
 DIST python-gitlab-3.13.0.tar.gz 270646 BLAKE2B ff7e3c35525ac1bf1cb6dc6e668ca9c8aeefb12073636f115c8e078aa4b9f623f6d847d8487e85e9a325b6f0ad1ef93826631cb32fd86c0bd9023688aac5add9 SHA512 373347392d7030c817a8dcb4cceea71d0609f9e09dce348514c1ca024307094b1a72e287c871ce5fcba9b9d4cdfcc7dc6b4495e2b225b845a3dff2e2dfc4fe82
 DIST python-gitlab-4.6.0.tar.gz 470253 BLAKE2B 25859017478c9c1896088bd706da1980f5c90dff075fa8a9373933852e1a83daf543f7a48acce4619da7077cdfaf64b0cc9f868cd99ee4d8868294f3328d0d13 SHA512 1d0178dd4d0456b25d5d6ecbcb39137cbc273bf4ac1863b696d39fcdb50c927b606b18ea3b21ce66e92102979584bc3922e65577e0d0c72ae937e984ec21cbc3
+DIST python-gitlab-5.6.0.tar.gz 396148 BLAKE2B e203d2ce80ba18e8376b9a7b74c264b04cf0468949d4952b9db8d966f1e6503fc0bf0664cf4667df2f58b2de0c5a9407f0f13fd91bd72c49b2adea79145c3b12 SHA512 fa8276f6ae20b18fad0698a011e6e628f24885e907a9979cfa0e3e2097d5a03342f95ff253fd43d43a25fc51d40d9d76c76839b70f6a1e5a85eea49ef8d88973
diff --git a/dev-vcs/python-gitlab/python-gitlab-4.6.0.ebuild b/dev-vcs/python-gitlab/python-gitlab-4.6.0.ebuild
index bb10aaafcf5b..8571108be3a2 100644
--- a/dev-vcs/python-gitlab/python-gitlab-4.6.0.ebuild
+++ b/dev-vcs/python-gitlab/python-gitlab-4.6.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -25,9 +25,7 @@ LICENSE="LGPL-3"
 SLOT="0"
 
 BDEPEND="test? (
-		dev-python/coverage[${PYTHON_USEDEP}]
 		>=dev-python/pytest-console-scripts-1.3.1[${PYTHON_USEDEP}]
-		dev-python/pytest-cov[${PYTHON_USEDEP}]
 		>=dev-python/pyyaml-5.2[${PYTHON_USEDEP}]
 		dev-python/responses[${PYTHON_USEDEP}]
 		)"
@@ -37,6 +35,14 @@ RDEPEND=">=dev-python/requests-2.32.2[${PYTHON_USEDEP}]
 
 distutils_enable_tests pytest
 
+EPYTEST_IGNORE=(
+	# These tests do not make sense downstream
+	"tests/smoke/test_dists.py"
+	# Requires ability to run docker and pytest-docker
+	# https://bugs.gentoo.org/938085
+	"tests/functional"
+)
+
 python_install_all() {
 	distutils-r1_python_install_all
 	dodoc -r *.rst docs
diff --git a/dev-vcs/python-gitlab/python-gitlab-5.6.0.ebuild b/dev-vcs/python-gitlab/python-gitlab-5.6.0.ebuild
new file mode 100644
index 000000000000..e75ec6b33fa2
--- /dev/null
+++ b/dev-vcs/python-gitlab/python-gitlab-5.6.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+MY_PN="${PN/-/_}"
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+inherit distutils-r1
+
+DESCRIPTION="Python command line interface to gitlab API"
+HOMEPAGE="https://github.com/python-gitlab/python-gitlab/"
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/python-gitlab/python-gitlab"
+	inherit git-r3
+else
+	inherit pypi
+	SRC_URI="$(pypi_sdist_url) -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/requests-2.32.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-1.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/anyio[${PYTHON_USEDEP}]
+		>=dev-python/pytest-console-scripts-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.2[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/respx[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# These tests do not make sense downstream
+	"tests/smoke/test_dists.py"
+	# Requires ability to run docker and pytest-docker
+	# https://bugs.gentoo.org/938085
+	"tests/functional"
+	# Requires unpackaged gql (Used optionally for graphql support at runtime)
+	"tests/unit/test_graphql.py"
+)
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc -r *.rst docs
+}