Adding metadata

27 files changed, 553 insertions, 163 deletions

diff --git a/dev-python/atomicwrites/atomicwrites-1.4.0-r2.ebuild b/dev-python/atomicwrites/atomicwrites-1.4.0-r2.ebuild
new file mode 100644
index 000000000000..d63eff7142cb
--- /dev/null
+++ b/dev-python/atomicwrites/atomicwrites-1.4.0-r2.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Atomic file writes"
+HOMEPAGE="
+	https://github.com/untitaker/python-atomicwrites/
+	https://pypi.org/project/atomicwrites/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
diff --git a/dev-python/build/build-0.7.0-r1.ebuild b/dev-python/build/build-0.7.0-r1.ebuild
new file mode 100644
index 000000000000..1f1b04252da0
--- /dev/null
+++ b/dev-python/build/build-0.7.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="A simple, correct PEP517 package builder"
+HOMEPAGE="
+	https://pypi.org/project/build/
+	https://github.com/pypa/build/
+"
+SRC_URI="
+	https://github.com/pypa/build/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-19.0[${PYTHON_USEDEP}]
+	>=dev-python/pep517-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/filelock-3[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-rerunfailures-9.1[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-56.0.0[${PYTHON_USEDEP}]
+		>=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by the presence of flit_core
+		tests/test_util.py::test_wheel_metadata_isolation
+		# broken by the presence of virtualenv (it changes the error
+		# messages, sic!)
+		tests/test_env.py::test_isolated_env_log
+		tests/test_main.py::test_output_env_subprocess_error
+		'tests/test_main.py::test_output[via-sdist-isolation]'
+		'tests/test_main.py::test_output[wheel-direct-isolation]'
+		# Internet
+		tests/test_main.py::test_build_package
+		tests/test_main.py::test_build_package_via_sdist
+		'tests/test_util.py::test_wheel_metadata[True]'
+		tests/test_util.py::test_with_get_requires
+	)
+
+	epytest -p no:flaky \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/cffi/Manifest b/dev-python/cffi/Manifest
index 1ef47710c4b5..d02ce8a9359e 100644
--- a/dev-python/cffi/Manifest
+++ b/dev-python/cffi/Manifest
@@ -1,2 +1 @@
-DIST cffi-1.14.6.tar.gz 475744 BLAKE2B 46e3f1f61746f659c066d83fdb07b83c289eda68056c6f9e364ea6f30cd56c190e4fdb35586c064b2402483704a7c1e9399d7f30cb49a78eec21797146da36f2 SHA512 30a8b25b74921a90a1fa96d05de1f25437d0fbbf73b7de0bb9ce22dfcaccbd78376b605525fe970212221d3e598357a9b1da420bfbd1a3e513263ed2b789e813
 DIST cffi-1.15.0.tar.gz 484058 BLAKE2B 0d2d470c7eb11b8a9526be816b153c4483a5cfb529d3d220a804842facae1f06e2a822aa2be9abb1b5648cb36a97033bffc1dd235d83bdf8c075d67a907aa7d9 SHA512 ee83efde6f77f4a0c5889088c4c208ed7b9071fe06dfc16a8d2396de07f78fe859e1e39866760198a9d700f3b7359e8715e8a3e4907feb81d3fc4b8dd0dbaca1
diff --git a/dev-python/cffi/cffi-1.14.6.ebuild b/dev-python/cffi/cffi-1.14.6.ebuild
deleted file mode 100644
index c35c1208310f..000000000000
--- a/dev-python/cffi/cffi-1.14.6.ebuild
+++ /dev/null
@@ -1,51 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
-EAPI=7
-
-# DO NOT ADD pypy to PYTHON_COMPAT
-# pypy bundles a modified version of cffi. Use python_gen_cond_dep instead.
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-inherit distutils-r1 toolchain-funcs
-
-DESCRIPTION="Foreign Function Interface for Python calling C code"
-HOMEPAGE="https://cffi.readthedocs.io/ https://pypi.org/project/cffi/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0/${PV}"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-
-DEPEND="dev-libs/libffi:="
-RDEPEND="${DEPEND}
-	dev-python/pycparser[${PYTHON_USEDEP}]"
-BDEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-distutils_enable_sphinx doc/source
-distutils_enable_tests pytest
-
-PATCHES=(
-	"${FILESDIR}"/cffi-1.14.0-darwin-no-brew.patch
-)
-
-src_prepare() {
-	if [[ ${CHOST} == *darwin* ]] ; then
-		# Don't obsessively try to find libffi
-		sed -i -e "s/.*\-iwithsysroot\/usr\/include\/ffi.*/\tpass/" setup.py || die
-	fi
-	distutils-r1_src_prepare
-}
-
-src_configure() {
-	tc-export PKG_CONFIG
-}
-
-python_test() {
-	"${EPYTHON}" -c "import _cffi_backend as backend" || die
-	epytest \
-		--ignore testing/test_zintegration.py \
-		--ignore testing/embedding \
-		c/ testing/
-}
diff --git a/dev-python/grpclib/Manifest b/dev-python/grpclib/Manifest
new file mode 100644
index 000000000000..95fb988eef35
--- /dev/null
+++ b/dev-python/grpclib/Manifest
@@ -0,0 +1,2 @@
+DIST grpclib-0.4.2.tar.gz 116997 BLAKE2B 8a3ad3022a4963f0539c212b66af615f4c1a73cec49801118af25ad141741aed692e16389687f690f885d9f85dc53a5e1b8208a5d8af111c2e50fdefef0684ce SHA512 a25ee2286431d294dd4b07b3ac34387608ca3dbabdf6d54a09b1a33fe66c75ba88f3f5e90160a55dc614871c93bc6ccfb884d149bbd624e13d792b44271b534f
+DIST grpclib-0.4.3_rc2.tar.gz 116904 BLAKE2B c4a0bf70c4f8d218829e10811fb532bcd1bea7eeec10aa2ee06e286af68e653b73d6db1b0e859821d1587fc5fa81e7a8ab2473b24e746b53b1a5134589a6e68c SHA512 185118ce1f1fca4db3dfc8fa781ef7a09f366aa4f0bfb1f37222f307c4d30c9527c5ffd74d4afce1e27cff69c76c6f8e9fb054920a41da000f723e9a79219f07
diff --git a/dev-python/grpclib/grpclib-0.4.2.ebuild b/dev-python/grpclib/grpclib-0.4.2.ebuild
new file mode 100644
index 000000000000..5c737dac7b19
--- /dev/null
+++ b/dev-python/grpclib/grpclib-0.4.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python gRPC implementation for asyncio"
+HOMEPAGE="https://github.com/vmagamedov/grpclib"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/vmagamedov/grpclib"
+else
+	MY_PV="${PV/_rc/rc}"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	SRC_URI="https://github.com/vmagamedov/${PN}/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/h2-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hpack-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperframe-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/multidict-6.0.2[${PYTHON_USEDEP}]
+	>=dev-python/grpcio-tools-1.43.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/async_timeout[${PYTHON_USEDEP}]
+		dev-python/googleapis-common-protos[${PYTHON_USEDEP}]
+		dev-python/Faker[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'dev-python/sphinx_rtd_theme'
+
+python_test() {
+	[[ ${EPYTHON} == python3.10 ]] && local EPYTEST_DESELECT=(
+		# does not work in python3.10 due to the bug in ssl https://bugs.python.org/issue46067
+		'tests/test_client_channel.py::test_default_ssl_context'
+	)
+	epytest
+}
diff --git a/dev-python/grpclib/grpclib-0.4.3_rc2.ebuild b/dev-python/grpclib/grpclib-0.4.3_rc2.ebuild
new file mode 100644
index 000000000000..1803c5a17842
--- /dev/null
+++ b/dev-python/grpclib/grpclib-0.4.3_rc2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python gRPC implementation for asyncio"
+HOMEPAGE="https://github.com/vmagamedov/grpclib"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/vmagamedov/grpclib"
+else
+	MY_PV="${PV/_rc/rc}"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	SRC_URI="https://github.com/vmagamedov/${PN}/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/h2-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hpack-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperframe-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/multidict-6.0.2[${PYTHON_USEDEP}]
+	>=dev-python/grpcio-tools-1.43.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/async_timeout[${PYTHON_USEDEP}]
+		dev-python/googleapis-common-protos[${PYTHON_USEDEP}]
+		dev-python/Faker[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'dev-python/sphinx_rtd_theme'
diff --git a/dev-python/grpclib/metadata.xml b/dev-python/grpclib/metadata.xml
new file mode 100644
index 000000000000..204efcfd87fc
--- /dev/null
+++ b/dev-python/grpclib/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>antonin.riha@protonmail.com</email>
+  <name>Antonín Říha</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/vmagamedov/grpclib/issues</bugs-to>
+ </upstream>
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pep517/pep517-0.12.0-r1.ebuild b/dev-python/pep517/pep517-0.12.0-r1.ebuild
index b236dbbe2048..254897f23794 100644
--- a/dev-python/pep517/pep517-0.12.0-r1.ebuild
+++ b/dev-python/pep517/pep517-0.12.0-r1.ebuild
@@ -12,21 +12,25 @@ DESCRIPTION="Wrappers to build Python packages using PEP 517 hooks"
 HOMEPAGE="
 	https://pypi.org/project/pep517/
 	https://github.com/pypa/pep517/
-	https://pep517.readthedocs.io/"
+	https://pep517.readthedocs.io/
+"
 SRC_URI="
 	https://github.com/pypa/pep517/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
+		-> ${P}.gh.tar.gz
+"
 
 LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
-	dev-python/tomli[${PYTHON_USEDEP}]"
+	dev-python/tomli[${PYTHON_USEDEP}]
+"
 BDEPEND="
 	test? (
 		dev-python/testpath[${PYTHON_USEDEP}]
-	)"
+	)
+"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/ply/ply-3.11-r2.ebuild b/dev-python/ply/ply-3.11-r2.ebuild
new file mode 100644
index 000000000000..0dddfa43b415
--- /dev/null
+++ b/dev-python/ply/ply-3.11-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Lex-Yacc library"
+HOMEPAGE="
+	http://www.dabeaz.com/ply/
+	https://github.com/dabeaz/ply/
+	https://pypi.org/project/ply/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples"
+
+DOCS=( ANNOUNCE CHANGES TODO )
+
+PATCHES=(
+	"${FILESDIR}/3.6-picklefile-IOError.patch"
+)
+
+python_test() {
+	# Checks for pyc/pyo files
+	local -x PYTHONDONTWRITEBYTECODE=
+
+	cd test || die
+	local t
+	for t in testlex.py testyacc.py; do
+		"${EPYTHON}" "${t}" -v || die "${t} fails with ${EPYTHON}"
+	done
+}
+
+python_install_all() {
+	local HTML_DOCS=( doc/. )
+	use examples && dodoc -r example
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pycparser/pycparser-2.21-r1.ebuild b/dev-python/pycparser/pycparser-2.21-r1.ebuild
new file mode 100644
index 000000000000..ef22af9fa8b3
--- /dev/null
+++ b/dev-python/pycparser/pycparser-2.21-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="C parser and AST generator written in Python"
+HOMEPAGE="
+	https://github.com/eliben/pycparser/
+	https://pypi.org/project/pycparser/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	dev-python/ply:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# remove the original files to guarantee their regen
+	rm pycparser/{c_ast,lextab,yacctab}.py || die
+
+	# kill sys.path manipulations to force the tests to use built files
+	sed -i -e '/sys\.path/d' tests/*.py || die
+
+	# Ensure we can find tests in our directory
+	sed -i -e 's/from tests.test_util/from test_util/g' tests/test_*.py || die
+
+	ln -s "${S}"/examples tests/examples || die
+
+	rm tests/test_examples.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Skip tests if cpp is not in PATH
+	type -P cpp >/dev/null || return 0
+	# change workdir to avoid '.' import
+	cd tests || die
+
+	# Ensure that 'cpp' is called with the right arguments
+	# Tests don't seem to always pass the include they intend to use.
+	mkdir -p "${T}"/bin || die
+	cat > "${T}"/bin/cpp <<-EOF || die
+	#!${BROOT}/bin/bash
+	exec ${BROOT}/usr/bin/cpp -I${S}/utils/fake_libc_include/ \$@
+	EOF
+	chmod +x "${T}"/bin/cpp || die
+
+	PATH="${T}/bin:${PATH}" eunittest
+}
diff --git a/dev-python/pytest-asyncio/pytest-asyncio-0.18.3.ebuild b/dev-python/pytest-asyncio/pytest-asyncio-0.18.3.ebuild
index 1b02e3ff352e..bfa95df4e63b 100644
--- a/dev-python/pytest-asyncio/pytest-asyncio-0.18.3.ebuild
+++ b/dev-python/pytest-asyncio/pytest-asyncio-0.18.3.ebuild
@@ -5,25 +5,33 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="Library for testing asyncio code with pytest"
-HOMEPAGE="https://github.com/pytest-dev/pytest-asyncio
-	https://pypi.org/project/pytest-asyncio/"
-SRC_URI="https://github.com/pytest-dev/pytest-asyncio/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-asyncio/
+	https://pypi.org/project/pytest-asyncio/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pytest-asyncio/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
 
 LICENSE="Apache-2.0"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
 
 RDEPEND="
-	>=dev-python/pytest-5.4.0[${PYTHON_USEDEP}]"
+	>=dev-python/pytest-5.4.0[${PYTHON_USEDEP}]
+"
 BDEPEND="
 	dev-python/setuptools_scm[${PYTHON_USEDEP}]
 	test? (
 		dev-python/flaky[${PYTHON_USEDEP}]
 		>=dev-python/hypothesis-3.64[${PYTHON_USEDEP}]
-	)"
+	)
+"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/pytest-mock/pytest-mock-3.7.0.ebuild b/dev-python/pytest-mock/pytest-mock-3.7.0.ebuild
index 16b2afcb1975..6b89ed1c8c7c 100644
--- a/dev-python/pytest-mock/pytest-mock-3.7.0.ebuild
+++ b/dev-python/pytest-mock/pytest-mock-3.7.0.ebuild
@@ -5,10 +5,14 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="Thin-wrapper around the mock package for easier use with pytest"
-HOMEPAGE="https://github.com/pytest-dev/pytest-mock/"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-mock/
+	https://pypi.org/project/pytest-mock/
+"
 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
@@ -16,21 +20,24 @@ SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
 
 RDEPEND="
-	>=dev-python/pytest-6[${PYTHON_USEDEP}]"
+	>=dev-python/pytest-6[${PYTHON_USEDEP}]
+"
 BDEPEND="
 	dev-python/setuptools_scm[${PYTHON_USEDEP}]
 	test? (
 		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
-	)"
+	)
+"
 
 distutils_enable_tests pytest
 
 python_test() {
 	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
 	local -x PYTEST_PLUGINS=pytest_mock,pytest_asyncio.plugin
+	local EPYTEST_DESELECT=()
 
 	if has_version dev-python/mock; then
-		local EPYTEST_DESELECT=(
+		EPYTEST_DESELECT+=(
 			tests/test_pytest_mock.py::test_standalone_mock
 		)
 	fi
diff --git a/dev-python/python-betterproto/Manifest b/dev-python/python-betterproto/Manifest
new file mode 100644
index 000000000000..07be9d4d8816
--- /dev/null
+++ b/dev-python/python-betterproto/Manifest
@@ -0,0 +1 @@
+DIST python-betterproto-2.0.0_beta4.tar.gz 137744 BLAKE2B 55cde21cca516ae935d8ff99303e3dcf78d952c470eaac2f91b5fa1dc20069e0ad150a0b59518d450c897547a3b3025d9ad683294adca5be6d66f06ba8034615 SHA512 10fc514e7a6d1ab87dd44e00d75d8f48752fa1ece26ccc671eeac502164aee2b8e4a30ec908e4abbb4b1c6671c72fc982764d74ccd0ac0f099d3533dcde64352
diff --git a/dev-python/python-betterproto/metadata.xml b/dev-python/python-betterproto/metadata.xml
new file mode 100644
index 000000000000..f52a95675fe8
--- /dev/null
+++ b/dev-python/python-betterproto/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>antonin.riha@protonmail.com</email>
+  <name>Antonín Říha</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/danielgtaylor/python-betterproto/issues</bugs-to>
+ </upstream>
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild b/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild
new file mode 100644
index 000000000000..47b97da44a44
--- /dev/null
+++ b/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Better Protobuf / gRPC Support for Python"
+HOMEPAGE="https://github.com/danielgtaylor/python-betterproto"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/danielgtaylor/python-betterproto"
+else
+	MY_PV="${PV/_beta/b}"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	SRC_URI="https://github.com/danielgtaylor/${PN}/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/grpclib-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/black-19.3[${PYTHON_USEDEP}]
+		>=dev-python/isort-5.10.1[${PYTHON_USEDEP}]
+		>=dev-python/grpcio-tools-1.40.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.1.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.12.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'>=dev-python/sphinx_rtd_theme-0.5.0'
+
+python_test() {
+	"${EPYTHON}" -m tests.generate -v
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "protoc compilation support" dev-python/black
+	optfeature "protoc compilation support" dev-python/isort
+	optfeature "protoc compilation support" dev-python/grpcio-tools
+}
diff --git a/dev-python/python-betterproto/python-betterproto-9999.ebuild b/dev-python/python-betterproto/python-betterproto-9999.ebuild
new file mode 100644
index 000000000000..2c0aa6026633
--- /dev/null
+++ b/dev-python/python-betterproto/python-betterproto-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Better Protobuf / gRPC Support for Python"
+HOMEPAGE="https://github.com/danielgtaylor/python-betterproto"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/danielgtaylor/python-betterproto"
+else
+	MY_PV="${PV/_beta/b}"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	SRC_URI="https://github.com/danielgtaylor/${PN}/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~mips ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/grpclib-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/black-19.3[${PYTHON_USEDEP}]
+		>=dev-python/isort-5.10.1[${PYTHON_USEDEP}]
+		>=dev-python/grpcio-tools-1.40.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.1.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.12.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'>=dev-python/sphinx_rtd_theme-0.5.0'
+
+python_test() {
+	"${EPYTHON}" -m tests.generate -v
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "protoc compilation support" dev-python/black
+	optfeature "protoc compilation support" dev-python/isort
+	optfeature "protoc compilation support" dev-python/grpcio-tools
+}
diff --git a/dev-python/pytz/pytz-2022.1.ebuild b/dev-python/pytz/pytz-2022.1.ebuild
index a8fd6a2d23b6..8d04c834b422 100644
--- a/dev-python/pytz/pytz-2022.1.ebuild
+++ b/dev-python/pytz/pytz-2022.1.ebuild
@@ -22,11 +22,13 @@ KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv
 IUSE=""
 
 DEPEND="
-	|| ( >=sys-libs/timezone-data-2017a sys-libs/glibc[vanilla] )
+	|| (
+		>=sys-libs/timezone-data-2017a
+		sys-libs/glibc[vanilla]
+	)
 "
-RDEPEND="${DEPEND}"
-BDEPEND="
-	app-arch/unzip
+RDEPEND="
+	${DEPEND}
 "
 
 PATCHES=(
diff --git a/dev-python/pyyaml/Manifest b/dev-python/pyyaml/Manifest
index c11baf76eb9e..a415685ef288 100644
--- a/dev-python/pyyaml/Manifest
+++ b/dev-python/pyyaml/Manifest
@@ -1,2 +1 @@
-DIST pyyaml-5.4.1.gh.tar.gz 173319 BLAKE2B b81cdec32588a419840dd536a2d8addb41eec3e20897f6c464a00a5badb4d6eed9b34b4f95146695187e7d9bcf2d03b81e884290c6dc47927be6192dfdb21eab SHA512 691e54fd9ca01fdc0dcb7de03ddd1970614d92a716c2437032999f9001f90a2ebbcc195a49bfdbe54da0f7a63178c83b02b05b18b5b1024127013f004d1f5997
 DIST pyyaml-6.0.gh.tar.gz 119855 BLAKE2B 286678ac81f2e6c252d285d2f98dab98894787e3aa164a29a697986f56200c7b71b0a768edf6d50e61065efcd054078673270872162a4975409928d7dd67aacc SHA512 cbcacc3560a035e2082867e93a9733f8660ea4c7f60573d07642f33a5453dcdc88d67299c3bcb97c27b843202a45d40de7444eb5e815bd4955129c9fc8ae04ad
diff --git a/dev-python/pyyaml/files/pyyaml-5.1-cve-2017-18342.patch b/dev-python/pyyaml/files/pyyaml-5.1-cve-2017-18342.patch
deleted file mode 100644
index 28626ba9e974..000000000000
--- a/dev-python/pyyaml/files/pyyaml-5.1-cve-2017-18342.patch
+++ /dev/null
@@ -1,40 +0,0 @@
-diff --git a/lib/yaml/__init__.py b/lib/yaml/__init__.py
-index e7a419d..5f80761 100644
---- a/lib/yaml/__init__.py
-+++ b/lib/yaml/__init__.py
-@@ -106,6 +106,7 @@ def load(stream, Loader=None):
-     and produce the corresponding Python object.
-     """
-     if Loader is None:
-+        raise RuntimeError("Unsafe load() call disabled by Gentoo. See bug #659348")
-         load_warning('load')
-         Loader = FullLoader
- 
-@@ -121,6 +122,7 @@ def load_all(stream, Loader=None):
-     and produce corresponding Python objects.
-     """
-     if Loader is None:
-+        raise RuntimeError("Unsafe load() call disabled by Gentoo. See bug #659348")
-         load_warning('load_all')
-         Loader = FullLoader
- 
-diff --git a/lib3/yaml/__init__.py b/lib3/yaml/__init__.py
-index 5df0bb5..6952ba5 100644
---- a/lib3/yaml/__init__.py
-+++ b/lib3/yaml/__init__.py
-@@ -106,6 +106,7 @@ def load(stream, Loader=None):
-     and produce the corresponding Python object.
-     """
-     if Loader is None:
-+        raise RuntimeError("Unsafe load() call disabled by Gentoo. See bug #659348")
-         load_warning('load')
-         Loader = FullLoader
- 
-@@ -121,6 +122,7 @@ def load_all(stream, Loader=None):
-     and produce corresponding Python objects.
-     """
-     if Loader is None:
-+        raise RuntimeError("Unsafe load() call disabled by Gentoo. See bug #659348")
-         load_warning('load_all')
-         Loader = FullLoader
- 
diff --git a/dev-python/pyyaml/metadata.xml b/dev-python/pyyaml/metadata.xml
index 79197aa367ec..8d2fd663cb3f 100644
--- a/dev-python/pyyaml/metadata.xml
+++ b/dev-python/pyyaml/metadata.xml
@@ -8,8 +8,5 @@
  <upstream>
   <remote-id type="cpe">cpe:/a:pyyaml:pyyaml</remote-id>
  </upstream>
- <use>
-  <flag name="libyaml">enable support for C implementation using libyaml</flag>
- </use>
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pyyaml/pyyaml-5.4.1.ebuild b/dev-python/pyyaml/pyyaml-5.4.1.ebuild
deleted file mode 100644
index 672456567ca3..000000000000
--- a/dev-python/pyyaml/pyyaml-5.4.1.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-inherit distutils-r1
-
-DESCRIPTION="YAML parser and emitter for Python"
-HOMEPAGE="https://pyyaml.org/wiki/PyYAML
-	https://pypi.org/project/PyYAML/
-	https://github.com/yaml/pyyaml"
-SRC_URI="https://github.com/yaml/pyyaml/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
-IUSE="examples +libyaml"
-
-BDEPEND="
-	libyaml? (
-		$(python_gen_cond_dep '
-			dev-python/cython[${PYTHON_USEDEP}]
-		' 'python*')
-	)
-"
-RDEPEND="libyaml? ( dev-libs/libyaml:= )"
-DEPEND="${RDEPEND}"
-
-PATCHES=(
-	# bug #659348
-	"${FILESDIR}/pyyaml-5.1-cve-2017-18342.patch"
-)
-
-distutils_enable_tests setup.py
-
-python_configure_all() {
-	mydistutilsargs=( $(use_with libyaml) )
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}
-	fi
-}
diff --git a/dev-python/setuptools-git/setuptools-git-1.2-r3.ebuild b/dev-python/setuptools-git/setuptools-git-1.2-r3.ebuild
new file mode 100644
index 000000000000..354294597037
--- /dev/null
+++ b/dev-python/setuptools-git/setuptools-git-1.2-r3.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Setuptools revision control system plugin for Git"
+HOMEPAGE="
+	https://github.com/msabramo/setuptools-git/
+	https://pypi.org/project/setuptools-git/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-vcs/git
+"
+BDEPEND=${RDEPEND}
+
+distutils_enable_tests unittest
+
+src_test() {
+	git config --global user.name "test user" || die
+	git config --global user.email "test@email.com" || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/simplejson/simplejson-3.17.5-r1.ebuild b/dev-python/simplejson/simplejson-3.17.5-r1.ebuild
new file mode 100644
index 000000000000..a87875868312
--- /dev/null
+++ b/dev-python/simplejson/simplejson-3.17.5-r1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple, fast, extensible JSON encoder/decoder for Python"
+HOMEPAGE="
+	https://github.com/simplejson/simplejson/
+	https://pypi.org/project/simplejson/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( MIT AFL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+DOCS=( README.rst CHANGES.txt )
+
+distutils_enable_tests unittest
diff --git a/dev-python/tomli-w/tomli-w-1.0.0-r1.ebuild b/dev-python/tomli-w/tomli-w-1.0.0-r1.ebuild
index 78d8530cb5e3..8652fd459246 100644
--- a/dev-python/tomli-w/tomli-w-1.0.0-r1.ebuild
+++ b/dev-python/tomli-w/tomli-w-1.0.0-r1.ebuild
@@ -11,16 +11,23 @@ inherit distutils-r1
 DESCRIPTION="A lil' TOML writer"
 HOMEPAGE="
 	https://pypi.org/project/tomli-w/
-	https://github.com/hukkin/tomli-w/"
+	https://github.com/hukkin/tomli-w/
+"
 SRC_URI="
 	https://github.com/hukkin/tomli-w/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
+		-> ${P}.gh.tar.gz
+"
 
 LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 BDEPEND="
-	test? ( dev-python/tomli[${PYTHON_USEDEP}] )"
+	test? ( dev-python/tomli[${PYTHON_USEDEP}] )
+"
 
 distutils_enable_tests pytest
+
+python_test() {
+	epytest tests
+}
diff --git a/dev-python/ytmusicapi/Manifest b/dev-python/ytmusicapi/Manifest
index 623dc793ef1e..768552cf5336 100644
--- a/dev-python/ytmusicapi/Manifest
+++ b/dev-python/ytmusicapi/Manifest
@@ -1 +1,2 @@
 DIST ytmusicapi-0.21.0.tar.gz 48457 BLAKE2B ace8818c2a6859bb17d98fa608ac8cf7a806745741e634f639f4022527021089dc9b0b7bc48c0f999937a4599847a144afcb9f7e5585daa5d7b0ea1d5d12e399 SHA512 c34abbe8ba8d3b92ac162ffc9679ab21ce6c618a349aaeaa6c06b5597a3aed14e9b9f78a6b351ba545729da1c0bd57c2b7f999957bd8e56b0b453c04624bca4b
+DIST ytmusicapi-0.22.0.tar.gz 50474 BLAKE2B cd0d3a0c45a754560cb70b1766888d76a4b4c1b956f0112d761b1ee8663d7ed792c2befc71c5430464daacb19b7bcff48b7e2d079fd5de08db4583a110b4002a SHA512 3286e67e80c5b73e18b7d30040faca76d790b1b4ac45e635d721f5465379d525af89e6f6635353d3849c43d67c8b59a632423d3bee5a24a2e9c993cc009f2286
diff --git a/dev-python/ytmusicapi/ytmusicapi-0.22.0.ebuild b/dev-python/ytmusicapi/ytmusicapi-0.22.0.ebuild
new file mode 100644
index 000000000000..61a29587d588
--- /dev/null
+++ b/dev-python/ytmusicapi/ytmusicapi-0.22.0.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Unofficial API for YouTube Music"
+HOMEPAGE="https://ytmusicapi.readthedocs.io/"
+SRC_URI="https://github.com/sigma67/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+RDEPEND="dev-python/requests[${PYTHON_USEDEP}]"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme