Updating liguros repo21.1.2

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-ruby/bcrypt_pbkdf/bcrypt_pbkdf-1.1.0.ebuild b/dev-ruby/bcrypt_pbkdf/bcrypt_pbkdf-1.1.0.ebuild
new file mode 100644
index 000000000000..20942ab3e80c
--- /dev/null
+++ b/dev-ruby/bcrypt_pbkdf/bcrypt_pbkdf-1.1.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby25 ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Implements bcrypt_pdkfd (a variant of PBKDF2 with bcrypt-based PRF)"
+HOMEPAGE="https://github.com/net-ssh/bcrypt_pbkdf-ruby"
+
+LICENSE="MIT"
+SLOT="1"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE=""
+
+ruby_add_bdepend "test? ( virtual/ruby-ssl )"
+
+all_ruby_prepare() {
+	# Don't use a ruby-bundled version of libsodium
+	sed -i -e '/rbnacl\/libsodium/ s:^:#:' test/bcrypt_pnkdf/engine_test.rb || die
+
+	# Avoid unneeded rake-compiler dependency
+	sed -e '/extensiontask/ s:^:#:' -e '/ExtensionTask/,/^end/ s:^:#:' \
+		-e '/bundler/ s:^:#:' \
+		-i Rakefile || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/mri extconf.rb || die
+
+	# Some methods may not be inlined on x86 but they are not defined either, bug 629164
+	sed -i -e 's:-Wl,--no-undefined::' ext/mri/Makefile || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/mri
+	cp ext/mri/bcrypt_pbkdf_ext.so lib/ || die
+}