Adding metadata

25 files changed, 527 insertions, 4 deletions

diff --git a/dev-python/Faker/Faker-9.8.1.ebuild b/dev-python/Faker/Faker-9.8.1.ebuild
new file mode 100644
index 000000000000..1f1f09ada79c
--- /dev/null
+++ b/dev-python/Faker/Faker-9.8.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="https://github.com/joke2k/faker"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/text-unidecode-1.3[${PYTHON_USEDEP}]
+	!dev-ruby/faker"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/random2[${PYTHON_USEDEP}]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index ce7d9a68a738..5cc8ff5de607 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -3,3 +3,4 @@ DIST Faker-9.5.0.tar.gz 1176231 BLAKE2B 5b1fbdec6952ee18c4f7243e1776cc5b44b99b21
 DIST Faker-9.6.0.tar.gz 1171903 BLAKE2B 2d7a7fae74d25cb67a339400952e9b783d26fb0b623bf75543e1b3d2c83dde86a0cbecb462ad236a6799e6f2527fc6fdcef22996128c9d6a8e0a6193b9273b6d SHA512 6b68188ab6996d593fd029b2e62f3d2c0f22259ffa737c6700cf032b0528c9809699c57a849c34e0c40e37d6784155309832a0a795c8775d114d3d1033e9b3fe
 DIST Faker-9.7.1.tar.gz 1175336 BLAKE2B 0af66ad2b04a5ab97bd13945f6b0e2b39ea1ad3f3a9c11b6f8e86718ac27636e19a1ddcc79d202bc820b3fe23ae17cd604e8bc5a5a34904c71efd654c3612ec4 SHA512 8b88a7b04ac37d7e122045e0cbad06c929a4973cf8c88f71546bb3d1e955a704a863d3ac999eaaeae801edc1154d98f3f14a657e7c6b99bee5fee2d1b68a0613
 DIST Faker-9.8.0.tar.gz 1198218 BLAKE2B eb021752b0e085fbe3732039489ade33b9657603e44c5ea0d83b95cdde98fed07e1f8552f40fcf5623d9803a65d218e3f07c212fd2abf21d1b3734ffac31f700 SHA512 451111507876c41a62efec7f6e3628beb46d56104c626c112cdec6f335862bd8f3a1f7f64a40cdf793125fbf43f65f710140a7e129ed5eedbb28915a91f8b312
+DIST Faker-9.8.1.tar.gz 1198229 BLAKE2B 8877a9da582fcd81b8b374c344343c9ba4a21d1cd0160694300030b2ace4b7b517fb8a62c1f0ffeacf3a950703b882ff5b484d54fdabc5b9c8b49658c45d421f SHA512 a93d625311358100c7a1dfe33dfda64b5890dd25e8d6e3dd095329ab2156c76abf3f00fe6b2c335316bbe3f42322adda2bcae3a9a312ddf4778d8143796667a0
diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index 3ca6b3a7af09..63ea38e41c56 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -4,3 +4,4 @@ DIST astroid-2.8.0.tar.gz 384821 BLAKE2B 74150d67fd883b2bd4356c49c9c1b148a5e98b4
 DIST astroid-2.8.2.tar.gz 388957 BLAKE2B 0e91b1978d8715f91b24e1d7f817bf7db3c4ca8c2c7af09f5df98b5a40c9307d54ec4051f08aa5062ffe51e5c396ae2e38078e1e124e23855fc207e34638719c SHA512 15b73c24517217ab54157d6568abf2c81c70e47980aece58eaf1d946e9d5d44316467ddaf2153fd8f6278cea80cfd09dc31783b215305c71c09d1e4e6f406862
 DIST astroid-2.8.3.tar.gz 389855 BLAKE2B 355d6ae4a7c1bc9726e46a6eecf7538ecf91294220b10bcf4af26882b2c928544b6337c7368032587ba31bd0de19ed962d092bf8a783f74720d313b33fc96b90 SHA512 b93aed7a3092b726ef0d3e1b1703bf3e198d6eeea8d6faf40da8616d33a093f7e249dde930b85be7e0c358f5a151de12cad8571daa8cfc346d082670c556db08
 DIST astroid-2.8.4.tar.gz 391667 BLAKE2B 118a9dce88ac081d0057134cf4fb158fb8ca9c0d9807e9071910c86cad90c42518b7033a05504f617dcaf2cab73afe26be35224bf6b14aef618f77c15da07424 SHA512 8dc0746cabee8ae6f171d89df4ff2236b0f7c525694356e7169fb7ba5dc61a0febc04e4dfd1d116bc120170e5c70814b74df7625a2cce9b35aab40558bf6bd41
+DIST astroid-2.8.5.tar.gz 393800 BLAKE2B eb3e7abe877da8054dd9e5bbad89e23e8cc6bfdb5c224674c1559d0bf6fbdfd562ef33d65457b26394fc9de38f77e5ce3c15509d71993d0d07ddfd00b97fbcd2 SHA512 4dcad05763419db2814c4e6a8f0a9b62d967e8855ac77a3cedf90f6186d5c68bcf037ac36e4af8dfcbaad3abab3b8ec2485a5973f5ac1952971c335a827948ce
diff --git a/dev-python/astroid/astroid-2.8.5.ebuild b/dev-python/astroid/astroid-2.8.5.ebuild
new file mode 100644
index 000000000000..5ce9c5de2ad1
--- /dev/null
+++ b/dev-python/astroid/astroid-2.8.5.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/PyCQA/astroid/
+	https://pypi.org/project/astroid/"
+SRC_URI="
+	https://github.com/PyCQA/astroid/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.10[${PYTHON_USEDEP}]
+	<dev-python/wrapt-1.14[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local deselect=(
+		# no clue why it's broken
+		tests/unittest_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/bandit/Manifest b/dev-python/bandit/Manifest
index 53d4c6bd118c..96c5a71f5342 100644
--- a/dev-python/bandit/Manifest
+++ b/dev-python/bandit/Manifest
@@ -1 +1,2 @@
 DIST bandit-1.7.0.tar.gz 506225 BLAKE2B 6e2383576b2091ab98757381bfd5915331fc7b08a251e817a6964d963de60b070f7c4dc7958dd366cf95333f4abc157e80433490ab8b923580cb45d855c13092 SHA512 c51af7ab4c667c376a11f142fa35881a776d420bd3ef41421bd29a713e0b56bbf1622e24cd878e24f57594f03d06b7c2b8258fcf34f57e3a68df4200a34becdc
+DIST bandit-1.7.1.tar.gz 503072 BLAKE2B 1e88b662d8dda0d5c1a1fd7ee2eaa1787b8c4952acefb60c347aa98b3534d9ba212229b050dcf717169fb39132ef77d2d92af834392a0bcaa0b9fbc7d2a4804c SHA512 6543bb0f69339a8d970cf0dd1bcec1392057c5c7fbf229fa4f4e6c9d21a39206f1f3fa17509ca2038cd1671d4b57316f92ee053c1beab102e8d20096d10b685d
diff --git a/dev-python/bandit/bandit-1.7.0.ebuild b/dev-python/bandit/bandit-1.7.0.ebuild
index 0d98ebebec4c..de01395e5473 100644
--- a/dev-python/bandit/bandit-1.7.0.ebuild
+++ b/dev-python/bandit/bandit-1.7.0.ebuild
@@ -37,9 +37,9 @@ RDEPEND="
 	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
 	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]"
 
-python_prepare() {
+src_prepare() {
 	sed -i 's/yaml.load/yaml.safe_load/g' tests/unit/formatters/test_yaml.py || die
-	distutils-r1_python_prepare_all
+	distutils-r1_src_prepare
 }
 
 python_test() {
diff --git a/dev-python/bandit/bandit-1.7.1.ebuild b/dev-python/bandit/bandit-1.7.1.ebuild
new file mode 100644
index 000000000000..4939943a8d7d
--- /dev/null
+++ b/dev-python/bandit/bandit-1.7.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A security linter from OpenStack Security"
+HOMEPAGE="https://github.com/PyCQA/bandit"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~s390 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/GitPython-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/hacking-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.3.0[${PYTHON_USEDEP}]
+		>=dev-python/beautifulsoup4-4.8.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-1.9.4[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+		dev-python/toml[${PYTHON_USEDEP}]
+	)"
+
+python_test() {
+	distutils_install_for_testing
+	"${EPYTHON}" -m stestr init || die
+	"${EPYTHON}" -m stestr run -v || die "Tests failes with ${EPYTHON}"
+}
diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 524cfbd65ad1..2f716c3517af 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1,2 +1,3 @@
 DIST nbconvert-6.0.7.tar.gz 896833 BLAKE2B 1b5b39144509aa9f61dc1e9675b112d69ed2e2f9859f3ce7ccfac517d89fff0010062c03ded1c3db571c84dd8d4f8ba12e4851245f370d2e671d24921dd50ab6 SHA512 3c78fa4d777a79a08606a39bb31f6b329dc9d28c1ef2ea9f3253746dce853a295e8fe85b14c65b04762aa5acd5facc879232a375875a2ca6dc9477cc1ab88786
 DIST nbconvert-6.2.0.tar.gz 898501 BLAKE2B 6dfcd33c4bf625a2f68dd4b89cc15d100a2b036e08f3918731f019d171224c218f669e07fd7d6aed712c52448dbf71e6173a49b560faa7d5f13e3cce62df0fff SHA512 ed67cafd23dbe9d8e08292877cae9c889518218659f2ca615fe52fe937f70cdca3e300a28dbda81578ede7784458443bb9fa1994e05c154dd5473015b91c9af3
+DIST nbconvert-6.3.0.tar.gz 900850 BLAKE2B 8ef7d3bfcb914bf4be064ef440faab283fcc71e53579a681deb343d307a8b39cca2d0b83828b9df7c45ee7e9e06164ba6daa234b678197bc8a3202cd7e560c06 SHA512 efbe18c50e408fcb7d920c5ee070d19e19f0347f7073cf86b45046f3e30bd30ab8174115c539020fbf404faf5fc6e55dc7df1ad27accb45f1b2acf2db1d325e6
diff --git a/dev-python/nbconvert/nbconvert-6.3.0.ebuild b/dev-python/nbconvert/nbconvert-6.3.0.ebuild
new file mode 100644
index 000000000000..ca212315a39c
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.3.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+# Skip inkscape on hppa b/c tests should skip it gracefully if not around
+# It's a heavy dependency.
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		!hppa? ( media-gfx/inkscape )
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		nbconvert/exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	epytest --pyargs nbconvert
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
diff --git a/dev-python/pyparsing/Manifest b/dev-python/pyparsing/Manifest
index cfe378d950f2..e4247371ebab 100644
--- a/dev-python/pyparsing/Manifest
+++ b/dev-python/pyparsing/Manifest
@@ -4,3 +4,4 @@ DIST pyparsing_3.0.1.tar.gz 936219 BLAKE2B cc7dc4670f37a09e98c8bda785bac4121150f
 DIST pyparsing_3.0.3.tar.gz 938435 BLAKE2B 5237244693759ffc19637b4d8ee52f98b7160160c1f422a1720b9a8848025f37cb8b314aae505acb7696cc1546c495d049a6a93b3824d784b89aee3565001a4a SHA512 19735a3125620716a0a843156e6e9285c7811aa4db876fdc9fed7413dff77c0670fea5a0a16bc074704c6fec45f0129d1a3680b2123abf3c414fa75d73e03d36
 DIST pyparsing_3.0.4.tar.gz 939837 BLAKE2B 27130518d1f3a4e497ecd4fa1fc624516bcb62488baf881ae3c8888bca48c957a4c6f0bf8d29aeeca8b1aa907c04ca41f3a61e876b78f1ea50684e24b12a2422 SHA512 01acf9b7663feae57e82ac3139c35687ea2754874425acfcf29b82595977660dab86ec35665e96400eb92acfbb51fb2326e010b960be7570de7575296078bd31
 DIST pyparsing_3.0.5.tar.gz 940615 BLAKE2B 7ca78eb4ddd769a49f9538757fc3aae1a1fa11ed1a8fd4483ac80bf50b483e0a8ca5ee13739fbb8c40a6009e3dd48aabab6fbb29fdd01f6f82c11b22348408e1 SHA512 b3efebc911f3c3850ebbb573299a843aab1ca2fb612e41d93947f59ebba9a716ca099b5ec2f9ad8091cb82f6018910205d8409c403f26fb64e72cbb474d05223
+DIST pyparsing_3.0.6.tar.gz 942509 BLAKE2B 1ece2e83dd4193c8364bf690afc54090b46658fced62fc852b0098208d2ae4b18e96f050e63d8751c4b5cf95aa178a11dd1c37fc9d63ae1551639b5c91fe81d8 SHA512 5e94f1dcb4560a0f8e5b9a979b691b6362939648d03e9ea03f74e3aeeddafc09029c8e82c42a517aebe4a0483fd06cac03ae45030e074a40576f9570ed1eb5cc
diff --git a/dev-python/pyparsing/pyparsing-3.0.6.ebuild b/dev-python/pyparsing/pyparsing-3.0.6.ebuild
new file mode 100644
index 000000000000..798e1d9c0ea4
--- /dev/null
+++ b/dev-python/pyparsing/pyparsing-3.0.6.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2004-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+MY_P=${P/-/_}
+DESCRIPTION="Easy-to-use Python module for text parsing"
+HOMEPAGE="https://github.com/pyparsing/pyparsing https://pypi.org/project/pyparsing/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${MY_P}.tar.gz"
+S=${WORKDIR}/${PN}-${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# railroad-diagrams not packaged (and not suitable for packaging yet)
+	tests/test_diagram.py
+)
+
+EPYTEST_DESELECT=(
+	# also railroad-diagrams
+	tests/test_unit.py::Test02_WithoutPackrat::testEmptyExpressionsAreHandledProperly
+	tests/test_unit.py::Test04_WithPackrat::testEmptyExpressionsAreHandledProperly
+	tests/test_unit.py::Test06_WithBoundedPackrat::testEmptyExpressionsAreHandledProperly
+	tests/test_unit.py::Test08_WithUnboundedPackrat::testEmptyExpressionsAreHandledProperly
+	tests/test_unit.py::Test09_WithLeftRecursionParsing::testEmptyExpressionsAreHandledProperly
+	tests/test_unit.py::Test10_WithLeftRecursionParsingBoundedMemo::testEmptyExpressionsAreHandledProperly
+)
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pysol_cards/Manifest b/dev-python/pysol_cards/Manifest
index e66862899baa..e8a7e5057f9d 100644
--- a/dev-python/pysol_cards/Manifest
+++ b/dev-python/pysol_cards/Manifest
@@ -1,2 +1,3 @@
 DIST pysol_cards-0.10.2.tar.gz 20776 BLAKE2B b9f3f20e983453196a7db78ac81c17eb35f157e6419a9dd25e6286ab82763bf2a1601177e41abfe0f49367189a4a78ac66e4f77151c52acae006e3198ff8c524 SHA512 df8848c63ad12496c4346fc51fbac803b7a27c274147d458c78f937b70c804cddeeece8c6a980ef2a422bb17771ee1825c9824843e7d1cbc47e3678e506a30c5
 DIST pysol_cards-0.12.0.tar.gz 21337 BLAKE2B 5d31dc32b7b968366b34481623d2c71ae29f54ff497028f4300e0448dbc27c4529c0524fd33793b84e1f03bcacba3629c8476bf589511a5bb8c56ce7ef7a8fc5 SHA512 c40bd7398e6cdd4d0c10f5c8ffaa2c0d274acafdfeb7d7bdbf36420a650157412e25d270c4e8c03ca2a9e07a9fdca97f14d0175773613eb76b447e05aff942e1
+DIST pysol_cards-0.14.2.tar.gz 18113 BLAKE2B 63704d97598927b600a8f34eb46565e8bf927bc27cd409579de6ac5f4b9154a881b1727c30a61381c169a267b313a4aabfe796a98341208ffb9a8327ca83ec71 SHA512 5e296819ebd6a874175c098b0000524defeb22456bdce961270ecfe26de48fb0d5f5b56eeb3457a12c51f72c9d90abdd35ebaf91244ceaa7d3034caff2b59386
diff --git a/dev-python/pysol_cards/pysol_cards-0.14.2.ebuild b/dev-python/pysol_cards/pysol_cards-0.14.2.ebuild
new file mode 100644
index 000000000000..87f1c34b73ce
--- /dev/null
+++ b/dev-python/pysol_cards/pysol_cards-0.14.2.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Deal PySol FreeCell cards"
+HOMEPAGE="https://pypi.org/project/pysol-cards/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/random2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/pytest-tornado/pytest-tornado-0.8.1.ebuild b/dev-python/pytest-tornado/pytest-tornado-0.8.1.ebuild
index e69ee18fd470..288b244f31ba 100644
--- a/dev-python/pytest-tornado/pytest-tornado-0.8.1.ebuild
+++ b/dev-python/pytest-tornado/pytest-tornado-0.8.1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://github.com/eugeniy/pytest-tornado/archive/refs/tags/v${PV}.tar.
 
 SLOT="0"
 LICENSE="Apache-2.0"
-KEYWORDS="amd64 sparc x86"
+KEYWORDS="amd64 ~riscv sparc x86"
 
 RDEPEND="
 	>=dev-python/pytest-3.6[${PYTHON_USEDEP}]
diff --git a/dev-python/pytest/pytest-6.2.5-r1.ebuild b/dev-python/pytest/pytest-6.2.5-r2.ebuild
index 040c550f22c9..25f0730ecc8f 100644
--- a/dev-python/pytest/pytest-6.2.5-r1.ebuild
+++ b/dev-python/pytest/pytest-6.2.5-r2.ebuild
@@ -23,7 +23,7 @@ RDEPEND="
 	dev-python/packaging[${PYTHON_USEDEP}]
 	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
 	>=dev-python/py-1.8.2[${PYTHON_USEDEP}]
-	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
 "
 BDEPEND="
 	>=dev-python/setuptools_scm-3.4[${PYTHON_USEDEP}]
diff --git a/dev-python/python-cinderclient/Manifest b/dev-python/python-cinderclient/Manifest
index 2566317b8f61..384895f82596 100644
--- a/dev-python/python-cinderclient/Manifest
+++ b/dev-python/python-cinderclient/Manifest
@@ -1 +1,2 @@
 DIST python-cinderclient-8.0.0.tar.gz 236611 BLAKE2B 818279d06b597a00a66c34cf3b468e8293aaf1e90fd04c996e118ea206d475e598d7c8b9ca78542bd07ada1db5d7a2c7ea9a3748fe85ad787d283c8d8073ecc6 SHA512 ae0c5e1d6f0c173382f57f95ac05ec8872a8ed548b145c1f91d96ab7b9e4602cba11a7205c26c81027ca4ad07cbb69f675244e3606ae5dca00c22eeb8bedc126
+DIST python-cinderclient-8.1.0.tar.gz 235387 BLAKE2B 04b6d9c847ee2f56ccde1e9c953b919282dc45a078b4444cc88d00633d2158ec175d042ef988b1b97781de0de643c7703178dd847a792a8f3f5509b9ff331e68 SHA512 414e7334f84e84edc9a8eb6588be780899c408ce2d744e24622004759e0127f4a73167f78a6ce432d2ed44a745b721cf5c42439f19adbea009451573df5fdf14
diff --git a/dev-python/python-cinderclient/python-cinderclient-8.1.0.ebuild b/dev-python/python-cinderclient/python-cinderclient-8.1.0.ebuild
new file mode 100644
index 000000000000..8742404d0327
--- /dev/null
+++ b/dev-python/python-cinderclient/python-cinderclient-8.1.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Cinder API"
+HOMEPAGE="https://launchpad.net/python-cinderclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>=dev-python/keystoneauth-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-5.0.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pbr-5.5.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.25.1[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.5.1[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-3.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/oslo-serialization[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b cinderclient/tests/unit
+}
diff --git a/dev-python/python-glanceclient/Manifest b/dev-python/python-glanceclient/Manifest
index 27a194790ada..d94f3355c8b6 100644
--- a/dev-python/python-glanceclient/Manifest
+++ b/dev-python/python-glanceclient/Manifest
@@ -1 +1,2 @@
 DIST python-glanceclient-3.2.2.tar.gz 191501 BLAKE2B 0ccafb81aa01f35313a6d312496538b0a3c7f2b8df9f0523b244fdcaf55eedb48a7b9beb750b56df2303bf0e4f32e6cd85bdb998618584bae05f36db606b0eed SHA512 900c8120f2a06f2bf5016ea22883b78926c5b8b27782692f3e44a473985e31cd8c6285371ef16f61dfac79828add8d841363f043453cd68ca6ddb31c8c126606
+DIST python-glanceclient-3.5.0.tar.gz 198273 BLAKE2B 7861a2124a9474c4f6267f5b82e6d7fa9825d3cdc8411fbb05afabf69928dd230a881452de57cf54f9cd1a52157f806826036d85f6a93651980ce65e86afd520 SHA512 e5db1afeea7e3f653d7afac7961aeb3ec28df5dc40bba6b8b70795efcfc66928c2af45ecc0e4bbcc0d59a0157599e4ef3af090a8b0ccd0d727e8a94d4f8c866e
diff --git a/dev-python/python-glanceclient/python-glanceclient-3.5.0.ebuild b/dev-python/python-glanceclient/python-glanceclient-3.5.0.ebuild
new file mode 100644
index 000000000000..280a15ef32be
--- /dev/null
+++ b/dev-python/python-glanceclient/python-glanceclient-3.5.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Glance API"
+HOMEPAGE="https://github.com/openstack/python-glanceclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>=dev-python/keystoneauth-3.6.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-17.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/warlock-1.2.0[${PYTHON_USEDEP}]
+	<dev-python/warlock-2[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b glanceclient/tests/unit
+}
diff --git a/dev-python/python-openstackclient/Manifest b/dev-python/python-openstackclient/Manifest
index 9188d3f6ceeb..56063a9499ba 100644
--- a/dev-python/python-openstackclient/Manifest
+++ b/dev-python/python-openstackclient/Manifest
@@ -1 +1,2 @@
 DIST python-openstackclient-5.6.0.tar.gz 815567 BLAKE2B 9421af19527d1aa004f9e8928c40896fc001960f12dce11d860185e0c2c396642972099823710bf21fd838ec78681601d4196ce99e16d90836f6117e8ff97c5f SHA512 821abe0f85e53d7f52fd01a87a4d77a63fae029d2f03901f3ed5e47a4dd52fb8d00452a53027a347f83d73851ee3b57da4b025fb799571be256e78cdc6b96f9c
+DIST python-openstackclient-5.7.0.tar.gz 817269 BLAKE2B ce44a0c7466c473ae55c9c2198535f3333f361295121a517cabc61178b1363a8e51078a332f3297123138f3bcea021d1c2a610942099e4710d7e61a0cdfab721 SHA512 ca789640d1cc5c6ceae206652ac9629865dce07158e4f01ef28e841b6c362974add16de3047d520986cf7690a0c49ab308221b4e657d8484cedae892d1d5c3ce
diff --git a/dev-python/python-openstackclient/python-openstackclient-5.7.0.ebuild b/dev-python/python-openstackclient/python-openstackclient-5.7.0.ebuild
new file mode 100644
index 000000000000..2c48ef04ff14
--- /dev/null
+++ b/dev-python/python-openstackclient/python-openstackclient-5.7.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack APIs"
+HOMEPAGE="https://github.com/openstack/python-openstackclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/openstacksdk-0.56.0[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.22.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-cinderclient-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/tempest-17.1.0[${PYTHON_USEDEP}]
+		>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Depends on specific runner
+	sed -e 's/test_command_has_logger/_&/' -i openstackclient/tests/unit/common/test_command.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstackclient/tests/unit
+}
diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index f0e059b357d9..d172113c70f1 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1,2 +1,3 @@
 DIST tempest-29.0.0.tar.gz 1090497 BLAKE2B 520e9de1fc326d9a64d7ab5e93887f3bd455d9c47d29e0774bfb362b1baff6c1dd13fc6df2c756f0e73dd2b33ecb02ea61abdca9ea1ae68474ba53271c6c9e93 SHA512 03049d6cf0e77bac1afafad88b5b0fd22abaa40ed24ffd2c0c989dbadf277c09d703f0d9f7b34f4f68a4b5858b061ea9586ef66e26749b0822af0e426d1b81a7
 DIST tempest-29.1.0.tar.gz 1091318 BLAKE2B 152900742fe10beebbcec69e20be35d20e3cd652f309de849ee9306e76d0f9dc6508ee2f66a577f6b85578aafc47ccb42b554b796813d845788b57ea49cf7cf1 SHA512 591018fcd6f0fa6ff9343a2f6c855bcd858ab805d9b28585bbdd05e319af74b833d316b64e88e5a53dfc53d58a247beb625c475ee884cfb60205d0f64bf0ba86
+DIST tempest-29.2.0.tar.gz 1092824 BLAKE2B cad7284ab5a5a39a1a5bdf9f2365a85d337e4ebe17243bc3692a98402ef7f11b27b94e0252d9d427f358c343b736b500db5386098950c88b09f23d87de9ad856 SHA512 4042bce9c5d7cd26d652189d82ee91ac43d73a515b690820dfe05b70c2e792ec6f3bb0be5566bb37e81965015f62773414c8a16cc77512b1e52f141eafbd542d
diff --git a/dev-python/tempest/tempest-29.2.0.ebuild b/dev-python/tempest/tempest-29.2.0.ebuild
new file mode 100644
index 000000000000..2c043e84e8cd
--- /dev/null
+++ b/dev-python/tempest/tempest-29.2.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="https://pypi.org/project/tempest/ https://docs.openstack.org/tempest/latest/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hacking[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	distutils_install_for_testing
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1 OS_TEST_TIMEOUT=320
+	eunittest -b -s tempest/tests -t .
+}
+
+src_install() {
+	distutils-r1_src_install
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/zulip-api/Manifest b/dev-python/zulip-api/Manifest
index e9cd07787eba..7455c261a3e9 100644
--- a/dev-python/zulip-api/Manifest
+++ b/dev-python/zulip-api/Manifest
@@ -1 +1,2 @@
 DIST zulip-api-0.8.0.tar.gz 2509787 BLAKE2B c3fb4ab277beb5f9ddc264016cda3ad3b3884912c03fdf0de7f25b0129eb4a43864b9a90712c1335933ba2c9c6371d63d8cd2b98a72a7f940ca3e77062459d52 SHA512 fd882cb93519ff575a3346d2a9ccbdb1d09fc83dfc0c34379fb2ee013176c6f769f63198cb78414d136e8ca054a2903231085bddefee14635fa2cefb2d1e59fb
+DIST zulip-api-0.8.1.tar.gz 2515621 BLAKE2B 0bde3513f285deff6956e701ec0ab31a045fd70fd16b8b47ec424b194502e99facb11cd5c22b95acba5ced12ba041c901d93387c59cdd281a6a1a1ecbebbac8c SHA512 42c7feb0864fbe6432edd5fd7ac68b7f183d749a4692230e2a233472a8c05277c4b03deff0cee46a01b67e9f150f00d37f68a71bac70dbe6c8e1aa639a8f965d
diff --git a/dev-python/zulip-api/zulip-api-0.8.1.ebuild b/dev-python/zulip-api/zulip-api-0.8.1.ebuild
new file mode 100644
index 000000000000..e59c134eef4f
--- /dev/null
+++ b/dev-python/zulip-api/zulip-api-0.8.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2021 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="ncurses"
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+
+inherit distutils-r1
+
+DESCRIPTION="Zulip's PyPI packages"
+HOMEPAGE="https://pypi.org/project/zulip/ https://github.com/zulip/python-zulip-api"
+SRC_URI="https://github.com/zulip/python-${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~ia64 ~mips ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
+IUSE=""
+DEPEND="
+	>=dev-python/requests-0.12.1
+	dev-python/distro
+"
+S="${WORKDIR}/python-${P}"
+
+src_prepare() {
+	EPYTHON=python3
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	cd ${S}/zulip
+	default
+	python setup.py build_ext --inplace
+}
+
+src_install() {
+	cd ${S}/zulip
+	default
+	python setup.py install --root="${D}"
+	python_optimize
+}