Adding metadata

3 files changed, 109 insertions, 8 deletions

diff --git a/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild b/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild
index 1801db4b3a41..7760f7388531 100644
--- a/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild
+++ b/dev-tex/pythontex/pythontex-0.18_p20251112.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -16,7 +16,7 @@ S="${WORKDIR}/${PN}-${COMMIT}"
 
 LICENSE="LPPL-1.3 BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+KEYWORDS="amd64 ppc ~riscv x86"
 IUSE="doc highlighting"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
diff --git a/dev-tex/rubber/rubber-1.6.7-r1.ebuild b/dev-tex/rubber/rubber-1.6.7-r1.ebuild
new file mode 100644
index 000000000000..bc3aef7f356f
--- /dev/null
+++ b/dev-tex/rubber/rubber-1.6.7-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+DISTUTILS_USE_PEP517=hatchling
+inherit distutils-r1
+
+if [[ ${PV} == *9999* ]] || [[ -n "${EGIT_COMMIT_ID}" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/latex-rubber/${PN}.git"
+else
+	# NOTE: Cannot be "PYPI_PN=latex-rubber" + "inherit pypi" due to missing files
+	SRC_URI="https://gitlab.com/latex-rubber/${PN}/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="amd64 ppc ~riscv x86"
+fi
+
+DESCRIPTION="LaTeX wrapper for automatically building documents"
+HOMEPAGE="https://gitlab.com/latex-rubber/rubber"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="virtual/latex-base"
+# Test dependencies:
+# - app-text/texlive-core for rubber's 'cweave' test
+# - dev-lang/R for rubber's 'knitr' test (requires knitr R library, currently disabled)
+# - dev-texlive/texlive-latexextra for rubber's 'combine' test (currently disabled)
+BDEPEND="${RDEPEND}
+	virtual/texi2dvi
+	test? (
+		app-text/ghostscript-gpl
+		app-text/texlive-core
+		dev-tex/biber
+		dev-tex/biblatex
+		dev-tex/bibtexu
+		dev-tex/glossaries
+		dev-tex/latex-beamer
+		$(python_gen_cond_dep 'dev-tex/pythontex[${PYTHON_USEDEP}]')
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-pstricks
+		media-gfx/asymptote[latex]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.4-pythontex.patch
+)
+
+pkg_setup() {
+	# https://bugs.gentoo.org/727996
+	export VARTEXFONTS="${T}"/fonts
+}
+
+python_test() {
+	cd tests || die
+
+	# Disable the broken 'combine' test as it uses the 'combine' as a
+	# latex package when it is only a document class (probably only in
+	# newer versions of combine). Also note that this tests works
+	# under debian 'buster'. TODO: Look into potential modifications
+	# done by debian.
+	touch combine/disable || die
+
+	# This test does not work under Gentoo nor Debian 'buster'.
+	# TODO: Investigate why it does not work.
+	touch cweb-latex/disable || die
+
+	# TODO: Investigate why the following are failing.
+	touch fig2dev-dvi/disable || die
+	touch fig2dev-path/disable || die
+	touch fig2dev-path-inplace/disable || die
+	touch fig2dev-path-into/disable || die
+	touch graphicx-dotted-files/disable || die
+	touch hooks-input-file/disable || die
+	touch knitr/disable || die
+
+	# Even tough metapost is available, those tests fail on Gentoo
+	# (while they succeed on Debian 'buster').
+	# TODO: Determine why.
+	# ERROR:mpost:I can't read MetaPost's log file, this is wrong.
+	touch metapost/disable || die
+	# expected error message not reported by Rubber
+	touch metapost-error/disable || die
+	# ERROR:mpost:I can't read MetaPost's log file, this is wrong.
+	touch metapost-input/disable || die
+
+	./run.sh * || die "Tests failed with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Move misplaced files to correct location
+	doinfo doc/${PN}/${PN}.info
+	rm "${ED}"/usr/share/doc/${PN}/${PN}.{texi,info} || die
+	mv "${ED}"/usr/share/doc/{${PN}/*,${PF}/} || die
+	rmdir "${ED}"/usr/share/doc/${PN} || die
+}
diff --git a/dev-tex/rubber/rubber-9999.ebuild b/dev-tex/rubber/rubber-9999.ebuild
index 6ca6225dee06..2736f73476fa 100644
--- a/dev-tex/rubber/rubber-9999.ebuild
+++ b/dev-tex/rubber/rubber-9999.ebuild
@@ -1,14 +1,13 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 PYTHON_COMPAT=( python3_{10..14} )
 DISTUTILS_USE_PEP517=hatchling
-
 inherit distutils-r1
 
-if [[ ${PV} == "9999" ]] || [[ -n "${EGIT_COMMIT_ID}" ]]; then
+if [[ ${PV} == *9999* ]] || [[ -n "${EGIT_COMMIT_ID}" ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://gitlab.com/latex-rubber/${PN}.git"
 else
@@ -17,7 +16,7 @@ else
 	KEYWORDS="~amd64 ~ppc ~riscv ~x86"
 fi
 
-DESCRIPTION="A LaTeX wrapper for automatically building documents"
+DESCRIPTION="LaTeX wrapper for automatically building documents"
 HOMEPAGE="https://gitlab.com/latex-rubber/rubber"
 
 LICENSE="GPL-3+"
@@ -26,7 +25,6 @@ IUSE="test"
 RESTRICT="!test? ( test )"
 
 RDEPEND="virtual/latex-base"
-
 # Test dependencies:
 # - app-text/texlive-core for rubber's 'cweave' test
 # - dev-lang/R for rubber's 'knitr' test (requires knitr R library, currently disabled)
@@ -39,12 +37,13 @@ BDEPEND="
 		app-text/texlive-core
 		dev-tex/biber
 		dev-tex/biblatex
+		dev-tex/bibtexu
 		dev-tex/glossaries
 		dev-tex/latex-beamer
 		$(python_gen_cond_dep 'dev-tex/pythontex[${PYTHON_USEDEP}]')
 		dev-texlive/texlive-latexextra
 		dev-texlive/texlive-pstricks
-		media-gfx/asymptote
+		media-gfx/asymptote[latex]
 	)
 "