Adding metadata

4 files changed, 130 insertions, 3 deletions

diff --git a/dev-ruby/em-websocket/em-websocket-0.5.3-r1.ebuild b/dev-ruby/em-websocket/em-websocket-0.5.3-r1.ebuild
index f8f77ccf97a5..a0304a794db7 100644
--- a/dev-ruby/em-websocket/em-websocket-0.5.3-r1.ebuild
+++ b/dev-ruby/em-websocket/em-websocket-0.5.3-r1.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-USE_RUBY="ruby30 ruby31 ruby32"
+USE_RUBY="ruby32 ruby33 ruby34 ruby40"
 
 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
 
diff --git a/dev-ruby/em-websocket/metadata.xml b/dev-ruby/em-websocket/metadata.xml
index 246d194b7ec0..c21c2e8bfaa2 100644
--- a/dev-ruby/em-websocket/metadata.xml
+++ b/dev-ruby/em-websocket/metadata.xml
@@ -5,6 +5,9 @@
   <email>ruby@gentoo.org</email>
   <name>Gentoo Ruby Project</name>
  </maintainer>
- 
+ <upstream>
+  <remote-id type="rubygems">em-websocket</remote-id>
+  <doc>https://www.rubydoc.info/gems/em-websocket/</doc>
+ </upstream>
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-ruby/eventmachine/eventmachine-1.2.7-r5.ebuild b/dev-ruby/eventmachine/eventmachine-1.2.7-r5.ebuild
new file mode 100644
index 000000000000..54c00076cfca
--- /dev/null
+++ b/dev-ruby/eventmachine/eventmachine-1.2.7-r5.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34 ruby40"
+
+RUBY_FAKEGEM_DOCDIR="rdoc"
+RUBY_FAKEGEM_EXTRADOC="docs/*.md CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="eventmachine.gemspec"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/extconf.rb ext/fastfilereader/extconf.rb)
+RUBY_FAKEGEM_EXTRAINSTALL=(examples)
+
+inherit ruby-fakegem
+
+DESCRIPTION="EventMachine is a fast, simple event-processing library for Ruby programs"
+HOMEPAGE="https://github.com/eventmachine/eventmachine"
+SRC_URI="https://github.com/eventmachine/eventmachine/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+# Collection of upstream patches to fix compatibility with newer OpenSSL
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-openssl-patches.tar.bz2"
+
+LICENSE="|| ( GPL-2 Ruby-BSD )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86 ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="${DEPEND}
+	dev-libs/openssl:0="
+RDEPEND="${RDEPEND}
+	dev-libs/openssl:0="
+
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 )"
+
+PATCHES=(
+	# Collection of upstream patches (rebased by Fedora, thanks!) to
+	# fix (mostly test) compatibility with >= OpenSSL 1.1.1.
+	"${WORKDIR}"/all/patches/
+	# Backport upstream changes for ruby 3
+	"${FILESDIR}"/${P}-test-processes.patch
+	"${FILESDIR}"/${P}-ruby3-process-status.patch
+	# Backport upstream changes for ruby 3.3
+	"${FILESDIR}"/${P}-ruby33.patch
+)
+
+all_ruby_prepare() {
+	# Remove package tasks to avoid dependency on rake-compiler.
+	rm rakelib/package.rake || die
+
+	sed -i -e '/git ls-files/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+	# Remove the resolver tests since they require network access and
+	# the localhost test fails with an IPv6 localhost.
+	rm tests/test_resolver.rb || die
+
+	# Needs a tty
+	rm tests/test_kb.rb || die
+
+	# Avoid tests that require network access
+	sed -e '/test_bind_connect/,/^  end/ s:^:#:' \
+		-e '/test_invalid_address_bind_connect_src/,/^  end/ s:^:#:' \
+		-e '/test_invalid_address_bind_connect_dst/,/^  end/ s:^:#:' \
+		-i tests/test_basic.rb || die
+	sed -e '/test_ipv6_udp_local_server/,/^    end/ s:^:#:' \
+		-e '/test_ipv6_tcp_local_server/,/^    end/ s:^:#:' \
+		-i tests/test_ipv6.rb || die
+	sed -e '/test_for_real/,/^    end/ s:^:#:' -i tests/test_pending_connect_timeout.rb || die
+	sed -e '/test_connect_timeout/,/^  end/ s:^:#:' -i tests/test_unbind_reason.rb || die
+	sed -e '/test_cookie/,/^  end/ s:^:#:' \
+		-e '/test_http_client/,/^  end/ s:^:#:' \
+		-e '/test_version_1_0/,/^  end/ s:^:#:' \
+		-i tests/test_httpclient.rb || die
+	sed -e '/test_get/,/^  end/ s:^:#:' \
+		-e '/test_https_get/,/^  end/ s:^:#:' \
+		-i tests/test_httpclient2.rb || die
+
+	# Avoid test that deliberately triggers a C++ exception which causes
+	# a SEGFAULT. This does not appear to happen upstream (on travis).
+	rm tests/test_exc.rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib -S testrb-2 tests/test_*.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+}
diff --git a/dev-ruby/eventmachine/files/eventmachine-1.2.7-ruby33.patch b/dev-ruby/eventmachine/files/eventmachine-1.2.7-ruby33.patch
new file mode 100644
index 000000000000..513c18508e59
--- /dev/null
+++ b/dev-ruby/eventmachine/files/eventmachine-1.2.7-ruby33.patch
@@ -0,0 +1,35 @@
+https://github.com/eventmachine/eventmachine/pull/988
+https://github.com/eventmachine/eventmachine/commit/3980847f4463bcaf80c06f53e95b7eb1dddd2404
+
+From 3980847f4463bcaf80c06f53e95b7eb1dddd2404 Mon Sep 17 00:00:00 2001
+From: Antonio Terceiro <asa@terceiro.xyz>
+Date: Thu, 5 Sep 2024 12:10:49 -0300
+Subject: [PATCH] Fix usage of Process::Status on ruby3.3 (#988)
+
+--- a/ext/extconf.rb
++++ b/ext/extconf.rb
+@@ -140,6 +140,7 @@ def find_openssl_library
+ 
+ # Add for changes to Process::Status in Ruby 3
+ add_define("IS_RUBY_3_OR_LATER") if RUBY_VERSION > "3.0"
++add_define("IS_RUBY_3_3_OR_LATER") if RUBY_VERSION > "3.3"
+ 
+ # Adjust number of file descriptors (FD) on Windows
+ 
+--- a/ext/rubymain.cpp
++++ b/ext/rubymain.cpp
+@@ -563,7 +563,13 @@ static VALUE t_get_subprocess_status (VALUE self UNUSED, VALUE signature)
+ 	if (evma_get_subprocess_status (NUM2BSIG (signature), &status)) {
+ 		if (evma_get_subprocess_pid (NUM2BSIG (signature), &pid)) {
+ 
+-#ifdef IS_RUBY_3_OR_LATER
++#if defined(IS_RUBY_3_3_OR_LATER)
++			proc_status = rb_obj_alloc(rb_cProcessStatus);
++			struct rb_process_status *data = NULL;
++			data = (rb_process_status*)RTYPEDDATA_GET_DATA(proc_status);
++			data->pid = pid;
++			data->status = status;
++#elif defined(IS_RUBY_3_OR_LATER)
+ 			struct rb_process_status *data = NULL;
+ 
+ 			/* Defined to match static definition from MRI Ruby 3.0 process.c