Adding metadata

39 files changed, 873 insertions, 71 deletions

diff --git a/dev-python/autocommand/autocommand-2.2.1_p20211118.ebuild b/dev-python/autocommand/autocommand-2.2.1_p20211118.ebuild
index c17753688b76..f59038d43f94 100644
--- a/dev-python/autocommand/autocommand-2.2.1_p20211118.ebuild
+++ b/dev-python/autocommand/autocommand-2.2.1_p20211118.ebuild
@@ -5,6 +5,7 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 COMMIT="031c9750c74e3313b954b09e3027aaa6595649bb"
diff --git a/dev-python/babelfont/babelfont-3.0.0_alpha8.ebuild b/dev-python/babelfont/babelfont-3.0.0_alpha8.ebuild
index 09e0a131a93c..e5f29919ec0f 100644
--- a/dev-python/babelfont/babelfont-3.0.0_alpha8.ebuild
+++ b/dev-python/babelfont/babelfont-3.0.0_alpha8.ebuild
@@ -3,6 +3,7 @@
 
 EAPI=8
 
+DISTUTILS_USE_PEP517=poetry
 MYP="${P/_alpha/a}"
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
 
@@ -21,10 +22,14 @@ LICENSE="MIT"
 SLOT="0"
 
 RDEPEND="
-	dev-python/defcon[${PYTHON_USEDEP}]
-	dev-python/fontParts[${PYTHON_USEDEP}]
-	dev-python/fonttools[${PYTHON_USEDEP}]
-	dev-python/glyphsLib[${PYTHON_USEDEP}]
+	>=dev-python/orjson-3.5.1[${PYTHON_USEDEP}]
+	>=dev-python/fonttools-4.21.1[${PYTHON_USEDEP}]
+	>=dev-python/ufoLib2-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/openstep-plist-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/glyphsLib-5.3.2[${PYTHON_USEDEP}]
+	>=dev-python/glyphsLib-5.3.2[${PYTHON_USEDEP}]
+	>=dev-python/cu2qu-1.6.7[${PYTHON_USEDEP}]
+	dev-python/fontFeatures[${PYTHON_USEDEP}]
 "
 DEPEND="${RDEPEND}"
 
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index d8f7173fb31a..1b7d2e24a687 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,5 +1,6 @@
 DIST boto3-1.22.10.tar.gz 497369 BLAKE2B 448cb581fa31746083da4271436071b1ab5625207e5cc0560746beca9216a9748191206238a950a5a04cc178c20b744d19d3d99c1aefb775eaa79c5b96b75cbd SHA512 0e4ed0cf8f14997b4e61d926491fba05e4ec06dfae347e65ab3dceb48d61e24860e82fb922a7eac73e1e1322679418c96915c62f6279bad694685361d9970d7d
 DIST boto3-1.22.11.tar.gz 497893 BLAKE2B 07b757e4ab108eb70273dc3df082394dc730223417d1776f38c195831d2361578ed8722b107224b9e6c79685c7fedb02c386ea92c749d654a2f70b28d8de1e3e SHA512 f1367f66a93af59bcff2d29df6064440eac579e3aba4ab65083904de7a44b2c175fcfc2fd7836a8b0a425cf5519847c5e17075d42e82d46b2a0c4b46b7d5dabf
+DIST boto3-1.22.12.tar.gz 498085 BLAKE2B 650ebe35436fcbb087063ff0cbbda4a8d8643fa551e2061c27ec797b62daf6ad1b5ae4c5271bd73404f8c6cf11d2b4b6b066eb7cebde478f68db7ed8fbfc813a SHA512 db2479d5b7b0cedb063af34155d3e54bea507fc5526fbcacc5b1a2d20120c8d564d155d91ca3cf6753cf7ceafa7de2789a7547cfefde6ac290829c7c02fa2aa4
 DIST boto3-1.22.4.tar.gz 495554 BLAKE2B 4c06e2101bcc96e4fab7e088f8593c7b1cfd2b07431d4cd062666df6c1f5d55d9b7fb594268e9a86c4793d35bc3d8de2644244728cf62833dfefb62525eedbdc SHA512 26dbd9ed1af900f7466a1767ada3fb8ee86fa09ca21733f857e2748d98525661fc76e69d75440fe913260e75245cf30298493417d055399a242af0aedaffd349
 DIST boto3-1.22.7.tar.gz 496523 BLAKE2B 400370268e51b229bd3c465ccc43df93b713e3088baf76cbb7367cdc75b8374b787fee635cc921b431d5e1471a60a990d57a306d8ebdb14f0c462f211b323f99 SHA512 a7b56723a0fd692496a4e397ca29139f0813bfcea365877900441f01f38e5fd15d20a1642a5717940994bdfc840540d38b9a594e2510ab070ae62fadf9b4958b
 DIST boto3-1.22.8.tar.gz 496856 BLAKE2B c7707eae7a5966dbe04e86c35270674f532286d3fbed46580836729988e55cdeba872496de750af89de6a7afdc6b19bbe4f8b9025580dc9b825cd04a87530b21 SHA512 43498179a59c2a1c9401f0629fbf0f3ff1dd51d2208ade828ff283b44be28fd539af68d4fb274e5e8c6c01bd03699872cd1a81d006f4c929dcdbf7227f77416f
diff --git a/dev-python/boto3/boto3-1.22.12.ebuild b/dev-python/boto3/boto3-1.22.12.ebuild
new file mode 100644
index 000000000000..6e54ecb92f37
--- /dev/null
+++ b/dev-python/boto3/boto3-1.22.12.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 1377a95e0c96..e6f0dd5cfec9 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,5 +1,6 @@
 DIST botocore-1.25.10.tar.gz 8963726 BLAKE2B 9823581417f4ddbca840fec85421c01089987ae53fff3825463a79e2663c753d0aa00c2f3dc714d5bf62ee491b4521964869c8e39c5f88ebd562676267b35831 SHA512 6daaec14be1cafdf43bdb4b182a31649d88ee3a9b7e2a88409e3a9fc5279479f78800a0b49ec405936e6695ac4c1b672a62b31b2486049193734ade98f275a10
 DIST botocore-1.25.11.tar.gz 8965078 BLAKE2B 9303ea0c5bd298be3167a887bf8a5b66edbe0f2c82273841daabf975c1f78f18e80092252d0c9c79e05992039ea1048cfe36f4ecf9e5a941e2ad80f7a7ede314 SHA512 2afe95fc0ee2d50e87c6ffc8cbd189fea71f0a97ce508c01642f0a736cb2fe220531324366fddad3e725bc81ca4ef3ffdf2c281c3c89075cae5416f5722b1b1d
+DIST botocore-1.25.12.tar.gz 8964692 BLAKE2B f039aa570d74a2fb5cacfb4d43ab2e34c677f471a6d325fe02afa2aa7231960dd70f13b8b0c988fbf9c0dec2bda7b95ac2069b00233211c30aa2d9e0cf287747 SHA512 da88d66db527216f81101fe30a2c90cf423025bbe28d7fda227fc80b9a33696c63630a885e5809810688dc80eb274898301a3877855c904b8c8bd8b85edc12a3
 DIST botocore-1.25.4.tar.gz 8955210 BLAKE2B 50880e9d7f57e4f3b8662625a64e9470eaf8a984fdbcc34239bfe604544ccd3ac62e953d7be4e1b486fab4ad0d571361ffc9fdc43cb860cd37a95c33d7b824b2 SHA512 a04e03271d217ab1ef5488dcfedda2904b8e628dae969c74e284d004ae72f18d9734d3f7cf775235c8384b30f4d0fbfda7c0e5dcd687039ddb7b339330e63317
 DIST botocore-1.25.7.tar.gz 8961319 BLAKE2B 1d22e3cd625252f1e6c6b13b9317750b48765150006ca0b632fd15aa6f31079855a1b6c7201cbed0ebfc7147a87389e1a4445d0736829554f8063b68944107cf SHA512 a22a35a1de87aff2efa7b4b5f478e44be7ce2eadf0b7da43af2a0de9ba315a9b75ac59da29a8f10ed15bbf6ff4d76d904407f95a7f8f08049c546450bd6c7c4d
 DIST botocore-1.25.8.tar.gz 8961194 BLAKE2B 4a13f5b01352ff0cb8932431e9431229a73fe922c2719ee571fa26ed55faa0315e0bdd561dcf2069748d13c809c7c5b7e2a35051d5d8bbd498677658b69ff454 SHA512 bc78c24629308d4d8cb4190646b7f465713a5462c54ff0946fdbcfa8b87951fa337a2f8f97bbd27991a79da03d140b890f2b021f865c7550b791d2fbb95282a1
diff --git a/dev-python/botocore/botocore-1.25.12.ebuild b/dev-python/botocore/botocore-1.25.12.ebuild
new file mode 100644
index 000000000000..f5cc64418e9a
--- /dev/null
+++ b/dev-python/botocore/botocore-1.25.12.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/build/build-0.7.0-r1.ebuild b/dev-python/build/build-0.7.0-r1.ebuild
index 1f1b04252da0..597ae7f1126b 100644
--- a/dev-python/build/build-0.7.0-r1.ebuild
+++ b/dev-python/build/build-0.7.0-r1.ebuild
@@ -55,7 +55,11 @@ python_test() {
 		'tests/test_util.py::test_wheel_metadata[True]'
 		tests/test_util.py::test_with_get_requires
 	)
+	[[ ${EPYTHON} == python3.11 ]] && EPYTEST_DESELECT+=(
+		# fixed in git but the patch is large-ish
+		tests/test_env.py::test_executable_missing_post_creation
+	)
 
-	epytest -p no:flaky \
-		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+	epytest -p no:flaky -n "$(makeopts_jobs)" \
+		-W"ignore:path is deprecated.:DeprecationWarning"
 }
diff --git a/dev-python/databases/Manifest b/dev-python/databases/Manifest
index c0460b3aacb7..0debb7b5bbe8 100644
--- a/dev-python/databases/Manifest
+++ b/dev-python/databases/Manifest
@@ -1,2 +1 @@
-DIST databases-0.4.3.tar.gz 26517 BLAKE2B 38b9f86e42740a723f4022b225913e0e7a2c635eb34793fcbf62efa0917ddb6b7ee3b59cce7f4c8503aef31befb0caea3fb3e655617606296cb8ae1bb4cebfc7 SHA512 aa49f1a33edd3bf9ae7aa203dcef4941d1a1766c930cbe34405caf3dca0801bbca494ec39357591b6339977b86294d32a031bf2020f206436e7d19edc6a8e158
 DIST databases-0.5.3.tar.gz 28342 BLAKE2B dcf8533a49b92a325bfda1440fd5bac3f9bd69751496c6fcdf72c422cc19c552a7458dc4ea0607a2a1ad9ade9afbb8cac00e178c29b6b11f7011bd4eae1f70a0 SHA512 bd0c4f1bf0f81e017ea55e41a6d4821ee17e0f995b600a50955fba68841443147dd234534b9c72d753b99785a5a08ac6e3d839894ec4760c602372cccbd4c1c0
diff --git a/dev-python/databases/databases-0.4.3.ebuild b/dev-python/databases/databases-0.4.3.ebuild
deleted file mode 100644
index 8459cc04c73e..000000000000
--- a/dev-python/databases/databases-0.4.3.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-
-DOCS_BUILDER="mkdocs"
-DOCS_DEPEND="dev-python/mkdocs-material"
-
-inherit distutils-r1 docs optfeature
-
-DESCRIPTION="Async database support for Python."
-HOMEPAGE="
-	https://www.encode.io/databases/
-	https://github.com/encode/databases
-"
-SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="<dev-python/sqlalchemy-1.4.0[${PYTHON_USEDEP}]"
-
-BDEPEND="test? (
-	dev-python/aiopg[${PYTHON_USEDEP}]
-	dev-python/aiosqlite[${PYTHON_USEDEP}]
-	dev-python/async_timeout[${PYTHON_USEDEP}]
-	dev-python/asyncpg[${PYTHON_USEDEP}]
-	dev-python/psycopg[${PYTHON_USEDEP}]
-	dev-python/pymysql[${PYTHON_USEDEP}]
-	dev-python/starlette[${PYTHON_USEDEP}]
-)"
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# do not install LICENSE to /usr/
-	sed -i -e '/data_files/d' setup.py || die
-	# fix tests
-	sed -i -e '/databases.backends.mysql/d' tests/test_connection_options.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_test() {
-	TEST_DATABASE_URLS="" epytest \
-		--deselect tests/test_connection_options.py::test_mysql_pool_size \
-		--deselect tests/test_connection_options.py::test_mysql_explicit_pool_size \
-		--deselect tests/test_connection_options.py::test_mysql_ssl \
-		--deselect tests/test_connection_options.py::test_mysql_explicit_ssl \
-		--deselect tests/test_connection_options.py::test_mysql_pool_recycle \
-		--deselect tests/test_databases.py \
-		--deselect tests/test_integration.py::test_integration
-}
-
-pkg_postinst() {
-	optfeature "postgresql support" dev-python/asyncpg dev-python/psycopg
-	optfeature "mysql support" dev-python/pymysql
-	optfeature "sqlite support" dev-python/aiosqlite
-	optfeature "postgresql+aiopg support" dev-python/aiopg
-}
diff --git a/dev-python/distlib/distlib-0.3.4-r2.ebuild b/dev-python/distlib/distlib-0.3.4-r2.ebuild
index 2f6df4bed940..1e61702c5e11 100644
--- a/dev-python/distlib/distlib-0.3.4-r2.ebuild
+++ b/dev-python/distlib/distlib-0.3.4-r2.ebuild
@@ -47,6 +47,8 @@ src_prepare() {
 	sed -i -e 's:test_custom_shebang:_&:' tests/test_scripts.py || die
 	# broken with py3.11, doesn't look important
 	sed -i -e 's:test_sequencer_basic:_&:' tests/test_util.py || die
+	# https://bugs.gentoo.org/843839
+	sed -i -e 's:test_interpreter_args:_&:' tests/test_scripts.py || die
 
 	distutils-r1_src_prepare
 }
diff --git a/dev-python/gbinder/Manifest b/dev-python/gbinder/Manifest
new file mode 100644
index 000000000000..a17031d3241f
--- /dev/null
+++ b/dev-python/gbinder/Manifest
@@ -0,0 +1 @@
+DIST gbinder-1.0.0.tar.gz 22640 BLAKE2B dbd0b07c693c803c6646fded1ea0b546d7dc40a1a5f1592601d28d63dbe5113b2bcc07314710c7ba1b47f3417b943398e720ece089ff8a68856e7b2cfda55ae1 SHA512 3b52c01c99321108a3d5c0129fb4fcf22d164e5de1e197f0e01a77e3bcbf9c4fd7ee35ce58131f545f65561c622b30f5919f4bdc995005b00a18a15c695fbf51
diff --git a/dev-python/gbinder/files/gbinder-1.0.0-setuppy-extensions.patch b/dev-python/gbinder/files/gbinder-1.0.0-setuppy-extensions.patch
new file mode 100644
index 000000000000..5990393e32b5
--- /dev/null
+++ b/dev-python/gbinder/files/gbinder-1.0.0-setuppy-extensions.patch
@@ -0,0 +1,22 @@
+From 79d40e9e564772973f7f085ed5c48e3fc625e0f5 Mon Sep 17 00:00:00 2001
+From: Erfan Abdi <erfangplus@gmail.com>
+Date: Mon, 6 Sep 2021 13:57:22 +0430
+Subject: [PATCH] setup: Drop None from keywords
+
+---
+ setup.py | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git a/setup.py b/setup.py
+index cf3a42e..ed2b1ed 100644
+--- a/setup.py
++++ b/setup.py
+@@ -19,6 +19,8 @@ def pkgconfig(package, kw):
+ 
+ extension_kwargs = { 'sources': ["gbinder" + file_ext] }
+ extension_kwargs = pkgconfig('libgbinder', extension_kwargs)
++if None in extension_kwargs:
++    del extension_kwargs[None]
+ extensions = [Extension('gbinder', **extension_kwargs)]
+ 
+ if USE_CYTHON:
diff --git a/dev-python/gbinder/gbinder-1.0.0.ebuild b/dev-python/gbinder/gbinder-1.0.0.ebuild
new file mode 100644
index 000000000000..585b31afa4dd
--- /dev/null
+++ b/dev-python/gbinder/gbinder-1.0.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+if [[ ${PV} != *9999* ]]; then
+	MY_PN="${PN}-python"
+	MY_P="${MY_PN}-${PV}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/erfanoabdi/gbinder-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	PATCHES=( "${FILESDIR}/${P}-setuppy-extensions.patch" )
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/erfanoabdi/gbinder-python.git"
+fi
+
+DESCRIPTION="Python bindings for libgbinder"
+HOMEPAGE="https://github.com/erfanoabdi/gbinder-python"
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND="dev-libs/gbinder"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+python_compile() {
+	distutils-r1_python_compile --cython
+}
diff --git a/dev-python/gbinder/gbinder-9999.ebuild b/dev-python/gbinder/gbinder-9999.ebuild
new file mode 100644
index 000000000000..585b31afa4dd
--- /dev/null
+++ b/dev-python/gbinder/gbinder-9999.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+if [[ ${PV} != *9999* ]]; then
+	MY_PN="${PN}-python"
+	MY_P="${MY_PN}-${PV}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/erfanoabdi/gbinder-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	PATCHES=( "${FILESDIR}/${P}-setuppy-extensions.patch" )
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/erfanoabdi/gbinder-python.git"
+fi
+
+DESCRIPTION="Python bindings for libgbinder"
+HOMEPAGE="https://github.com/erfanoabdi/gbinder-python"
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND="dev-libs/gbinder"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+python_compile() {
+	distutils-r1_python_compile --cython
+}
diff --git a/dev-python/gbinder/metadata.xml b/dev-python/gbinder/metadata.xml
new file mode 100644
index 000000000000..8c8101bcdb2c
--- /dev/null
+++ b/dev-python/gbinder/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>core@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
+ 
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index bb6d3226a1bb..7e83c194765e 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -7,3 +7,4 @@ DIST hypothesis-python-6.45.3.tar.gz 9191554 BLAKE2B 0fc07224be3c0f9f852d86c7054
 DIST hypothesis-python-6.46.0.tar.gz 9192054 BLAKE2B acfb6136b43f29b62ebd843a8c1437955f2f6681af16293f0f0a0fb651c0a69fb06c15b67fac8f9f73ad2459e0a5a0e4292e5dae1eb0a49e14760849a3af944f SHA512 5fcfd72d17a69e0dcd23a0d5633c15507017750dce61ae2be457151e4099ea7aea66b7d8b0aad98615453763935bb353197b094191dea78ece3ff297c89cf71f
 DIST hypothesis-python-6.46.1.tar.gz 9192240 BLAKE2B cb38e1f7fdc4a9586c3920f2d9270a9ad08a77eab52ba493e4ae4fb8ab17780b49f0e4f52004bc330021836a1470feffb96554757495259d34cf52f4ae2b264f SHA512 b273e6c77251544314babdc891e8c2f3f9098b97ba25cfa7eee960773e4508840c27af2b993daa00546cb269eb58d74b6bbfefef2d8869e2d202622983af520a
 DIST hypothesis-python-6.46.2.tar.gz 9305176 BLAKE2B 7d0abe4fc055eeb4660efbba9900b43209cc5ef1fd7b2362545e0d4145837cb7779cdf96c96cdd3770c1605ec8104818ece5cd012a90b164ab8ab63709d1c911 SHA512 207b4202aa36a28891c8051009ee6b8b6a8f0823840db7e4fc6840ebe6455060340f16f7e2e25bc5ad2adca1ff7fd8b58668ec2ca355b4579ec03aac616e786d
+DIST hypothesis-python-6.46.3.tar.gz 9306685 BLAKE2B a26c08361a7a58d8de8d8458a73c5c3c57f04dd2008ab31e604f0addc18fb7a52a7f4a98318498b398cd1ac5d2d718fd722c4d17e0b6ef326e0457355fda7482 SHA512 d55c3c4a57d18aa7f6d876123b09bcab32d508f5aa40048f2db7f0cab3948ebb6fab5f12d291ae4740cdd1c61c2d612c1ce804028bb59914efc132404224d1ee
diff --git a/dev-python/hypothesis/hypothesis-6.46.3.ebuild b/dev-python/hypothesis/hypothesis-6.46.3.ebuild
new file mode 100644
index 000000000000..8b5222a2f449
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.46.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' python3_{8..10})
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" python3.{8..10}; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/jsonpickle/Manifest b/dev-python/jsonpickle/Manifest
index 24fd7c25cf73..e27f98f94be7 100644
--- a/dev-python/jsonpickle/Manifest
+++ b/dev-python/jsonpickle/Manifest
@@ -1 +1,2 @@
 DIST jsonpickle-2.1.0.tar.gz 186799 BLAKE2B a9e82a046fc77e1a4d5e7b1f13fc34f07e0e42e34922258bb0bd5aa4557bfec2b5fc06e450a0391522ae27380306111001204eb4f5429c2ad1f908fc4dec40a0 SHA512 46e8bcc2e24616da43b87bf8371ec9b39de1e8e33380684c05b7d7c6695f17bcc21150848c3306d235f89c5d74c69b6fda79e93fc823665d72cc88d9d89d8484
+DIST jsonpickle-2.2.0.tar.gz 189866 BLAKE2B d8fcd0e8b71947b734c59240d9fa4f0b35b9b0ac2e2940a9baf05c160771db0eae5f011b61e3b1c0bc746a740ac2e137a392931e270fea3acf4884578133283e SHA512 b6cb35316e32f38875cbfa3784a3930f669d4ea730ead6117242070590647987383e9f933c193b8c246c40dba87ad56600a65db89c45c18a790b3c1f9232b245
diff --git a/dev-python/jsonpickle/jsonpickle-2.2.0.ebuild b/dev-python/jsonpickle/jsonpickle-2.2.0.ebuild
new file mode 100644
index 000000000000..c7d715c518c0
--- /dev/null
+++ b/dev-python/jsonpickle/jsonpickle-2.2.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for serializing any arbitrary object graph into JSON"
+HOMEPAGE="
+	https://github.com/jsonpickle/jsonpickle/
+	https://pypi.org/project/jsonpickle/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/feedparser[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/jaraco-packaging \
+	dev-python/rst-linker
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e 's:--flake8 --cov::' pytest.ini || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# unpackaged bson dependency
+		tests/bson_test.py
+		# broken when gmpy is installed
+		# https://github.com/jsonpickle/jsonpickle/issues/328
+		# https://github.com/jsonpickle/jsonpickle/issues/316
+		tests/ecdsa_test.py
+	)
+	epytest
+}
+
+pkg_postinst() {
+	# Unpackaged optional backends: yajl, demjson
+	optfeature "encoding numpy-based data" dev-python/numpy
+	optfeature "encoding pandas objects" dev-python/pandas
+	optfeature "fast JSON backend" dev-python/simplejson
+}
diff --git a/dev-python/matrix-client/Manifest b/dev-python/matrix-client/Manifest
new file mode 100644
index 000000000000..a4a9d312ad23
--- /dev/null
+++ b/dev-python/matrix-client/Manifest
@@ -0,0 +1 @@
+DIST matrix-client-0.4.0.tar.gz 48982 BLAKE2B 1a44067a88319c84ff8e9cd23b4f8fb2941d217511c1bf1448e63e968ccc922850f9be8391cdbceb404ea2709b79b7c373b51b2320aff2395452e5525c34d10a SHA512 40c69a9909b1bb9487d89ee824915ffd5264b99e68b6b32e603f95a78c196293267c12226ea55ab26ffe24b494ff16a7dc193e9d62d8f526c8c76735317da6ad
diff --git a/dev-python/matrix-client/files/setup_py.patch b/dev-python/matrix-client/files/setup_py.patch
new file mode 100644
index 000000000000..c4cc4c51769b
--- /dev/null
+++ b/dev-python/matrix-client/files/setup_py.patch
@@ -0,0 +1,11 @@
+diff -urN matrix_client-0.4.0.orig/setup.py matrix_client-0.4.0/setup.py
+--- matrix_client-0.4.0.orig/setup.py	2022-05-12 10:42:34.391396131 +0200
++++ matrix_client-0.4.0/setup.py	2022-05-12 10:47:19.988377071 +0200
+@@ -48,7 +48,6 @@
+         'requests~=2.22',
+         'urllib3~=1.21',
+     ],
+-    setup_requires=['pytest-runner~=5.1'],
+     tests_require=['pytest >=4.6.5, <6.0.0', 'responses >=0.10.6, ==0.10.*'],
+     extras_require={
+         'test': ['pytest >=4.6, <6.0.0', 'responses >=0.10.6, ==0.10.*'],
diff --git a/dev-python/matrix-client/matrix-client-0.4.0-r3.ebuild b/dev-python/matrix-client/matrix-client-0.4.0-r3.ebuild
new file mode 100644
index 000000000000..c6b11d2669e8
--- /dev/null
+++ b/dev-python/matrix-client/matrix-client-0.4.0-r3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2021-2022 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/_}
+DESCRIPTION="Client-Server SDK for Matrix"
+HOMEPAGE="https://github.com/matrix-org/matrix-python-sdk https://pypi.org/project/matrix-client/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND=">=dev-python/requests-2.22[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]"
+DEPEND="${REDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	cd ${S}
+	eapply ${FILESDIR}/setup_py.patch
+	# removing test directory, as it is not allowed to be installed
+	rm -rf test
+	default
+}
+
+python_test() {
+	nosetests --verbose || die
+	py.test -v -v || die
+}
diff --git a/dev-python/matrix-client/metadata.xml b/dev-python/matrix-client/metadata.xml
new file mode 100644
index 000000000000..06fdc2f832be
--- /dev/null
+++ b/dev-python/matrix-client/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>dev@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
+ <maintainer type="project">
+  <email>b@edevau.net</email>
+  <name>Andreas Billmeier</name>
+ </maintainer>
+ <maintainer status="unknown">
+  <email>team@matrix.org</email>
+  <name>The Matrix.org Team</name>
+ </maintainer>
+ 
+ <origin>ports</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/neutron-lib/Manifest b/dev-python/neutron-lib/Manifest
index 247c039105dc..437c92c079ef 100644
--- a/dev-python/neutron-lib/Manifest
+++ b/dev-python/neutron-lib/Manifest
@@ -1 +1,2 @@
 DIST neutron-lib-2.20.0.tar.gz 525240 BLAKE2B 00dd2186f475e63bd145aeab0fe220687a86065755993c1168c038143e593e9e32493f4d3c83d6ecd609fb40bfec917b3be3ce9abe1501d8f25dbfead1f01bf1 SHA512 f6dc52900dde441e9e9b62bfa21fb0b03fdd2310e3084941c973d1ad6a6e55d11ca28bacdebba4165ced4c0f91208f6f3ee654d0f35808c84f08d6ea647240ec
+DIST neutron-lib-2.21.0.tar.gz 519557 BLAKE2B 6e60c87906fc0edba3b1b1d2b2d0f91985911607df2a49c0d0ff1d209505c6f4dd35e27e9b8a91836af082d52697798bb1324ca9e08915d5b5d4dab5bb6d036c SHA512 55d1d457ee092216b045f39f7e2bc5f6ddaeed14ecafccbae2b0efb6e83357f7fb1a522aff1b467c2b43ab46b379502a57214580456009cc64a5c51896c35233
diff --git a/dev-python/neutron-lib/neutron-lib-2.21.0.ebuild b/dev-python/neutron-lib/neutron-lib-2.21.0.ebuild
new file mode 100644
index 000000000000..982eff1bce93
--- /dev/null
+++ b/dev-python/neutron-lib/neutron-lib-2.21.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+EPYTEST_IGNORE=( neutron_lib/tests/unit/hacking )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Neutron shared routines and utilities"
+HOMEPAGE="
+	https://github.com/openstack/neutron-lib
+	https://opendev.org/openstack/neutron-lib
+	https://pypi.org/project/neutron-lib/
+
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pbr-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pecan-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.14.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/os-ken-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.44.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-4.3.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-3.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-2.25.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.24.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.31.2[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/setproctitle-1.1.10[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/os-traits-0.9.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-3.1.0[${PYTHON_USEDEP}]
+		>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+distutils_enable_tests pytest
diff --git a/dev-python/orjson/orjson-3.6.8-r1.ebuild b/dev-python/orjson/orjson-3.6.8-r1.ebuild
new file mode 100644
index 000000000000..c93117e989dd
--- /dev/null
+++ b/dev-python/orjson/orjson-3.6.8-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+	ahash-0.7.6
+	arrayvec-0.7.2
+	associative-cache-1.0.1
+	autocfg-1.1.0
+	bytecount-0.6.2
+	cfg-if-1.0.0
+	chrono-0.4.19
+	encoding_rs-0.8.31
+	getrandom-0.2.6
+	inlinable_string-0.1.15
+	itoa-1.0.1
+	libc-0.2.123
+	libm-0.1.4
+	num-integer-0.1.44
+	num-traits-0.2.14
+	once_cell-1.10.0
+	packed_simd_2-0.3.7
+	pyo3-build-config-0.16.4
+	pyo3-ffi-0.16.4
+	ryu-1.0.9
+	serde-1.0.136
+	serde_json-1.0.79
+	simdutf8-0.1.4
+	smallvec-1.8.0
+	target-lexicon-0.12.3
+	version_check-0.9.4
+	wasi-0.10.2+wasi-snapshot-preview1
+"
+DISTUTILS_USE_PEP517=maturin
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+QA_FLAGS_IGNORED="*"
+
+inherit cargo distutils-r1
+
+DESCRIPTION="Fast, correct Python JSON library supporting dataclasses, datetimes, and numpy"
+HOMEPAGE="https://github.com/ijl/orjson"
+SRC_URI="
+	https://github.com/ijl/orjson/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+	$(cargo_crate_uris ${CRATES})
+"
+
+LICENSE="
+	Apache-2.0 MIT
+	BSD
+	|| ( Apache-2.0 MIT )
+	|| ( Apache-2.0 Apache-2.0-with-LLVM-exceptions MIT )
+	|| ( Apache-2.0 Boost-1.0 )
+"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="debug"
+
+BDEPEND="
+	test? (
+		dev-python/arrow[${PYTHON_USEDEP}]
+		dev-python/orjson[${PYTHON_USEDEP}]
+		dev-python/pendulum[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+
+		$(python_gen_cond_dep 'dev-python/numpy[${PYTHON_USEDEP}]' python3_{8,9})
+		$(python_gen_cond_dep '>=dev-python/xxhash-1.4.3[${PYTHON_USEDEP}]' python3_8)
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-3.6.7-no-strip.patch" )
+
+distutils_enable_tests pytest
diff --git a/dev-python/pip/Manifest b/dev-python/pip/Manifest
index 03bd9c69113b..edb1fd4d31f6 100644
--- a/dev-python/pip/Manifest
+++ b/dev-python/pip/Manifest
@@ -1,4 +1,6 @@
 DIST pip-22.0.4.tar.gz 9325766 BLAKE2B 9ce5a25e6fb9aedc39e2cddab2a8af3b47dbaaaf8bd22c39f8301b784e6e9f5434f63d5ef467f4d819b15bcd5cf8d3da52db34b3514c7b4a15823f77cb47e1c1 SHA512 af6d1787b4fe97f2eec9c2e3e3f0f756efca8cb83f6ecdae797986fb6050ee60d872a8a8eb7502a32c4334fc0c7af8cf3c58ce980407d0e9f89eec28a4290093
 DIST setuptools-57.4.0-py3-none-any.whl 819017 BLAKE2B afba86cf9aeea58ee869fdc11bbb192abbf2f89710e468b90dc291fec228ca16202483e36195a5ad4e2b8d210326bc83e2be6ec696ab413d94ffaeb05bb9c030 SHA512 9bf230f4e0e72acab07ab372a6ca05adb3d175a8079d2f73d327c632f3d27b8ee10442d3e60f4c94a6e61d5ba2212fc78187ca6e1717e15bb570bdce4263fd0b
+DIST setuptools-62.2.0-py3-none-any.whl 1143965 BLAKE2B 42bf650892d2e5810f18f8002fc6318b5abf890d04b2a3050784b93da88d806af5118eee65ed89b06e1cb908e4c7f6aa50222fba4b8617ab36923cfb624528ae SHA512 496593580b5537fb142bc775d060d01ef3c9069fc06564b5e9cb8e2a56e8f264c1dc7438d38a17f8b7e20d509a6b4f62cdfaf290c4ed82e071a1cc10a297b8b8
 DIST virtualenv-16.7.11.tar.gz 8134533 BLAKE2B ea81e11c210d911bf9576edf7b1754721b270adcc5d9633415d33b8f659149d64932fe2d366200121ec00c266c25dae380e248add438fc357477114eba4dfb4e SHA512 82d0d2a964508511e8e1686703581ff543f65791dc2449d9741d46ea57c4c89673947d2477ba374176f05fcea2a5ca572aa650c61c4f3271c4d73d1ff9d9ff42
+DIST virtualenv-16.7.12.tar.gz 8906590 BLAKE2B a1f206769e4e5797562906162e492e44c4a72720e4f88a0362dc802ce2df20c65aaab6a72dce2238445601a10fae59bd90cd362217994d30911f105afd71c5fa SHA512 0278b33fb19f6553e70ad3dcffa6ea1a455ff435b216ac9b4fadff216b2932714faa2bb6027af3058010111d8511a5c2fcd424f31c9645be361603971f111c8e
 DIST wheel-0.36.2-py2.py3-none-any.whl 35046 BLAKE2B bc4e8dab7c74eea34d3b4a813b7eaf6295a99a396a861b6cdd76f743043e89140bad132bdd13e385e8945ce02e0798e1d3ac73fc1b23bde5b2a83e4bb4dd5cdc SHA512 6bb5119b4d3704fe1e3c1eaaa3124edab13f61b46f8a0a8e75974fac4e5b25d8b53606071a03a8d8990ad1cfe2ab247ddea260098df2c0c35ae965be47080284
diff --git a/dev-python/pip/pip-22.0.4-r1.ebuild b/dev-python/pip/pip-22.0.4-r1.ebuild
new file mode 100644
index 000000000000..a37c828464dc
--- /dev/null
+++ b/dev-python/pip/pip-22.0.4-r1.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit bash-completion-r1 distutils-r1 multiprocessing
+
+# setuptools & wheel .whl files are required for testing,
+# the exact version is not very important.
+SETUPTOOLS_WHL="setuptools-62.2.0-py3-none-any.whl"
+WHEEL_WHL="wheel-0.36.2-py2.py3-none-any.whl"
+# upstream still requires virtualenv-16 for testing, we are now fetching
+# it directly to avoid blockers with virtualenv-20
+VENV_PV=16.7.12
+
+DESCRIPTION="The PyPA recommended tool for installing Python packages"
+HOMEPAGE="
+	https://pip.pypa.io/en/stable/
+	https://pypi.org/project/pip/
+	https://github.com/pypa/pip/
+"
+SRC_URI="
+	https://github.com/pypa/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+	test? (
+		https://files.pythonhosted.org/packages/py3/s/setuptools/${SETUPTOOLS_WHL}
+		https://files.pythonhosted.org/packages/py2.py3/w/wheel/${WHEEL_WHL}
+		https://github.com/pypa/virtualenv/archive/${VENV_PV}.tar.gz
+			-> virtualenv-${VENV_PV}.tar.gz
+	)
+"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+IUSE="vanilla"
+
+RDEPEND="
+	>=dev-python/setuptools-39.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/freezegun[${PYTHON_USEDEP}]
+			dev-python/pretend[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/scripttest[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/werkzeug[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+			!alpha? ( !hppa? ( !ia64? (
+				dev-python/cryptography[${PYTHON_USEDEP}]
+			) ) )
+		' python3_{8..10})
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-21.3-no-coverage.patch"
+	)
+	if ! use vanilla; then
+		PATCHES+=( "${FILESDIR}/pip-20.0.2-disable-system-install.patch" )
+	fi
+
+	distutils-r1_python_prepare_all
+
+	if use test; then
+		mkdir tests/data/common_wheels/ || die
+		cp "${DISTDIR}"/{${SETUPTOOLS_WHL},${WHEEL_WHL}} \
+			tests/data/common_wheels/ || die
+	fi
+}
+
+python_compile_all() {
+	# 'pip completion' command embeds full $0 into completion script, which confuses
+	# 'complete' and causes QA warning when running as "${PYTHON} -m pip".
+	# This trick sets correct $0 while still calling just installed pip.
+	local pipcmd='import sys; sys.argv[0] = "pip"; __file__ = ""; from pip._internal.cli.main import main; sys.exit(main())'
+	"${EPYTHON}" -c "${pipcmd}" completion --bash > completion.bash || die
+	"${EPYTHON}" -c "${pipcmd}" completion --zsh > completion.zsh || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" python3.{8..10} ]]; then
+		einfo "Skipping tests on ${EPYTHON} since virtualenv-16 is broken"
+		return 0
+	fi
+
+	local EPYTEST_DESELECT=(
+		tests/functional/test_install.py::test_double_install_fail
+		tests/functional/test_list.py::test_multiple_exclude_and_normalization
+		# Internet
+		tests/functional/test_install.py::test_install_editable_with_prefix_setup_cfg
+		tests/functional/test_install.py::test_editable_install__local_dir_no_setup_py_with_pyproject
+		tests/functional/test_install.py::test_editable_install__local_dir_setup_requires_with_pyproject
+	)
+
+	if ! has_version "dev-python/cryptography[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/functional/test_install.py::test_install_sends_client_cert
+			tests/functional/test_install_config.py::test_do_not_prompt_for_authentication
+			tests/functional/test_install_config.py::test_prompt_for_authentication
+			tests/functional/test_install_config.py::test_prompt_for_keyring_if_needed
+		)
+	fi
+
+	local -x GENTOO_PIP_TESTING=1
+	local -x PYTHONPATH="${WORKDIR}/virtualenv-${VENV_PV}"
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+	epytest -m "not network" -n "$(makeopts_jobs)"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS.txt docs/html/**/*.rst )
+	distutils-r1_python_install_all
+
+	newbashcomp completion.bash pip
+
+	insinto /usr/share/zsh/site-functions
+	newins completion.zsh _pip
+}
diff --git a/dev-python/puremagic/Manifest b/dev-python/puremagic/Manifest
index 8bc3572c0e31..646bf60e86db 100644
--- a/dev-python/puremagic/Manifest
+++ b/dev-python/puremagic/Manifest
@@ -1,2 +1,3 @@
 DIST puremagic-1.11.tar.gz 295026 BLAKE2B 4d210807d9f5eb0c2eb88b0c18aa5cdf56170b347de4f95b92c08492d5f038759b39c1aa2d6ed4bc91e96e036e6f4d0891449af8aee3beac65c4d692fa295ec0 SHA512 4d4c9a93cd56a02aefb7090c92b41048f33923bef14022158f39c39ac93326b7180b8cc97495ad5ed3eec7d9f1379a5508829ee779aaba9b8aa8f975e787b1f5
 DIST puremagic-1.12.tar.gz 296831 BLAKE2B cd9979fba1016b1c4cbdd9ef1402d11dbe2faf37767e3232cf400b798cce328d90d224765cc2bf39fd0988abdfe39d1527dd7aa6e31b4737d00c1578f1cc3101 SHA512 b50e22b7597f206e8d6dbc0e2c120af21a7246568f059c6145e45471eedf04c797a9f00864468d5e05c9536f49f7fc6c7b30a83e67bf248e10ebaf8300726fde
+DIST puremagic-1.13.gh.tar.gz 300110 BLAKE2B d436735126d465cd43bc5537b2fb9385297d626b19b5b881c63fc7f3559600c9318c7ad91955cf66df2962ad122d2b42919bdee4460bc16ddb7750d4ffdc2fa2 SHA512 495777751874d4f2213b8bedb4bc3b2cdfdcacc5a1dd7cad85545fce473b8beca9a38fbe513d26c37455686265482b8bde7024111e76501d489aee7e5750d97f
diff --git a/dev-python/puremagic/puremagic-1.13.ebuild b/dev-python/puremagic/puremagic-1.13.ebuild
new file mode 100644
index 000000000000..91ed793e4648
--- /dev/null
+++ b/dev-python/puremagic/puremagic-1.13.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure python implementation of magic file detection"
+HOMEPAGE="
+	https://github.com/cdgriffith/puremagic/
+	https://pypi.org/project/puremagic/
+"
+SRC_URI="
+	https://github.com/cdgriffith/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DOCS=( CHANGELOG.md README.rst )
+
+distutils_enable_tests pytest
diff --git a/dev-python/pyghmi/Manifest b/dev-python/pyghmi/Manifest
index 84d46972ed3b..2501afc995e9 100644
--- a/dev-python/pyghmi/Manifest
+++ b/dev-python/pyghmi/Manifest
@@ -4,3 +4,4 @@ DIST pyghmi-1.5.38.tar.gz 241170 BLAKE2B f056fb985ca1281fc481bf9ccaa5a6c86a05655
 DIST pyghmi-1.5.39.tar.gz 241157 BLAKE2B f406ad0dd6ae2b45c34aae14738f10c86f0a62082f7da2ab75b8e01558a9c0a8aa4c123cca935a0f3f03f5ae92d799d283dd81155d3c31c886555184f69be2b7 SHA512 efbc603002870edbeb4944207521077f5c25ed080578d3008a542a0e65d3769fe1da7105ed15d85acc3931a126a440e64b6ff9d88f6f4a3b66a5cdabcbab3e4c
 DIST pyghmi-1.5.40.tar.gz 241230 BLAKE2B 265fc07c18fe17987340932d1b67bb631907a0b66832ca79794117ccff9bff99fcf9046f2d0911878b16b2b2e179fe05b0980e34ec9125895abeda1a7d04aca5 SHA512 3bf35fb68fa867689b3218963fc811a94d26072688eee5b1952d5694608d81b1fd6658bb335e96dac57513bff3ee8a10db83a79d6373a025a23c1ad0fba7b172
 DIST pyghmi-1.5.41.tar.gz 241325 BLAKE2B 40e69bea087c81b7375af96af65576eb4faacb0e52aba5bf9e719e4fe87bf9e320be79fdcfb7308e44a08e7da92d26ece8a483ba8489c04f0df0984300d94eab SHA512 80f859defc28c48c81deb4addb984d61a88eaa0fec1a9de8ab517001f16f8dabf6ce860142020f115158561e9cf75b4e8675fdd9aedeb7d9bd0ae3f38115e912
+DIST pyghmi-1.5.42.tar.gz 241338 BLAKE2B f005697a13517f707bc74132d54ebdcc3752409aa147fdc9e99143f1c6a0507e24725e8bc2bc07980e017e6c6fff9868f84bf02fb598a2b580531aba0b66eafc SHA512 ec191a9862a4e6f28a8dbcb54759ad5c3a81ca3f85ecd4c9bbad634a3392296d5aad49d809a099d2719f2235dee2fac962374a4109dee120a4aba521a589afd5
diff --git a/dev-python/pyghmi/pyghmi-1.5.42.ebuild b/dev-python/pyghmi/pyghmi-1.5.42.ebuild
new file mode 100644
index 000000000000..06198e92f933
--- /dev/null
+++ b/dev-python/pyghmi/pyghmi-1.5.42.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A pure python implementation of IPMI protocol"
+HOMEPAGE="
+	https://opendev.org/x/pyghmi/
+	https://pypi.org/project/pyghmi/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-2.1[${PYTHON_USEDEP}]
+	dev-python/pbr[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.5[${PYTHON_USEDEP}]
+		>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/pytest-rerunfailures/pytest-rerunfailures-10.2-r1.ebuild b/dev-python/pytest-rerunfailures/pytest-rerunfailures-10.2-r1.ebuild
new file mode 100644
index 000000000000..8961af6ac951
--- /dev/null
+++ b/dev-python/pytest-rerunfailures/pytest-rerunfailures-10.2-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="pytest plugin to re-run tests to eliminate flaky failures"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-rerunfailures/
+	https://pypi.org/project/pytest-rerunfailures/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MPL-2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_rerunfailures
+	if has_version "dev-python/pytest-xdist[${PYTHON_USEDEP}]"; then
+		PYTEST_PLUGINS+=,xdist.plugin
+	fi
+	epytest
+}
diff --git a/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild b/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild
index 47b97da44a44..000f78506f36 100644
--- a/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild
+++ b/dev-python/python-betterproto/python-betterproto-2.0.0_beta4.ebuild
@@ -31,6 +31,7 @@ BDEPEND="
 	test? (
 		>=dev-python/black-19.3[${PYTHON_USEDEP}]
 		>=dev-python/isort-5.10.1[${PYTHON_USEDEP}]
+		>=dev-python/jinja-2.11.2[${PYTHON_USEDEP}]
 		>=dev-python/grpcio-tools-1.40.0[${PYTHON_USEDEP}]
 		>=dev-python/pytest-mock-3.1.1[${PYTHON_USEDEP}]
 		>=dev-python/pytest-asyncio-0.12.0[${PYTHON_USEDEP}]
@@ -50,4 +51,5 @@ pkg_postinst() {
 	optfeature "protoc compilation support" dev-python/black
 	optfeature "protoc compilation support" dev-python/isort
 	optfeature "protoc compilation support" dev-python/grpcio-tools
+	optfeature "protoc compilation support" dev-python/jinja
 }
diff --git a/dev-python/python-betterproto/python-betterproto-9999.ebuild b/dev-python/python-betterproto/python-betterproto-9999.ebuild
index 47b97da44a44..000f78506f36 100644
--- a/dev-python/python-betterproto/python-betterproto-9999.ebuild
+++ b/dev-python/python-betterproto/python-betterproto-9999.ebuild
@@ -31,6 +31,7 @@ BDEPEND="
 	test? (
 		>=dev-python/black-19.3[${PYTHON_USEDEP}]
 		>=dev-python/isort-5.10.1[${PYTHON_USEDEP}]
+		>=dev-python/jinja-2.11.2[${PYTHON_USEDEP}]
 		>=dev-python/grpcio-tools-1.40.0[${PYTHON_USEDEP}]
 		>=dev-python/pytest-mock-3.1.1[${PYTHON_USEDEP}]
 		>=dev-python/pytest-asyncio-0.12.0[${PYTHON_USEDEP}]
@@ -50,4 +51,5 @@ pkg_postinst() {
 	optfeature "protoc compilation support" dev-python/black
 	optfeature "protoc compilation support" dev-python/isort
 	optfeature "protoc compilation support" dev-python/grpcio-tools
+	optfeature "protoc compilation support" dev-python/jinja
 }
diff --git a/dev-python/readthedocs-sphinx-ext/Manifest b/dev-python/readthedocs-sphinx-ext/Manifest
index f8baeb212617..2be2e32a9a29 100644
--- a/dev-python/readthedocs-sphinx-ext/Manifest
+++ b/dev-python/readthedocs-sphinx-ext/Manifest
@@ -1 +1,2 @@
 DIST readthedocs-sphinx-ext-2.1.5.tar.gz 12351 BLAKE2B 5cb3e821b04dabb492cac194ec3be4cdf5874811d8e57556c653611d4a1e2d57a38c00492662d1530f25f15a011834a7966af4c58b9f8f8fe71559753cf3d79d SHA512 0d2960ca55bf9be4faad0a8aa9cdcde74aaa69529b98be6059377ae037ce447d5919617fd8d4afb85ece6dc7f2693426e1a5574049025859e300211f7a5802fb
+DIST readthedocs-sphinx-ext-2.1.6.tar.gz 12343 BLAKE2B bbc1b80e18c1023ef498b7508b1acc400279042ec224bb5d51e60eef586ca2a95a740cddf4bf4a2f165c7012a521cff01196286ca21a51c5a0ffde03e2bdb70f SHA512 f9a4cffbd8939162c2a439e08f5f52a2313f00f42b3efecd4fa1431aa85aac205afcd04b5ecda089a4a239ef77e4f885a7cba9884219229b7c576f173bc52b14
diff --git a/dev-python/readthedocs-sphinx-ext/readthedocs-sphinx-ext-2.1.6.ebuild b/dev-python/readthedocs-sphinx-ext/readthedocs-sphinx-ext-2.1.6.ebuild
new file mode 100644
index 000000000000..f8fee9001171
--- /dev/null
+++ b/dev-python/readthedocs-sphinx-ext/readthedocs-sphinx-ext-2.1.6.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Code specific for Read the Docs and Sphinx"
+HOMEPAGE="
+	https://github.com/readthedocs/readthedocs-sphinx-ext/
+	https://pypi.org/project/readthedocs-sphinx-ext/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/jinja-2.9[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+PDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( ${PDEPEND} )
+"
+
+# unittest should be sufficient but tests are very verbose, so pytest's
+# output capture is most welcome
+distutils_enable_tests pytest
diff --git a/dev-python/twisted/twisted-22.1.0-r1.ebuild b/dev-python/twisted/twisted-22.1.0-r1.ebuild
index 2d41d7260181..9f8d7ed1960a 100644
--- a/dev-python/twisted/twisted-22.1.0-r1.ebuild
+++ b/dev-python/twisted/twisted-22.1.0-r1.ebuild
@@ -18,7 +18,7 @@ S=${WORKDIR}/${PN}-${P}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc ~x86"
+KEYWORDS="~alpha amd64 ~arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc ~x86"
 IUSE="conch crypt http2 serial test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/virtualenv/virtualenv-20.14.1-r1.ebuild b/dev-python/virtualenv/virtualenv-20.14.1-r1.ebuild
index 28e34315db38..d1df9021d54c 100644
--- a/dev-python/virtualenv/virtualenv-20.14.1-r1.ebuild
+++ b/dev-python/virtualenv/virtualenv-20.14.1-r1.ebuild
@@ -87,6 +87,11 @@ python_test() {
 		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
 		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
 	)
+	[[ ${EPYTHON} == python3.11 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		tests/unit/discovery/py_info/test_py_info.py::test_py_info_setuptools
+		tests/unit/discovery/py_info/test_py_info.py::test_custom_venv_install_scheme_is_prefered
+	)
 
 	epytest
 }