Adding metadata

4 files changed, 117 insertions, 0 deletions

diff --git a/dev-util/hxtools/Manifest b/dev-util/hxtools/Manifest
new file mode 100644
index 000000000000..5553dee1e030
--- /dev/null
+++ b/dev-util/hxtools/Manifest
@@ -0,0 +1,2 @@
+DIST hxtools-20201116.tar.xz 208540 BLAKE2B 4797657be631308083e75cde3a9ca7f3b73ed5d1ba48822b208a2abe5888d497109c4482957657b11bcd8abf09134162ab8d9a7d4d8e1d58c0522505c07ac5ea SHA512 3ff9dc1f42bea168f43575b2d8f565589a28cf18ed411772ccf179a0ebd9cf3bdb0c280646eacbcc528f5aae894c5835e80f5c9513f97688848ee3cc2625adc4
+DIST hxtools-20251011.tar.zst 202730 BLAKE2B 1abc36e0dc958c2ae6b5716b24dbcc7f1414697880515921c975c8da1361a88ba9192347b754b510b27c1699decff50fae44177063d22a43a1fcbcd6d74cfac1 SHA512 a7e7d759106694b2f0b32c323326c2b64d4e5aabf431219fb76a9b587edebc0a6d69376fa340ad3af6936d3be97041deb411cfe2f530a0ec2b662c662e6d8f88
diff --git a/dev-util/hxtools/hxtools-20201116.ebuild b/dev-util/hxtools/hxtools-20201116.ebuild
new file mode 100644
index 000000000000..10d8f9635463
--- /dev/null
+++ b/dev-util/hxtools/hxtools-20201116.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A collection of tools and scripts"
+HOMEPAGE="https://inai.de/projects/hxtools/"
+SRC_URI="https://inai.de/files/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	>=sys-apps/pciutils-3
+	>=sys-apps/util-linux-2.19
+	>=sys-libs/libhx-3.12.1:=
+	dev-lang/perl
+	sys-libs/libcap:=
+	x11-libs/libxcb:0=
+"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	default
+
+	# man2html is provided by man
+	rm -r "${ED}"/usr/bin/man2html || die
+	rm -r "${ED}"/usr/share/man/man1/man2html* || die
+
+	# Don't collide with dev-util/cwdiff
+	mv "${ED}"/usr/bin/cwdiff "${ED}"/usr/bin/cwdiff.hx || die
+	mv "${ED}"/usr/share/man/man1/cwdiff.1 "${ED}"/usr/share/man/man1/cwdiff.hx.1 || die
+
+	# Gentoo doesn't have /usr/share/kbd:
+	mv "${ED}"/usr/share/kbd/* "${ED}"/usr/share/ || die
+	gzip "${ED}"/usr/share/consolefonts/*fnt || die
+}
diff --git a/dev-util/hxtools/hxtools-20251011-r1.ebuild b/dev-util/hxtools/hxtools-20251011-r1.ebuild
new file mode 100644
index 000000000000..2eb8b217bdfb
--- /dev/null
+++ b/dev-util/hxtools/hxtools-20251011-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit eapi9-ver unpacker
+
+DESCRIPTION="Collection of tools and scripts"
+HOMEPAGE="https://inai.de/projects/hxtools/"
+SRC_URI="https://inai.de/files/${PN}/${P}.tar.zst"
+
+LICENSE="BSD-2-with-patent GPL-2+ GPL-3 LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	dev-lang/perl
+	>=sys-apps/pciutils-3
+	>=sys-apps/util-linux-2.19
+	sys-libs/libcap:=
+	>=sys-libs/libhx-5.1:=
+	x11-libs/libxcb:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(unpacker_src_uri_depends)
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Don't collide with dev-util/cwdiff, sys-fs/xcp
+	sed -i -e 's/cwdiff/cwdiff.hx/' doc/cwdiff.1 || die
+	sed -i -e 's/xcp/xcp.hx/' doc/xcp.1 || die
+	sed -i -e 's/cwdiff/cwdiff.hx/' \
+		-e 's/xcp/xcp.hx/' doc/hxtools.7 || die
+}
+
+src_configure() {
+	# Gentoo doesn't have /usr/share/kbd
+	econf --with-kbddatadir="${EPREFIX}"/usr/share
+}
+
+src_install() {
+	default
+
+	# man2html is provided by man
+	rm -r "${ED}"/usr/bin/man2html || die
+	rm -r "${ED}"/usr/share/man/man1/man2html* || die
+
+	# Don't collide with dev-util/cwdiff
+	mv "${ED}"/usr/bin/cwdiff "${ED}"/usr/bin/cwdiff.hx || die
+	mv "${ED}"/usr/share/man/man1/cwdiff.1 "${ED}"/usr/share/man/man1/cwdiff.hx.1 || die
+	# Don't collide with sys-fs/xcp
+	mv "${ED}"/usr/bin/xcp "${ED}"/usr/bin/xcp.hx || die
+	mv "${ED}"/usr/share/man/man1/xcp.1 "${ED}"/usr/share/man/man1/xcp.hx.1 || die
+	# Don't collide with app-text/xmlformat
+	mv "${ED}"/usr/bin/xmlformat "${ED}"/usr/bin/xmlformat.hx || die
+
+	gzip -r "${ED}"/usr/share/consolefonts || die
+	gzip -r "${ED}"/usr/share/keymaps || die
+}
+
+pkg_postinst() {
+	if ver_replacing -lt 20251011; then
+		elog "vfontas has moved to package app-misc/consoleet-utils"
+	fi
+	if ver_replacing -lt 20251011-r1; then
+		elog "xcp and xmlformat have been renamed to xcp.hx and xmlformat.hx to avoid package collisions"
+	fi
+}
diff --git a/dev-util/hxtools/metadata.xml b/dev-util/hxtools/metadata.xml
new file mode 100644
index 000000000000..5f33304011d5
--- /dev/null
+++ b/dev-util/hxtools/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>