Adding metadata

21 files changed, 355 insertions, 2 deletions

diff --git a/dev-python/cfn-python-lint/Manifest b/dev-python/cfn-python-lint/Manifest
index b92661f5a322..489db1c7757a 100644
--- a/dev-python/cfn-python-lint/Manifest
+++ b/dev-python/cfn-python-lint/Manifest
@@ -1,3 +1,4 @@
 DIST cfn-python-lint-0.47.2.tar.gz 6478541 BLAKE2B 1955c6aa43512d4249741db982a6e4e5fe46daa3197d028590269d74690de2f67a1615e4907bfc434fb1e265770780a5c0da2a19c2bdfa8b44dfc7b0386e4405 SHA512 26e2e4cc26090e6da54ff0f90b9e35767e1d5677321cfb84ff00f820477d6ab576e7f58219346f48eb838dccf662df3a8a75e709cfa9690868d85130745f0cc8
 DIST cfn-python-lint-0.48.1.tar.gz 6531054 BLAKE2B 76aab248bf8d043c274b6a6d17c9ecada3b92fb0688a32989095771206a2f37728216fe1eb5d247237457d88279b04870a5808f7a93c15f77cf53c6734a3e4aa SHA512 11373f9755d0955d57dfb48fb806565cc22d2f6deeba261dbf1446b95960bce915b4b2d0bb3e1884b59a7874ead18b0cc196bd599bcdcc935a4ab0f18b4276aa
 DIST cfn-python-lint-0.48.2.tar.gz 6710036 BLAKE2B 00f607dacbf1c10f8b82cac1ad98fb1f12a56149284bcfa7491ca2cf1c03a315ce3857eb3b6e7a3862ff1fe39b499a17840bcaed66d67ccaf19ac0bb32de8dcc SHA512 15f4506e272d53fb118d17b98a55b05ed4b870d2c39a48198d69a99ac80db04f23e596f61297672a91a020e5fd22b442ad5085d80491101c2af428e8fbfc8c24
+DIST cfn-python-lint-0.48.3.tar.gz 6758651 BLAKE2B a8aeaffb0791789b25c94c630532ced223432f9902cf60664e4b111d162b4379d6307eda5c8f8074f7d2917ff25f44657016894b2140c8ea1dbf3259b24dde38 SHA512 ab1555719edb9b3541bfe60ce2701cca9e2ab9f4627c1b46ab8f4920477531f56f14f393b3575525da81b6aefd087b6c3cac516bdd6eb1db0f31304d7c63e1cb
diff --git a/dev-python/cfn-python-lint/cfn-python-lint-0.48.3.ebuild b/dev-python/cfn-python-lint/cfn-python-lint-0.48.3.ebuild
new file mode 100644
index 000000000000..fbf7b8c88b2b
--- /dev/null
+++ b/dev-python/cfn-python-lint/cfn-python-lint-0.48.3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="https://pypi.org/project/cfn-lint/ https://github.com/aws-cloudformation/cfn-python-lint"
+SRC_URI="https://github.com/aws-cloudformation/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.25.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources[${PYTHON_USEDEP}]
+	' python3_6)
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install unittest
+
+PATCHES=(
+	"${FILESDIR}/cfn-python-lint-0.30.1-tests.patch"
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	# requires git checkout
+	sed -e 's:test_update_docs:_&:' \
+		-i test/unit/module/maintenance/test_update_documentation.py || die
+	# requires Internet
+	sed -e 's:test_update_resource_specs_python:_&:' \
+		-i test/unit/module/maintenance/test_update_resource_specs.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/cython-test-exception-raiser/cython-test-exception-raiser-1.0.0.ebuild b/dev-python/cython-test-exception-raiser/cython-test-exception-raiser-1.0.0.ebuild
index 4170617b955b..294c126e387a 100644
--- a/dev-python/cython-test-exception-raiser/cython-test-exception-raiser-1.0.0.ebuild
+++ b/dev-python/cython-test-exception-raiser/cython-test-exception-raiser-1.0.0.ebuild
@@ -16,6 +16,6 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86"
 
 BDEPEND="dev-python/cython[${PYTHON_USEDEP}]"
diff --git a/dev-python/fsspec/Manifest b/dev-python/fsspec/Manifest
index 300c1f5d450c..83a50a560940 100644
--- a/dev-python/fsspec/Manifest
+++ b/dev-python/fsspec/Manifest
@@ -1,3 +1,4 @@
 DIST filesystem_spec-0.8.5.tar.gz 255904 BLAKE2B df400276dbc53a453e9e9a00acb2e93a86a5f239237533bab036a16bd48d6d709f68241febe75f6f72281162ba4a563a087405a1064e18805ce2501095d778fb SHA512 20001fd02348f15e764a9e20eab98267f6746bd7e86187914d3db3098061aa62cb296595c3519696ae1e99ef896d49df0fcec846aaf6e5c281dd1a344ef6c393
 DIST filesystem_spec-0.8.7.tar.gz 277744 BLAKE2B 4957b716d622ecd2a1bb381b291253970682dde2c90a0e8dd76dfcc3ce3c9ba55846d97df8c1fcedd4e0d5af1c10eccc6c94418f2e78e9fffde846d12c11e170 SHA512 6eb89bf1e19ac1313aad2217aaaf4686f2e2e831a2cd339f9e12b8319fb080b82f0b90b10af53c2e6febd98a34ae8520444fee3c6394e7ab5fd5ca68d56e5454
 DIST filesystem_spec-0.9.0.tar.gz 286641 BLAKE2B 70603c14d955640251f0922afaf7fa7cd3739c827218cb708fac27883b671e059ef17eb02b4d482904278855d06958e2159b49e232c558f78befd925472bca6f SHA512 68235dc592a7c7e85e5aab1b4409825f9c0a15c6841f96f54cef66c1b6ef166e930b910bd140bbaeb818f2f1f3dfc9a5752f3c479a97b6c5ce8e7d7ea98721af
+DIST filesystem_spec-2021.04.0.tar.gz 288179 BLAKE2B 896982345533fef9593f393209202e0a90473e9826ced9d69854dca20c66c64b85e1b1c44413dda718cdd1af7f41ac821b4d67b600536b32a873a4f73ab32801 SHA512 6806d6fbae89b514955a309346f19b2d199db10aecece728d117798368c311e3fbb38161fd5a54ea4a60ee7e656d2e50fdf8c4444ec3d6bdd761229b4a6341f2
diff --git a/dev-python/fsspec/fsspec-2021.04.0.ebuild b/dev-python/fsspec/fsspec-2021.04.0.ebuild
new file mode 100644
index 000000000000..0264e4aa640c
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2021.04.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_P=filesystem_spec-${PV}
+
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="https://github.com/intake/filesystem_spec/
+	https://pypi.org/project/fsspec/"
+SRC_URI="
+	https://github.com/intake/filesystem_spec/archive/${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	# sftp and smb require server started via docker
+	epytest \
+		--deselect fsspec/tests/test_spec.py::test_find \
+		--ignore fsspec/implementations/tests/test_dbfs.py \
+		--ignore fsspec/implementations/tests/test_sftp.py \
+		--ignore fsspec/implementations/tests/test_smb.py
+}
diff --git a/dev-python/jsonpointer/metadata.xml b/dev-python/jsonpointer/metadata.xml
index 6970a1129f76..09d0a8d98f69 100644
--- a/dev-python/jsonpointer/metadata.xml
+++ b/dev-python/jsonpointer/metadata.xml
@@ -18,4 +18,5 @@
   <remote-id type="github">stefankoegl/python-json-pointer</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pyatspi/Manifest b/dev-python/pyatspi/Manifest
index f4a02a997de2..3912a10f292f 100644
--- a/dev-python/pyatspi/Manifest
+++ b/dev-python/pyatspi/Manifest
@@ -1 +1,2 @@
 DIST pyatspi-2.36.0.tar.xz 315076 BLAKE2B f3f92dafab68ce003e9d63f8ebf901ef834eafb1fab3ddd2051dcfb308b79d7ce6fc4d9187ed51f3af8bebad5e6ef2296c19215ee209ad37fe717f332af8d8f7 SHA512 709236fd992f570426043e32b201bdfee06bb28faa3d1237778f4069d3548b88b8336e53c0951359f5c7e2914b90f6f682ac58e33c84e32f360bdc32662800af
+DIST pyatspi-2.38.1.tar.xz 316724 BLAKE2B 59ca2569575f3d319d33972477ebc966670138df8cb6570ac260dd903f54df66fd12beeeee53e3380938e4571910b99ae2bf3f395776b16a73ac27f8fa023c49 SHA512 bf8f1ee9a6e00014a84e4329bb971bec8b4bc8f72c3905ca585ca20b1cf000b855965159fcc10871eb92e9808a6b41b5d793f3ab563ff0867f185279eedcd487
diff --git a/dev-python/pyatspi/pyatspi-2.38.1.ebuild b/dev-python/pyatspi/pyatspi-2.38.1.ebuild
new file mode 100644
index 000000000000..a5bdf010b1c6
--- /dev/null
+++ b/dev-python/pyatspi/pyatspi-2.38.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit gnome2 python-r1 virtualx
+
+DESCRIPTION="Python client bindings for D-Bus AT-SPI"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+	test? ( x11-libs/gtk+:3 )
+"
+RDEPEND="${DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-2.34[introspection]
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure $(use_enable test tests)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir virtx dbus-run-session emake check
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installing
+
+	docinto examples
+	dodoc examples/*.py
+}
diff --git a/dev-python/pydata-sphinx-theme/Manifest b/dev-python/pydata-sphinx-theme/Manifest
index 31e2c96974d7..4dafe1fde9af 100644
--- a/dev-python/pydata-sphinx-theme/Manifest
+++ b/dev-python/pydata-sphinx-theme/Manifest
@@ -2,3 +2,4 @@ DIST pydata-sphinx-theme-0.4.3.tar.gz 3279359 BLAKE2B c2a57fc7dd70f8d57a0b56bb45
 DIST pydata-sphinx-theme-0.5.1.tar.gz 2556119 BLAKE2B cc8ea35cda2829f884699f8200ce1e8fbe9dbcd06fc7b4d3e51d587572d6d66d90bd57d9bab9f1e6fb55688ec6531bb7de72646030e97eca7c34da51f5756fcb SHA512 50996dbe1ea25f751056b837480a5d30662c169c420b27c50aa14c583a2f3601aad34718433ad00a938425142af1e937f1ffe8e341194b60b9c915167f070c43
 DIST pydata-sphinx-theme-0.5.2.tar.gz 2556695 BLAKE2B bcf54d1353fb8a46e19b738e26127f0109f1d837f4aa76e532ffa03d9cbc3a8183839575c2846f32621ff9e6a61331d62481af23e7d5e10cb5b3de060a419f18 SHA512 949e3e6effda7c2fc01c27d346a388c897a7bf035c83a204404279b6047a60382217e5520c3680faec1d0b91379c147585307461120fec630a5a11b9df451b19
 DIST pydata-sphinx-theme-0.6.0.tar.gz 2566282 BLAKE2B 4e2614dff0ba4bcfd8c6679e7ec8f5b484d3c825555636e11ffc900effb4d3a8d47dde5b60e8deb020189cb01174de726e800d12b9d0cdd376a7d3c380832628 SHA512 d4ed38a0af2163cbbdc7d4a98c4df55563a8916df293b386b911f50a9fd1778002e2f4218f79b16c0ebfb9441d8a0d6574af622a6c686b0f8ebdad39b2fa2f41
+DIST pydata-sphinx-theme-0.6.1.tar.gz 2616798 BLAKE2B 884ee7e25f7265d10e4a50072e7da57b3ba439f733afb04a3541954eca30e2add99d8a099e263f09ef86710281b1d39b320171f116740a1d81dbeb14f23eba36 SHA512 a4655d448ee3a40a5f99782d586624fc32e7aa295a6974598453716432617701cfffe1ebdfa0b6a251baf9d07b25e05677c7957c9925a2efd2da2e102eca0a8b
diff --git a/dev-python/pydata-sphinx-theme/metadata.xml b/dev-python/pydata-sphinx-theme/metadata.xml
index 501cacdafd14..075de5ad7f7e 100644
--- a/dev-python/pydata-sphinx-theme/metadata.xml
+++ b/dev-python/pydata-sphinx-theme/metadata.xml
@@ -14,6 +14,7 @@
   <name>Python</name>
  </maintainer>
  <upstream>
+  <remote-id type="github">pydata/pydata-sphinx-theme</remote-id>
   <remote-id type="pypi">pydata-sphinx-theme</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
diff --git a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.6.1.ebuild b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.6.1.ebuild
new file mode 100644
index 000000000000..285dc33c77cf
--- /dev/null
+++ b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.6.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Bootstrap-based Sphinx theme from the PyData community"
+HOMEPAGE="https://github.com/pydata/pydata-sphinx-theme"
+SRC_URI="https://github.com/pydata/pydata-sphinx-theme/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-with-disclosure"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/beautifulsoup[${PYTHON_USEDEP}]
+		dev-python/pytest-regressions[${PYTHON_USEDEP}]
+	)"
+
+# https://github.com/pydata/pydata-sphinx-theme/issues/367
+RDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.17[${PYTHON_USEDEP}]
+"
+
+# TODO: fix this: Sandbox violation to /usr/local/share
+#distutils_enable_sphinx docs dev-python/commonmark dev-python/recommonmark dev-python/numpydoc dev-python/jupyter-sphinx dev-python/plotly dev-python/xarray
+distutils_enable_tests pytest
diff --git a/dev-python/pymssql/Manifest b/dev-python/pymssql/Manifest
index 22e69da2c454..e8a27b1ffdfa 100644
--- a/dev-python/pymssql/Manifest
+++ b/dev-python/pymssql/Manifest
@@ -1 +1,2 @@
 DIST pymssql-2.1.5.tar.gz 167928 BLAKE2B c94fc29fa9d83627dbee05095a7c0d6e4e2d42ac34b0e6801bbc757d89728aee409c98519d6e8bfe8d5009f06f88bd23a3e62c050f2c964cb7139bdd3185a0b5 SHA512 7cc7336d4c2fcb7c3958fb3127801e3505fd93259d1aaef40a67941ef5aa519e285cdb04fd378c9712f29b0f8a25ce1747a4a8dc21ec57b004c9f0ceb8f5afab
+DIST pymssql-2.2.1.tar.gz 170421 BLAKE2B 0bd57ffef97f6a557bf78056ed0f184c3b5de09fa031f80f1b7420486bb137ba1750c2ac63e89c0476a3b1808e08beb037b2d9c3fce89bce98a266626222b5c7 SHA512 d44fbe506d7daf3b5fc1dfa20b99814aa3ed025cf8e4e14097f53014bc21918e0969e15149fa93c39367a06567502be08bb673e30ebdf87d6fc2c30b01216b7c
diff --git a/dev-python/pymssql/files/pymssql-2.2.1-clock_gettime.patch b/dev-python/pymssql/files/pymssql-2.2.1-clock_gettime.patch
new file mode 100644
index 000000000000..76d07e27db24
--- /dev/null
+++ b/dev-python/pymssql/files/pymssql-2.2.1-clock_gettime.patch
@@ -0,0 +1,27 @@
+From d130cacf5be53b4c15bb64787d82b1225b1485e7 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Sat, 17 Apr 2021 13:10:34 +0200
+Subject: [PATCH] Check for clock_gettime() only when linking statically
+
+The extension module does not use clock_gettime() directly, so I presume
+it is only necessary when linking statically to FreeTDS.
+---
+ setup.py | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/setup.py b/setup.py
+index 3ac434e..0295d01 100644
+--- a/setup.py
++++ b/setup.py
+@@ -95,7 +95,7 @@ if not WINDOWS:
+ print("setup.py: include_dirs =>", include_dirs)
+ print("setup.py: library_dirs =>", library_dirs)
+ 
+-if not WINDOWS:
++if LINK_FREETDS_STATICALLY and not WINDOWS:
+     # check for clock_gettime, link with librt for glibc<2.17
+     from dev import ccompiler
+     compiler = ccompiler.new_compiler()
+-- 
+2.31.1
+
diff --git a/dev-python/pymssql/pymssql-2.2.1.ebuild b/dev-python/pymssql/pymssql-2.2.1.ebuild
new file mode 100644
index 000000000000..f4f083082cbd
--- /dev/null
+++ b/dev-python/pymssql/pymssql-2.2.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Simple MSSQL python extension module"
+HOMEPAGE="https://www.pymssql.org/ https://pypi.org/project/pymssql/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="test"
+
+# tests need a running instance of freetds
+RESTRICT="test"
+
+RDEPEND=">=dev-db/freetds-0.63[mssql]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-clock_gettime.patch
+)
+
+distutils_enable_tests pytest
+
+src_configure() {
+	export LINK_FREETDS_STATICALLY=no
+}
diff --git a/dev-python/sh/metadata.xml b/dev-python/sh/metadata.xml
index 8d8f2ea6f7e2..6213c2680482 100644
--- a/dev-python/sh/metadata.xml
+++ b/dev-python/sh/metadata.xml
@@ -20,4 +20,5 @@
   <remote-id type="github">amoffat/sh</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/sqlalchemy/Manifest b/dev-python/sqlalchemy/Manifest
index 5c330beb71d4..35cf421c62ba 100644
--- a/dev-python/sqlalchemy/Manifest
+++ b/dev-python/sqlalchemy/Manifest
@@ -5,3 +5,4 @@ DIST SQLAlchemy-1.4.5.tar.gz 7502502 BLAKE2B d3b07bdf65a31e124d705c22de9ec9d57f5
 DIST SQLAlchemy-1.4.6.tar.gz 7519545 BLAKE2B ba7c9abc716dc20f5342d1f133d1a1959dff8c804268440215e9181f58cac3d2bae3052c76abf3de2551330af5946cd7f8427acaca9d73ae068444db8cc22c5b SHA512 09914c9cce75f7d973fc55bd79099c8998da343ff727eb1ab5ab3ad23555a7d8386709f9e431c7ad2eadb938dac1d79839073ee554d81bfea4128f77e73dc20a
 DIST SQLAlchemy-1.4.7.tar.gz 7531300 BLAKE2B c0b7288fc909f3402a28bccb84dee916a7bffdb5a3e1cd49ee05ca5c1f113f39302a9534436a558638070b21a75a87b2b10b47d17c6672d1bb908ac37d5e10b5 SHA512 54d9812decb2b0b1611c7c3b08001e1e35904f97c54417bfc3e3ba2ff13b6ccc11f74a34b5a7d77095e0a6d48cb356df9af64b189f4122ab04886eccc2b2e455
 DIST SQLAlchemy-1.4.8.tar.gz 7539106 BLAKE2B 063fc2c5bf8408e216cb52e873131eac60469b17da309743d0fcaa50292bc5799c309ce14301ff4769b1d8d1ce33b2fa543f22b967057bedffce13fad469f343 SHA512 2263683ba659871b55a41917e13b16e823accf0017e28c5225e869c81f5aa1983aeb7425afd15136296be9d1ad021721095b949fb7d869c2cdc50d05a39f6a02
+DIST SQLAlchemy-1.4.9.tar.gz 7542348 BLAKE2B 5e51eac41f3170f4516c87e0ad2f1f196a18b8e46df2ade2fd3ce9c876a62eeeec328f23c1839a89010959b2b130f8fd73f632212a5e0bf48532e61deeb8cb3d SHA512 60b3e6fc8ae0193762b44b6605dc85759d4e6e1d0e9ec892a7caec2c21ed55fc6fc968f78bffdd012392b5d5340d4616aa31e9156ad1c82b60c5aebc5b2d9d99
diff --git a/dev-python/sqlalchemy/sqlalchemy-1.4.9.ebuild b/dev-python/sqlalchemy/sqlalchemy-1.4.9.ebuild
new file mode 100644
index 000000000000..aa99618e929b
--- /dev/null
+++ b/dev-python/sqlalchemy/sqlalchemy-1.4.9.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="sqlite?"
+
+inherit distutils-r1 multiprocessing optfeature
+
+MY_PN="SQLAlchemy"
+MY_P="${MY_PN}-${PV/_beta/b}"
+
+DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
+HOMEPAGE="https://www.sqlalchemy.org/ https://pypi.org/project/SQLAlchemy/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="examples +sqlite test"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' python3_7 pypy3)
+"
+# Use pytest-xdist to speed up tests
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove optional/partial dep on greenlet, greenlet is not very portable
+	sed -i -e '/greenlet/d' setup.cfg || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Disable tests hardcoding function call counts specific to Python versions.
+	epytest --ignore test/aaa_profiling \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "MySQL support" dev-python/mysqlclient dev-python/pymysql \
+		dev-python/mysql-connector-python
+	optfeature "mssql support" dev-python/pymssql
+	optfeature "postgresql support" dev-python/psycopg:2
+}
diff --git a/dev-python/twisted/twisted-21.2.0.ebuild b/dev-python/twisted/twisted-21.2.0.ebuild
index fd8225b6d547..34a01b097b14 100644
--- a/dev-python/twisted/twisted-21.2.0.ebuild
+++ b/dev-python/twisted/twisted-21.2.0.ebuild
@@ -18,7 +18,7 @@ S=${WORKDIR}/${PN}-${P}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86"
 IUSE="conch crypt http2 serial test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/xlrd/metadata.xml b/dev-python/xlrd/metadata.xml
index bbcda078b642..1fe574e29649 100644
--- a/dev-python/xlrd/metadata.xml
+++ b/dev-python/xlrd/metadata.xml
@@ -12,4 +12,5 @@
   <remote-id type="github">python-excel/xlrd</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/zstd/Manifest b/dev-python/zstd/Manifest
index fa2ef8165947..55da06cf3c5c 100644
--- a/dev-python/zstd/Manifest
+++ b/dev-python/zstd/Manifest
@@ -1 +1,2 @@
 DIST zstd-1.4.5.1.tar.gz 483105 BLAKE2B 5edd7d2c7cb26817d2a7f30536373d19a6939140dea3fb93589ff45495d51afbd1e98c4f73145869dd8a72a35c0e7543a7a21d688771746485b4dd275933dff8 SHA512 f27e255bc66798b2227d39eaa7648803e7753556b522d3dc37e82413f01dcff44b05f652c210e9832077876bd954a3abdad5ed1823f5f50217b83159bbaf896d
+DIST zstd-1.4.9.1.tar.gz 516353 BLAKE2B ec318c1b6e3d44a8959dae61c2ba3f2210c0cb9daf88519b07b1df8801b8345a2b9c18fddab497a478a1c6e03118f42f9526019a624f86f347691b7daea17bb0 SHA512 53816d252611ce3a1aa0dfa7b568ce8ffba07dd8ca6009ab3406680e674f5040633718cc65e1d5a0cfea1e1f5dd746a8f3e91b313b2be39b0ed4c6f9d887b24e
diff --git a/dev-python/zstd/zstd-1.4.9.1.ebuild b/dev-python/zstd/zstd-1.4.9.1.ebuild
new file mode 100644
index 000000000000..f73c5d5311fb
--- /dev/null
+++ b/dev-python/zstd/zstd-1.4.9.1.ebuild
@@ -0,0 +1,21 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Simple python bindings to Yann Collet ZSTD compression library"
+HOMEPAGE="https://github.com/sergey-dryabzhinsky/python-zstd"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	app-arch/zstd:=
+	!dev-python/zstandard[${PYTHON_USEDEP}]
+"
+DEPEND=${RDEPEND}