Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.

3 files changed, 94 insertions, 0 deletions

diff --git a/dev-util/xxdiff/Manifest b/dev-util/xxdiff/Manifest
new file mode 100644
index 000000000000..389ca8ecd8c5
--- /dev/null
+++ b/dev-util/xxdiff/Manifest
@@ -0,0 +1 @@
+DIST xxdiff-5.1_p20250320.tar.gz 2057252 BLAKE2B c70f6c2d1139d97d5e96902ee61cb3cb94379043ddc6b946668b3fc74b5901f11ef3894a40dfda3eee04481e75f00aae6034cbe4a656379e6119e6ad3446a758 SHA512 6c9ac0993dbcb3a2572bedc9f027ab5a47d2a1067f05285190921bf3af2cf2e905d4abb4b8989bc6c2a39cf4bb54dc5d645f4deb9f2d1d468498ca44b5335164
diff --git a/dev-util/xxdiff/metadata.xml b/dev-util/xxdiff/metadata.xml
new file mode 100644
index 000000000000..b694e7a29a1f
--- /dev/null
+++ b/dev-util/xxdiff/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+	<use>
+		<flag name="scripts">Install python helper scripts</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">blais/xxdiff</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-util/xxdiff/xxdiff-5.1_p20250320.ebuild b/dev-util/xxdiff/xxdiff-5.1_p20250320.ebuild
new file mode 100644
index 000000000000..e6d7fd0d6e63
--- /dev/null
+++ b/dev-util/xxdiff/xxdiff-5.1_p20250320.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_OPTIONAL=1
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 qmake-utils
+
+DESCRIPTION="Graphical file and directories comparator and merge tool"
+HOMEPAGE="https://furius.ca/xxdiff/ https://github.com/blais/xxdiff"
+COMMIT="a5593c1c675fb79d0ec2b6e353abba1fb0179aa7"
+SRC_URI="https://github.com/blais/xxdiff/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="scripts"
+REQUIRED_USE="scripts? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-qt/qtbase:6[gui,widgets]
+	scripts? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	${RDEPEND}
+	app-alternatives/yacc
+"
+BDEPEND="
+	scripts? (
+		${DISTUTILS_DEPS}
+		${PYTHON_DEPS}
+	)
+"
+
+pkg_setup() {
+	use scripts && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# don't use bundled getopt #944133
+	sed -e '/getopt.*/d' -i src/xxdiff.pro || die
+
+	use scripts && distutils-r1_src_prepare
+}
+
+src_configure() {
+	pushd src >/dev/null || die
+		# mimic src/Makefile.bootstrap
+		eqmake6
+		cat Makefile.extra >> Makefile || die
+	popd || die
+}
+
+src_compile() {
+	emake -C src MAKEDIR=.
+
+	use scripts && distutils-r1_src_compile
+}
+
+src_install() {
+	local DOCS=( CHANGES README* TODO doc/*.txt src/doc.txt tools )
+	local HTML_DOCS=( doc/*.{png,html} src/doc.html )
+
+	dobin bin/xxdiff
+	doman "${S}"/src/xxdiff.1
+
+	if use scripts; then
+		distutils-r1_src_install
+		# no port to py3
+		rm "${ED}"/usr/bin/termdiff || die
+	fi
+
+	einstalldocs
+}