Updating liguros repo

7 files changed, 155 insertions, 7 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index f0656fd2bde3..51d0df48bd0b 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,3 +4,4 @@ DIST boto3-1.15.10.tar.gz 336021 BLAKE2B 71a8bcfd115c0066931e616d1d3678d51ba0946
 DIST boto3-1.15.18.tar.gz 336927 BLAKE2B 0ddc7fbd0fffcbeafeee7b9aa0f699087369f315551e243175793c82d95c97dbbe8997d5fc280e9fed18612d1058d858a7b34b0b1b4ac7905774009beb62c0a6 SHA512 2dc88c27bafe7ff2f2b00be94c37e7cabc94f09ca0ccb898a5d29cd8087bb1945d226ed5d87e955250775038fc039740e68d93662b465e99a16cfebfd2fa2944
 DIST boto3-1.16.1.tar.gz 337145 BLAKE2B 553b20514d268be967b80cab9694085d8cd3456277d459cf0f92943274eac8cf8fc23b4ed9dc92a9c04f02e3f1f1fd483f71111c9e0cfa22e989098ca5fa762d SHA512 6f8d1848fb89e841054cba6c295b7ccce7fab37ba5312a0b5f87588c8cf9d61124b3988c4565a4b055976ffafdb8ed7fc9268a21ac3160e80ffdf739c8e1609a
 DIST boto3-1.16.2.tar.gz 337212 BLAKE2B ebde42cf6b6fec3f00df6cf7e9f8769a2a8295aba0960708d4fb97b0cea4ed68ca5ea698b42485c94dacf0dfbca2fefe12ed878d027eeccee53fdf844afab48e SHA512 305dbbbf5beba3503ae3c4f6ad02ecd7cd55057d19c5c8081dbbb00a620e4a4a1dc55df111e5078ed8172d706f9f868675cd110024d0a8303fba7bf1195cd9cc
+DIST boto3-1.16.3.tar.gz 337217 BLAKE2B f088b596561156823a8caa5b0053688bdac8bdf3f2a54ff0bfd3724fe563493a681c4a16c5a85f990d3edad6c31cb1f0ec7a1fd01deb325a30a1623cc0f1439e SHA512 7bb5ac693a6a0a938c4c83e94cb82dc02fed5edd4709f28961f7123103b38ffb24975c7861d50ebe773fb318f7225442911c8c55b7a621301f270a25f796f104
diff --git a/dev-python/boto3/boto3-1.16.3.ebuild b/dev-python/boto3/boto3-1.16.3.ebuild
new file mode 100644
index 000000000000..12584b2fba42
--- /dev/null
+++ b/dev-python/boto3/boto3-1.16.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index db47d9439541..0810416ed28a 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,3 +4,4 @@ DIST botocore-1.18.10.tar.gz 6899351 BLAKE2B 4de11277fd8df8436818cd50d946e7e5319
 DIST botocore-1.18.18.tar.gz 6942407 BLAKE2B e58183d5aa79a210d82c1dc21806c9c86f993498055c52742e4c1ef2f697ae1faf120b9edf8efeb229dad3f3230f0847b534ac071a1e4d32136eacc3c18c7c84 SHA512 a92a20c86390905f22c10e3ba649008b7c9ccab147b6b3aecc89f26dc891aaf38a974fd8ba1f792a38ac89a98dba64a949741445abf7db133f60189d1e8da31e
 DIST botocore-1.19.1.tar.gz 6944577 BLAKE2B ade1c8c3318971f25220d2c5bf82879d9a1cf30ed49066d4d13bf04351dc2fa7a910fcba6dba248d33bcf3e244c8b99c7df66cc3edc6f65b38b8ff2412a68e34 SHA512 e0fd4e8c4fca53c7e034e840ffd9f362c3a41a898188980a382d528334204d13a9dcd597b4a1eb8ce792ffb31e31213167b8e6e952353c339612755b88c1c635
 DIST botocore-1.19.2.tar.gz 6949309 BLAKE2B 0d13155e32bc44578df8b372ccdceddc13d5012696245f441e0b935c0a58c8f78e38c9aabe03e242159cbc45d8034fe1bfaffc545ce5d2d95aa2a765c778e36a SHA512 88486e813e476b789b7c0b9fa74bc95ac2a67818439f2ff2564fe30c988ec0fb9be8a2f9c2ebce9418d1eeda4c88c94d6d3ec37cec185d48a388577fc2458c88
+DIST botocore-1.19.3.tar.gz 6950797 BLAKE2B f8f97e699e9b31cf56d8a35ff75831e9c545abe1980e4e4af3453c83be6ff6efa51fb9368e984fc871bd1123df283940d42c7adced672bdf21d7a13c3bc6f9b1 SHA512 8eaf72543c5a5e2e4a08cc6998c71971ee9e70d476e384b66472ec2f16d204ae70056925bba1e1476fd55a272750e4907a617e38a96e1b4324e172081a9c1b54
diff --git a/dev-python/botocore/botocore-1.19.3.ebuild b/dev-python/botocore/botocore-1.19.3.ebuild
new file mode 100644
index 000000000000..ef5dd742ea0c
--- /dev/null
+++ b/dev-python/botocore/botocore-1.19.3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/importlib_resources/Manifest b/dev-python/importlib_resources/Manifest
index b15eabb3a070..9dfbc236e496 100644
--- a/dev-python/importlib_resources/Manifest
+++ b/dev-python/importlib_resources/Manifest
@@ -1,2 +1,3 @@
 DIST importlib_resources-1.5.0.tar.gz 23660 BLAKE2B aed7a2d730f945505083812355a63d3a88e07b057cf46394f3475135143e535e33dc3ebded24d233797020c805dc35decf5c5ce53758798b093f03f2951daa87 SHA512 34d14c1ff3121cc6f9ef1d3d4417831e3476e9facfcc9b35152c28a59a2c75d7723f171f4b48852f79ec46cbf54b066580745744bc54d349e2bfe12a353a9aed
 DIST importlib_resources-3.0.0.tar.gz 26725 BLAKE2B e2517b0d1e576ce949ac05230892acbad59c09fa4b84401b3c957e83f40b50d12bc02360b135fe949d12c43f8f557006824e4e4a3e9ff2ce879c03362569a00c SHA512 cd29e268cacef3729024af6cae8394ce5aa8c1d8a28397fd8f009c7eaa908ed3775508bde86c26b0d233c25261b8509abb1e16c378c7c8a9bb0906224f3fdd54
+DIST importlib_resources-3.1.0.tar.gz 27630 BLAKE2B fbfa4464580c7ec8a880161a3e28c9fc783676ddbc5470e419cdabe7fc7c037a59fb6a29dcc9cc523ad47b2624e0df4738cfe6e7bbf09704f4512c96eb34474f SHA512 0f659afc3f65d7245c137fe447606e138391bddbdcc1cfacafe94bcb557245d8f576d4d489f209047a0cbc2a60e79e37ee9419062c7472f12e0aee0acec7056a
diff --git a/dev-python/importlib_resources/importlib_resources-3.1.0.ebuild b/dev-python/importlib_resources/importlib_resources-3.1.0.ebuild
new file mode 100644
index 000000000000..0b790a02dd70
--- /dev/null
+++ b/dev-python/importlib_resources/importlib_resources-3.1.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# This is a backport of Python 3.9's importlib.resources
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Read resources from Python packages"
+HOMEPAGE="https://github.com/python/importlib_resources"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/zipp[${PYTHON_USEDEP}]
+	' pypy3 python3_{6,7})
+"
+BDEPEND="
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs dev-python/rst-linker dev-python/jaraco-packaging
diff --git a/dev-python/importlib_resources/metadata.xml b/dev-python/importlib_resources/metadata.xml
index a338efdac6af..e17f228d9bbf 100644
--- a/dev-python/importlib_resources/metadata.xml
+++ b/dev-python/importlib_resources/metadata.xml
@@ -10,16 +10,16 @@
 		<name>Python</name>
 	</maintainer>
 	<longdescription>
-		Backport of Python 3.7’s standard library importlib.resources
-		module for Python 2.7, and 3.4 through 3.6. Users of Python
-		3.7 and beyond are encouraged to use the standard library
-		module, and in fact for these versions, importlib_resources
-		just shadows that module.
+		Backport of Python standard library importlib.resources module
+		for Python 2.7, and 3.4 through 3.8. Users of Python 3.9 and beyond
+		should use the standard library module, since for these versions,
+		importlib_resources just delegates to that module.
 	</longdescription>
 	<upstream>
-		<remote-id type="gitlab">python-devs/importlib_resources</remote-id>
+		<remote-id type="github">python/importlib_resources</remote-id>
 		<remote-id type="pypi">importlib_resources</remote-id>
-		<bugs-to>https://gitlab.com/python-devs/importlib_resources/issues</bugs-to>
+		<bugs-to>https://github.com/python/importlib_resources/issues</bugs-to>
+		<doc>https://importlib-resources.readthedocs.io/</doc>
 	</upstream>
 	<origin>gentoo-staging</origin>
 </pkgmetadata>