Adding metadata

4 files changed, 247 insertions, 97 deletions

diff --git a/dev-python/libvirt-python/Manifest b/dev-python/libvirt-python/Manifest
index 9ccf639b430c..25444c932f1f 100644
--- a/dev-python/libvirt-python/Manifest
+++ b/dev-python/libvirt-python/Manifest
@@ -1,5 +1,7 @@
 DIST libvirt-python-10.1.0.tar.gz 246933 BLAKE2B f95757c6e88271874f2e6c5efd52f4b075dee96902287b66f535f3d154eea58f7fa5156c7303c108eed34552917227cd0e1abbf4ce78d619dd113d24763780bb SHA512 b1a316703f577ebeafc6f96b5988f3716c24acfea674834c9034d488c456ca1d0386d602942ff4e0d2e947252a2d7049af4c6531407f9ff9a3b981c7c6c3fd37
 DIST libvirt-python-10.1.0.tar.gz.asc 833 BLAKE2B ae970da8b897efa3c8abf596fa653e2fed23e11dc1e1531093ce7fb1c3f9c76659fb71aab828a02c141bd59695eb6989a39f2c99fdd8494e40a8ded43c727fb8 SHA512 deb6af1a7d59bae6498175c842be7995262d0503a0614267b4fa8a157d5d094d8aacd34184b4149a0821750d57ba3ad36af1fec1f7e9532625bb620229bf404d
+DIST libvirt-python-10.10.0.tar.gz 241054 BLAKE2B 9eb9a6caa4dfaffb136912ab4c98b87277b57757d86537c0b2e05cc0fbdffb48a4e09bb7fbdf92b31eb2397fffdc94f42e036110fc8146a218d165134f276b94 SHA512 7724a9ce89b39a62746c0524643e89850a6fcc796d2c6481f6000b047637216391742921d9dae84b97de0fd8707d906cba4955567416cf5cd93aed6f689a6cb4
+DIST libvirt-python-10.10.0.tar.gz.asc 833 BLAKE2B 31567fae7df4072217bdb3c0a85f597c8dea625d2ddc20de1424268379bf6adcd2e459a73902797d24ad53a7d155711744d5b82799f630854cd29cedb1479188 SHA512 81fcfffadace42f6c49d2802250793e14e0db8eebb136c6054e1f29c52f97246ab4eba630c5723eddc031e9fff9fe1bf7312a399494764c6043aa9f2c41e8495
 DIST libvirt-python-10.3.0.tar.gz 238840 BLAKE2B 35f4b15609550f9f255ee046fda4df22099926779ded4e7a75c02cdfef9156a366f3aa62a92d75bb7bfaa4c5220679ac3231844dc35c0f7db6dd362c81b9ed77 SHA512 5c5b4b6e52887a5fe0436581ef6233e78abbf702db87936743329e62a1e3c66c124ed6e2c2b92d6215027e6cbe459c536a8436ac3cea63269bff78ec3c9efc98
 DIST libvirt-python-10.3.0.tar.gz.asc 833 BLAKE2B 75f38beedc069543f634f0b880e439a6dbc4aea6eec29bbc229a5169f09aa55c5207a3f445f5e70da2b4cb94e7397bdd937f7d5088f7cd7b4f57d3d57e6196c1 SHA512 adeb63e8ecbdbac498d0971bea837f6a8ef5fa673bbade52a623e2f7a70600c443b87ca32cfe9c61c33f9f785eb1215815bf12fbd3cc4d9d4f60a3b898bb3cfb
 DIST libvirt-python-10.5.0.tar.gz 240191 BLAKE2B d4f801f89f1db1b84c565d53b048b9ae8b61127d6c99e0d463fd7cd7d666cc108e4157cdd483e33d3716db14e29ebdcbea82b4196b9c9bd6e9092233a54a267e SHA512 1114405f52c9bfcfd733a26d7d2a51439fca6012313c22f40c4b488f55690d2564a26ab9376c285245e9899ef68fa136bb943ebb3702aa679874d0b98f3cebd7
diff --git a/dev-python/libvirt-python/libvirt-python-10.10.0.ebuild b/dev-python/libvirt-python/libvirt-python-10.10.0.ebuild
new file mode 100644
index 000000000000..16cc53178842
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-10.10.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+inherit distutils-r1 verify-sig
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt-python.git"
+	RDEPEND="app-emulation/libvirt:="
+else
+	MY_P="${P/_rc/-rc}"
+	SRC_URI="https://download.libvirt.org/python/${MY_P}.tar.gz
+		verify-sig? ( https://download.libvirt.org/python/${MY_P}.tar.gz.asc )"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+
+S="${WORKDIR}/${P%_rc*}"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	verify-sig? ( sec-keys/openpgp-keys-libvirt )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/libvirt.org.asc
+
+distutils_enable_tests pytest
+
+python_compile() {
+	# setuptools is broken for C extensions, bug #907718
+	distutils-r1_python_compile -j1
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pyqtgraph/pyqtgraph-0.13.7-r1.ebuild b/dev-python/pyqtgraph/pyqtgraph-0.13.7-r1.ebuild
deleted file mode 100644
index 8f8c89f46d48..000000000000
--- a/dev-python/pyqtgraph/pyqtgraph-0.13.7-r1.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1
-
-DESCRIPTION="A pure-python graphics and GUI library built on PyQt and numpy"
-HOMEPAGE="
-	https://www.pyqtgraph.org/
-	https://github.com/pyqtgraph/pyqtgraph/
-	https://pypi.org/project/pyqtgraph/
-"
-SRC_URI="
-	https://github.com/pyqtgraph/pyqtgraph/archive/${P}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-S=${WORKDIR}/${PN}-${P}
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~riscv ~x86"
-IUSE="opengl svg"
-REQUIRED_USE="test? ( opengl svg )"
-
-RDEPEND="
-	>=dev-python/numpy-1.22[${PYTHON_USEDEP}]
-	dev-python/pyqt6[gui,widgets,opengl=,svg=,${PYTHON_USEDEP}]
-	dev-python/scipy[${PYTHON_USEDEP}]
-	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
-"
-BDEPEND="
-	test? (
-		dev-python/h5py[${PYTHON_USEDEP}]
-		dev-python/pyqt6[testlib,${PYTHON_USEDEP}]
-		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
-		dev-vcs/git
-	)
-"
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	if ! use opengl; then
-		rm -r pyqtgraph/opengl || die
-	fi
-
-	# pyqtgraph will automatically use any QT bindings it finds,
-	# Since we only want qt6, hardcode this where upstream allows an envvar to pick.
-	sed -i "s/QT_LIB = os.getenv('PYQTGRAPH_QT_LIB')/QT_LIB = 'PyQt6'/" pyqtgraph/Qt/__init__.py ||
-		die "Failed to set QT_LIB"
-
-	# We only want to run tests for qt6 so don't try other frontends if they're installed.
-	if use test; then
-		awk -i inplace '
-		/frontends = {/ {
-			i = 6 # length of frontends
-
-		print "frontends = {"
-		print "    Qt.PYQT6: False,"
-		print "}"
-		}
-		i > 0 {
-			i--
-			next
-		}
-		{ print }
-		' pyqtgraph/examples/test_examples.py || die "Failed to patch test frontends"
-	fi
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# apparently fragile
-		tests/test_reload.py::test_reload
-
-		# TODO
-		tests/exporters/test_svg.py::test_plotscene
-		tests/graphicsItems/test_ROI.py::test_PolyLineROI
-
-		# pyside2 is normally skipped if not installed but these two
-		# fail if it is installed
-		# TODO: this could be due to USE flags, revisit when pyside2
-		# gains py3.9
-		'pyqtgraph/examples/test_examples.py::testExamples[ DateAxisItem_QtDesigner.py - PySide2 ]'
-		'pyqtgraph/examples/test_examples.py::testExamples[ designerExample.py - PySide2 ]'
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p xvfb
-}
diff --git a/dev-python/pyqtgraph/pyqtgraph-0.13.7-r2.ebuild b/dev-python/pyqtgraph/pyqtgraph-0.13.7-r2.ebuild
new file mode 100644
index 000000000000..14563ff1c3bb
--- /dev/null
+++ b/dev-python/pyqtgraph/pyqtgraph-0.13.7-r2.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A pure-python graphics and GUI library built on PyQt and numpy"
+HOMEPAGE="
+	https://www.pyqtgraph.org/
+	https://github.com/pyqtgraph/pyqtgraph/
+	https://pypi.org/project/pyqtgraph/
+"
+SRC_URI="
+	https://github.com/pyqtgraph/pyqtgraph/archive/${P}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~riscv ~x86"
+IUSE="opengl svg qt5 +qt6"
+REQUIRED_USE="test? ( opengl svg ) || ( qt5 qt6 )"
+
+RDEPEND="
+	>=dev-python/numpy-1.22[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	qt5? ( dev-python/pyqt5[gui,widgets,opengl=,svg=,${PYTHON_USEDEP}] )
+	qt6? ( dev-python/pyqt6[gui,widgets,opengl=,svg=,${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		dev-python/h5py[${PYTHON_USEDEP}]
+		qt5? ( dev-python/pyqt5[testlib,${PYTHON_USEDEP}] )
+		qt6? ( dev-python/pyqt6[testlib,${PYTHON_USEDEP}] )
+		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	if ! use opengl; then
+		rm -r pyqtgraph/opengl || die
+	fi
+
+	# pyqtgraph will automatically use any QT bindings it finds,
+	# patch the supported Qt versions to only include the ones we have enabled
+	# This can be simplified to:
+	# `sed 's/QT_LIB = os.getenv('PYQTGRAPH_QT_LIB')/'QT_LIB = "PyQt6"/' -i pyqtgraph/Qt/__init__.py`
+	# when we only need to support pyqt6.
+	local upstream_supported_qt=(
+		PySide{,2,6}
+		PyQt{4,5,6}
+	)
+	local gentoo_qt=()
+	local is_supported_impl use_qt qt
+	# pyqtgraph has conditionals that depend on these values; we can't just remove them.
+	# set deselected or unsupported to None to avoid more patching
+	for qt in "${upstream_supported_qt[@]}"; do
+		is_supported_impl=0
+		case ${qt} in
+			PyQt5) is_supported_impl=1; use_qt=${qt:2} ;;
+			PyQt6) is_supported_impl=1; use_qt=${qt:2} ;;
+		esac
+		if [[ "${is_supported_impl}" -eq 0 ]]; then
+			gentoo_qt+=( "${qt^^} = None" )
+			continue
+		fi
+		if use ${use_qt,,}; then
+			gentoo_qt+=( "${qt^^} = '${qt}'" )
+		else
+			gentoo_qt+=( "${qt^^} = None" )
+		fi
+	done
+
+	awk -v qt_string="$(printf "%s\n" "${gentoo_qt[@]}")" -i inplace '
+	BEGIN {
+		i = 0
+		split(qt_string, qt_array, "\n")
+		j = 1
+	}
+	/PYSIDE = '"'"'PySide'"'"'/ {
+		i = 6 # length of upstream_supported_qt
+		for (k = 1; k <= length(qt_array); k++) {
+		print qt_array[k]
+		j++
+		}
+	}
+	i > 0 {
+		i--
+		next
+	}
+	{ print }
+	' pyqtgraph/Qt/__init__.py || die "Failed to patch supported Qt versions"
+
+	# We also need to remove them from load order.
+	local liborder=()
+	local qt
+	# The order is important (we want to prefer the newest at runtime)
+	for qt in qt6 qt5; do
+		if use ${qt}; then
+			if [[ "${qt}" == qt* ]]; then
+				liborder+=( "PY${qt^^}" )
+			else
+				liborder+=( "${qt^^}" )
+			fi
+		fi
+	done
+
+	awk -v libOrder="$(printf "%s, " "${liborder[@]}")" -i inplace '
+	BEGIN {
+		libOrder = "[" substr(libOrder, 1, length(libOrder) - 2) "]"
+	}
+	/libOrder = \[PYQT6, PYSIDE6, PYQT5, PYSIDE2\]/ {
+		sub(/\[PYQT6, PYSIDE6, PYQT5, PYSIDE2\]/, libOrder)
+	}
+	{ print }
+	' pyqtgraph/Qt/__init__.py || die "Failed to patch qt version order"
+
+	# Finally update the list of supported frontends in test to never try unsupported or deselected
+	if use test; then
+		local frontends=()
+		for qt in qt5 qt6; do
+			if use ${qt}; then
+				frontends+=( "Qt.PY${qt^^}: False," )
+			fi
+		done
+		awk -v frontends="$(printf "%s\n" "${frontends[@]}")" -i inplace '
+		BEGIN {
+			i = 0
+			split(frontends, frontend_array, "\n")
+			j = 1
+		}
+		/frontends = {/ {
+			i = 6 # length of frontends
+
+		print "frontends = {"
+		for (k = 1; k <= length(frontend_array); k++) {
+			print "    " frontend_array[k]
+		}
+		print "}"
+		}
+		i > 0 {
+			i--
+			next
+		}
+		{ print }
+		' pyqtgraph/examples/test_examples.py || die "Failed to patch test frontends"
+	fi
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# apparently fragile
+		tests/test_reload.py::test_reload
+
+		# TODO
+		tests/exporters/test_svg.py::test_plotscene
+		tests/graphicsItems/test_ROI.py::test_PolyLineROI
+
+		# pyside2 is normally skipped if not installed but these two
+		# fail if it is installed
+		# TODO: this could be due to USE flags, revisit when pyside2
+		# gains py3.9
+		'pyqtgraph/examples/test_examples.py::testExamples[ DateAxisItem_QtDesigner.py - PySide2 ]'
+		'pyqtgraph/examples/test_examples.py::testExamples[ designerExample.py - PySide2 ]'
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p xvfb
+}