Adding metadata

51 files changed, 1089 insertions, 112 deletions

diff --git a/dev-python/Faker/Faker-13.14.0.ebuild b/dev-python/Faker/Faker-13.14.0.ebuild
deleted file mode 100644
index cfcce92aba99..000000000000
--- a/dev-python/Faker/Faker-13.14.0.ebuild
+++ /dev/null
@@ -1,34 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="A Python package that generates fake data for you"
-HOMEPAGE="
-	https://github.com/joke2k/faker/
-	https://pypi.org/project/Faker/
-"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
-	!dev-ruby/faker
-"
-BDEPEND="
-	test? (
-		dev-python/freezegun[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP},tiff]
-		dev-python/random2[${PYTHON_USEDEP}]
-		dev-python/validators[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
diff --git a/dev-python/Faker/Faker-13.15.0.ebuild b/dev-python/Faker/Faker-13.15.0.ebuild
deleted file mode 100644
index cfcce92aba99..000000000000
--- a/dev-python/Faker/Faker-13.15.0.ebuild
+++ /dev/null
@@ -1,34 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="A Python package that generates fake data for you"
-HOMEPAGE="
-	https://github.com/joke2k/faker/
-	https://pypi.org/project/Faker/
-"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
-	!dev-ruby/faker
-"
-BDEPEND="
-	test? (
-		dev-python/freezegun[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP},tiff]
-		dev-python/random2[${PYTHON_USEDEP}]
-		dev-python/validators[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
diff --git a/dev-python/Faker/Faker-13.15.1.ebuild b/dev-python/Faker/Faker-13.15.1.ebuild
deleted file mode 100644
index cfcce92aba99..000000000000
--- a/dev-python/Faker/Faker-13.15.1.ebuild
+++ /dev/null
@@ -1,34 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="A Python package that generates fake data for you"
-HOMEPAGE="
-	https://github.com/joke2k/faker/
-	https://pypi.org/project/Faker/
-"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
-	!dev-ruby/faker
-"
-BDEPEND="
-	test? (
-		dev-python/freezegun[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP},tiff]
-		dev-python/random2[${PYTHON_USEDEP}]
-		dev-python/validators[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
diff --git a/dev-python/Faker/Faker-13.13.0.ebuild b/dev-python/Faker/Faker-14.2.0.ebuild
index cfcce92aba99..cfcce92aba99 100644
--- a/dev-python/Faker/Faker-13.13.0.ebuild
+++ b/dev-python/Faker/Faker-14.2.0.ebuild
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index b996488a0d97..759c57d09e8c 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,6 +1,3 @@
-DIST Faker-13.13.0.tar.gz 1528907 BLAKE2B be4593ba271330822f10590aa8e15c4658cd8a19333ab769d32178b72c15b504b8a5269443100250a863af25e40c582244e815cf612dbf8a57833f470ddeec09 SHA512 9e794bf95d40040dfa98439d0d9da19a90dd202905d4825c82453e202adad80bbea6da74ce0d36d8e205381d419a19b8b1fb60b32e20e97ee69b315f4f0c8eb9
-DIST Faker-13.14.0.tar.gz 1529502 BLAKE2B 57c5182742f4383bc0590f953dbf8de7075b331da8d9893b84149ce8d3004e545acccf9f113d94eb608b634d9ad42a466d813c5f0311e037d8977fa04eaf36af SHA512 05edbad684a89b0cb4df4965be63b43729047075eed98de9678d98383b28d2ae6d3c645c03ab86d7bc935160c1ab744494d608749213322e318b465c0d47e9c7
-DIST Faker-13.15.0.tar.gz 1531111 BLAKE2B b6e91f7e47f5040894647b53eff92ddc8384fe9edfe19aa4d3706c2d5e54100d171b37609968bba068c89d9c946f92b5966b9e8f502863ab3730d9857a342853 SHA512 6de6de872e19f82a716fdf10f594e3d77b160bde46e7c8d20610621728ee3e555b4090835dba220da96d98db5eaac8c0e4290786441441f220b7458f442b99f3
-DIST Faker-13.15.1.tar.gz 1531442 BLAKE2B 890bcf69ebcb97f8d7441e7b899ed0fec851b5f291a03606e3a3cb6dc8838522fed839b77fd6899122347fa3c8cef14c0a0f6f1039b66331ab2263bc4675d378 SHA512 e405ee0cf1aed0b3c01f60bf10f5e72c6b55977deb9b004875dbb5eb5cd24da1b979cfa9234be30946a640ab21fc1d95393c15e2bf839bef373978959f7eb784
 DIST Faker-14.0.0.tar.gz 1536015 BLAKE2B e3d0f5745203ac441bb4f4a4deb4ebc9045f532b3b0801e8d6904bd0e68bc2fff9edc9a78492051c9d7938121ff74d307764ef5be266d3c0afe4f1212c52968e SHA512 7b0a2558e050cdaddb796bdcec458a3b43eea605f8e8a74e2949870fbc5e0ccf11cf7ae7f1ed01629038a2125d853e26a8543479f1b7f7637e02a1e3af5c577b
 DIST Faker-14.1.0.tar.gz 1598360 BLAKE2B 953dfd718b143e493ca2129f69ada12b6d5e5e3b04b5e2ebeedbd57855da1f8d7cb3bda3dfa1050debce4281d605ac4c10d74538422c5da41e72caaf10c2b2ad SHA512 50d0452d946e3899813ea1aa0b207451fc765e1ee3cc2196b13eb095a91a888e825064b63651b610240fe9e90158a318fca80dbcdbb7b5a70568bafa7653fb67
+DIST Faker-14.2.0.tar.gz 1599246 BLAKE2B ec618ac03fe68dae72b9cc0a4a42390157ea669151756c2c8dc722a0de19d2c1a2207d318b4ac270d1aeefab298445cb92e43e4ab1d524d80e8bb1600c71b71f SHA512 cebeecd78635bcbf18d8332cdfcb28d65214b06d01b6f4b4e95fed37f03d1a32b8fa2b1e0c8ccaa2a34fbbda805a58dfde8d4f84391a791f95177cf8bca9ba5b
diff --git a/dev-python/black/Manifest b/dev-python/black/Manifest
index 72e1f49e703b..d647b8433833 100644
--- a/dev-python/black/Manifest
+++ b/dev-python/black/Manifest
@@ -1,3 +1,4 @@
 DIST black-22.1.0.tar.gz 1161720 BLAKE2B d74cbdd39dc1576583cee57089cb6d75a338f2d6640697adda79d38d02eeb51664049dca934d5014761d0fd4080ca2f40a3ea10c30e40bde9fe6af6c178b202c SHA512 9b97a3b32ecebebeb61ea581784a9b2215540c20533097fe87d5ef3c046dbe7c2ab8f2f21d1884cbe0ddd458434f17eb9b540764f955385873e6fdef86c3014c
 DIST black-22.3.0.tar.gz 1154456 BLAKE2B c89b43722839748dff0ce60debb684cd8eeae5ef5fb7e080f6b0031412381d7be121ce62ad252a67fa7930726243680a4bf183417611617be5af39722164289d SHA512 fc44576b93a6e158f625ad5444247f6a59a1ebcc7f0c73ed40d557a9a865457b297eabd492f01999e51ee3e5c3fa83f3d6e3c10937ecaa8c1d36f7541736d2e4
 DIST black-22.6.0.gh.tar.gz 1165070 BLAKE2B ce2eef529e230954a13913063dbb9000fa13f4debb2e5ed33605e8efe5c6d62fc1b3c0b7847c26ad931b9becae43fa23b15701a1672c1e056f729810020cc282 SHA512 72e4b4dfc69436e4dbee5a75ea72a1be69a26dc37a5e4d7edfb84d62736f0e0aba8d14420f3069798b568bd8ba916e8850f0c958afc9b6134ee8832e54d3dc4c
+DIST black-22.8.0.gh.tar.gz 1173503 BLAKE2B 851e2dedf35871dc07caaafbffa15aa91e18640a352df717e19dc98b48134af21343e36faf90899fedd700149f988f5385c18c2d01ca330ef6e7a721cbe41a38 SHA512 f9db2079aedb14a8d9388a2c0997ffd55c74636d487ef7a3ad86fcd038a3e5d3f63168a1bca266b3e3128cd8590a641bd4259be9c238a8df968c3c085682d3b6
diff --git a/dev-python/black/black-22.8.0.ebuild b/dev-python/black/black-22.8.0.ebuild
new file mode 100644
index 000000000000..8e51b7ba2e42
--- /dev/null
+++ b/dev-python/black/black-22.8.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="
+	https://black.readthedocs.io/en/stable/
+	https://github.com/psf/black/
+	https://pypi.org/project/black/
+"
+SRC_URI="
+	https://github.com/psf/black/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-3.10.0.0[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-6.3.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/aiohttp-3.7.4[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" "dev-python/aiohttp dev-python/aiohttp-cors"
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 6a149978ac92..12c9b29b23aa 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.24.56.gh.tar.gz 529533 BLAKE2B 7d41281f9cc645e8ca83a71e6eabf1d54373208488cc14bd723b32f56a4e2e1d3b4fa407ab495a9409ae9635f1dc2b7ce2fdebc9bfd1c263e0d9b29d5925daec SHA512 ffc86fbf45fa1264f26474115edcee3f62abc93e0a23fd7ca800c1995924e4cf71e84f852d28217863427061646d1ffd9e24d68d1c531d8b480d126e449f76f0
 DIST boto3-1.24.61.gh.tar.gz 531957 BLAKE2B b8cff8dea6b74ce1238a734cf1e2fb41ede27243216bf6c5b0e0d99a43948a6dc6999fe3ff0a13616b3a4ba0e1c675963faef5a299b9c1a86e3713eee9f07741 SHA512 7d957b9c9a120698fb2f7d1368500e456ea5e7834e4fc09c1680333b16056f089eea60480e50919c1dcc4596c72e43a74f6b57d433ed01f1ef53c7804b6dc2dc
 DIST boto3-1.24.63.gh.tar.gz 533004 BLAKE2B f678fbea81cf1be2f28d2463fbf50ff841d0a2c027f2f80cb99364b686aa8b72cd02345e6f8532e2d3b2b6c4a676f50640e1c3d3fc50d53a1aa549d90b8f7bc0 SHA512 771b3911180df5bc85b0ee1a4b8762bf387a1f55f37501b8b10bb3971e5cfb91fb072c4f9ea405d16b6351b1d34c8dce6e9564dfabd2414f6162ca8cc5ba3bc9
+DIST boto3-1.24.64.gh.tar.gz 533638 BLAKE2B 1cf4774e17226b453aec3203eea6f343e0921f0ec95669a13788303176da571d467fdf6d558201b449a426e450bfd932b0a79f773f029495e3be6451c07ab9f9 SHA512 6d844b57cf751ff40ad7efa3b4f1f2ec3f00aca2cdf43524a30282a4347f52e1e7cb7762085740b9c3d5e16331b5a1b6b1e2de09904f7d1fabde903c8f8258c3
diff --git a/dev-python/boto3/boto3-1.24.64.ebuild b/dev-python/boto3/boto3-1.24.64.ebuild
new file mode 100644
index 000000000000..e4a98e2e28f5
--- /dev/null
+++ b/dev-python/boto3/boto3-1.24.64.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 6b4cc8d7a8b3..59ee3e019a3f 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.27.56.gh.tar.gz 9545974 BLAKE2B 514c859f854aed83c3bb13ed3eab9999840d61e6f36e2c860f272f0fafde110d83da93f2843c419c577d0a8c737835c069438d322fc95581bb7c292ed16639a5 SHA512 c0bdeeb9254c5528034058932050874a0e40aee220f2d67a93c163e645e32badeae6517da23f69cf10452d5ed33a23188204bcdac385e43303882601e6e45922
 DIST botocore-1.27.61.gh.tar.gz 9575336 BLAKE2B bbc2bb49ee84293d9d7d9f0cc3da70a141778bd68ecc45117a9e99bd8ceba7576b52ed0d5381b085c6a7ae32195a6709e76144f27681cd8d07338ed404b1b236 SHA512 1e1ce615a2b02bab2587bb475e783d197cf27496cb1c0c1b06c51453e545ed293b1fab555f23a67246a4a5babb6c5d12fafee2d6f8b997d168e43f62a5e16bfd
 DIST botocore-1.27.63.gh.tar.gz 9581263 BLAKE2B 3b225160fe0095aa77754c874ceff558c56f547e0454a67fd13c8f093abbef975ff5cf878576b4b6235b1783aaae2278d05026b29d41a95e6168928b035cd1fb SHA512 b3698a0d5ea2e63de3fe94441a1781034d24c0ae5ff06a427ac55eb2cdd05bf917b01fcd9e1bbd389a1d4ac6b625d534b37c1d6c8c72b23670b66d892d5fe6da
+DIST botocore-1.27.64.gh.tar.gz 9588817 BLAKE2B 2479d7f6565a78baf7b9504bfdbba74f486b37968bf5074fc1eac150bcf410bd64d23fe47c1a057a38a94c8b4d29bf393613fa739c6c2007e5f523852ae02a24 SHA512 40e689b86997961c149877dc896281f722d09c2ab95149f4a40e98cd55a4a35ce77da5ff793f53801609b9084879ce2af8679771bd6bde2305c9cb27a1360e74
diff --git a/dev-python/botocore/botocore-1.27.64.ebuild b/dev-python/botocore/botocore-1.27.64.ebuild
new file mode 100644
index 000000000000..ba4830d69cb3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.27.64.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/django-configurations/Manifest b/dev-python/django-configurations/Manifest
index ab7809eb6eca..1fee3c094acf 100644
--- a/dev-python/django-configurations/Manifest
+++ b/dev-python/django-configurations/Manifest
@@ -1 +1,2 @@
 DIST django-configurations-2.3.2.gh.tar.gz 38475 BLAKE2B 2b3c583e665a08a46bc0ca0c52ae4326fbdfb794d102deecbd13f953e8b6f3fd39b3b747c591fc9717c6a0792258cdb9041de53e71db2034de1a31ddf5bfc0ea SHA512 4cb5a7b284a0025ba93b32e158fb65b57e66230938181b921a1b1264848113b697eb45ac6ad2fc4f26f3bc29ea5f77acbfd5307b20ef2d385e29c2c1746295b3
+DIST django-configurations-2.4.gh.tar.gz 38563 BLAKE2B a454cc492354c1b969a1b0389ccb21088e99af17b5056ae514b36b5c2fd7391368437093d1a075814dfb8e15ec8ce3ec3c5269d5c867b4a03a5269a533826a31 SHA512 de9793c5fce869ef77e4396dd5ea45fc57728d702383885599d3a08b16e37e0e425258aacd671ac78592df813c8fa3a08b33ad9410843f7d7976589da33592ca
diff --git a/dev-python/django-configurations/django-configurations-2.4.ebuild b/dev-python/django-configurations/django-configurations-2.4.ebuild
new file mode 100644
index 000000000000..b9891282be9c
--- /dev/null
+++ b/dev-python/django-configurations/django-configurations-2.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A helper for organizing Django settings"
+HOMEPAGE="
+	https://pypi.org/project/django-configurations/
+	https://github.com/jazzband/django-configurations/
+	https://django-configurations.readthedocs.io/
+"
+SRC_URI="
+	https://github.com/jazzband/django-configurations/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/django-cache-url[${PYTHON_USEDEP}]
+		dev-python/dj-database-url[${PYTHON_USEDEP}]
+		dev-python/dj-email-url[${PYTHON_USEDEP}]
+		dev-python/dj-search-url[${PYTHON_USEDEP}]
+	)
+"
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.settings.main
+	local -x DJANGO_CONFIGURATION=Test
+	PYTHONPATH=. django-cadmin test -v2 || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/fritzconnection/Manifest b/dev-python/fritzconnection/Manifest
index 55da5d2101b4..6d24c3bd27c1 100644
--- a/dev-python/fritzconnection/Manifest
+++ b/dev-python/fritzconnection/Manifest
@@ -1,2 +1,3 @@
 DIST fritzconnection-1.10.0.gh.tar.gz 146309 BLAKE2B 64b01a561a015fae10dc3aced2576afce5d27555aba019028de32d5dc0ee9099f4248d900ac1de0f18321d52537dd7b77ff010ce44ca863ef9b5c5e228c61071 SHA512 86acce864624f67fdbd407157565cec434d029907b4d295a3e5e1bb41d8856ca1eae99681fd3c44033c6bcef8ecc594483f734e08c4fb733e685c01147dd3c29
+DIST fritzconnection-1.10.1.gh.tar.gz 146297 BLAKE2B bbb8601d3c5f9f379275dae8e293385f9c4dca44eb9e74b22f12cd4e89a50a3dd2c8220aa0e28408f3f136192c43a5d4bc37347e047caed42f889cc303b02f52 SHA512 fd860a563eeefba374ccc8d2ab8319dd07b6c02c12fd9b7ff00353d86b041757fded308f5a0859cee8d190c5c51b5308290eb656e77ed8e3882ee482568cd677
 DIST fritzconnection-1.9.1.gh.tar.gz 79580 BLAKE2B 6972c92aabb9c516e2b4d3d18bea2daf8002a12c9939a5badd1ceb8f7539a243f99778a3ded0cd057850b54e9cb2a0ca9d2c31be688eaf81f4b279b74d10fc55 SHA512 55642cf1db581c62091d63fdfa9bf4fe36c545df686eae7d0f886b4ef8c186668e6f8fb7bc7786e13936764ea771e0dba79e62b57f19348dd562bf23a27d6369
diff --git a/dev-python/fritzconnection/fritzconnection-1.10.1.ebuild b/dev-python/fritzconnection/fritzconnection-1.10.1.ebuild
new file mode 100644
index 000000000000..d3d39df875cf
--- /dev/null
+++ b/dev-python/fritzconnection/fritzconnection-1.10.1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Lib/tool to communicate with AVM FRITZ! devices using TR-064 protocol over UPnP"
+HOMEPAGE="https://github.com/kbr/fritzconnection"
+LICENSE="MIT"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/kbr/fritzconnection"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/kbr/fritzconnection/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+RDEPEND=">=dev-python/requests-2.22[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/fsspec/Manifest b/dev-python/fsspec/Manifest
index 0a97cead7eae..7eaf3477868f 100644
--- a/dev-python/fsspec/Manifest
+++ b/dev-python/fsspec/Manifest
@@ -1,3 +1,4 @@
 DIST filesystem_spec-2022.7.1.gh.tar.gz 338526 BLAKE2B ef19c41a4e9fe3fb1a5146967bab505c26590aa4c074152523b705d8cac5eeb6e30834e1adbbb1669f5bbb58891cabd3960208cdfa9f619e0bbc5cbfe5f4ef55 SHA512 07178bf22e07091935256296b303e273c03e2ddc15a5aa1110f84c27cadaf9c650204e37c472cb10280e92f24b01fa8b16fe32db21a30d14d232c5a11e05a45c
 DIST filesystem_spec-2022.8.0.gh.tar.gz 338839 BLAKE2B 6d70e20a435caab098db2437137fcd80efdcb08ff3018daf5c72ceb958fcca354eb6a12a525ea023fd042cf54099fe991a444c3627989bc3f0e38bddd8d57aca SHA512 843ee51d7dec362623ebe584def6bb7c8b5521434befd89bba178969bb9fbe53b9b488f0f8d301d600fe2f97e876a6b74f92c9d0e9b8941aaa70f5514e6516ee
 DIST filesystem_spec-2022.8.1.gh.tar.gz 338463 BLAKE2B e155dfecf1d9cae7f436f9387e9c1e822205f74a7b7484089fa1a7567d1293d699ba4a3ef8f9453720a22fbc41dedfed0455da64a46b7458c7b39d2a5d4f8c29 SHA512 ab37ba926ea834fa2938e851e2f273c624400165b097642ba2b103a126b8d8cdc9acf7a5683ad2fa5df24dbe3c1ec2b228683b8c3489af917b13729f8bef0c0b
+DIST filesystem_spec-2022.8.2.gh.tar.gz 338456 BLAKE2B 79208de0f7c694f9e247a0d4589d439fd80f07a893df9dbaeeb1ec01bb1dfe2ba6c73f70fa60e5109cf076aa104cef81ab247fc26172be2b0317a108f5aae75f SHA512 2d288ace6469af4a90475f33f2a662ab2696b3c974539b7f41c3fc86699c9d3da8f1cfdff7be2a228d8c7eda02c1ca6558690cdeab0847b007235d2b866f3c2a
diff --git a/dev-python/fsspec/fsspec-2022.8.2.ebuild b/dev-python/fsspec/fsspec-2022.8.2.ebuild
new file mode 100644
index 000000000000..e6bba4b5cfd5
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2022.8.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=filesystem_spec-${PV}
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="
+	https://github.com/fsspec/filesystem_spec/
+	https://pypi.org/project/fsspec/
+"
+SRC_URI="
+	https://github.com/fsspec/filesystem_spec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+EPYTEST_DESELECT=(
+	fsspec/tests/test_spec.py::test_find
+)
+
+EPYTEST_IGNORE=(
+	# sftp and smb require server started via docker
+	fsspec/implementations/tests/test_dbfs.py
+	fsspec/implementations/tests/test_sftp.py
+	fsspec/implementations/tests/test_smb.py
+	# unhappy about dev-python/fuse-python (?)
+	fsspec/tests/test_fuse.py
+)
diff --git a/dev-python/keyring/Manifest b/dev-python/keyring/Manifest
index b7a93d52a8ae..e059a4779a9b 100644
--- a/dev-python/keyring/Manifest
+++ b/dev-python/keyring/Manifest
@@ -1,3 +1,4 @@
 DIST keyring-23.7.0.gh.tar.gz 45352 BLAKE2B 8cad2f2c7443adf710220d546a080c4ca106c9939f5a91ef56cd6f034cf71fcb86515005f17adf3ffc35ab616ed722e469ae0c92040d57d4183d6a4ced6a2682 SHA512 351afb3e376350192d5b02f2cb9bdf4bc28d551e4184145bd05ba7fd0c950c7cfeae0f75ed63bfed670648e2b7d2f491b894939d37edbdb0869d4cb74a4fc97e
 DIST keyring-23.8.0.gh.tar.gz 45941 BLAKE2B db78b53e2d2964c65d850df4226954db696037fa220f003d91e94603ce12b4d3668b7b53a91b71244d8555ba9c9195309a2e8a9aafd88d12da0f1a916b469857 SHA512 daa0b88b9f7c6e94eb589c15f364ff2a0fb83cead50b4fcafa6214072681d4346c8abe7ee8ab76f0ab93b7c7bccc551f65912dbfa749256e226f1e84793676dc
 DIST keyring-23.8.2.gh.tar.gz 45987 BLAKE2B 3a8faf6487c2d4dd76e549585a236e4744e5a4d23a778515425e7e78c7161717c2d16b8f268fbc8b8c59d6fb3fb39fc789b0dd92363b6d61073047af8d99b804 SHA512 af5c764d355c548d1f1364006dbaf6ee366a7dbbda9649145dafa5d610a4691ab4488151c054359e26a467312653601ddf722bddf35deae309067355337eddec
+DIST keyring-23.9.0.gh.tar.gz 46610 BLAKE2B 31581974d40d4fd0febd576db3967f29a09e9d9251c59fa2d0198cb80f3ec49d043fdde4002f3893cffce6936f4e9e2186457f870ba97e65a22c70a2741e17d3 SHA512 c8432d61ef94a56cd3aafa3f766cc1488585cadbea757eb63ba3d73a0b373ac949a27edba4b282ffb8629fcd9a3a6c0b0acea90dd377bf3f2fe5a290b82e4b44
diff --git a/dev-python/keyring/keyring-23.9.0.ebuild b/dev-python/keyring/keyring-23.9.0.ebuild
new file mode 100644
index 000000000000..506352eae9f4
--- /dev/null
+++ b/dev-python/keyring/keyring-23.9.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="
+	https://github.com/jaraco/keyring/
+	https://pypi.org/project/keyring/
+"
+SRC_URI="
+	https://github.com/jaraco/keyring/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+SLOT="0"
+LICENSE="PSF-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/secretstorage-3.2[${PYTHON_USEDEP}]
+	>=dev-python/jeepney-0.4.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-3.6[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+EPYTEST_DESELECT=(
+	# this test fails if importlib-metadata returns more than one
+	# entry, i.e. when keyring is installed already
+	tests/test_packaging.py::test_entry_point
+)
+
+EPYTEST_IGNORE=(
+	# apparently does not unlock the keyring properly
+	tests/backends/test_libsecret.py
+	# hangs
+	tests/backends/test_kwallet.py
+)
diff --git a/dev-python/libvirt-python/Manifest b/dev-python/libvirt-python/Manifest
index 95cd7e51cc42..25fa524e0841 100644
--- a/dev-python/libvirt-python/Manifest
+++ b/dev-python/libvirt-python/Manifest
@@ -14,3 +14,5 @@ DIST libvirt-python-8.4.0.tar.gz 231985 BLAKE2B 64d37074e04cdb02332987dc46e6dd7b
 DIST libvirt-python-8.4.0.tar.gz.asc 833 BLAKE2B fa6f5e10ca3e06c017e9988e676dd2beca2bcb88f4d55d7a1740d42b4ea56ff0cdb4fd7698392ce1eead7a81fafcc1475eb6270329f56e191a4a4551120e982b SHA512 855869856ff41338c4ed1b707db4a0ace97a60e51d19183a0c1f904695b8a367249ae6266a45d79449443325cc85485db89dc73b09ac318c206cc03ab36ef179
 DIST libvirt-python-8.5.0.tar.gz 235414 BLAKE2B 616c8415f94a6c53b9bcd6ff7433993a3d40eb49ff13eaf81eee52c52806fb1d281216e8bd591deeee6058e2cb5161310d0ae1217467cd1f0525c00d7252214d SHA512 0e922301243200229c01659e57b4abad69a85931ea3ffcb70b117f313971d266d036dc6c1dbe42d48380d5ad9ed72326603101eb33d6a68dd6b7253a6e197aff
 DIST libvirt-python-8.5.0.tar.gz.asc 833 BLAKE2B 5b3c37ee02d6a5cefcc81945b9f4c67f19d297f03ad16e2666e87c3ea54ac609d774d3bb90a47e4098914460fd0928f66641f52185fe367cad9794636a809836 SHA512 4fae1d23f7ef2fccb38dee397173f3571b64969672cbe297e3622b9a0194e4a434329de543e886a4a20a9e1e0e3f1fec10a08d924ec0e728b9e29a44877c7e24
+DIST libvirt-python-8.7.0.tar.gz 236343 BLAKE2B 563cd1a18f06c0210465905267c46b3e5c598a9dcb208f468660d40988a4f6d80e61feed3702d830d465769eebb2c4d6604ef9449700923795c0485c36e38680 SHA512 f7883964875657a11c6756e31fda59eadba8394b71dda04df366aac85b163f3ffb379054bace38922d10d0b8972d1e1210d1513498cfd5cd8f0b76d6985ee945
+DIST libvirt-python-8.7.0.tar.gz.asc 833 BLAKE2B 5386780d75114c21105d012fd0ec2fd22fdd979dd6cdaea59f578eff4c0616e377da52d8aec05f337b837fda663ce8afb6d670e960ee65146679cd8c9a60b12b SHA512 499324c7cb520edbd1778a16434de43be062545255abb271832a636ff1ce9f4ba87e90226a181e081d084fccd6c190acc15763fecfc89e80093845589c12f535
diff --git a/dev-python/libvirt-python/libvirt-python-8.7.0.ebuild b/dev-python/libvirt-python/libvirt-python-8.7.0.ebuild
new file mode 100644
index 000000000000..1e4b92098d8b
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-8.7.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+MY_P="${P/_rc/-rc}"
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/libvirt.org.asc
+inherit distutils-r1 verify-sig
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt-python.git"
+	RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+	SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz
+		verify-sig? ( https://libvirt.org/sources/python/${MY_P}.tar.gz.asc )"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	verify-sig? ( sec-keys/openpgp-keys-libvirt )
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/nbclient/Manifest b/dev-python/nbclient/Manifest
index d2413da27530..d66140a4798e 100644
--- a/dev-python/nbclient/Manifest
+++ b/dev-python/nbclient/Manifest
@@ -1 +1,2 @@
 DIST nbclient-0.6.6.gh.tar.gz 78247 BLAKE2B 06793fe792dcb8606d74e85a7a5c4d8f3ba850f81191bf205706e404e67bfe3d6914dff5790c5d6dca62d7797482518b5d87b06da34f06a5cb44a8a0ff6855e4 SHA512 8ca0333a47920994d8afe7c8943b366d4669e7ad91daab1a36c57480b70e51dfd05c7cd44acd2a2005b8c0a6b41c4fe6be0fc22b75a3efe291e9c35dd334643c
+DIST nbclient-0.6.7.gh.tar.gz 78345 BLAKE2B dba9c98ab7d0b65470268dabc5d7dbee65e9c800252e61de6e9fe28a59a2da5c9b2046b7835468a8807445bb657152071cad7a28c717049d5762c13634175e34 SHA512 67fc7a6685df783a0d3af728e18ad2ff7a46d17c66a8e23f651a4d329896ee84d7dda8fcc62c94e277a742c74fe51b9f15f415add747a346ddf3d29056382f23
diff --git a/dev-python/nbclient/nbclient-0.6.7.ebuild b/dev-python/nbclient/nbclient-0.6.7.ebuild
new file mode 100644
index 000000000000..d813ead69722
--- /dev/null
+++ b/dev-python/nbclient/nbclient-0.6.7.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client library for executing Jupyter notebooks"
+HOMEPAGE="
+	https://nbclient.readthedocs.io/en/latest/
+	https://github.com/jupyter/nbclient/
+	https://pypi.org/project/nbclient/
+"
+SRC_URI="
+	https://github.com/jupyter/nbclient/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/jupyter_client-6.1.5[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.0[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		dev-python/xmltodict[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	'nbclient/tests/test_client.py::test_run_all_notebooks[Interrupt.ipynb-opts6]'
+)
diff --git a/dev-python/openapi-schema-validator/Manifest b/dev-python/openapi-schema-validator/Manifest
index 5300489e840f..c4d757e499ae 100644
--- a/dev-python/openapi-schema-validator/Manifest
+++ b/dev-python/openapi-schema-validator/Manifest
@@ -1,3 +1,4 @@
 DIST openapi-schema-validator-0.2.3.gh.tar.gz 25501 BLAKE2B d961cabca647f59d4d4188f1941ce5b2475e02520bcc10e7cd29817c8ea8ebaaac5af1ffb0e3d5079ed2d1493414cdaf55336744b142385754585e748af8ac98 SHA512 e6dfe3d6cc99fa9723102ced42040203157639be68b0438d7bfae4499e51cdb6257a36dca10425a5d5e692cebb958468ebeee722116b99d800a6fcf972400c66
 DIST openapi-schema-validator-0.3.0.gh.tar.gz 27083 BLAKE2B 288f5d18874625c69eccf9be6442258ff8af735795eac0ee0449e5976584b1af22c1ea771bb79b4fa68623e60d417b140737e0d1ee85791027393650f0c1f747 SHA512 003ea97a1cac598eb3728d96291d8be56c6ba9e2d3cd4f77c1258962f67b460a887f4473fed39587870583e13a83403623c3b2f96fa8d02345583cd3bdaf008b
 DIST openapi-schema-validator-0.3.1.gh.tar.gz 23232 BLAKE2B d02f9004d7baf96e76fb035e212efbdb773f1d7685c8b73107d887ad1cdf2496afd4232bd4fbb263597106b6a7e7d0eb7e6efbe64f422ca11ff228d5f2f51fdb SHA512 72564409e80c8dd8578ba2a363865623aa03b8b2324abd37bea31c503632a367bacf81d8de801579b80347906d2b24c14371c9b37b70176e0bf51ca8c6b9e071
+DIST openapi-schema-validator-0.3.3.gh.tar.gz 16389 BLAKE2B af700555fd3a21e85cd7205dc549c305c5830bf8b3d3e36f8755153a12e0e6cd8db08cd75350760608db4f38774f369b51b239e47bb7dc6352a7559bf39ef02b SHA512 a621573f7d840bd6e8eb096a820a5ebdf4a07f186f2babda2128b34c66bd8249262d017cdeddec61d9984947666b73cb23a7ac419afd5ae892c14b7b754db57b
diff --git a/dev-python/openapi-schema-validator/openapi-schema-validator-0.3.3.ebuild b/dev-python/openapi-schema-validator/openapi-schema-validator-0.3.3.ebuild
new file mode 100644
index 000000000000..2c287cc8bd19
--- /dev/null
+++ b/dev-python/openapi-schema-validator/openapi-schema-validator-0.3.3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenAPI schema validation for Python"
+HOMEPAGE="
+	https://github.com/p1c2u/openapi-schema-validator/
+	https://pypi.org/project/openapi-schema-validator/
+"
+SRC_URI="
+	https://github.com/p1c2u/openapi-schema-validator/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/isodate[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.0.0[${PYTHON_USEDEP}]
+	dev-python/rfc3339-validator[${PYTHON_USEDEP}]
+	dev-python/strict-rfc3339[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e '/--cov/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 57107c34117d..e1f59029b2c1 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1,3 +1,4 @@
 DIST pikepdf-5.4.2.gh.tar.gz 2901145 BLAKE2B d7559901f59e5bd08ef660b88a4e9d50ac1bb64b397bcd56c1ed707ea7c0d9eca61d7ffe9e98361c01f3b71b640a9da1376c130fa5dff3324bbe2d64ce267347 SHA512 9afbd565ae82c65f743ffe7dc37509a15b03a1057bbdf4243ebacf4e0d315f9dead31fcd0f8b34023850a4d85aec302c229b1df0f045db4b1a8c171b58732b48
 DIST pikepdf-5.5.0.gh.tar.gz 2901781 BLAKE2B 8bc04627b781a65965c0679f2cccc8c7849d1f4e25008a50ee5965b4a4cb6c3c26f86d478a916228a37039a0fc062257cbf08db01e62ea877de208f7a64772e9 SHA512 61e802d52b3bce83ca1d0543a025e5390223bd856e1033a0df8ac63f457dc0b1473cf2c64965d857ceccde472d2d513fb335db6604c184cdcf2231129dfa5e38
 DIST pikepdf-5.6.0.gh.tar.gz 2904572 BLAKE2B c248eb44d7b093029dcc0b84be64bb361dab50eaf6ee91dc4a9d95dd645266243d44e2f2f96496d2ea3f2a92e7cbee5ec48a545f8e640e15fae87ff86c1ed973 SHA512 dd579c43c4e6186fa07b7e8bbdc8f65afc7b8b4063ae65eab2b0e986d7f2db38a0a71de73efad2a7d691af2d300f85076fc3ea61ed9c6b40265d53b4bdaa6133
+DIST pikepdf-5.6.1.gh.tar.gz 2905150 BLAKE2B 35c06251debb935b88f13e27f42f80b36275575d7848409bb19fa380be7429b785b8fea36e7d882a49df2e40e6c34fcc3d900b1b362f5ccf600780291f43d1f7 SHA512 add8edb16cba2081c479739ec215dc8c96a1896a159febb5bc2f74c2da1e8cf83b12a1302e1ad2ce8ab6fbf01a16104f8efb9c7a764fa1eedbc795dc45a71dfe
diff --git a/dev-python/pikepdf/pikepdf-5.6.1.ebuild b/dev-python/pikepdf/pikepdf-5.6.1.ebuild
new file mode 100644
index 000000000000..cea416014946
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-5.6.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/v${PV/_p/.post}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	>=app-text/qpdf-10.6.2:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecation[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-9[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.9.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.9.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-7.0.5[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e '/-n auto/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/psycopg/Manifest b/dev-python/psycopg/Manifest
index b7e2b0d57f26..79a4dc3be840 100644
--- a/dev-python/psycopg/Manifest
+++ b/dev-python/psycopg/Manifest
@@ -1,2 +1,3 @@
 DIST psycopg-3.0.16.gh.tar.gz 386693 BLAKE2B c6c0bd9832e65180e7de76b04ef7c81f4c2d0981894d090b933ce0efaaafdf6b62d1d71a4c70c7c9b848b67e576a71953116925f9e991a4ed99b53067e24cbba SHA512 655e01bb00972dacae590f2e8ce5948226acb827b55099e7f362fdee9210f07b755f4da10d2fadd468aa95eaa3f72e7658a1ab26870d4ac159ee266ce1f8140c
+DIST psycopg-3.1.gh.tar.gz 463892 BLAKE2B 94100bed4807771f6c4d0469737b160955f3f6bfcff84240c9e15dd9b7b88765583952b712642740c97f6ec42223edcf74fb2c5390a185f44ca0eb8858e76100 SHA512 057a14d614ccb9f36a7db7a82c3d48953658a1c6af2a2265a93a3f6c1db421275e51e1be4d59e2ea98b638f3da8c24c9d2a4d9aabf6190c47691dd632c9339f9
 DIST psycopg2-2.9.3.tar.gz 380611 BLAKE2B 78099da7378dcfa8b7f28aae4d533a7e890cdb7ae4c0cc718a9411e630fd07b56f074760fc29de8fe08fe727328cca39414a5f297fb92ed2f7471a24e633d18d SHA512 048184d1d162a371fc0fba711448a6fa8a6aac193421f4484c7f7b91c39065d5b632fa34fc15a901eca055d597302b1f9e38330b248ed0e4653dcdc544b0d660
diff --git a/dev-python/psycopg/psycopg-3.1.ebuild b/dev-python/psycopg/psycopg-3.1.ebuild
new file mode 100644
index 000000000000..e2ea7d3f0728
--- /dev/null
+++ b/dev-python/psycopg/psycopg-3.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="PostgreSQL database adapter for Python"
+HOMEPAGE="
+	https://www.psycopg.org/psycopg3/
+	https://github.com/psycopg/psycopg/
+	https://pypi.org/project/psycopg/
+"
+SRC_URI="
+	https://github.com/psycopg/psycopg/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${P}/psycopg
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+
+DEPEND="
+	>=dev-db/postgresql-8.1:*
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/backports-zoneinfo-0.2.0[${PYTHON_USEDEP}]
+	' 3.8)
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-db/postgresql-8.1[server]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/dnspython[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# tests for the psycopg_pool package
+	tests/pool
+	# some broken mypy magic
+	tests/test_module.py::test_version
+	tests/test_module.py::test_version_c
+	tests/test_typing.py
+	tests/crdb/test_typing.py
+	# TODO, relying on undefined ordering in Python?
+	tests/test_dns_srv.py::test_srv
+)
+
+src_test() {
+	# tests are lurking in top-level directory
+	cd .. || die
+
+	initdb -D "${T}"/pgsql || die
+	# TODO: random port
+	pg_ctl -w -D "${T}"/pgsql start \
+		-o "-h '' -k '${T}'" || die
+	createdb -h "${T}" test || die
+
+	local -x PSYCOPG_TEST_DSN="host=${T} dbname=test"
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${T}"/pgsql stop || die
+}
diff --git a/dev-python/pyphen/Manifest b/dev-python/pyphen/Manifest
index f90e01c84bcd..cb07a67ab4d0 100644
--- a/dev-python/pyphen/Manifest
+++ b/dev-python/pyphen/Manifest
@@ -1 +1,2 @@
 DIST Pyphen-0.12.0.tar.gz 1969022 BLAKE2B 9b7f6712a2085507684ddde52401a75b05d0a13a530572f0f08b9143168a8ea61a5ee73983606b19f88ff23f3c5344aa87722c3986291c7349f82e95dd3b1f19 SHA512 abecf0773f59b7a757b47c6512f1bf8e98f4709b285f04cf235c085ab4767eb95deab8ede4b792d6f4a6156d47287f9f712cb658939ed5afc475644e282adbd3
+DIST pyphen-0.13.0.gh.tar.gz 1976723 BLAKE2B 2a2934cabf13f1b77477d131622cd2f03c342557bdfe3b2f7cfbbf31c4538850e021e074798d80300f87b2557f87cbf3bbeafd01da03b38a7036609e61e140ec SHA512 67897cec0b213a755af53ac21c61ddc1ac573a724658543174c3f88adb5f3db367fecf3afb1e7035c0d5b87e624daa2fe7650cb6e44c63d3b9ef6962bbc5d9e2
diff --git a/dev-python/pyphen/pyphen-0.13.0.ebuild b/dev-python/pyphen/pyphen-0.13.0.ebuild
new file mode 100644
index 000000000000..e4e9571cc492
--- /dev/null
+++ b/dev-python/pyphen/pyphen-0.13.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python module for hyphenation using hunspell dictionaries"
+HOMEPAGE="https://github.com/Kozea/Pyphen"
+SRC_URI="https://github.com/Kozea/Pyphen/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S=${WORKDIR}/${P^}
+
+LICENSE="GPL-2+ LGPL-2+ MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# avoid dep on extra plugins
+	sed -e '/addopts/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pyside2-tools/pyside2-tools-5.15.5.ebuild b/dev-python/pyside2-tools/pyside2-tools-5.15.5.ebuild
index 13005dc87ae4..6dc8006b4236 100644
--- a/dev-python/pyside2-tools/pyside2-tools-5.15.5.ebuild
+++ b/dev-python/pyside2-tools/pyside2-tools-5.15.5.ebuild
@@ -19,7 +19,7 @@ S="${WORKDIR}/${MY_P}/sources/${PN}"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 arm64 ~x86"
+KEYWORDS="amd64 arm64 ~x86"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="${PYTHON_DEPS}
diff --git a/dev-python/pyside2/pyside2-5.15.5.ebuild b/dev-python/pyside2/pyside2-5.15.5.ebuild
index b3a31e7b9e2b..4c6984d8e1e0 100644
--- a/dev-python/pyside2/pyside2-5.15.5.ebuild
+++ b/dev-python/pyside2/pyside2-5.15.5.ebuild
@@ -37,7 +37,7 @@ S="${WORKDIR}/${MY_P}/sources/pyside2"
 # x11extras (for X)
 LICENSE="|| ( GPL-2 GPL-3+ LGPL-3 )"
 SLOT="0"
-KEYWORDS="~amd64 ~arm arm64 ~x86"
+KEYWORDS="amd64 ~arm arm64 ~x86"
 IUSE="
 	3d charts +concurrent datavis designer gles2-only +gui help location
 	multimedia +network positioning +printsupport qml quick script scripttools
diff --git a/dev-python/pytest-localserver/Manifest b/dev-python/pytest-localserver/Manifest
index 3e408fc2d500..84e9d27fb3e7 100644
--- a/dev-python/pytest-localserver/Manifest
+++ b/dev-python/pytest-localserver/Manifest
@@ -1 +1,2 @@
 DIST pytest-localserver-0.6.0.tar.gz 182346 BLAKE2B b8f56c6db3bc9c260c747cdf707aac0de22152111d3a8f9c0ea8adb8e5e556edf4a1ffa0d4fd517bf95428c69ebc0c1629a103c3b8f44a57b939f696cb9240cd SHA512 149796393af260fa5d69560852e9d11b569515b8486859302af2ed369a93bbb7cad11f54210851bd4030d8f7f5936a0306fe9599bc8477bdfc61d3d0a83cb205
+DIST pytest-localserver-0.7.0.tar.gz 184154 BLAKE2B 31f05dd4f156c8a547dacaf39c1aa1a576f2f84e625d64b96409212768a7d9967944931f85ab293d26f348e3a65eba1c5e341c6c08992271c10e65b2fa453cc4 SHA512 1fb1acaeb190d35ebd05cdd63ce15e4a9138802901cef8c25c1fa6dd177d8af2b6b2749f5a052942bf655ffd2ff6105de8a652d73faab369ce6dcf3219bb2394
diff --git a/dev-python/pytest-localserver/pytest-localserver-0.7.0.ebuild b/dev-python/pytest-localserver/pytest-localserver-0.7.0.ebuild
new file mode 100644
index 000000000000..290ef08a62fa
--- /dev/null
+++ b/dev-python/pytest-localserver/pytest-localserver-0.7.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Pytest plugin to test server connections locally"
+HOMEPAGE="https://pypi.org/project/pytest-localserver/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/werkzeug-0.10[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# requires aiosmtpd that is dead and broken beyond repair
+	tests/test_smtp.py
+)
+
+src_prepare() {
+	# remove aiosmtpd dep
+	sed -e '/aiosmtpd/d' -i setup.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/python-cinderclient/python-cinderclient-9.1.0.ebuild b/dev-python/python-cinderclient/python-cinderclient-9.1.0.ebuild
index 6310c74a4f53..1dee2d2013a2 100644
--- a/dev-python/python-cinderclient/python-cinderclient-9.1.0.ebuild
+++ b/dev-python/python-cinderclient/python-cinderclient-9.1.0.ebuild
@@ -26,6 +26,7 @@ RDEPEND="
 	>=dev-python/simplejson-3.5.1[${PYTHON_USEDEP}]
 	>=dev-python/stevedore-3.3.0[${PYTHON_USEDEP}]
 "
+# Tests fail with dev-python/prettytable-3.4.0
 BDEPEND="
 	dev-python/pbr[${PYTHON_USEDEP}]
 	test? (
@@ -34,6 +35,7 @@ BDEPEND="
 		dev-python/oslo-serialization[${PYTHON_USEDEP}]
 		dev-python/requests-mock[${PYTHON_USEDEP}]
 		dev-python/testtools[${PYTHON_USEDEP}]
+		<dev-python/prettytable-3.4.0[${PYTHON_USEDEP}]
 	)
 "
 
diff --git a/dev-python/python-cstruct/Manifest b/dev-python/python-cstruct/Manifest
index 9e7cc4c9d953..636836e5e0e4 100644
--- a/dev-python/python-cstruct/Manifest
+++ b/dev-python/python-cstruct/Manifest
@@ -1,2 +1,2 @@
-DIST python-cstruct-2.1.tar.gz 17298 BLAKE2B 9acc10f0d386c4413634945fc94b3e44210617c408ee18cf6533f70e7d64c609d463e9beceeea7c79b125e0bf0ab67a720d9ff98f45b4e7ce1f51d9280b55733 SHA512 c56c87d291c4aa2afcfdbcbbc19c03ec634b6fb0dcde9d516ef2a9079be2fea52a053c47cd20dfc0fe6537ac90939364da659d8eb4763069a9990681207d432c
 DIST python-cstruct-2.2.gh.tar.gz 18764 BLAKE2B 75aaffae27fef59799e52866f8169cc5d7362ef1553a56986f361ef7cfb7ca3e7d8c67fe0f112ec8e03ddacf45885e19fc1ce0d9d27c7581deafbf7e7fe1789b SHA512 5a1d62b596fef08a48020557e82fc81360430d94f18ce0667919815d57b944102067c2fe5723372616f73c995afd3a1f674e4a37e406d0dc7eeaf9fe3ef8f484
+DIST python-cstruct-2.3.gh.tar.gz 19043 BLAKE2B dd445da91d155dc576523d5c15dc963493dfb62e7e79fae6c436e69654432eadbc30b0001026f5613268800eb0a3a01392120b11e7b3995cff16477850818c9f SHA512 5700a3d8ef58130bc5b3b5d7c36102f6a878fd8d5b9104804f0c206e583e77d7a9c9ff8e8008d9bd1ee72d55167e48cd3f9ba776816eb25ceb8ceaf0c880b597
diff --git a/dev-python/python-cstruct/python-cstruct-2.1-r1.ebuild b/dev-python/python-cstruct/python-cstruct-2.3.ebuild
index b795533f3741..870df7088705 100644
--- a/dev-python/python-cstruct/python-cstruct-2.1-r1.ebuild
+++ b/dev-python/python-cstruct/python-cstruct-2.3.ebuild
@@ -8,8 +8,12 @@ PYTHON_COMPAT=( python3_{7,8,9,10} )
 inherit distutils-r1
 
 DESCRIPTION="C-style structs for Python"
-HOMEPAGE="https://github.com/andreax79/python-cstruct https://pypi.org/project/cstruct/"
-SRC_URI="https://github.com/andreax79/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="https://github.com/andreax79/python-cstruct
+	https://pypi.org/project/cstruct/"
+SRC_URI="
+	https://github.com/andreax79/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
 
 LICENSE="MIT"
 SLOT="0"
@@ -18,3 +22,9 @@ KEYWORDS="~amd64 ~x86"
 DOCS=( README.md )
 
 distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -e "/find_packages(/s@exclude=\[@&'tests', @" -i setup.py || die
+}
diff --git a/dev-python/python-glanceclient/Manifest b/dev-python/python-glanceclient/Manifest
index 663cf8f0b608..cc2c40c14710 100644
--- a/dev-python/python-glanceclient/Manifest
+++ b/dev-python/python-glanceclient/Manifest
@@ -1 +1,2 @@
 DIST python-glanceclient-4.0.1.tar.gz 202810 BLAKE2B ccc328aac739979d9ef3b3c4b6cccbef0865860827112c73a7d15d257f1735c69bac54d5771a27d6e6dbfaada4825b624d312a17195b081f3b5800b662c3f926 SHA512 23e931741430c0ba9606b5f013c6724285f8d49691c092c11db97434d963bd257639df769cdbc0e18ea2f5a57c13b03c887e8a091fdb40b292ae6a33f28b4e31
+DIST python-glanceclient-4.1.0.tar.gz 204252 BLAKE2B 484753886663f10b93fc2d9a0c3c2a1359324d989edfa26c0fe26cb7ab74897a5a81a3fac201d53af375d111e0b1e043fce79b1f3d3f153854bd9f63db756a9f SHA512 413d5a77c4b014f6300513552aca33a04e9a34e9bfa9c93ecc9008c79123ba7f20e527f3ad7506d066c0d215aa7fbf57a589a5f015fe1bc52479b8c57c760adf
diff --git a/dev-python/python-glanceclient/python-glanceclient-4.1.0.ebuild b/dev-python/python-glanceclient/python-glanceclient-4.1.0.ebuild
new file mode 100644
index 000000000000..467089a67b5d
--- /dev/null
+++ b/dev-python/python-glanceclient/python-glanceclient-4.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Glance API"
+HOMEPAGE="https://github.com/openstack/python-glanceclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/keystoneauth-3.6.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-17.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/warlock-1.2.0[${PYTHON_USEDEP}]
+	<dev-python/warlock-2[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+"
+# Tests fail with dev-python/prettytable-3.4.0
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		<dev-python/prettytable-3.4.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b glanceclient/tests/unit
+}
diff --git a/dev-python/python-novaclient/Manifest b/dev-python/python-novaclient/Manifest
index 34e6b13c2bd2..0c641d78a686 100644
--- a/dev-python/python-novaclient/Manifest
+++ b/dev-python/python-novaclient/Manifest
@@ -1 +1,2 @@
 DIST python-novaclient-18.0.0.tar.gz 335142 BLAKE2B 0b76ce92897e16310892427efc9062d20d1316be61e7391eaf9aca618844c4420f963591d1aa773b2d1ae1785aaf63888de6aec5baabbbedb09e4937a14d24d2 SHA512 fe3c5ad591679329a77421a1ef520823855d0ba1a7aa077d92a8b01e2b8bdab814c8cc94b5f76c1e59d6c7e70355f6efebd7b3596a4d4f74966aaedc38deac4a
+DIST python-novaclient-18.1.0.tar.gz 337772 BLAKE2B 593b47e86401e83ca9b42a62bb42e531becc8ca66fb460675f3bfacea237c6d643dd38cd41abb0185714c5ee1afae10c5aea269f16672cd5131f6058e08064d6 SHA512 907acbb3b9aae0c0ad463425260b2ca4ff968efd9ac2113b36d19dfa5bced29fca0ca6f549b479b3b6089b9b6e558f3ae31617edd99e2485eafe8403893f6501
diff --git a/dev-python/python-novaclient/python-novaclient-18.1.0.ebuild b/dev-python/python-novaclient/python-novaclient-18.1.0.ebuild
new file mode 100644
index 000000000000..cfe1e6748476
--- /dev/null
+++ b/dev-python/python-novaclient/python-novaclient-18.1.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Nova API"
+HOMEPAGE="https://github.com/openstack/python-novaclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.2[${PYTHON_USEDEP}]
+	>dev-python/requests-2.12.2[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
+"
+# Tests fail with dev-python/prettytable-3.4.0
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bandit[${PYTHON_USEDEP}]
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/python-keystoneclient[${PYTHON_USEDEP}]
+		dev-python/python-cinderclient[${PYTHON_USEDEP}]
+		dev-python/python-glanceclient[${PYTHON_USEDEP}]
+		dev-python/python-neutronclient[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/openstacksdk[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+		<dev-python/prettytable-3.4.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	sed -e 's/test_osprofiler/_&/' -i novaclient/tests/unit/test_shell.py || die
+	sed -e 's/novaclient\.tests\.unit\.//' -i novaclient/tests/unit/test_api_versions.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b novaclient/tests/unit
+}
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index cea8d00f22cb..1b94513dc246 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -1,2 +1,3 @@
 DIST sentry-sdk-1.9.5.gh.tar.gz 272096 BLAKE2B 179be647b92a74a1836f26add33e4b98007d19eff7454eb4968a2029003b7c1601d2eecad162a109508942b2f65086db32df6191c7f7986b5ab831295a8d3775 SHA512 d909ea9552a845b7022fdbbd06e3c49b2f136ca66771f20cb74b82f9eda7f63bee6c095eddefad7623a224bb9d6bf2b775c3c9405a0b55cd520952c3fe67c22d
 DIST sentry-sdk-1.9.6.gh.tar.gz 270120 BLAKE2B d5918f4ed21f3ee50d76a780416c458b3f917a314a9dfbdbe4b4b63727fa3b7ead61d04546b6ebf57c262143ccc694811e6f888ca1d39155aa98f3225508ab94 SHA512 ad8717f456706edb31e01e8c19b8b81d98b15423d62b2dba8a86fc78a4756c8176b4a0758ebb599f84dd4e6e85258c47e350c8f55e80314a4a70631966c83de6
+DIST sentry-sdk-1.9.7.gh.tar.gz 270209 BLAKE2B d1671bb45efa8aa785dc33a5d27e1d44843000809a88c4b081bbaca31be9ece65c6b192cadd46df912e1e1ca8650c7246f9946adb85117e88d13446965e190ac SHA512 d5c9a32e2c4001892cd03357d3b0cfe4c789eb0f4a12f6431920624795d4ed70a4055351541e12d9ee0be6e0fa689190e53c05fac53a27dad30e9f9fbe0711c1
diff --git a/dev-python/sentry-sdk/sentry-sdk-1.9.7.ebuild b/dev-python/sentry-sdk/sentry-sdk-1.9.7.ebuild
new file mode 100644
index 000000000000..aa4b4106f18f
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-1.9.7.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="
+	https://sentry.io/
+	https://github.com/getsentry/sentry-python/
+	https://pypi.org/project/sentry-sdk/
+"
+SRC_URI="
+	https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/eventlet[${PYTHON_USEDEP}]
+		' python3_{8..9})
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# tests require Internet access
+	tests/integrations/httpx/test_httpx.py
+	tests/integrations/requests/test_requests.py
+	tests/integrations/stdlib/test_httplib.py
+	tests/integrations/flask/test_flask.py
+	tests/integrations/django/test_basic.py
+	# wtf is it supposed to do?!
+	tests/integrations/gcp/test_gcp.py
+	# broken by rq-1.10.1 (optional dep)
+	tests/integrations/rq/test_rq.py
+	# fastapi is not packaged
+	tests/integrations/asgi/test_fastapi.py
+	# TODO
+	tests/integrations/bottle
+	# requires python-multipart (TODO: package it)
+	tests/integrations/starlette
+)
+
+EPYTEST_DESELECT=(
+	# hangs
+	'tests/test_transport.py::test_transport_works'
+	# TODO
+	'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+	tests/test_client.py::test_databag_depth_stripping
+	tests/test_client.py::test_databag_string_stripping
+	tests/test_client.py::test_databag_breadth_stripping
+	tests/integrations/asgi/test_asgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/asgi/test_asgi.py::test_websocket
+	tests/integrations/aiohttp/test_aiohttp.py::test_transaction_style
+	tests/integrations/aiohttp/test_aiohttp.py::test_traces_sampler_gets_request_object_in_sampling_context
+	# incompatible version?
+	tests/integrations/falcon/test_falcon.py
+	tests/integrations/sqlalchemy/test_sqlalchemy.py::test_too_large_event_truncated
+	# test_circular_references: apparently fragile
+	'tests/integrations/threading/test_threading.py::test_circular_references'
+	# test for new feature, fails with IndexError
+	tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+	# TODO
+	tests/integrations/wsgi/test_wsgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/wsgi/test_wsgi.py::test_profile_sent_when_profiling_enabled
+)
diff --git a/dev-python/shiboken2/shiboken2-5.15.5.ebuild b/dev-python/shiboken2/shiboken2-5.15.5.ebuild
index c5457f658764..8fb8cc4d5569 100644
--- a/dev-python/shiboken2/shiboken2-5.15.5.ebuild
+++ b/dev-python/shiboken2/shiboken2-5.15.5.ebuild
@@ -29,7 +29,7 @@ S="${WORKDIR}/${MY_P}/sources/shiboken2"
 # arbitrarily relicensed. (TODO)
 LICENSE="|| ( GPL-2 GPL-3+ LGPL-3 ) GPL-3"
 SLOT="0"
-KEYWORDS="~amd64 ~arm arm64 ~x86"
+KEYWORDS="amd64 ~arm arm64 ~x86"
 IUSE="+docstrings numpy test vulkan"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
diff --git a/dev-python/sniffio/Manifest b/dev-python/sniffio/Manifest
index d096430d8bf3..b2afe8788f9f 100644
--- a/dev-python/sniffio/Manifest
+++ b/dev-python/sniffio/Manifest
@@ -1 +1,2 @@
 DIST sniffio-1.2.0.gh.tar.gz 17335 BLAKE2B 0d67baa18702ac38932680bdc741c87ee0a31342cc752c1463a7f90720ea0ebf6d62ef682a042c58e8fe96456e1461638e0f02c6f60da5f5e0d07464be27a4a3 SHA512 8e1dd2bb6fc22ee5824adfffe688ff0621b8c1ef5daea594dedce13d5e04a498e05816bb32e9bbed206a653a330ff710df57c888ddcff00a6254eafddc538273
+DIST sniffio-1.3.0.gh.tar.gz 16867 BLAKE2B 44ab59d7477055aeaa0b08983094d8d12493edd5ded6ebd8e1bb048fbb2024325473dc37ebb5f66a10d8275b4e68b8c7f8dfb26088dc30c97a29d9f002fbc667 SHA512 3a9584eea20f5a69958f206fad9f01ef7fc40735f48a6cfaa11ba6eea1e7b8cc8c8053416595fe23276e162b0ab5dd6a41fb30bd9f7994f03b3d3242d5b40ef6
diff --git a/dev-python/sniffio/sniffio-1.3.0.ebuild b/dev-python/sniffio/sniffio-1.3.0.ebuild
new file mode 100644
index 000000000000..f0ae948d24dc
--- /dev/null
+++ b/dev-python/sniffio/sniffio-1.3.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Sniff out which async library your code is running under"
+HOMEPAGE="
+	https://github.com/python-trio/sniffio/
+	https://pypi.org/project/sniffio/
+"
+SRC_URI="
+	https://github.com/python-trio/sniffio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# curio is not packaged
+	sniffio/_tests/test_sniffio.py::test_curio
+)
diff --git a/dev-python/swagger-spec-validator/Manifest b/dev-python/swagger-spec-validator/Manifest
index 0157bab898e2..c20e474badcf 100644
--- a/dev-python/swagger-spec-validator/Manifest
+++ b/dev-python/swagger-spec-validator/Manifest
@@ -1 +1,2 @@
 DIST swagger-spec-validator-2.7.4.gh.tar.gz 47446 BLAKE2B d284bede24477cfc942d094937cec12224535902383779c223899ab7b359ea45427777ebc8d5f264a76696eae6746b619d35824090ae2f87c6acda4ef040b293 SHA512 d65c060f4730413280a188b01cf62d0f2d77fa04461bb60f2711d1806be2e7b8de16c23d952440a838f57acd50294a16114d34eeee988902fb90c099404c7942
+DIST swagger-spec-validator-2.7.5.gh.tar.gz 47455 BLAKE2B cc061be216bf5bdd6ea21f9053e6784e99704dcad06f900d9ed0910737db7e10c241648624f68271f414d75d53323a850648794887f7f656e1a61ec9727df86a SHA512 0307522f660b16441052d2d3744b8fd81d69b99954e57e99630142c554405a4011df928b853b7dde21733bbec6b12771c89c477055b5d97ff91d3c8694594b8e
diff --git a/dev-python/swagger-spec-validator/swagger-spec-validator-2.7.5.ebuild b/dev-python/swagger-spec-validator/swagger-spec-validator-2.7.5.ebuild
new file mode 100644
index 000000000000..906522955a57
--- /dev/null
+++ b/dev-python/swagger-spec-validator/swagger-spec-validator-2.7.5.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="validate Swagger specs against Swagger 1.1 or 2.0 specification"
+HOMEPAGE="https://github.com/Yelp/swagger_spec_validator"
+SRC_URI="
+	https://github.com/Yelp/swagger_spec_validator/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${PN//-/_}-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx_rtd_theme
diff --git a/dev-python/vcrpy/Manifest b/dev-python/vcrpy/Manifest
index 33a6913fe413..dff64dec5c8f 100644
--- a/dev-python/vcrpy/Manifest
+++ b/dev-python/vcrpy/Manifest
@@ -1 +1,2 @@
 DIST vcrpy-4.2.0.gh.tar.gz 331096 BLAKE2B dccb9310da42c6f75d0d503cb64aa09876447098bff2ad6a1507a0e0907ce05a89d46ccc159e79f310e027fc8f3075b7474274ad39ca4778acbc6d2a8f633004 SHA512 61eeec585fc78be1ae6d4f9047123c9680611e436bb5980fb7c6b885e16b2ef9bd5ce921efff7e87a222b3662c7009dbf0a8df24cdb9849d09deb24957ba4889
+DIST vcrpy-4.2.1.gh.tar.gz 331180 BLAKE2B 345e4c148963e2109d02be4e96986083236bd29fa8049c7cc54483f12d0506cde5c116b6f2fe80e099599b22a73e2f6240f7bb91e4a7d8af7f4e8e741097160d SHA512 59231e5164cda3099b18d099f0ef97e062e6401e52e5dfc4022aa89ca02881e9e6e3c782f12c288f5281b3b3bf175dc33a267bc6d2b40791582a1221f5d7aaab
diff --git a/dev-python/vcrpy/vcrpy-4.2.1.ebuild b/dev-python/vcrpy/vcrpy-4.2.1.ebuild
new file mode 100644
index 000000000000..b28237cffa2f
--- /dev/null
+++ b/dev-python/vcrpy/vcrpy-4.2.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Automatically mock your HTTP interactions to simplify and speed up testing"
+HOMEPAGE="
+	https://github.com/kevin1024/vcrpy/
+	https://pypi.org/project/vcrpy/
+"
+SRC_URI="
+	https://github.com/kevin1024/vcrpy/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/httplib2-0.9.1[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# these tests require Internet
+		tests/integration/test_aiohttp.py
+		tests/integration/test_boto.py
+		tests/integration/test_httplib2.py::test_effective_url
+		tests/integration/test_httpx.py
+		tests/integration/test_urllib2.py::test_effective_url
+		tests/integration/test_urllib3.py::test_redirects
+		tests/integration/test_wild.py::test_amazon_doctype
+		tests/integration/test_wild.py::test_flickr_should_respond_with_200
+		tests/unit/test_stubs.py::TestVCRConnection::testing_connect
+	)
+
+	local -x REQUESTS_CA_BUNDLE=$("${EPYTHON}" -m pytest_httpbin.certs)
+	epytest
+}