Adding metadata

25 files changed, 681 insertions, 1 deletions

diff --git a/dev-python/discogs-client/Manifest b/dev-python/discogs-client/Manifest
index eb50cfca2ea4..3377ae453cb4 100644
--- a/dev-python/discogs-client/Manifest
+++ b/dev-python/discogs-client/Manifest
@@ -1 +1,2 @@
 DIST python3-discogs-client-2.5.tar.gz 36003 BLAKE2B e2350cc2eed986566be79ce3b529885113739da6b42f77dd405456e0552a68d51d1945f3ba569e05b9afc6304233a8b5ebe7c9f4f8105d62d9d159da7a0ff3ec SHA512 d6c90d6f0b472cdeda2a0d019386e3ab609ff46a82c3eefcd9b69162e1f94b34d58916dfb2364afb8cd9def0bf11e60cbed2e2c2dbb03206ea9a0faf141aa4ec
+DIST python3-discogs-client-2.6.tar.gz 36426 BLAKE2B 1d2ae337beb0aaf9cc7310b13909a0a9172c79813ccc0a581af5478cbf45b28d2654b963df2881ad858fcabd5e85594c9a41458283e9e2c9c90ed4d6ad57853c SHA512 2b2ed4a56337b184266832682f7fa4d8726cc414b89446b2a6e96131d82c01c60bd78ac3336bdf94a3077ea25a313fbd532ba574cad64ddc9ab0229d0d7e44b1
diff --git a/dev-python/discogs-client/discogs-client-2.6.ebuild b/dev-python/discogs-client/discogs-client-2.6.ebuild
new file mode 100644
index 000000000000..5ffb535ec3a6
--- /dev/null
+++ b/dev-python/discogs-client/discogs-client-2.6.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/joalla/discogs_client.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/p/python3-${PN}/python3-${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/python3-${P}"
+fi
+
+DESCRIPTION="Continuation of the official Python API client for Discogs"
+HOMEPAGE="
+	https://github.com/joalla/discogs_client/
+	https://pypi.org/project/python3-discogs-client/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+
+RDEPEND="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/oauthlib[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/dj-database-url/Manifest b/dev-python/dj-database-url/Manifest
index c509d39cdb43..7278dce3f1f7 100644
--- a/dev-python/dj-database-url/Manifest
+++ b/dev-python/dj-database-url/Manifest
@@ -1,2 +1,3 @@
 DIST dj-database-url-1.0.0.gh.tar.gz 11355 BLAKE2B 9ea50eb2646367333556133020a59f332cb69e05fb392f328558f77cb03ffa968cf62241f3823e28600799a1399ac1335b90477a26a4931b0df7b695b502e9be SHA512 35ca0c05910812e10bf63b061afb434ac7c562e3d994b6e452250fe4ec95983fe8353aec0df9c7638a990684e612863ddada5be48485a1db3120e110f6d0fa94
 DIST dj-database-url-1.1.0.gh.tar.gz 12095 BLAKE2B 61d32e20ce06451300474f88debb12e960ea6efce8706d6f61991eb204cc8be62f40f38272d9ef177dfa6f4f8a7502c38d17e4c2b01ccb2b256b1dc5329c8dd7 SHA512 4c2ee396daf1a8052a981f8b8df1ba02405020bd4ce3e36df0e34d8be745e5b71a5eb7fef8fc7bff05a8846e9aa1d29857d71e9ba7aa2b5ac0fcb9fabc9f0e60
+DIST dj-database-url-1.2.0.gh.tar.gz 12479 BLAKE2B cc3fed00cd7329a9ee8f3ced5830cf05b7046960ae6397c68b8e67e0609c0284dba01a1736447b45f219290405a0ab4720267feba276b453555e3b8ac2f0d88a SHA512 72b713a3a1ad4c70d857c5c72e671095ef1b7ec8ebd19902296ea49b63b9bf6d0084d03561c8fb47c533da431b44ee17651b45f3f699faceaed0ee6bfe7c921a
diff --git a/dev-python/dj-database-url/dj-database-url-1.2.0.ebuild b/dev-python/dj-database-url/dj-database-url-1.2.0.ebuild
new file mode 100644
index 000000000000..6ab7aa2f2437
--- /dev/null
+++ b/dev-python/dj-database-url/dj-database-url-1.2.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Use Database URLs in your Django Application"
+HOMEPAGE="
+	https://github.com/jazzband/dj-database-url/
+	https://pypi.org/project/dj-database-url/
+"
+SRC_URI="
+	https://github.com/jazzband/dj-database-url/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index c70dd861dd79..d946630036d3 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -2,3 +2,4 @@ DIST google-api-python-client-2.65.0.gh.tar.gz 36079173 BLAKE2B 32e60989dbc6e02e
 DIST google-api-python-client-2.66.0.gh.tar.gz 36477219 BLAKE2B 1da02e7747fd1421bdc62180103784af7b50ab0a672ac932f2fe28c22141a922d6f59d9c11ee74b78ff13583bdeee98d35f7b6d616af84fe99aa3d1a0de17342 SHA512 6b3cdf7279067080ff216d184f23c76c74c586e34b70afd936f1d10671fc0c7e7a8ba446a1ca5a9003bab2e3855e939376610ff4e45811fd6ead5e4942f62247
 DIST google-api-python-client-2.68.0.gh.tar.gz 37053945 BLAKE2B 7a73b80737b73198531207d203c2010969a9dbdd5012071944ec86bd6c2c63eb0a86bf2941a4c37544629aeae32b367cc8d9209300c63e8d1be39f32bef1d91f SHA512 9b70ad6f05d28198ee82984e263e770c995143770123a8aaeb605aad880464e951b8849bbed8c7cb511bd7beebed1df965fdd53b2e6a161905a0a2e481d5b68a
 DIST google-api-python-client-2.69.0.gh.tar.gz 37357078 BLAKE2B 1f8c421823a1ef5483a137d72f705e35a7c43426f2a2d7d2fba97ce64cf07fb10892bd6553bcd9331873a2ba7a9b51364f80781e8b811fe8f14208d1447c1d32 SHA512 2b6ead1e0133bed9aa25a42b70da49a11c867493c6ae9f3ded5c2964cd2fa4132eed7ef7670d43f616c3dae7bb0c4ad8e17986758ea76d81f35227edf20208b3
+DIST google-api-python-client-2.70.0.gh.tar.gz 37420341 BLAKE2B 8bc148c2cfeb1be59d3db8494a8701f6fc06949c57d7cc930aba44ee9ab3cc7f4450ec988c37ef8ccc0cb990bbc1fe75415d6f6b94ad00121e6e458698b5ff2b SHA512 5c1b8b0dbf545da17d9d5f3fc6ddd3c966d72b1034bb37e3acc5199dd39d40421b6608d6622ea539864022d0e19bc4a3123e9d666d2687a60fc7928201967ff1
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.70.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.70.0.ebuild
new file mode 100644
index 000000000000..63e5333c4693
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.70.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="
+	https://github.com/googleapis/google-api-python-client/
+	https://pypi.org/project/google-api-python-client/
+"
+SRC_URI="
+	https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-core-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/google-auth-oauthlib/Manifest b/dev-python/google-auth-oauthlib/Manifest
index a45ccefff02a..41f82b85b277 100644
--- a/dev-python/google-auth-oauthlib/Manifest
+++ b/dev-python/google-auth-oauthlib/Manifest
@@ -1 +1,2 @@
 DIST google-auth-library-python-oauthlib-0.7.1.gh.tar.gz 70325 BLAKE2B 969b6de0b873ab9532b46549e82bef14c71777f67d4c8813ab7d94cb66239469e3647f683f074b0f495d7db6578e87c57e4e96e8920891d6912e5b807644c559 SHA512 e35d5090d83015ca4c7a5f7166ad4e7ed1c845845239bfe1fc56df6a9ce925afaa47db435c6eac5a66364e2a4c866d1e8ae49dcf34066e90b4f8d6dcdb670bfb
+DIST google-auth-library-python-oauthlib-0.8.0.gh.tar.gz 71774 BLAKE2B 100aa01586f5df18453713610f3ed954a196e3d0c8d4dc15b8a67335951cbc2eaa15e3fa4bf7c7ba161418550bb7cfc68630fca0efe697a9c65ccbd7e0ce05d9 SHA512 3090d9b3ad25df6e8151e49a0cd96e7226aac2cecbbf289ccbc8cf4704ec86d882c11546b26f3a2ba9b047c19408f0cb939b9caf489aa935f49f8990ab7bfa55
diff --git a/dev-python/google-auth-oauthlib/google-auth-oauthlib-0.8.0.ebuild b/dev-python/google-auth-oauthlib/google-auth-oauthlib-0.8.0.ebuild
new file mode 100644
index 000000000000..be53ce5c8745
--- /dev/null
+++ b/dev-python/google-auth-oauthlib/google-auth-oauthlib-0.8.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=google-auth-library-python-oauthlib-${PV}
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python-oauthlib/
+	https://pypi.org/project/google-auth-oauthlib/
+"
+SRC_URI="
+	https://github.com/googleapis/google-auth-library-python-oauthlib/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/click-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-2.13.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-oauthlib-0.7.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/gst-python/gst-python-1.20.4.ebuild b/dev-python/gst-python/gst-python-1.20.4.ebuild
index 94d1b3070c2a..c729aaecc6c1 100644
--- a/dev-python/gst-python/gst-python-1.20.4.ebuild
+++ b/dev-python/gst-python/gst-python-1.20.4.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"
 
 LICENSE="LGPL-2+"
 SLOT="1.0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+KEYWORDS="~alpha ~amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="${PYTHON_DEPS}
diff --git a/dev-python/ipdb/Manifest b/dev-python/ipdb/Manifest
index 69f64b611215..987bd05d5ca3 100644
--- a/dev-python/ipdb/Manifest
+++ b/dev-python/ipdb/Manifest
@@ -1 +1,2 @@
+DIST ipdb-0.13.11.tar.gz 16770 BLAKE2B 849bb91f9fd2d0443f7696aee5e2b1de87a284b410189a471be91175e792132e816abcace865b788454d59ddbf5bc443c98e6308d0453b7a7a81a580c3afd24e SHA512 c44e012db71aa543742f16bd737e1e18db3f060b65c8fa0eaa6ce7567f99f44b5aa09bfb44457c6e4d6fb1fac8d822ece580bc4036adbd612f4d50a82f0eba21
 DIST ipdb-0.13.9.tar.gz 16820 BLAKE2B d028fff2c4273fd4a57c3338093f0065868856b4f7b2b95aa0db3c2b1e7c5906fc17b5b55b79b3a3809465214bd91ac1891cefc1604ed866edaa2811380175f6 SHA512 da0ac6d8a7451e90cf433ab2a0d4e43fff76be03082da5cf31b83fdc56174fde7f0256009ad9a407d805c0bf12da5fa2f081e1aa0e0ce73ca648262acd385671
diff --git a/dev-python/ipdb/ipdb-0.13.11.ebuild b/dev-python/ipdb/ipdb-0.13.11.ebuild
new file mode 100644
index 000000000000..a09fbe23f8a1
--- /dev/null
+++ b/dev-python/ipdb/ipdb-0.13.11.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="IPython-enabled pdb"
+HOMEPAGE="
+	https://github.com/gotcha/ipdb/
+	https://pypi.org/project/ipdb/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/ipython-7.17[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/tomli[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( AUTHORS HISTORY.txt README.rst )
+
+distutils_enable_tests unittest
+
+pkg_postinst() {
+	optfeature "pyproject.toml support" dev-python/tomli
+}
diff --git a/dev-python/isort/Manifest b/dev-python/isort/Manifest
index fd4260d7faa5..5aac182706cb 100644
--- a/dev-python/isort/Manifest
+++ b/dev-python/isort/Manifest
@@ -1 +1,2 @@
 DIST isort-5.10.1.gh.tar.gz 728462 BLAKE2B 5b892b9849293e8730e6d89592bace62009a8589d185b4d3a5bafded605ccd46fd0f2986fbad5cf1d72321d030e3193a111ab7e6114c6b4a7a67696f546b3a14 SHA512 545c1844bacc1d2d9e87e60b03b30a846ee1ebbfe2a229c3e018a2e1cc6e9a04a3691f1b2e7ec8575806f2341bc1af15eb64904b4eabd786d6b9b289cea5ce2a
+DIST isort-5.11.1.gh.tar.gz 731273 BLAKE2B 9044579ae53df64b78762384eba9b329017c12a1e8208382b56fa76a0d54443379b17463ff547f014d18b0bc06a9d1382b4a7e3c7a44c6a6ada1a8ed836460eb SHA512 0d891bb0b546d01a4bb5ca4f8f62683c8864b396e2c15549b5f40da4c3b630ae9100026f95c7be78aae2e3238e9d173fdb08ea9eca519631f7dea64e0643d4d1
diff --git a/dev-python/isort/isort-5.11.1.ebuild b/dev-python/isort/isort-5.11.1.ebuild
new file mode 100644
index 000000000000..e210d455a713
--- /dev/null
+++ b/dev-python/isort/isort-5.11.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A python utility/library to sort imports"
+HOMEPAGE="
+	https://github.com/PyCQA/isort/
+	https://pypi.org/project/isort/
+"
+SRC_URI="
+	https://github.com/PyCQA/isort/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/tomli[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/black[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pylama[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unbundle tomli
+	sed -i -e 's:from ._vendored ::' isort/settings.py || die
+	rm -r isort/_vendored || die
+	# leftover toml import used to determine .toml support
+	sed -i -e 's:import toml:toml = True:' tests/unit/test_isort.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Install necessary plugins
+	local p
+	for p in example*/; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local EPYTEST_IGNORE=(
+		# Excluded from upstream's test script
+		tests/unit/test_deprecated_finders.py
+	)
+	epytest tests/unit
+}
diff --git a/dev-python/libtmux/Manifest b/dev-python/libtmux/Manifest
index 73d777533a01..1337b3e0bd00 100644
--- a/dev-python/libtmux/Manifest
+++ b/dev-python/libtmux/Manifest
@@ -1,2 +1,3 @@
 DIST libtmux-0.15.10.gh.tar.gz 240378 BLAKE2B 81841a25b01bb26d2c612a14cd4518c48b12162d4aafa280fe0d6de269d149bddaffe72f4ce2c735e41b00cd2bfec19773d7cd3b9fd927c892f11f0cdf8e8a88 SHA512 8ee870c94bd3e3a9fffc19854f978d4faad747ea395e53c3576adc9cc2dcdd3cbdedeeb589a2dc11b0ac836931ffbdcea06a4a850b2ead163235dda2334defb5
 DIST libtmux-0.15.9.gh.tar.gz 239611 BLAKE2B 7a171c827fde0ddf3fa0191c00d4e22e5027d925781f7231497c09a038f16d3408ba894d4f8d71470a0d8dbb8f1fc387971d3c8ec94d9f03a3f0af0e2ac0c7c7 SHA512 e7599dece70188cd210de7a1e554d86ba12b8479757dd03903cf3e0608e8e9cf3d181e4c0afc7432d6977dece931707120399690932099ed7d07d847ac76655c
+DIST libtmux-0.16.1.gh.tar.gz 246412 BLAKE2B ec95f3aab5b48b9d6a22698c9480e969aba2136225f4728ccbf57deabed105bc6f098e49d3072bf2e5edf8a436f9e36e04b39b8d8e87d206c0ed2703d63ceed2 SHA512 0eb739679a80def01b3810bfe93971eb6c272b4b694ce5e4b846bde8721d2d919f5f8a5e8b6332279a59abfea4bd1e0a510d2ba2ee2d35ff71271920e40cec60
diff --git a/dev-python/libtmux/libtmux-0.16.1.ebuild b/dev-python/libtmux/libtmux-0.16.1.ebuild
new file mode 100644
index 000000000000..52b1d12894ad
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.16.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python API for tmux"
+HOMEPAGE="
+	https://libtmux.git-pull.com/
+	https://github.com/tmux-python/libtmux/
+	https://pypi.org/project/libtmux/
+"
+SRC_URI="
+	https://github.com/tmux-python/libtmux/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twine[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	libtmux/pane.py::libtmux.pane.Pane.send_keys
+)
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+	rm requirements/doc.txt || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	sed -e '/addopts/s:--doctest-docutils-modules::' \
+		-e '/README\.md/d' \
+		-i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/psycopg/Manifest b/dev-python/psycopg/Manifest
index 51ab189f7c2c..f42169d47844 100644
--- a/dev-python/psycopg/Manifest
+++ b/dev-python/psycopg/Manifest
@@ -1,2 +1,3 @@
 DIST psycopg-3.1.4.gh.tar.gz 469317 BLAKE2B a6df49a5adefbeb310602473e950ef77f0c613d8a33d41ee37dbfec544dfd014dba8dae5f78ce2bc89f2d9531ccbdd6ea07665ca638f29a4a7d0d1006bc0d778 SHA512 2bf49d6eb7e20c6f22adf47cef6dce691f38f4b310f2fbf3986f3ad14c7d390d53b9edeb3365bbf096941cc2d2affe2ddd542fe93ef37c41109742c9f9af4ba7
+DIST psycopg-3.1.5.gh.tar.gz 478528 BLAKE2B f0e6d1970b81875481bf0939d750d585f9ce4be1ccf838d1884a54d366614ec1ca76756b455d28b559ef4f49696eda68fa3b42f8c0cc18d9ce9fd1ce21029830 SHA512 006a9a6b7d34ed6f0411c33001334b9e9d29c8d1fe5e9e3b940d5664cc5c06ce10bc278ee1906a96073843ca2f8effaada8789aa390de97e543e19cc452546d1
 DIST psycopg2-2.9.4.tar.gz 384017 BLAKE2B 4bc0afcc890c8a257c1ccd5c6e4e5301857a80f8b1428aa46c1473c9e18f5d2914a2e592c13336b06106217bb334d9b0321835bdd123f1627cbeb29dedf97bf7 SHA512 259088e42e0ab0d8a1a0ccf04f5e560f32c6179b4a0a0059e91bcf269baa8f4b0f1f949c332c640a2438c927a29b2c144078a861f8e18ba9c764da7c93c73b8d
diff --git a/dev-python/psycopg/psycopg-3.1.5.ebuild b/dev-python/psycopg/psycopg-3.1.5.ebuild
new file mode 100644
index 000000000000..51949d3195b0
--- /dev/null
+++ b/dev-python/psycopg/psycopg-3.1.5.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="PostgreSQL database adapter for Python"
+HOMEPAGE="
+	https://www.psycopg.org/psycopg3/
+	https://github.com/psycopg/psycopg/
+	https://pypi.org/project/psycopg/
+"
+SRC_URI="
+	https://github.com/psycopg/psycopg/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${P}/psycopg
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+
+DEPEND="
+	>=dev-db/postgresql-8.1:*
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/backports-zoneinfo-0.2.0[${PYTHON_USEDEP}]
+	' 3.8)
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-db/postgresql-8.1[server]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/dnspython[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# tests for the psycopg_pool package
+	tests/pool
+	# some broken mypy magic
+	tests/test_module.py::test_version
+	tests/test_module.py::test_version_c
+	tests/test_typing.py
+	tests/crdb/test_typing.py
+	# TODO, relying on undefined ordering in Python?
+	tests/test_dns_srv.py::test_srv
+)
+
+src_test() {
+	# tests are lurking in top-level directory
+	cd .. || die
+
+	initdb -D "${T}"/pgsql || die
+	# TODO: random port
+	pg_ctl -w -D "${T}"/pgsql start \
+		-o "-h '' -k '${T}'" || die
+	createdb -h "${T}" test || die
+
+	local -x PSYCOPG_TEST_DSN="host=${T} dbname=test"
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${T}"/pgsql stop || die
+}
diff --git a/dev-python/pydevd/Manifest b/dev-python/pydevd/Manifest
index 479c822fd011..ca72674849f4 100644
--- a/dev-python/pydevd/Manifest
+++ b/dev-python/pydevd/Manifest
@@ -1 +1,2 @@
 DIST pydev_debugger_2_9_1.tar.gz 3974089 BLAKE2B 73e0cea547964e313120af2d27ce0166b5afc2d613428ce96cbc58786dddae99507058a217c0eac7cb071bead8d52b2e9bda8e0c88aff31566a979edc420278b SHA512 67f4d31fa59512ec6738a777537a6f856d312f3a81d7bee497ddc50bf02dcab8c04c64c7e5181e48afea01f9de4300a1cafeb3745cea841d7bb7c26b15ced40b
+DIST pydevd-2.9.3.gh.tar.gz 3979334 BLAKE2B f26af62d12d89317ffc9e670c78bac2c977195897dfb858861f6d12a331714c084d11dc030efe82777d51f9cd429b54d78c7126f366fdda15ebd315121b55dcd SHA512 c8d30658e84a1edd3e4d0cd35563f50231b6a2df247fecab5e90236c4c80da10e7fe5f182b1791f86063d3228d115d32d388087605e58842505ab19aabe75444
diff --git a/dev-python/pydevd/pydevd-2.9.3.ebuild b/dev-python/pydevd/pydevd-2.9.3.ebuild
new file mode 100644
index 000000000000..e45ab3c8b7f7
--- /dev/null
+++ b/dev-python/pydevd/pydevd-2.9.3.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit distutils-r1 toolchain-funcs
+
+MY_P="pydev_debugger_${PV//./_}"
+
+DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
+HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
+SRC_URI="
+	https://github.com/fabioz/PyDev.Debugger/archive/${MY_P}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/PyDev.Debugger-${MY_P}"
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# After removing and recompiling the prebuilt lib the tests fail?
+# For some reason the test suite is executing a slightly different gdb command
+# then before, which is lacking the file name of the lib that was pre built:
+# gdb: No symbol table is loaded. Use the "file" command
+# This also happens outside of portage so it is not related to any *FLAGS
+RESTRICT="test"
+
+BDEPEND="
+	test? (
+		dev-python/untangle[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+# Block against the version of debugpy that still bundles pydevd
+RDEPEND="
+	!<dev-python/debugpy-1.4.2
+	sys-devel/gdb
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# Drop -O3 and -flto compiler args
+	sed -i \
+		-e 's/extra_link_args = extra_compile_args\[\:\]/pass/g' \
+		-e '/extra_compile_args/d' \
+		setup.py || die
+
+	# Clean up some prebuilt files
+	rm -r third_party || die
+	cd pydevd_attach_to_process || die
+
+	# Remove these Windows files
+	rm attach_{amd64,x86}.dll || die
+	rm inject_dll_{amd64,x86}.exe || die
+	rm run_code_on_dllmain_{amd64,x86}.dll || die
+	rm -r windows winappdbg || die
+
+	# Remove these MacOS files
+	rm attach_x86_64.dylib || die
+
+	# Remove these prebuilt linux files
+	rm attach_linux_{amd64,x86}.so || die
+
+	cd linux_and_mac || die
+	rm compile_mac.sh || die
+}
+
+src_compile() {
+	pushd pydevd_attach_to_process/linux_and_mac || die
+	# recompile removed file (extracted from compile_linux.sh)
+	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CPPFLAGS} -o "attach_linux_${ARCH}.so" \
+		${LDFLAGS} -nostartfiles attach.cpp -ldl || die
+	mv "attach_linux_${ARCH}.so" ../ || die
+	popd || die
+
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# Remove this duplicate that is installed directly to /usr/
+	# These files are also correctly installed to the python site-packages dir
+	rm -r "${ED}/usr/pydevd_attach_to_process" || die
+}
diff --git a/dev-python/pyproj/Manifest b/dev-python/pyproj/Manifest
index 97a3eb1094e1..851eb67e54c3 100644
--- a/dev-python/pyproj/Manifest
+++ b/dev-python/pyproj/Manifest
@@ -1 +1,2 @@
 DIST pyproj-3.4.0.gh.tar.gz 231365 BLAKE2B a62e02a33424583ffec1e1de603a0162ea187b4eb093be51b957fb720b3625c7e4b65162f1272fb4a057edfd92f8146d74c17f1ad68a3beb0ae199df8641e03b SHA512 d0e9425ea5a10ce1620c2a2b3279be786741e75ad698a2430e38237acb73e2cd7dbd16dbb4cf952f52c38810526f4528c08f9bb0795a34fdab2f39686e6914c9
+DIST pyproj-3.4.1.gh.tar.gz 232371 BLAKE2B 70b0ccbf898c6b52b2a24db811f8d49df89a67afda5a4d2d486aa30e21fdd6438842346a876138a3018edd5308c6c6f49c1473c345507be3af831a3a734ae5a2 SHA512 e1588906c42a6cbf832ea2d2a0cf271271b1b3559fccfd7798d823f80653184a660bf14ab6f741f7d0a5b49361e2519893eb155746761d4a02248c1021660e60
diff --git a/dev-python/pyproj/pyproj-3.4.1.ebuild b/dev-python/pyproj/pyproj-3.4.1.ebuild
new file mode 100644
index 000000000000..4fd9050c2ee1
--- /dev/null
+++ b/dev-python/pyproj/pyproj-3.4.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to the PROJ library"
+HOMEPAGE="
+	https://github.com/pyproj4/pyproj/
+	https://pypi.org/project/pyproj/
+"
+SRC_URI="
+	https://github.com/pyproj4/pyproj/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+
+RDEPEND="
+	>=sci-libs/proj-8.2.0:=
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/furo
+distutils_enable_tests pytest
+
+src_configure() {
+	# Avoid greedily trying -L/usr/lib, etc
+	# https://github.com/pyproj4/pyproj/blob/main/setup.py#L76
+	export PROJ_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
+	export PROJ_INCDIR="${ESYSROOT}/usr/include"
+}
+
+python_test() {
+	rm -rf pyproj || die
+	epytest -m "not network" test
+}
diff --git a/dev-python/pytoolconfig/Manifest b/dev-python/pytoolconfig/Manifest
index e9a86dcc77cf..c383ac34138e 100644
--- a/dev-python/pytoolconfig/Manifest
+++ b/dev-python/pytoolconfig/Manifest
@@ -1 +1,2 @@
 DIST pytoolconfig-1.2.2.tar.gz 16195 BLAKE2B 02434bf9bc815fe1beeb13496427d6735fd0eebca66371eaa1a8df5d318879584b9e27d7b2272535e41af91b46544264d570b2727e524e6ba52c4e4be475ad84 SHA512 5bcbf7f2fc7941e128b3e717ff213e1e43be417ca3b906fa75a40f822815a4ea79b55cbb3e297caa3abf9032fedda1a791165491f52d4bbce5f4d29eea3c3599
+DIST pytoolconfig-1.2.4.tar.gz 15910 BLAKE2B 53ab143179dc59d3d1bcf6debb16280d60b3d877514dff78389c413e9d73cb56fb6feaa76abffa53afba44a57eccb387b19b5ab4d621fff3dd49836d42e5ba43 SHA512 bcf78054419ea4f783f79716724032f3f34072b10543dd7939418086095f37cf1a7c1df2c89dfca20096e99768ce8d5f74ef3bb7dd4919735bd85e332342e106
diff --git a/dev-python/pytoolconfig/pytoolconfig-1.2.4.ebuild b/dev-python/pytoolconfig/pytoolconfig-1.2.4.ebuild
new file mode 100644
index 000000000000..e1edfdb4a037
--- /dev/null
+++ b/dev-python/pytoolconfig/pytoolconfig-1.2.4.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python tool configuration"
+HOMEPAGE="
+	https://pypi.org/project/pytoolconfig/
+	https://github.com/bageljrkhanofemus/pytoolconfig/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{8..10} )
+"
+BDEPEND="
+	>=dev-python/pdm-pep517-1.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/sphinx-4.5.0[${PYTHON_USEDEP}]
+		>=dev-python/tabulate-0.8.9[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index c0099da9912a..b548d32d245d 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,4 @@
 DIST tox-3.27.1.gh.tar.gz 309006 BLAKE2B fa8aaa9cd5b03e54c166bb6b748290420b91498b26d2d124d9f88a64806b9ac0578c1886845b25aa024907f6a782c45609fa6c7657d9e1f538b59c2d9f0f4e14 SHA512 5f568bc6c53f871aae91928681dd6f2419b876a8e6ca925e65abae845b548ee3d00513741882875bbbacb78bf64935228d98213f940d3da8c3f788b73f177b79
 DIST tox-4.0.5.gh.tar.gz 277741 BLAKE2B 19250ec4365a38a149c59de99ebd3b819cc4aba7721c076cc6700a17eb56b7c4b61d5c3b11046dc6857d082f1c04e98c6a78b8c768551468bca5a6810c4b7749 SHA512 7bc6f5479df577b66a7e43b61520995d1d31d056baf5b6297d9dc6acb19da58ed1f7d0db13930ab114417f0ad752799ac512765af18041ec800022b18676db20
 DIST tox-4.0.8.gh.tar.gz 278697 BLAKE2B ef87b02d95447d52135aa745fd224f7ec1f76f5e99e37ee8dc4990a1577a5f4d2103f21d26e4b32946c20ccbc44aa7e3954e167dcf7599f548466574121ff7dd SHA512 bac13d4a74d76405c658a05eb50df258ae8f5ae8b821b36bc41d473562a0930667bf3b4eb96d873e92f89811af2a8dfd19009622efca8836f163aed53476b46a
+DIST tox-4.0.9.gh.tar.gz 279196 BLAKE2B 4e0c869a4bf28865eae50a6457875bc29012547069cdfe666fc1a8a12007fb5cff1501bf0f4c2791d38680328f2222bbbb37342bbfc6e7fc3ee4587ce6e70035 SHA512 341894cf879d48e4fbdd11271dfdff59ae5b719b02d8be46fa712b68528ad69ffe7df63639537b95e3f6dcf747dbf99b2d8daa18a87513d9c141e28cc59d6363
diff --git a/dev-python/tox/tox-4.0.9.ebuild b/dev-python/tox/tox-4.0.9.ebuild
new file mode 100644
index 000000000000..620c2a4536f4
--- /dev/null
+++ b/dev-python/tox/tox-4.0.9.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.2.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+	if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/util/test_spinner.py
+		)
+	fi
+
+	epytest
+}