Adding metadata

30 files changed, 722 insertions, 162 deletions

diff --git a/dev-python/PyQt6-WebEngine/PyQt6-WebEngine-6.5.0.ebuild b/dev-python/PyQt6-WebEngine/PyQt6-WebEngine-6.5.0.ebuild
index 28bcc63b79dd..c52ec1a8d81a 100644
--- a/dev-python/PyQt6-WebEngine/PyQt6-WebEngine-6.5.0.ebuild
+++ b/dev-python/PyQt6-WebEngine/PyQt6-WebEngine-6.5.0.ebuild
@@ -30,16 +30,18 @@ RDEPEND="
 DEPEND="${RDEPEND}"
 BDEPEND="
 	>=dev-python/PyQt-builder-1.15[${PYTHON_USEDEP}]
-	>=dev-qt/qtbase-${QT_PV}
-	sys-devel/gcc"
+	>=dev-qt/qtbase-${QT_PV}"
 
 src_prepare() {
 	default
 
-	# hack: qmake queries g++ directly for info (not building) and that doesn't
-	# work with clang, this is to make it at least respect CHOST (bug #726112)
+	# hack: qmake queries g++ or clang++ for info depending on which qtbase was
+	# built with, but ignores CHOST failing with -native-symlinks (bug #726112)
+	# and potentially using wrong information when cross-compiling
 	mkdir "${T}"/cxx || die
-	ln -s "$(type -P ${CHOST}-g++ || type -P g++ || die)" "${T}"/cxx/g++ || die
+	local cxx
+	! cxx=$(type -P "${CHOST}"-g++) || ln -s -- "${cxx}" "${T}"/cxx/g++ || die
+	! cxx=$(type -P "${CHOST}"-clang++) || ln -s -- "${cxx}" "${T}"/cxx/clang++ || die
 	PATH=${T}/cxx:${PATH}
 }
 
diff --git a/dev-python/PyQt6/Manifest b/dev-python/PyQt6/Manifest
index 4afae3cc918c..99e345106bf9 100644
--- a/dev-python/PyQt6/Manifest
+++ b/dev-python/PyQt6/Manifest
@@ -1,2 +1 @@
-DIST PyQt6-6.5.0.tar.gz 1033399 BLAKE2B a22ad07813c50d6b626b95aa168996ab51f9714fbf3bf3d6e41a233ec2edb8c8e2cb7edcf3b036bc4f69f0a8f1e6549cde512562a420c0809f84a0e04cfb9368 SHA512 c73d4c253245d2ccc776544bc651d47ea67067f57b49c3f820100701af4d79385ef4cabe9f65098f35daeba5f2921a566606be4f237e567f6f56360cc760f548
 DIST PyQt6-6.5.1.tar.gz 1036776 BLAKE2B e8e9ac2222de1864386d1fddb75414cf600e380e584e274cfcffbdeb1451cde9e199a43ad4c66cfc8a006cabc833904fe177ccf9dda85ac683f9c8e4f6f87e53 SHA512 8c1135ec48906fe842f0cb50e253a0325b478dd43a7f313b925aaf1d3c148f5462a3e96142470ab0efc0f24fcc8b15704242401cab9f8ec9c3c424e922c49681
diff --git a/dev-python/PyQt6/PyQt6-6.5.0.ebuild b/dev-python/PyQt6/PyQt6-6.5.0.ebuild
deleted file mode 100644
index 7c136ae47ccd..000000000000
--- a/dev-python/PyQt6/PyQt6-6.5.0.ebuild
+++ /dev/null
@@ -1,152 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=sip
-PYPI_NO_NORMALIZE=1
-PYTHON_COMPAT=( python3_{7,8,9,10,11} )
-inherit distutils-r1 flag-o-matic multiprocessing pypi qmake-utils
-
-# 'can' work with older Qt depending on features, but keeping it simple
-QT_PV="$(ver_cut 1-2):6"
-
-DESCRIPTION="Python bindings for the Qt framework"
-HOMEPAGE="https://www.riverbankcomputing.com/software/pyqt/"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64"
-# defaults match what is provided with qtbase by default (except testlib),
-# reduces the need to set flags but does increase build time a fair amount
-IUSE="
-	+dbus debug qml designer examples gles2-only +gui help multimedia
-	+network opengl positioning +printsupport quick quick3d serialport
-	spatialaudio +sql +ssl svg testlib webchannel websockets +widgets +xml"
-# see `grep -r "%Import " sip` and `grep qmake_QT project.py`
-REQUIRED_USE="
-	designer? ( gui widgets )
-	help? ( gui widgets )
-	multimedia? ( gui network )
-	opengl? ( gui )
-	printsupport? ( gui widgets )
-	qml? ( network )
-	quick3d? ( gui qml )
-	quick? ( gui qml )
-	spatialaudio? ( multimedia )
-	sql? ( widgets )
-	svg? ( gui )
-	testlib? ( gui widgets )
-	webchannel? ( network )
-	websockets? ( network )
-	widgets? ( gui )"
-
-# can use parts of the Qt private api and "sometimes" needs rebuilds wrt :=
-DEPEND="
-	>=dev-qt/qtbase-${QT_PV}=[dbus?,gles2-only=,gui?,network?,opengl?,sql?,ssl=,widgets?,xml?]
-	dbus? (
-		dev-python/dbus-python[${PYTHON_USEDEP}]
-		sys-apps/dbus
-	)
-	designer? ( >=dev-qt/qttools-${QT_PV}[designer] )
-	help? ( >=dev-qt/qttools-${QT_PV}[assistant] )
-	multimedia? ( >=dev-qt/qtmultimedia-${QT_PV} )
-	opengl? ( gles2-only? ( media-libs/libglvnd ) )
-	positioning? ( >=dev-qt/qtpositioning-${QT_PV} )
-	qml? ( >=dev-qt/qtdeclarative-${QT_PV} )
-	quick3d? ( >=dev-qt/qtquick3d-${QT_PV} )
-	serialport? ( >=dev-qt/qtserialport-${QT_PV} )
-	svg? ( >=dev-qt/qtsvg-${QT_PV} )
-	webchannel? ( >=dev-qt/qtwebchannel-${QT_PV} )
-	websockets? ( >=dev-qt/qtwebsockets-${QT_PV} )"
-RDEPEND="
-	${DEPEND}
-	>=dev-python/PyQt6-sip-13.4[${PYTHON_USEDEP}]"
-BDEPEND="
-	>=dev-python/PyQt-builder-1.15[${PYTHON_USEDEP}]
-	>=dev-qt/qtbase-${QT_PV}
-	sys-devel/gcc
-	dbus? ( virtual/pkgconfig )"
-
-src_prepare() {
-	default
-
-	# hack: qmake queries g++ directly for info (not building) and that doesn't
-	# work with clang, this is to make it at least respect CHOST (bug #726112)
-	mkdir "${T}"/cxx || die
-	ln -s "$(type -P ${CHOST}-g++ || type -P g++ || die)" "${T}"/cxx/g++ || die
-	PATH=${T}/cxx:${PATH}
-}
-
-python_configure_all() {
-	append-cxxflags -std=c++17 # for old gcc / clang that use <17 (bug #892331)
-	append-cxxflags ${CPPFLAGS} # respect CPPFLAGS
-
-	pyqt-use_enable() {
-		local state=$(usex ${1} --enable= --disable=)
-		shift
-		echo ${*/#/${state}}
-	}
-
-	DISTUTILS_ARGS=(
-		--jobs=$(makeopts_jobs)
-		--qmake="$(type -P qmake6 || die)"
-		--qmake-setting="$(qt5_get_qmake_args)"
-		--verbose
-		--confirm-license
-
-		# TODO: enable more as new qt6 packages get added
-		--disable=QAxContainer
-		--disable=QtBluetooth
-		--enable=QtCore
-		$(pyqt-use_enable dbus QtDBus)
-		$(pyqt-use_enable designer QtDesigner)
-		$(pyqt-use_enable help QtHelp)
-		$(pyqt-use_enable gui QtGui)
-		#--disable=QtLocation # force-disabled in project.py
-		$(pyqt-use_enable multimedia QtMultimedia \
-			$(usev widgets QtMultimediaWidgets))
-		$(pyqt-use_enable network QtNetwork)
-		--disable=QtNfc
-		$(pyqt-use_enable opengl QtOpenGL \
-			$(usev widgets QtOpenGLWidgets))
-		--disable=QtPdf #+QtPdfWidgets (QtPdf is disabled in qtwebengine:6)
-		$(pyqt-use_enable positioning QtPositioning)
-		$(pyqt-use_enable printsupport QtPrintSupport)
-		$(pyqt-use_enable qml QtQml)
-		$(pyqt-use_enable quick QtQuick \
-			$(usev widgets QtQuickWidgets))
-		$(pyqt-use_enable quick3d QtQuick3D)
-		--disable=QtRemoteObjects
-		--disable=QtSensors
-		$(pyqt-use_enable serialport QtSerialPort)
-		$(pyqt-use_enable spatialaudio QtSpatialAudio)
-		$(pyqt-use_enable sql QtSql)
-		$(pyqt-use_enable svg QtSvg \
-			$(usev widgets QtSvgWidgets))
-		$(pyqt-use_enable testlib QtTest)
-		--disable=QtTextToSpeech
-		$(pyqt-use_enable webchannel QtWebChannel)
-		$(pyqt-use_enable websockets QtWebSockets)
-		$(pyqt-use_enable widgets QtWidgets)
-		$(pyqt-use_enable xml QtXml)
-
-		$(usev debug '--debug --qml-debug --tracing')
-
-		$(usev !dbus --no-dbus-python)
-		# TODO?: plugins not in wheels by upstream, see project.py#L214
-		# (if needed by something, will need to be added to python_install)
-		$(usev !designer --no-designer-plugin)
-		$(usev !qml --no-qml-plugin)
-
-		$(usev !gles2-only --disabled-feature=PyQt_OpenGL_ES2)
-		$(usev !opengl --disabled-feature=PyQt_OpenGL)
-		$(usev !ssl --disabled-feature=PyQt_SSL)
-	)
-}
-
-python_install_all() {
-	einstalldocs
-	use examples && dodoc -r examples
-}
diff --git a/dev-python/PyQt6/PyQt6-6.5.1.ebuild b/dev-python/PyQt6/PyQt6-6.5.1.ebuild
index 4e9fd0b5fbec..7bbbfcd7a6cf 100644
--- a/dev-python/PyQt6/PyQt6-6.5.1.ebuild
+++ b/dev-python/PyQt6/PyQt6-6.5.1.ebuild
@@ -66,16 +66,18 @@ RDEPEND="
 BDEPEND="
 	>=dev-python/PyQt-builder-1.15[${PYTHON_USEDEP}]
 	>=dev-qt/qtbase-${QT_PV}
-	sys-devel/gcc
 	dbus? ( virtual/pkgconfig )"
 
 src_prepare() {
 	default
 
-	# hack: qmake queries g++ directly for info (not building) and that doesn't
-	# work with clang, this is to make it at least respect CHOST (bug #726112)
+	# hack: qmake queries g++ or clang++ for info depending on which qtbase was
+	# built with, but ignores CHOST failing with -native-symlinks (bug #726112)
+	# and potentially using wrong information when cross-compiling
 	mkdir "${T}"/cxx || die
-	ln -s "$(type -P ${CHOST}-g++ || type -P g++ || die)" "${T}"/cxx/g++ || die
+	local cxx
+	! cxx=$(type -P "${CHOST}"-g++) || ln -s -- "${cxx}" "${T}"/cxx/g++ || die
+	! cxx=$(type -P "${CHOST}"-clang++) || ln -s -- "${cxx}" "${T}"/cxx/clang++ || die
 	PATH=${T}/cxx:${PATH}
 }
 
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 21f3d23c315f..dbdc2a7dd50f 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,3 +4,4 @@ DIST boto3-1.26.151.gh.tar.gz 661732 BLAKE2B 8adc42757d828414dd4bde9f460bc9fd678
 DIST boto3-1.26.152.gh.tar.gz 662874 BLAKE2B 31866c0c3244cdb868fadaf985410e5577d8d75f37387ee44f6ce879ae06c282a4e85e262da4bab3e588918b126110c10b5a64bf7764f076baf495a4382cd225 SHA512 3d496da055172bbc840a3a6f8bd7df6f24bbb1f2f5dbacbbc0e337d4bd15d1355b9fd2e5dbb9e611aa1e415d11dc32bd0b61428a0d0ce7e2d55bb143a0cf1491
 DIST boto3-1.26.153.gh.tar.gz 663859 BLAKE2B 6c5a04fcaa6dde09a09552c2687a2ad1a780ce703cc60eda84c2fa6ad9061dd5f0a4aa0c8f7a7d15f73da2abd9f28d12f8f3d4f859a552cc355bde16f9b306aa SHA512 70117de2475d82f4bb94be2033b7ba18447290f767334d3ea11c60807619d76846003868439f1d025b396df12b91e126f4935f7438d649ca2ee7d629f0a499f4
 DIST boto3-1.26.154.gh.tar.gz 664248 BLAKE2B d36363c3a1561392fe9217c694f263ed34d10fee42141efffbe9d0899e5472d765af717a148deb9b3ef2abe654dcbb5840557d24644763a43ebda61fb39d7b5a SHA512 3aa8b243f9a39921c48d7d63ffb0be64f3bf8dbb824df03e7aafea072a218973660deb52b80ec23367f2a94f8bb9b2ee284a5b4d41d0edd81a1ea063cf94f453
+DIST boto3-1.26.155.gh.tar.gz 664838 BLAKE2B 35c78d4da5bcba6f218a854d67647b71b16915b380271ed03c79775c547ab69fadd750f58557460445d5a6448f927042cccb6cea6e14670dda7e59ccac3c5b5f SHA512 40197333b87c85119428faa35489207ffdc6c03cec03c6446e239d616bd19a40da1512e5ce43618fea9465f174564b533021ba95e26d105a00786dfe47ec7342
diff --git a/dev-python/boto3/boto3-1.26.155.ebuild b/dev-python/boto3/boto3-1.26.155.ebuild
new file mode 100644
index 000000000000..03c610b184f7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.155.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index b6f44746748c..9497e299a262 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,3 +4,4 @@ DIST botocore-1.29.151.gh.tar.gz 11618833 BLAKE2B cac8007e6177c029b97e288c244668
 DIST botocore-1.29.152.gh.tar.gz 11624895 BLAKE2B f6b8596548ab8ff5cbf401d98ebf90cd0425f0363f9be1b71f58649a98dd6c69a859deb80467621bcdc5c15ebe151df7960880ebc013d5834d5310e80a89e948 SHA512 f51f8e00e61ed51d39ec9e51a08cf0f57d29f5e1d4e77460cf28ed296f062cf9df2b5761a30d8a78b6bc4ca8a971032150929cb84147d099e45f8e0112a717e5
 DIST botocore-1.29.153.gh.tar.gz 11665559 BLAKE2B 82a51ba87753e4f241776652f846db39e5d3748997c635af960dfa389786f3abe3b622f2415abba1aaef81d12aee8b7197f1dea9e71a34e6fc18e1712a79eed5 SHA512 84f774eae433b8efecbc4ccf4990435cfa2f9a5fa1a6d29d94bbc57a75b6f3fd4c0b8392672a7d06a00ad7b5f0f4c3fcf66aa893ad655e3a1409083d8731df78
 DIST botocore-1.29.154.gh.tar.gz 11667747 BLAKE2B 0f5ad1bd37b977fcbf938bde18ddec0aab0ce71180e64b5f7318647843082cedead62215a99099a7b4f795228afa1093f22364fbe84b3ecd6c1d177a00f5ee8f SHA512 f66819a5b70ceb30b42bf448c9069d2ebfe68d25f33d4b489e1836b65a2233a3a62bd50d723c4b25531fa13fd49a4ba50cad9e67b6315954aa113428d8a87d4e
+DIST botocore-1.29.155.gh.tar.gz 11673165 BLAKE2B 653cc8b368d34502bcb16622677f11562d38a301e449e2712bcaa7702920a2e2291406fc370d58b562e92719f3945234578f1dc185e9b31e636f09e06f8a00bc SHA512 b4e0d46164953c7eb6fe185a3501a011395c48944028248f831347dd5abfa006c0e46196089d4c78010693f88137f49183b12381b984d99fc9a0a75b5d5892a2
diff --git a/dev-python/botocore/botocore-1.29.155.ebuild b/dev-python/botocore/botocore-1.29.155.ebuild
new file mode 100644
index 000000000000..509d06dedf97
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.155.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+		# urllib3-2 compatibility, mock relies on implementation details
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_no_response_from_server
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_returned
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_sends_307
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_sends_connection_header
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_handles_expect_100_with_different_reason_phrase
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_state_reset_on_connection_close
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/django-otp/Manifest b/dev-python/django-otp/Manifest
index ddc7cd033cda..eb46b5b19ba3 100644
--- a/dev-python/django-otp/Manifest
+++ b/dev-python/django-otp/Manifest
@@ -1,3 +1,4 @@
 DIST django-otp-1.1.6.gh.tar.gz 76790 BLAKE2B 442c2418a870ccc8034a080415befb09780f9228562a15737e0911a0343945908f9fc2e026220a4477a5e5e1a6c1e4c3f7d51c823d4a9019f2bc15ae3367d8a3 SHA512 58c64651a5b274542bf09604daf3e59fdb0ea4eb96e7d14e59fd10a042d86cffb5df462191198f12320ea706f4d9aa651ef2c79ad7aa33e9d4ba0d157d90f4fb
 DIST django_otp-1.2.0.tar.gz 64888 BLAKE2B 4b9eff29508b1ce537452ecf7337c7440acbab08b66c651080973d6a39e8e7cd5255f440e4dfb397886f562234d297333eee296ee9958075790e183e47e6637a SHA512 2f108ff08a01044a0f6572f4e5a57311c28926b5baf808f5013e6ffc1e40db77fd182b078ce53596b4ecee87fc0223fdf6fc41158e03a6ba3e80455234d64810
 DIST django_otp-1.2.1.tar.gz 65762 BLAKE2B 8243763a717c5f22513e10a03b8eeccf26d5e556cca15a22cad8e66ae8f6b4e6bfd53c43bf4de328e0b78f66895869a258ed1f42daaa0c3f686ae42ae0222ee5 SHA512 cb1ee0507dca15cd23d96c28566368079d38d85e3ef3a11ac14d25443c7d50ee62e8256dafe355632c33c84f74af54146890e58e17dc588e52502ee68716510f
+DIST django_otp-1.2.2.tar.gz 66391 BLAKE2B f66472ec2e3842ebc634edd8f689d1de51738381fd86c4af0859dee2f1bcf407b1c952c795203f9c742a95633ee14ce9253dcc1ffd7988c960e26b23a1ec5dfe SHA512 e8608f0a3b0aeaa82e509f034f69131eb1015124ecf84b734a5be58f62c309eee506b12fffe2aeb4b707e70c612413d1458bc64533102508c55255035432eb1f
diff --git a/dev-python/django-otp/django-otp-1.2.2.ebuild b/dev-python/django-otp/django-otp-1.2.2.ebuild
new file mode 100644
index 000000000000..f4a6dc83dd66
--- /dev/null
+++ b/dev-python/django-otp/django-otp-1.2.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Django framework adding two-factor authentication using one-time passwords"
+HOMEPAGE="
+	https://github.com/django-otp/django-otp/
+	https://pypi.org/project/django-otp/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/qrcode[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.9 3.10)
+		${RDEPEND}
+	)
+"
+
+python_test() {
+	local -x PYTHONPATH=test:${PYTHONPATH}
+	local -x DJANGO_SETTINGS_MODULE=test_project.settings
+	"${EPYTHON}" -m django test -v 2 django_otp ||
+		die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/django-redis/Manifest b/dev-python/django-redis/Manifest
index 69b6ca626cb7..14f4d48279bf 100644
--- a/dev-python/django-redis/Manifest
+++ b/dev-python/django-redis/Manifest
@@ -1 +1,2 @@
 DIST django-redis-5.2.0.tar.gz 44132 BLAKE2B 5d9680e43bfff506924b90cdce4fcbf40883a732af6b599c2e36d8549ce2aedbd69540b187152dc8fdc0d2a93b21c5fd2724d6386772f9b4af8632e38414b577 SHA512 65d3dc6b1d72c8b90908cf368cb66ac2eb74bdd32d0b42c8a5288b4448bd7444b21320251262627bc950eaf0d1a1ef0c3014761b690122bea9e5e20f744dd433
+DIST django-redis-5.3.0.tar.gz 44800 BLAKE2B 29a671f2899aefa6e59086bc194438aaf7e724b3edcefaf0c590a14e958847e86da34b8f94d4c29d62270f53f88395df2e911659e58471b5c037d1c2cd0f4dd7 SHA512 2867d405b69400355576eb3c052b4245844d56304979f09750251f8a2cf35ce704ebcdb6c80e6280fbfe24acfb237a3428f68081b6ada11ffc78257263703d7e
diff --git a/dev-python/django-redis/django-redis-5.3.0.ebuild b/dev-python/django-redis/django-redis-5.3.0.ebuild
new file mode 100644
index 000000000000..5374b6eeb19f
--- /dev/null
+++ b/dev-python/django-redis/django-redis-5.3.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Full featured redis cache backend for Django"
+HOMEPAGE="
+	https://github.com/jazzband/django-redis/
+	https://pypi.org/project/django-redis/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+	>=dev-python/redis-3.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/lz4[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e '/--cov/d' \
+		-e '/--no-cov/d' \
+		-i setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cd tests || die
+	local setting_file settings=(
+		settings.sqlite
+		settings.sqlite_json
+		settings.sqlite_lz4
+		settings.sqlite_msgpack
+		settings.sqlite_sharding
+		settings.sqlite_zlib
+		# TODO: requires pyzstd
+#		settings.sqlite_zstd
+	)
+	for setting_file in "${settings[@]}"; do
+		einfo "Testing ${setting_file} configuration"
+		epytest "--ds=${setting_file}"
+	done
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	"${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/google-auth/google-auth-2.20.0.ebuild b/dev-python/google-auth/google-auth-2.20.0-r1.ebuild
index 20b132312687..20b132312687 100644
--- a/dev-python/google-auth/google-auth-2.20.0.ebuild
+++ b/dev-python/google-auth/google-auth-2.20.0-r1.ebuild
diff --git a/dev-python/gsd/Manifest b/dev-python/gsd/Manifest
index 6d024ffef9cf..98d7e58e048e 100644
--- a/dev-python/gsd/Manifest
+++ b/dev-python/gsd/Manifest
@@ -1,3 +1,4 @@
+DIST gsd-3.0.0.tar.gz 106562 BLAKE2B 0a8616300a0f568de82e7a7fa56440b7cdd3abc86e530ff3c139a21d9f57750c0454d55e261bcdaeebb1d882ffcc6d69a09b7fe61fbf662b647ca46ad91b265c SHA512 2808fc52a46256413aeee98642f5cf2e2be8f3e09a8beb8626db7a71a1864566161d3496577d501a88caf5afde05212d80bac2fe2346f95c04a3284eb2c447d7
 DIST gsd-v2.8.0.tar.gz 107602 BLAKE2B 1317548dda93f7b7d07e74163f09aea9808ee50617e02c43f635339313e7604f5e06e0d488bdb7b336e96a7c80c1d1b1cbde0de6809102fedcfcdba2ced7c8ca SHA512 9346ed54a28d23cca9b1d3a82a86c4186dab47a6949e519e307ce121a3ed80105332360fb5a151cc68c403e00651746b2fef4d2c51781188a52569032f3bd700
 DIST gsd-v2.8.1.tar.gz 107943 BLAKE2B beeddac15851396a4969988396459ff244cc191d02618a5a2fe3059ad4e798b6f95a526fb46149d447c2478bb6f8eb9dae7e484bc15aeb7c0585b20808dfd1fa SHA512 6b68966abc92b46d84287687e975631a923b38aaca936d5031c27b8dc0fda5e02f13b725e0c87dfb61f68bbfa0ac906895479232b8ff646c98c12025e78ed6ee
 DIST gsd-v2.9.0.tar.gz 107656 BLAKE2B 78abd1bd832b1cd39844b87ddba6d687627c91624d3bcc3f81b7187b341bbcee1e2135934901bf1b860730ca4397298bd8d5d8723990e3f3efe3151bb941d406 SHA512 96883044b9c6cd580b2b45bc4db4b5f21121f83b4d67d2fc0449661e793a49466f26e497ef873d16a0af35bcb0926332fd4ce6f254f46582ba5cfccb8b52a02a
diff --git a/dev-python/gsd/gsd-3.0.0.ebuild b/dev-python/gsd/gsd-3.0.0.ebuild
new file mode 100644
index 000000000000..a6cedd541dcf
--- /dev/null
+++ b/dev-python/gsd/gsd-3.0.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="GSD - file format specification and a library to read and write it"
+HOMEPAGE="
+	https://github.com/glotzerlab/gsd/
+	https://pypi.org/project/gsd/
+"
+SRC_URI="
+	https://github.com/glotzerlab/gsd/releases/download/v${PV}/${P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	>=dev-python/numpy-1.24.2[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	cd "${T}" || die
+	epytest --pyargs gsd
+}
diff --git a/dev-python/jsonpatch/Manifest b/dev-python/jsonpatch/Manifest
index 3a766fbfb10a..7d18f8ebd857 100644
--- a/dev-python/jsonpatch/Manifest
+++ b/dev-python/jsonpatch/Manifest
@@ -1,2 +1,3 @@
 DIST jsonpatch-1.32.tar.gz 27988 BLAKE2B b60dc7607f644f1ffd095486c237e3bb537b465132725e98fc8799a42a92dcbb43e1e41d281fbc2ce2c4efec327ad681d7740129be55d94c51321e620d084d95 SHA512 4e2978555dd506e09553014d426c4e3a6c6d5c865428f11450952704007c8a0b2060b945cf1fa33a128151427e1c66919891466e095e96fff4316304f0b3ad1d
 DIST python-json-patch-1.32.gh.tar.gz 27988 BLAKE2B b60dc7607f644f1ffd095486c237e3bb537b465132725e98fc8799a42a92dcbb43e1e41d281fbc2ce2c4efec327ad681d7740129be55d94c51321e620d084d95 SHA512 4e2978555dd506e09553014d426c4e3a6c6d5c865428f11450952704007c8a0b2060b945cf1fa33a128151427e1c66919891466e095e96fff4316304f0b3ad1d
+DIST python-json-patch-1.33.gh.tar.gz 28475 BLAKE2B 7d95ab23e09141cbe26618c91b12558d5fbfecda3e5b148d834753a364155d30859a9bdc3d321bdfcc5269f7e0170671524ae78f5fe65a8c97041bab3fb522b9 SHA512 0685f63949bee135b19d0962bdaab32ba97e02772b6650d885be57c09a2e89546222ebba1a4cf146b2f91027790b0a3ff2ea072d66dcebf9153aa601638bbfa2
diff --git a/dev-python/jsonpatch/jsonpatch-1.33.ebuild b/dev-python/jsonpatch/jsonpatch-1.33.ebuild
new file mode 100644
index 000000000000..c339a4ff8acd
--- /dev/null
+++ b/dev-python/jsonpatch/jsonpatch-1.33.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=python-json-patch-${PV}
+DESCRIPTION="Apply JSON-Patches like http://tools.ietf.org/html/draft-pbryan-json-patch-04"
+HOMEPAGE="
+	https://github.com/stefankoegl/python-json-patch/
+	https://pypi.org/project/jsonpatch/
+"
+SRC_URI="
+	https://github.com/stefankoegl/python-json-patch/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jsonpointer-1.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_test() {
+	"${EPYTHON}" tests.py || die "Tests of tests.py fail with ${EPYTHON}"
+	"${EPYTHON}" ext_tests.py || die "Tests of ext_tests.py fail with ${EPYTHON}"
+}
diff --git a/dev-python/pytest-freezer/Manifest b/dev-python/pytest-freezer/Manifest
new file mode 100644
index 000000000000..0aa4de74538d
--- /dev/null
+++ b/dev-python/pytest-freezer/Manifest
@@ -0,0 +1 @@
+DIST pytest_freezer-0.4.6.tar.gz 8661714 BLAKE2B 03d2545762f0702776fb72b63ceffaa44e53775c2b96636223aee67b7d8503624dad02371cd9985eb507939b1346463d8a38bec9305518768ad63af0aca50147 SHA512 85b703d9ef20ff9d2186004d574357a89f0c19de251c9fdda4f47526b920df40b330c7970d06dcde2eccbcdd2a61f62ef995670d11a9a3fe6816eb64f5bc3158
diff --git a/dev-python/pytest-freezer/metadata.xml b/dev-python/pytest-freezer/metadata.xml
new file mode 100644
index 000000000000..a0d4c5913ba0
--- /dev/null
+++ b/dev-python/pytest-freezer/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pytest-freezer/pytest-freezer-0.4.6.ebuild b/dev-python/pytest-freezer/pytest-freezer-0.4.6.ebuild
new file mode 100644
index 000000000000..931c6487d184
--- /dev/null
+++ b/dev-python/pytest-freezer/pytest-freezer-0.4.6.ebuild
@@ -0,0 +1,26 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Pytest plugin providing a fixture interface for spulec/freezegun"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-freezer/
+	https://pypi.org/project/pytest-freezer/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/freezegun-1.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-3.6[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/sphinx-autodoc-typehints/Manifest b/dev-python/sphinx-autodoc-typehints/Manifest
index 438303ce5929..8ebc993a6e27 100644
--- a/dev-python/sphinx-autodoc-typehints/Manifest
+++ b/dev-python/sphinx-autodoc-typehints/Manifest
@@ -1,3 +1,4 @@
 DIST sphinx-autodoc-typehints-1.22.gh.tar.gz 35429 BLAKE2B d871de3d3a37b2632e6b43dcb4ce58fbf61bdfdb225650486fdffbbfff4148770f40096815d3e6807f4d3f789c0f7f7fdfef841a3d087f0b12e65671597207e3 SHA512 9fed312b5b63dcbf0b39e226486abd687e68c26eeb7303ee3049251c7007d7c364ceb196672ac16101b1a76493e0a0a4e1d9532e54eec250720a37f0c8f77fda
 DIST sphinx_autodoc_typehints-1.23.0.tar.gz 35945 BLAKE2B 4af9ddd722a1fc59d52009ef46ad7af828d826cce61e0bce260b68045d4abe3b184ffc0368b29f60eba210def8d8b3b37a5455442c156b326d4b9956c6afc32c SHA512 990db1f042913088fddf56cbc9ad5f401f7d886164c348aaf19fd1541fa1566a2d58d1c182e52d839d1dd32606ca3da1191b7062a6ed9c8f04dc6a47efaf5488
 DIST sphinx_autodoc_typehints-1.23.1.tar.gz 36243 BLAKE2B e53dc42a31e358ca1e3fbbe41a3002abd4e1f470ed259d5b0b6f8def81de91653d1cb609e44dc10409340775ca877ea394e4fba1a5f2c3a38c10ce33996e12c8 SHA512 fe10d0ae4d23a979125868fd6743b37d2f65e1297620142c13cb59b83ba242e4b45098cc580c18232be1b535f5927ba6dd401f7cd4d3a39c2aab3611a2a751ed
+DIST sphinx_autodoc_typehints-1.23.2.tar.gz 36198 BLAKE2B 15c47e89e50a1a88878f2ec5c511900ad5f0437975c041c99a33f2cc9e29de955b897bd6f853b010c0f8185cd669be9e8de351ee654e9bd640337a5771caeb62 SHA512 27e9a4179f050444dfbd3d4648212f1d56c47a938f8e33dded9121c5cd4637b4e2096eb383bbf663078223dc46973f3e0fcd02ecd162611d353ef5d702977f48
diff --git a/dev-python/sphinx-autodoc-typehints/sphinx-autodoc-typehints-1.23.2.ebuild b/dev-python/sphinx-autodoc-typehints/sphinx-autodoc-typehints-1.23.2.ebuild
new file mode 100644
index 000000000000..9367b43a299c
--- /dev/null
+++ b/dev-python/sphinx-autodoc-typehints/sphinx-autodoc-typehints-1.23.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Type hints support for the Sphinx autodoc extension"
+HOMEPAGE="
+	https://github.com/tox-dev/sphinx-autodoc-typehints/
+	https://pypi.org/project/sphinx-autodoc-typehints/
+"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/sphinx-5.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/nptyping-2.5[${PYTHON_USEDEP}]
+		>=dev-python/sphobjinv-2.3.1[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.5[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# this package is addicted to Internet
+	tests/test_sphinx_autodoc_typehints.py::test_format_annotation
+)
diff --git a/dev-python/time-machine/Manifest b/dev-python/time-machine/Manifest
index fe3c9dbbdccc..94f6241d2342 100644
--- a/dev-python/time-machine/Manifest
+++ b/dev-python/time-machine/Manifest
@@ -1 +1,2 @@
+DIST time-machine-2.10.0.gh.tar.gz 28770 BLAKE2B ba4ff7dd2559530e86e38d23600209f2e860a1541c9ef5536d07092678018c210ec5e0c63bc615e81b62e8179324953d023ba247c501aa94e16beb0345cacf8f SHA512 4a3120432cb6aacb1e022415094a4fb204d2f1b39c378307a0de34505d470982d81e1d2d940d0b9745c3edcd563ff55f9ab1d602bd1dea720a474fee5fa1e4af
 DIST time-machine-2.9.0.gh.tar.gz 28043 BLAKE2B 9a9a521c94b72a7464853661da791b6f57f5155ddc62ffceeb82f808903f4c337e6bf48fe8300bb4f9f5673fd175fd85038a4e80a39e8f3e096c12c27ee790ec SHA512 ecc780a72d279b49d026a8f3f89210cb4c90e02c5a517c08eadbabcb65216a24c603ace39afd76ea1e6ccdef589d5997581d0db7477bb28fe4d1e0510daf17a0
diff --git a/dev-python/time-machine/time-machine-2.10.0.ebuild b/dev-python/time-machine/time-machine-2.10.0.ebuild
new file mode 100644
index 000000000000..2fc6754c18c8
--- /dev/null
+++ b/dev-python/time-machine/time-machine-2.10.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Travel through time in your tests"
+HOMEPAGE="
+	https://github.com/adamchainz/time-machine/
+	https://pypi.org/project/time-machine/
+"
+SRC_URI="
+	https://github.com/adamchainz/time-machine/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index d227f90ac110..7a9f0239964b 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -3,3 +3,4 @@ DIST tox-4.5.1.tar.gz 170137 BLAKE2B 38ab00eb577e66211db0ecf8931087a8c5a14f8219e
 DIST tox-4.5.2.tar.gz 170336 BLAKE2B 1dcd2bbd7d153dbf0ac7bb48cdd1826d5fb915b7ef6d30a943138e06bb5d82d67db551f8c6d0342a5a81d91ddfd7da6ad8272fc016eaea27bcd4d69f6be9c605 SHA512 44a6c9821975205258402eaaa2010a0acde98190c77db0361da6c67d793de90871786fe2d78c6c9ee83100d7399e1eac857e2edaf94c64c81fb535ff871a363c
 DIST tox-4.6.0.tar.gz 170401 BLAKE2B ae9decd66677fc4e0422687dcd166a27df2f5617c4dbad1d99762542e0d7e1cbcb27892fce74217f85d3e93176475fa39a22a6dd99ccf141a12832862b436a02 SHA512 465db889630d1aa36329b41cf91537e7ca27fe0901b77b8b24d180ab854f2b7c062ae62bdcc931a33235b617e7c709d9290f0769b133b5cd40e398aea9a8d918
 DIST tox-4.6.1.tar.gz 172090 BLAKE2B ee86b8972ee273f07ab0197ab2f0b6ce4505206eebc412f6ec68007e1cf5ac270662e4cb61aa6eb5b08df07a5b20a28c498f9e730fe08fd04339ba918a7712e5 SHA512 b6571790275ee6d7f33dfd72c587b70476fc4ea0798a5331831bea69087cacd21eed546197bfb4a32cb4fe182b63b759977f194e19b56fb346ed251a00be9d6b
+DIST tox-4.6.2.tar.gz 172333 BLAKE2B 0fa9e7782eb18b525ff7f226b0fa9b8001f69f8b620b86a19bc2c19c349b2c8c7440a1de220387bccaa7a9044796db57ae63d16851c98a73ced2c495a01b5f3e SHA512 3e4663972f8c51a634f00c57c8b9b6704a628e912ef2e1854a8dfbd7bce13e44822984af9f69cb5b8a306ede545a565044cfeb8803cff41a530de7958fc07878
diff --git a/dev-python/tox/tox-4.6.2.ebuild b/dev-python/tox/tox-4.6.2.ebuild
new file mode 100644
index 000000000000..758ce1944858
--- /dev/null
+++ b/dev-python/tox/tox-4.6.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/cachetools-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.12.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.5.3[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.5.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	>=dev-python/virtualenv-20.23.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/build-0.10[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.11.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.10[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 1c2d9f5b74ca..7ff3e3a49985 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,3 +1,4 @@
 DIST virtualenv-20.21.0.tar.gz 12070063 BLAKE2B f69d5934191ccd8e9420c37e51b53df7876961d6f13d0f75845530893fd91df29a512e64eaa27135535816250a3149087029e6fe1b15317b8079af9cee2832ea SHA512 77aae5ebc5007093953c30da1eed996e851a65c7dd1f7a3a85961a1bb251b3d7970936eea1efe8babb216d2024072bdbf1c1a97ba8760a04a0abf6e7c3a27d09
 DIST virtualenv-20.22.0.tar.gz 6612036 BLAKE2B aeebf0a80dd96eb78dc4a2ca258e1089a9ce1a4e0bb66b1e8b5093353e298e22dbcc57acea7f5094dee29e4e855c51ce235901fd39d29fbfbc3dd96dcef8b15f SHA512 83d15b03abebd856b1636d0f00443f77882de9fdeb9dff67b72dc839d55f4e7e0668914ef3ac79cdf1d8cf147e29ba97feb720a5ebfcf24dc6cd27ec2e04384d
 DIST virtualenv-20.23.0.tar.gz 6617594 BLAKE2B 370cabd8b8fe24dc7bcaee9c9976d43ca36768824e5fa8c4167f701edba0498fc9faf7af12e8964b57246d2390d995562327067cb30d577ef70adcd9439b3a49 SHA512 90b5aae687984b982dd60d573f9b2cf9a525c135f93d51a9087940d2265a1dd0c59670dcfff9b3aa459a081b0b13d1183360022825f486c9cf2fc86bfc5b8bc3
+DIST virtualenv-20.23.1.tar.gz 6619074 BLAKE2B 0b35a1439b7e2a9eba9c676457a39d22c4318dd4925723bdfcd5ec36cdae236b5bd6aee44a7e4cea5f1febfac7dbf58a7b0e21bb150529f9b851eb065fbddede SHA512 9a19b8f4aff021f5419c10b5954118adb668294cdeffba7a43ed12f76fc6fc8aed8e53df68277a959deb7a4e81f81ed9b4797c17574c347610c8de8d85826af8
diff --git a/dev-python/virtualenv/virtualenv-20.23.1.ebuild b/dev-python/virtualenv/virtualenv-20.23.1.ebuild
new file mode 100644
index 000000000000..cb3f96d64f0a
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.23.1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	<dev-python/distlib-1[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+	<dev-python/filelock-4[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.12[${PYTHON_USEDEP}]
+	<dev-python/platformdirs-4[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.5.1[${PYTHON_USEDEP}]
+"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/pip-22.2.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/pytest-freezer-0.4.6[${PYTHON_USEDEP}]
+		' pypy3)
+		>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.8[${PYTHON_USEDEP}]
+		>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python3*')
+		dev-python/wheel[${PYTHON_USEDEP}]
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	)
+"
+# https://github.com/pypa/virtualenv/issues/2554
+BDEPEND+="
+	test? (
+		$(python_gen_cond_dep '
+			!!<dev-python/virtualenv-20.22[${PYTHON_USEDEP}]
+		' 3.9)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+		# tests failing without python2 installed
+		"tests/unit/create/test_creator.py::test_py_pyc_missing[True-False]"
+		"tests/unit/create/test_creator.py::test_py_pyc_missing[False-False]"
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+	[[ ${EPYTHON} == python3.1[12] ]] && EPYTEST_DESELECT+=(
+		# TODO
+		tests/unit/discovery/py_info/test_py_info.py::test_fallback_existent_system_executable
+	)
+	[[ ${EPYTHON} == python3.12 ]] && EPYTEST_DESELECT+=(
+		tests/unit/create/via_global_ref/test_build_c_ext.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x TZ=UTC
+	local plugins=( -p flaky -p pytest_mock )
+	if [[ ${EPYTHON} == pypy3 ]]; then
+		plugins+=( -p freezegun )
+	else
+		plugins+=( -p time_machine )
+	fi
+	epytest "${plugins[@]}"
+}
diff --git a/dev-python/ypy-websocket/Manifest b/dev-python/ypy-websocket/Manifest
index 2811306bb5f1..0d9797a9eda5 100644
--- a/dev-python/ypy-websocket/Manifest
+++ b/dev-python/ypy-websocket/Manifest
@@ -1,3 +1,4 @@
 DIST ypy-websocket-0.10.0.gh.tar.gz 14621 BLAKE2B c027ebd10a2a6ac7098d662435eb26b5c3a466d83c22a9db62a795be72df86ce34f0d233f05fb6179f07cf479222db1266c9a5070130da23f87f7adbbb9b471c SHA512 8267a3598c4c0e7b180f1718e9f84e05734f2e75acc971a531bf91cf9eaef4f0f5a4404ba0444aa7664c639ce877fb7409e0a65716dca046fe9423cc8f079b99
+DIST ypy-websocket-0.11.0.gh.tar.gz 19274 BLAKE2B 61222dd10259c4f35bfd81d8f5391189bbbd8d950f796d6bc7e69e8df8e3167095facf6fbd2c0eb79c4ec8fdc95fbbf4e5c88941283dfcd531db69dfc1cc18f2 SHA512 ff1616f3bf65c4c2909359de4483ae1d27f31b7771e8c83ade039599fd85933664128469a2ecd6d52864887227ab3630c86ba6d1a10273d4a2cffce6e598aa2b
 DIST ypy-websocket-0.8.4.gh.tar.gz 13416 BLAKE2B 9dd988d6eceb624bae2385180c408971a776f06324407506886c2ef5b8e713277a4c4fb0a2d328a20695d4db8808997c125bfb48faa60c93fe38bb1a1e899766 SHA512 20794b182bbf3958df9f3097ab8c4657acef1ca294c751e0524bc5a36cd7b7a6a2766ae9295cd5f9fc31070813d5b56e0e1e25e22931f63171f88b4757bb1584
 DIST ypy-websocket-0.9.0.gh.tar.gz 13677 BLAKE2B 663cf37af7ddddc1bf208da05bc92fc36d866b1a1f86eb2ae1d8362b023db95b68085b5d9eb35b5f34e106f41a819249db6a3d5d102f1c6a5bf04828d2a9cfc7 SHA512 5a193285fafc206de116e087ba10f37ee6e7238968d9c3e88537e054fd8c2238f9bf55c2b2dcb5871b8af9b080caba912a3526e124c33ea3156f19621312cdb4
diff --git a/dev-python/ypy-websocket/ypy-websocket-0.11.0.ebuild b/dev-python/ypy-websocket/ypy-websocket-0.11.0.ebuild
new file mode 100644
index 000000000000..0b67bfaf654b
--- /dev/null
+++ b/dev-python/ypy-websocket/ypy-websocket-0.11.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings to y-crdt "
+HOMEPAGE="
+	https://pypi.org/project/ypy-websocket/
+	https://github.com/y-crdt/ypy-websocket/
+"
+SRC_URI="
+	https://github.com/y-crdt/ypy-websocket/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	<dev-python/anyio-4[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.6.2[${PYTHON_USEDEP}]
+	<dev-python/aiosqlite-1[${PYTHON_USEDEP}]
+	>=dev-python/aiosqlite-0.18.0[${PYTHON_USEDEP}]
+	<dev-python/y-py-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/y-py-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+		dev-python/websockets[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Requires internet and nodejs
+	tests/test_ypy_yjs.py
+)
+
+distutils_enable_tests pytest