Adding metadata

27 files changed, 584 insertions, 10 deletions

diff --git a/dev-python/astroid/astroid-3.3.10.ebuild b/dev-python/astroid/astroid-3.3.10.ebuild
index 0fea4e31e299..0ff4d99433e6 100644
--- a/dev-python/astroid/astroid-3.3.10.ebuild
+++ b/dev-python/astroid/astroid-3.3.10.ebuild
@@ -39,13 +39,6 @@ distutils_enable_tests pytest
 
 export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
 
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# https://bugs.gentoo.org/951713
-	sed -i -e '/license-files.*Keep in sync/d' pyproject.toml || die
-}
-
 python_test() {
 	local EPYTEST_IGNORE=()
 	local EPYTEST_DESELECT=(
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 0d87ee0310da..18f1df2ec7b8 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.38.23.gh.tar.gz 946184 BLAKE2B cf405adb1f47bcaba2185f2c120b8642f8fe2f68a33bc807854ad32bcd7eec99282a800f13a5273225e7fda6e3415ad8ef7ffd173e5cad21539c0f2765836506 SHA512 fdd7c9ae335afa772b919ffa8989323f54a409e8f7e9483528a199e038aad3b341663ec3a72f78c695e2ef44601caf682e3f769c5a869ea2d0545c9dd7a035a8
 DIST boto3-1.38.27.gh.tar.gz 948453 BLAKE2B 4f775c14a439b4ca204d6728a7b077ed901e9b92f395871b05e9de29e5ce82ac2ab179f4c1914b3d52627b77a5fae136ad003bbeb2d1460597f9fb7b4a1ab93d SHA512 27ab3c3453b16649d58d6ee11ef62abd6e302889b0dc46067e4370af1e9fb4d75292886471f7c7fb530707c226ae78c42d0268d8cd9730fd27ad72ef1fb69d45
 DIST boto3-1.38.32.gh.tar.gz 952265 BLAKE2B a753ca5547a44cb8e163bb90b8446ebf535de5cdba95de5034aa6b196c3db8292afe6fe90e01fd1831fb3599b555779abddfd6ea7f07e406864dc70459dc9653 SHA512 6f81b22588e7de521c47b5621f85f69d50516c2b1f741f1dcc0641f3d57f2c7cf4cd40e833a911639b25ce08506eb1def013b0acd8ad50f5c196b894411e5dc0
+DIST boto3-1.38.33.gh.tar.gz 952926 BLAKE2B c273983f46a87d043adff81c98247b1f2f03af71550ea4e10777e26b28ae22ae2474189c5e8cf2ac68ad448430ccc38fe9cecb1e6122f771178c4306a85abd5f SHA512 4c9a8bc7652c94dd72d0233da016993cd339497f64ce1f90f63e29844ff7c5937ff186b4656a40646e4333b10e17902b3cf5b77d9a5ff5a1616a9e0f1be22e9a
diff --git a/dev-python/boto3/boto3-1.38.33.ebuild b/dev-python/boto3/boto3-1.38.33.ebuild
new file mode 100644
index 000000000000..0e521ede0704
--- /dev/null
+++ b/dev-python/boto3/boto3-1.38.33.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.13.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 620e997f9d64..105af1139166 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.38.23.gh.tar.gz 14649388 BLAKE2B d60b5e5d7fb445f332eed57f3317d3add82dd2123ab4199dc934a9a4d68c2b91947a9e50e3847da4bed06aac402542f2bbe4ea92bd47d72de86be3f8f5571b2f SHA512 d602d19c9160d10aeb06aae911052da50dd66ef0f43e459d5911bed24acba5ac948781f1e8f6f43b377847670f2d074e044f454b043ba33859fc0ca0ba67976a
 DIST botocore-1.38.27.gh.tar.gz 14666017 BLAKE2B 7527044c1b9586ac39b7cdaf1c51e6e263d3021015023e370a2ef30c600f33efd8e37697982148a99d56ec2e817b564f8c66cb75c1e8bd807858aad38fd6dab5 SHA512 2bc66dc805c610f96f52a8fbd716767dc0084f3d35517cc6c54d45a85330cb74c77becef234b323a72b9a9273211febb2604975fc2dbfaff3a51449123e6ad64
 DIST botocore-1.38.32.gh.tar.gz 14700669 BLAKE2B c88446a3fc16de58f0d52fa3ff6f345908951039d16e4616dcd3e918e7c2affd1aab48bc112acf1ad49f253eba4dcedaf01c336ed2eb5d2dcd0e7f35b67cd6a1 SHA512 2222c6b043274cfdae516f11bfe0f4281265a851f2cc187dbcaa7064bb6913bf44cdf3a782c5760af1187944a2f123ffc510e412ede6428e97cc2317e0829648
+DIST botocore-1.38.33.gh.tar.gz 14707771 BLAKE2B bf2d34e054e99205689e446edac267c30b046c67d89b9fefb345b9b1417d4dc54a04fe971a46271717aec6c9f4235238ee4f2d93b2d08a28d5150e85a1aae91a SHA512 03a5a3fa307044ac5c878237dc88d71b66e598cba01e23bf1b4ab32e2f0f20521dc9e25f83bdea097aa9de37f249aded9dffe602cfa9c083e48413786e2e0e8b
diff --git a/dev-python/botocore/botocore-1.38.33.ebuild b/dev-python/botocore/botocore-1.38.33.ebuild
new file mode 100644
index 000000000000..be6df9120cc8
--- /dev/null
+++ b/dev-python/botocore/botocore-1.38.33.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/editorconfig/Manifest b/dev-python/editorconfig/Manifest
index beb3411e2980..7a823c597b11 100644
--- a/dev-python/editorconfig/Manifest
+++ b/dev-python/editorconfig/Manifest
@@ -1,2 +1,3 @@
 DIST editorconfig-core-py-0.17.0.gh.tar.gz 19657 BLAKE2B d7e78d96454b637e6aee511d99ef38d92c549a24b426f4a8bd3c75217fd1a1513bc81a6e9f89cddf69c13d50a1a7414082ca1b16575af2cc1ee188a12cf87bca SHA512 9e9c90f646ad58634115fcf88cedefcd2613fb90bbe4a186618b0ee5adde76d014cf3506bcdc36638c28b1b3bb33bd0e0c3580f7d55cad981dd926d61493bdd1
+DIST editorconfig-core-py-0.17.1.gh.tar.gz 19843 BLAKE2B aabf892af435abd3c682a13f6b1573579427009c17de5c64c89cf9f210e17cdaa6d0063bfce22635b445829ece274eb63a9481296e45dd5981d36523401f38d8 SHA512 0f95a98826d85a2c5e6fdcc2619f50fd09722f78d24fe411df70e9fa5b064928df0ed711a6064dc3b6246b9425abc6b95945de494972dbd6972c36ac589678c9
 DIST editorconfig-core-test-d91029bdf1e3e0307714afe0d2cde7ba6fd208ab.gh.tar.gz 13962 BLAKE2B 2ad5d61d0c6b157083a3990d4deb2d06b1efab42c9e4e0f22a42a90317b9b0212b6dd019ee74c86c4f6ff1edfabb9423d63c3baa499622e80b80243ba7dcc677 SHA512 530ac91b7dc5b433c59251edd5928c6f9c579c343b85f0dbd7dc71de6eb2e34328dbb398f0e68a416f4f22c9c7bfa13a792bcfe4c0469902e3a1fe2ba6c9841f
diff --git a/dev-python/editorconfig/editorconfig-0.17.1.ebuild b/dev-python/editorconfig/editorconfig-0.17.1.ebuild
new file mode 100644
index 000000000000..719b723655d9
--- /dev/null
+++ b/dev-python/editorconfig/editorconfig-0.17.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit cmake distutils-r1
+
+MY_P=editorconfig-core-py-${PV}
+TESTVER="d91029bdf1e3e0307714afe0d2cde7ba6fd208ab"
+DESCRIPTION="Clone of EditorConfig core written in Python"
+HOMEPAGE="
+	https://editorconfig.org/
+	https://github.com/editorconfig/editorconfig-core-py/
+	https://pypi.org/project/EditorConfig/
+"
+SRC_URI="
+	https://github.com/editorconfig/editorconfig-core-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	test? (
+		https://github.com/editorconfig/editorconfig-core-test/archive/${TESTVER}.tar.gz
+			-> editorconfig-core-test-${TESTVER}.gh.tar.gz
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="PYTHON BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	cli? ( !app-text/editorconfig-core-c[cli] )
+"
+
+src_prepare() {
+	if use test; then
+		mv "${WORKDIR}"/editorconfig-core-test-${TESTVER}/* "${S}"/tests || die
+	fi
+	if ! use cli; then
+		sed -i -e '/editorconfig\.__main__/d' pyproject.toml || die
+	fi
+
+	cmake_src_prepare
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cmake_src_configure
+	cmake_src_compile
+	cmake_src_test
+}
diff --git a/dev-python/frozenlist/Manifest b/dev-python/frozenlist/Manifest
index 6c0a53576631..be7617b4366b 100644
--- a/dev-python/frozenlist/Manifest
+++ b/dev-python/frozenlist/Manifest
@@ -2,3 +2,4 @@ DIST frozenlist-1.5.0.gh.tar.gz 46957 BLAKE2B 385b6439985256c5fd074582001a9c3d8a
 DIST frozenlist-1.6.0.gh.tar.gz 49920 BLAKE2B e7f03eb3779e048d921f8383d34d82af82828ac587378c148d9f555cf69aa1324f63fb1a53e42bc3d411a647ccd3eabf5b276a9c2ebd7af14d03245c8f4d4721 SHA512 f7e3d8741335c5ebdb3e78684c6e4a91c2f7f389134f4b869d8ea67d167472814867f14e303211045977f0d409d6b1b9478b7cfa7718af5ae9bacb49d147af58
 DIST frozenlist-1.6.1.gh.tar.gz 49838 BLAKE2B 99e2bf456e9127b79940c53958f8aec377e00788d0778b08a55898f72d1f08ec1646ae7596d650687859d68b502e22360eebc33b82913b57f1877f15ba81bc22 SHA512 63776f6bbbc710d25a47a634df8020c347656d452d1912970ba9e94ffdaba28c999fe12ee6e9dca1622f9e7ab7ce60deda540bc3797f0ca6ec079c0d26b6cc84
 DIST frozenlist-1.6.2.gh.tar.gz 49853 BLAKE2B 88daf2ba5476902fbd1c49a547bfa1d2b6aca4892f3476c275bb7cfddd04c186a7db2dd85d810ef4f8a9ba097ea79a10f9b3604a575b693b3a011e50a17cf101 SHA512 98af12defa65033f42a1ead3012dc6a2df5b018fc96fb02449aeb42465bd22c86edb28663d35c5a2bdbcda71649c99e8edae98836de6ace6957599474a00dda7
+DIST frozenlist-1.7.0.gh.tar.gz 51128 BLAKE2B 8ce7444524bcc1d3bc0c4288a21a06830fb461dbb2c6226995dddca5574f90a88aac03bf21caa0401ffacf5d069096c2f7430325c74ae26105d03c6ff7348c06 SHA512 007118195032ebeeba172d2113b8e0af330d6a1ed67ad3ab4313c01b4948a3d5890e526fb3258e930e3ea8a221f239fd061abe3eead0c6b6196a95e78fb29422
diff --git a/dev-python/frozenlist/frozenlist-1.7.0.ebuild b/dev-python/frozenlist/frozenlist-1.7.0.ebuild
new file mode 100644
index 000000000000..9ac110983020
--- /dev/null
+++ b/dev-python/frozenlist/frozenlist-1.7.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A list-like structure which implements collections.abc.MutableSequence"
+HOMEPAGE="
+	https://pypi.org/project/frozenlist/
+	https://github.com/aio-libs/frozenlist/
+"
+SRC_URI="
+	https://github.com/aio-libs/frozenlist/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	native-extensions? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	# pypy is not using the C extension
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		local -x FROZENLIST_NO_EXTENSIONS=1
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	rm -rf frozenlist || die
+	epytest -o addopts=
+}
diff --git a/dev-python/narwhals/Manifest b/dev-python/narwhals/Manifest
index 170d95eaaf93..ac7ffa720919 100644
--- a/dev-python/narwhals/Manifest
+++ b/dev-python/narwhals/Manifest
@@ -1,2 +1,2 @@
-DIST narwhals-1.41.0.tar.gz 488446 BLAKE2B dbf5144fd96e4a4a555c88b32bb9acbdbcb419b3c2ddb61a4283ac492c100d4eadcd76f6e286295f0575a1d0ca24247928c2b31085230b66a028bdf9c291a36d SHA512 41492fd945863b2e87440983892b81e237e7cfdab0996eba7721b69b648a1c9267b21499494630750424dabbf50b5a5d756ae25ed76ec96346038715da2aaf85
 DIST narwhals-1.41.1.tar.gz 489404 BLAKE2B 001529ab92af6cdaaf84b65621a371ff5290e5eb3285e4a1e09014e0a4e1d9c3c757b01136ea9b88a445283cf4aa48a3c07b76094923cce091bb0117aa28c503 SHA512 a9cce0aaea480d0514d71c881cd4396490111554e0b29228426fb30588884cb5e73e3f02831d4e957c7d5b02e8ff39be5ca7ea7065a576864b5ccd5aecaaadb0
+DIST narwhals-1.42.0.tar.gz 490671 BLAKE2B 8d0671d22c79598e5be41f986f87ba002a16fefe2fd63bd88b68c97c253ffbf5988ffa40851899653241280d167f6fcdcdc0e4384e053c05cfad2cedd4d09ca7 SHA512 3fc574a04ae57220ddd90eca39ce729f022cb0d24170684e35dc3b80ebd2aeb6317a915c75f819a4fe52f60eb06c1c6eb84ae3e7e39c54c627a0e07573e3e3a3
diff --git a/dev-python/narwhals/narwhals-1.41.0.ebuild b/dev-python/narwhals/narwhals-1.42.0.ebuild
index 8422b7e22466..32948bed9942 100644
--- a/dev-python/narwhals/narwhals-1.41.0.ebuild
+++ b/dev-python/narwhals/narwhals-1.42.0.ebuild
@@ -32,5 +32,7 @@ distutils_enable_tests pytest
 
 python_test() {
 	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# make hypothesis more forgiving
+	local -x CI=1
 	epytest --runslow --constructors="pandas,pandas[nullable],pandas[pyarrow],pyarrow"
 }
diff --git a/dev-python/numexpr/Manifest b/dev-python/numexpr/Manifest
index b8856f6325ef..d8b582d5e1bb 100644
--- a/dev-python/numexpr/Manifest
+++ b/dev-python/numexpr/Manifest
@@ -1 +1,2 @@
 DIST numexpr-2.10.2.gh.tar.gz 122622 BLAKE2B 762bab8166989ca6839c029289ce3c196b13f2698c377095c1baaefbe333c75a4a27d552ad7c69c97ca63ed91b5343464c9b36aee118f1ec6a8c039e8719997a SHA512 d1414300fb173b3b66e48fe1d782649e8d4085f6da2c72eec89d37deb01686505bb33514b003d01fcd6c645e2a5cf8a967739fc360e62172beee30b4e02d1e9e
+DIST numexpr-2.11.0.gh.tar.gz 124469 BLAKE2B c00d2175925e5745e474d5b311faebf6bf8cf551a8d8d4ce679892c0b57a66bd9b007a51e8913ebc7d24924d46b1aa41476d3cefa358cb6cc3143dbbcf8cb835 SHA512 6a6d504a7eeb4aff16c975b204735befb2ca9152cf351b45c439e18e8a5a9b74b811271407da35c62a7d3a6e69012c70f686ee08740a10c0fddf91ae8a4c98f0
diff --git a/dev-python/numexpr/numexpr-2.11.0.ebuild b/dev-python/numexpr/numexpr-2.11.0.ebuild
new file mode 100644
index 000000000000..da0c8ae59a0c
--- /dev/null
+++ b/dev-python/numexpr/numexpr-2.11.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Fast numerical array expression evaluator for Python and NumPy"
+HOMEPAGE="
+	https://github.com/pydata/numexpr/
+	https://pypi.org/project/numexpr/
+"
+SRC_URI="https://github.com/pydata/numexpr/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+DEPEND="
+	>=dev-python/numpy-2.0.0_rc:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	pushd "${BUILD_DIR}/install/$(python_get_sitedir)" >/dev/null || die
+	"${EPYTHON}" - <<-EOF || die "Tests failed with ${EPYTHON}"
+		import sys,numexpr
+		sys.exit(0 if numexpr.test(verbosity=2).wasSuccessful() else 1)
+	EOF
+	pushd >/dev/null || die
+}
diff --git a/dev-python/phonenumbers/Manifest b/dev-python/phonenumbers/Manifest
index 52aa875face3..688592237d6b 100644
--- a/dev-python/phonenumbers/Manifest
+++ b/dev-python/phonenumbers/Manifest
@@ -1,2 +1,3 @@
 DIST python-phonenumbers-9.0.5.gh.tar.gz 4916518 BLAKE2B 9a2ad1e1410207319df745e39a386170a259f723c1c8e93044ba90d68658ff541cda529300a95495cd91b0ea703e3afb1fee301d68e4c8794d401f0125dc4240 SHA512 a6c8f78bbaba9be47205b085af52d210aa8f300f1e6388fcd75e25a4a5e72c30348ca02f9ab5a48708157d2182d935dbd37be0e104eab8c5d4081488dc4c06cf
 DIST python-phonenumbers-9.0.6.gh.tar.gz 4916579 BLAKE2B 937fcb5b2c51908d3505b0488effcc3353d2851a40deaca028297dbfb4965869cde7ae1c1acd5232b40582983da9affc0a2930b3b2ec98a6764c2bb11c57f87e SHA512 89c6e547f9e41ab937408504e589396992462c223b80263019db339f4336c4e0afac02ea118797fce53739a46aa3244dab09fedbbaee4fe651acf47740c45001
+DIST python-phonenumbers-9.0.7.gh.tar.gz 4916884 BLAKE2B 7290928928a94ade292171296f5257a7aa77031c03572bddf10d125353e06d76c64376edcdbf2387f5dd39bdec3a9a3873291c2136dcfa53a0d787b366012213 SHA512 752c46fc81353796e3a99774fa06e93ccd9b230a6025c00984567f92680d9f8fbc6a3ec1364f6bb0cd7a911a5c5d514c566279d5d43ff0b9f443cbad307a838b
diff --git a/dev-python/phonenumbers/phonenumbers-9.0.7.ebuild b/dev-python/phonenumbers/phonenumbers-9.0.7.ebuild
new file mode 100644
index 000000000000..85e8daf426e4
--- /dev/null
+++ b/dev-python/phonenumbers/phonenumbers-9.0.7.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+MY_P=python-${P}
+DESCRIPTION="Python port of Google's libphonenumber"
+HOMEPAGE="
+	https://github.com/daviddrysdale/python-phonenumbers/
+	https://pypi.org/project/phonenumbers/
+"
+SRC_URI="
+	https://github.com/daviddrysdale/python-phonenumbers/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/python
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/protobuf[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ../README.md )
+
+python_test() {
+	"${EPYTHON}" testwrapper.py -v || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/propcache/Manifest b/dev-python/propcache/Manifest
index a9c5f99e6779..956ba589e051 100644
--- a/dev-python/propcache/Manifest
+++ b/dev-python/propcache/Manifest
@@ -1 +1,2 @@
 DIST propcache-0.3.1.tar.gz 43651 BLAKE2B dbbd70f29c3b4d7ed9a976e0dde766f7ecc0b4e50f90d0d83c60c8633ebadd25dae8e01ce2cd0f8c00d0fae67a35316bc165f5c6e116cbbe290e2371d1e79f47 SHA512 c109678adc26193d972906d923abbfe7ddeb02829fa3adb82d28988b56497a9e8126ce7186f1b0414ca6e6aba6baaddadcefdf19f7e24fbe5831e2f8da06473e
+DIST propcache-0.3.2.tar.gz 44139 BLAKE2B ace9070dbfceb08fcef26f01f9aab291982a3f99f1f035fb113d539a613eeeb2b69b36b197c21d733b0a4b5d73cc22180aa6aca9f3a220dbd3cd471dc57d0ee4 SHA512 d85a89dd1d34936578eb05a869e0ec07679d477c716aa047bbda00688a2926fd8a1f712c9ddec3de38faa49762941120df12ebe88dc36278f20d84ee796b91fe
diff --git a/dev-python/propcache/propcache-0.3.2.ebuild b/dev-python/propcache/propcache-0.3.2.ebuild
new file mode 100644
index 000000000000..c8c2ce8246a9
--- /dev/null
+++ b/dev-python/propcache/propcache-0.3.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Yet another URL library"
+HOMEPAGE="
+	https://github.com/aio-libs/propcache/
+	https://pypi.org/project/propcache/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x PROPCACHE_NO_EXTENSIONS=0
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		PROPCACHE_NO_EXTENSIONS=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		tests/test_benchmarks.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local opts=()
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		opts+=( --no-c-extensions )
+	fi
+
+	rm -rf propcache || die
+	epytest -o addopts= "${opts[@]}"
+}
diff --git a/dev-python/requests/Manifest b/dev-python/requests/Manifest
index 1c23363adb05..a920ef424e0a 100644
--- a/dev-python/requests/Manifest
+++ b/dev-python/requests/Manifest
@@ -1,2 +1,3 @@
 DIST requests-2.32.3-patches.tar.xz 20028 BLAKE2B fb224c96f85d7f8f9c7c0ca7fc188ddcf12abe6239a83e4ec1fb96f949ed27007ea98a412fea2eb7d132a191ff20cec4cd0da20da10255125d8ab7890dc8c27e SHA512 be04a6a55ff3184c22b20a8f185fd7c6478db44d451fe396e61687a5f58d24b915a18f94fc888f6744eae745ede47831abdb1bca73e31fd26cf4478340b130e9
 DIST requests-2.32.3.tar.gz 131218 BLAKE2B c36bd80e0544e83b80c001e6bfdde7b8552e65b888d44d781f95d5a6302dd34dfd4368e18dbfeab3a014d7170946c502e3bf3a6dbd027a60a2f0f535c674d75c SHA512 20d413597ff4803a62156ada25ef2e8a5edd0d4dbf7d79cc7fcd88d51a76e019a7dacf41d7c3d546306f37c506ede68f16b9afea57c918db64e702382b1ae420
+DIST requests-2.32.4.tar.gz 135258 BLAKE2B 2ae4706d3a07b8484f9cddcb80a56121ecc2f16c345f6d518a259c45d20584d09e62eabb6e60ea76c2f558b5950c29e947c5ccb453774b1aeb953f5147c68f83 SHA512 8308da5ec2b1bd4442497dc8ecb21d4c1d3aba82987a264bc0f55b75d2522b303e5779f704d1b557a0f7d8a8f0a3533925cc34a58d98a95ce463a0dd59c5ac2d
diff --git a/dev-python/requests/requests-2.32.4.ebuild b/dev-python/requests/requests-2.32.4.ebuild
new file mode 100644
index 000000000000..6dc19173f27d
--- /dev/null
+++ b/dev-python/requests/requests-2.32.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HTTP library for human beings"
+HOMEPAGE="
+	https://requests.readthedocs.io/
+	https://github.com/psf/requests/
+	https://pypi.org/project/requests/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos"
+IUSE="socks5 test-rust"
+
+RDEPEND="
+	>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
+	<dev-python/charset-normalizer-4[${PYTHON_USEDEP}]
+	<dev-python/idna-4[${PYTHON_USEDEP}]
+	<dev-python/urllib3-3[${PYTHON_USEDEP}]
+	socks5? ( >=dev-python/pysocks-1.5.6[${PYTHON_USEDEP}] )
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/pytest-httpbin-2.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pysocks-1.5.6[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/trustme[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet (doctests)
+		requests/__init__.py::requests
+		requests/api.py::requests.api.request
+		requests/models.py::requests.models.PreparedRequest
+		requests/sessions.py::requests.sessions.Session
+		# require IPv4 interface in 10.* range
+		tests/test_requests.py::TestTimeout::test_connect_timeout
+		tests/test_requests.py::TestTimeout::test_total_timeout_connect
+	)
+
+	if ! has_version "dev-python/trustme[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_requests.py::TestRequests::test_https_warnings
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/ruamel-yaml/Manifest b/dev-python/ruamel-yaml/Manifest
index a003fbe43683..6d5d79831566 100644
--- a/dev-python/ruamel-yaml/Manifest
+++ b/dev-python/ruamel-yaml/Manifest
@@ -2,3 +2,4 @@ DIST ruamel.yaml-0.18.10.tar.xz 198860 BLAKE2B 02b6a1791002e5bd31c321c6307b7239b
 DIST ruamel.yaml-0.18.11.tar.xz 199288 BLAKE2B 61570938ce90a7143241d903a6ccb83137aedda3d726b9cce337217f3fc0cf27aadfb7d80510ef19574dd25c71451643bb8fda4d392a8b0c6f8f63595bb65af4 SHA512 3858ea80024c94e3e0f685fc93c4a94ffbf967269b3c8c0422590507d7639dbb2b70b86fc5ad536e9d5491d3082e5aeef85f7660837f786bf20acb04f7822c37
 DIST ruamel.yaml-0.18.12.tar.xz 199740 BLAKE2B 3eb891258980395f66428993c66b13ef79b1d26b91d1f60b7b461d3eb15c5de7afe4bf149dd077d12681fdae78544a919fca8826ba4f0705b6d4873d1850127c SHA512 982d640576a26d72ed1eb66bde9954c2e083c973eecc96a1e006fc904d4681a9a82574ba26a24dd697f503a77f8ab2f936f991e63a61b5e5d89894072404a41c
 DIST ruamel.yaml-0.18.13.tar.xz 200268 BLAKE2B 4663153bb8593bd8d41efd3c5bf301893364b3c5b211b129e25ee82a807da80574322911ebc0c490c7bec696474dc2b7c5e51ed9f503019940f6988a38c272e1 SHA512 a0b7fc7beeab4590e76f468442f97da8ac16078d5aae2ecece1b6b6d7cd34ed575aab6e1021be74332158cdf316eeb8a2690af22f72e2fb1192f30f23a517b09
+DIST ruamel.yaml-0.18.14.tar.xz 200428 BLAKE2B 805467fc7e572d3b0157ab734a864ea065e0ce74252a867498db0406606359e1c416dfad268cfc105ff00fe5f68ff37f64a4b1d50822bf48372ec583a420b70b SHA512 1245dbaf184cf98257df5d78c32f3775acf4873cb0696b852cf145cdcb7bd0c24c3c4bac5470f18341537a04fa56df4629b554d742341de3774cc78cdd0d1f8a
diff --git a/dev-python/ruamel-yaml/ruamel-yaml-0.18.14.ebuild b/dev-python/ruamel-yaml/ruamel-yaml-0.18.14.ebuild
new file mode 100644
index 000000000000..2bccc5e4d8cb
--- /dev/null
+++ b/dev-python/ruamel-yaml/ruamel-yaml-0.18.14.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1
+
+MY_P="${P/-/.}"
+DESCRIPTION="YAML parser/emitter that supports roundtrip comment preservation"
+HOMEPAGE="
+	https://pypi.org/project/ruamel.yaml/
+	https://sourceforge.net/projects/ruamel-yaml/
+"
+# PyPI tarballs do not include tests
+SRC_URI="https://downloads.sourceforge.net/ruamel-dl-tagged-releases/${MY_P}.tar.xz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/ruamel-yaml-clib[${PYTHON_USEDEP}]
+	!dev-python/namespace-ruamel
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		_test/test_deprecation.py::test_collections_deprecation
+	)
+	local EPYTEST_IGNORE=(
+		# Old PyYAML tests from lib/ require special set-up and are
+		# invoked indirectly via test_z_olddata, tell pytest itself
+		# to leave the subdir alone.
+		_test/lib/
+	)
+
+	# this is needed to keep the tests working while
+	# dev-python/namespace-ruamel is still installed
+	distutils_write_namespace ruamel
+	epytest
+}
diff --git a/dev-python/sigstore-protobuf-specs/Manifest b/dev-python/sigstore-protobuf-specs/Manifest
index 948009bab634..5d8fffb51092 100644
--- a/dev-python/sigstore-protobuf-specs/Manifest
+++ b/dev-python/sigstore-protobuf-specs/Manifest
@@ -1,3 +1,4 @@
 DIST sigstore_protobuf_specs-0.3.2.tar.gz 17529 BLAKE2B e12bcd471f20c993b0fd5cabc2abf424fd5d185d159321c34c14175d5e11089c18d631f612d81b083176359dc66948691e3711de4c91e1c64e55a5bd7df85543 SHA512 52559a5b2eb4f108950c41ab885fa22169b30de674af08314dd81dc1dbc568b887427d0fee497f5b98c230700f8d81c6901ccad77bddd7ca89f1a453d48c94ae
 DIST sigstore_protobuf_specs-0.4.1.tar.gz 19520 BLAKE2B 5a5a680dc83f737c6560ce0b38add4513a47c0863388adcd4fca050e198f5204b7fce2ab41b2ca26ad310d49b8afbe29091385a9e451743c31e50b46027b14ed SHA512 32811f0e93a05857ee13efe85b657360ca43c0cc089737166c7f302f54ff2f64eb3d836c544c9cbc43f99ab777fd661ad8642f26a932e996a4df72c4b9d17228
 DIST sigstore_protobuf_specs-0.4.2.tar.gz 20802 BLAKE2B 7a093e3f0f4f93a3eaf86342ac33987d1c6678cb524e512c93aa91119d380d48848cc391803628158a47405ed401fec8377c707adb08aec3a9ece684e0aeccb7 SHA512 06b9bf5094ebae71d59e2df116a0072e1ee92c1cff72059455ecbb867242fe3322923a749bed40739718e9d3f7dd2fdd4592aa20584e53dba721f17a587b8277
+DIST sigstore_protobuf_specs-0.4.3.tar.gz 21655 BLAKE2B ac50e6f2e3314c897750f1b087ce93975fd81d29c71378af763add8f837d2f71ba97bd9e0ed0002637b756c1ec406e4c282a35fe429309758c45373773c469b6 SHA512 d40fad6cb2db98c40d2856d0d0460196217dee0a881adc0f2225acbb2887144adf6717d7f8259d9ff17ec1f37c2f3447183917976b5ab2f65493671465d922ce
diff --git a/dev-python/sigstore-protobuf-specs/sigstore-protobuf-specs-0.4.3.ebuild b/dev-python/sigstore-protobuf-specs/sigstore-protobuf-specs-0.4.3.ebuild
new file mode 100644
index 000000000000..91d183b0922a
--- /dev/null
+++ b/dev-python/sigstore-protobuf-specs/sigstore-protobuf-specs-0.4.3.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A library for serializing and deserializing Sigstore messages"
+HOMEPAGE="
+	https://github.com/sigstore/protobuf-specs/tree/main/gen/pb-python/
+	https://pypi.org/project/sigstore-protobuf-specs/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	~dev-python/betterproto-2.0.0_beta7[${PYTHON_USEDEP}]
+	=dev-python/pydantic-2*[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index c6e3008a4251..74e215e9b3b1 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -1,4 +1,4 @@
-DIST sqlglot-26.25.0-crates.tar.xz 8859792 BLAKE2B abb2051b392c53dc3caa705ddd8df7076819a26dcdaa89fa3760559a79578db01e86943c2d0ffb8006263c2dca3aa50d20023eae9d772f8ebd12a8a2d3266cdd SHA512 7cca439a06433a62bcd4a2af33d240f46e9b5240cc158edbc654efb37a464aa0f1ebbe9749b2fc6352127b4809b63af2341fac6240050c414e578ae99444ba5d
-DIST sqlglot-26.25.0.tar.gz 5320294 BLAKE2B ca9a5d32d191f36685a8c0a278cd4d13b1680e04e5e1d8321c019bb135d261be68df79bd7817842240fd9c4b4ad6883753cf974683937db4eace55f2b7e490dd SHA512 7830df0ff9713cc2097c9adc0a1586c6066b3abb70aea116b73779d253bfeb0b248d28832be038f7844c8b832f649285eb143f4016eb00aca19f0a253e5ac50e
 DIST sqlglot-26.25.3-crates.tar.xz 8859792 BLAKE2B abb2051b392c53dc3caa705ddd8df7076819a26dcdaa89fa3760559a79578db01e86943c2d0ffb8006263c2dca3aa50d20023eae9d772f8ebd12a8a2d3266cdd SHA512 7cca439a06433a62bcd4a2af33d240f46e9b5240cc158edbc654efb37a464aa0f1ebbe9749b2fc6352127b4809b63af2341fac6240050c414e578ae99444ba5d
 DIST sqlglot-26.25.3.tar.gz 5322840 BLAKE2B dcef4993a1b1539f4fbc24de8cd4b83db89582487805d1eebc36ce8e6dba0df2bb6092b940d86bd997715ce24a8aadc7df690918333da507be7e37c849542281 SHA512 9ddd68845aa2e647b12e42e28626818facf33ea917ee126e9a236de426c1fa67c25ebc8349a05dfdbdf569c8a2988d717a6e60455c835a2ed6b0dd0c5c36ecdc
+DIST sqlglot-26.26.0-crates.tar.xz 8859792 BLAKE2B abb2051b392c53dc3caa705ddd8df7076819a26dcdaa89fa3760559a79578db01e86943c2d0ffb8006263c2dca3aa50d20023eae9d772f8ebd12a8a2d3266cdd SHA512 7cca439a06433a62bcd4a2af33d240f46e9b5240cc158edbc654efb37a464aa0f1ebbe9749b2fc6352127b4809b63af2341fac6240050c414e578ae99444ba5d
+DIST sqlglot-26.26.0.tar.gz 5325725 BLAKE2B 76d9228de4adf49f22fd2f07287f42fbfa2874629aae0d8daf061aa1e7eeb96448435754ed21d9a843c2cda7396fb9a68db6dd58b09029af0eb1150006af9f4c SHA512 f0b2c53ce5a4e365fdb6debda7e0356d87cd1b4ecca9c2af2d7b9834f682cb6c2fb353e72f855b3a9c5c3bbf9bab52d8f314926c8a3ad5a4fce47b8b23bfb824
diff --git a/dev-python/sqlglot/sqlglot-26.25.0.ebuild b/dev-python/sqlglot/sqlglot-26.26.0.ebuild
index 84a615136142..84a615136142 100644
--- a/dev-python/sqlglot/sqlglot-26.25.0.ebuild
+++ b/dev-python/sqlglot/sqlglot-26.26.0.ebuild
diff --git a/dev-python/yarl/Manifest b/dev-python/yarl/Manifest
index 7f75c734b272..10ad0908e4f7 100644
--- a/dev-python/yarl/Manifest
+++ b/dev-python/yarl/Manifest
@@ -1,3 +1,4 @@
 DIST yarl-1.18.3.tar.gz 181062 BLAKE2B 41e0e6173bb257b643d7678e3011af7ea7f6ac8100bd68aae6e5a9af95e36ae95f83c516a11169fd1d1d669742b3a8878267533c81289ec56a66bb0d53b2db25 SHA512 1686c5ef1b5f3e1cebd121abb7916e45f4a9b08d941a80c34861e87f6121187ee7a553a373405a9fef2332177adf55ffe89bc9a3cabbf24e31905357fdeceba3
 DIST yarl-1.19.0.tar.gz 184396 BLAKE2B 08e1e1d3aac39a1bace97f3d38f33dfa335309a6a809227d830497fb6fff6c506ff8457ec68de5cfc57f3661e190ecd78fbe2481af7e419d5d889d8f496852e0 SHA512 95cf1f26be8497e39ce150672ac95ff36a4a695b8fbb902edb4811b601cc3f73cf8b72b45625afe957649b7a49d08588db0a7b91b46c449c64c9e55fcbda8e23
 DIST yarl-1.20.0.tar.gz 185258 BLAKE2B 9ffe4d715bcadfa061e4fae7de7c5124c3442abc659cc112b19e02da89691ce13ee434cec1b96be139aca9abbe45afe13d8931a03cea7b41857d43f38cf5f62c SHA512 826bd2d95a8de05630a597b2427a3c37e50b6d44a73d7003ffb20add68abed4742fb5102c7bdfdb69509b39e7e63bf506ffa0f22138715bf9c8c1a3836bb7607
+DIST yarl-1.20.1.tar.gz 186428 BLAKE2B 904bc2fba743d7cc0f313166477ff93288816853d7831ed25b3589749878b78c5c10ccb0bb8d11cbad66cea8c5c8eab4fa32ff0542351cf1351a7de5c235ebd6 SHA512 2e7d2c69ddf07f04468b40dc929f5c54bcc3026386fa5fe98bc7f8b8f8aafee05d1df00a42377767e8a9e839f76b8cf569b8e373b3e94af6a954e68a4031fcc1
diff --git a/dev-python/yarl/yarl-1.20.1.ebuild b/dev-python/yarl/yarl-1.20.1.ebuild
new file mode 100644
index 000000000000..c7dfa7b9ada7
--- /dev/null
+++ b/dev-python/yarl/yarl-1.20.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Yet another URL library"
+HOMEPAGE="
+	https://github.com/aio-libs/yarl/
+	https://pypi.org/project/yarl/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+RDEPEND="
+	>=dev-python/idna-2.0[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.0[${PYTHON_USEDEP}]
+	>=dev-python/propcache-0.2.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x YARL_NO_EXTENSIONS=0
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		YARL_NO_EXTENSIONS=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# benchmarks
+		tests/test_quoting_benchmarks.py
+		tests/test_url_benchmarks.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local opts=()
+	# note different boolean logic than for backend (sigh)
+	local -x YARL_NO_EXTENSIONS=
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		YARL_NO_EXTENSIONS=1
+	fi
+
+	rm -rf yarl || die
+	epytest -o addopts= "${opts[@]}"
+}