Adding metadata

3 files changed, 68 insertions, 3 deletions

diff --git a/dev-util/hermes/Manifest b/dev-util/hermes/Manifest
index 20171a22d997..5bc0a2b44b72 100644
--- a/dev-util/hermes/Manifest
+++ b/dev-util/hermes/Manifest
@@ -1 +1,2 @@
 DIST hermes-2.9.tar.gz 59493 BLAKE2B 32b53b3ae8cf36851e5b82c859deeba8cd8f36f726bc1284f98729f4c357b85018833aa3c9a04962890cc6621d590a918fcbf21b756c58f88723bf9efc7a745b SHA512 1d4873c96d9039f3e003a3b8f2270c1fa82e9fe323111351d41537c375d8d6e356b50d6c4b950b905bee0662044d2adc887233359dca62876dfc80e74dc271f8
+DIST hermes-3.1.tar.gz 62456 BLAKE2B c9b21332c9ac7f69247fb748b5698e13c2cc1de5c29692fa7fddfe27878ac02d4f24629c4076fb85bfae887c6f1117b996933a9c2f474f8e01a913f84987842d SHA512 b9e5434cc50693a24fa52a176c910504702e89fb2ff931369e244e53e0eb9e24f53de4174c12cc351f7722180faca37f5c13829cdb84f54f0cb4da481f8d1650
diff --git a/dev-util/hermes/hermes-3.1.ebuild b/dev-util/hermes/hermes-3.1.ebuild
new file mode 100644
index 000000000000..35d944afe195
--- /dev/null
+++ b/dev-util/hermes/hermes-3.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1,3,4} luajit )
+inherit lua-single prefix
+
+DESCRIPTION="Lua based testing manager"
+HOMEPAGE="https://github.com/TACC/Hermes"
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/TACC/Hermes"
+else
+	SRC_URI="https://github.com/TACC/Hermes/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${P^}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}
+	$(lua_gen_cond_dep '
+		dev-lua/luafilesystem[${LUA_USEDEP}]
+		dev-lua/luaposix[${LUA_USEDEP}]
+	')
+"
+DEPEND="test? ( ${RDEPEND} )"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.8-lua-shebang.patch )
+
+src_prepare() {
+	default
+	hprefixify -w '/#\!\/bin\/bash/' tm/Tst.lua || die
+}
+
+src_compile() {
+	sed -e "s|@LUA@|${LUA}|g" \
+		-i lib/tool.lua \
+		-i bin/lua_cmd || die
+}
+
+src_test() {
+	local -x PATH="bin:${PATH}"
+	tm -vvv || die
+	testcleanup || die
+}
+
+src_install() {
+	dodir /opt/hermes
+	cp -r "${S}"/. "${ED}"/opt/hermes/ || die
+
+	newenvd - 99hermes <<- _EOF_
+		PATH="${EPREFIX}/opt/hermes/bin"
+	_EOF_
+}
diff --git a/dev-util/hermes/hermes-9999.ebuild b/dev-util/hermes/hermes-9999.ebuild
index 5d280a437275..bab55a3dbd63 100644
--- a/dev-util/hermes/hermes-9999.ebuild
+++ b/dev-util/hermes/hermes-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 LUA_COMPAT=( lua5-{1,3,4} luajit )
 inherit lua-single
@@ -51,5 +51,8 @@ src_install() {
 	dodir /opt/hermes
 	cp -r "${S}"/. "${ED}"/opt/hermes/ || die
 
-	doenvd "${FILESDIR}"/99hermes
+	newenvd - 99hermes <<- _EOF_
+		PATH="${EPREFIX}/opt/hermes/bin"
+	_EOF_
+
 }