Adding metadata

7 files changed, 262 insertions, 0 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 74d982882033..140eb28bdc25 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.18.60.tar.gz 428327 BLAKE2B d559c7512c7ab1160dfec4616741002ce82357d
 DIST boto3-1.18.65.tar.gz 429858 BLAKE2B fbc80e0d8d10f6d02fcf9b86c6b4be03a9c908318c507a7cde1eef0c36d8fe3a5d3be0f8c6178edfdd8bc82adf112f297a5f127cd2b442ce10fe4d37b3a21fa4 SHA512 631d8f618fb6d55b338b563e72e1ccc751b8937bb2660d033b885951ea5ec3ac6902f8c7b9918664d764be84fdef5af4e7a87d444cbc154ebf5ae06908f90714
 DIST boto3-1.19.5.tar.gz 433567 BLAKE2B 52c12a4dd18d6f02326f8002b345cc5df224455fc862daa700326ae1df258979211d2753f01e1a106f237de393e483dc8926bb4ef0e08bafa575f20811dccd55 SHA512 fad05102f0c3e7e30a3342009f6b3ae28f52758f17a0c22b4da9a03dd10d7f9149ea2ec0119f55ec7280824bd8173653271821e82fcd54ef9fb9161b2d62df70
 DIST boto3-1.19.6.tar.gz 434389 BLAKE2B 3c7e4c91c95b93358b4a31d401e03f8a397802004a6ee2bfc2ef1a31df8b89e8866fa73d3354509ae00537898cc8e04b878cc9d00f82ae4e94266e8185e7abd1 SHA512 6ba4f7a89d973991afe329b4c648c8ecb0bb256d63c7e60ae8bb70e6fd5fc9b1929168dfdd55f2c84039856a32c891013abf61dc2e65f516490c446b0dfaaac2
+DIST boto3-1.19.7.tar.gz 434848 BLAKE2B 102b2d985cbad6c6ff6fc7866f47c172028e4b1a56ef7eac5854b12aedfbca1b94eb426fead04397e119ebaf939f7732202718395775b0555f566ed938c27dc7 SHA512 40cf5341bfd7cc4cae4c542e39e4c5ec1b63ba3bfee5faedb75633e656700dd5e80a137b234b57d22cc1b7d85a2056ced4eb8b7189ab57c8f2c0269e8826811d
diff --git a/dev-python/boto3/boto3-1.19.7.ebuild b/dev-python/boto3/boto3-1.19.7.ebuild
new file mode 100644
index 000000000000..30a0b44d3f8c
--- /dev/null
+++ b/dev-python/boto3/boto3-1.19.7.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 24f97cc792f4..5f0402308aea 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.21.60.tar.gz 8253381 BLAKE2B f035a335f8d72c182f6fbd3f2216608bd56
 DIST botocore-1.21.65.tar.gz 8261668 BLAKE2B c955019d06aa1b2f4503673b7d9009e5d6e07ee4348e730e6b4d11285f3030f676f0efda58a72dd92cac8c6ba0cb57f8f879eb5298009ecbd227904d18a453bf SHA512 955d24d2d486524af7bee57a56e2e903458030420198f3e6ab49d61be52b812a98444a9d0f86503b121270d6642345ffad6053ad143374dc56ab908b385afb0a
 DIST botocore-1.22.5.tar.gz 8301083 BLAKE2B 91f9d38e7c5bcb0b8f58c04547ad45489f58d2240c6b7301cf632969a4a73cf4a1d51c8c68c8def27653c10041d2163ad7ca800dcf6fd07972b506bf2566cae3 SHA512 710a9eeee03dc79ca4ffacc4974f09ca769e1e3b8cb143f6f0349240dd8c2af8ee526a1dadb7310a26019363f683fc4149cb4c73d8b94a856a384fab7f84fb5c
 DIST botocore-1.22.6.tar.gz 8302901 BLAKE2B 4627c7bfcbd1750a6517c045b7c7c986c6defb9b35e413fae47e03fe24f3404ff4905c714212ad00193eb4dfa2893a0080da97acb538965a8792278915823a3b SHA512 f39eb6f339011709fa764d3783f225fbd4e4100e51466de9c87d6a3a5430823e81be1b024963ded49785b4fd49febdfa66dd3f91c3b9296508c3d71d794d170d
+DIST botocore-1.22.7.tar.gz 8306878 BLAKE2B fd427ced3eb3c2ce71a28f7334ee312293fc98c7b2d91991ce6c894f71bd39b356aa3a2f0a0495fd91e394be4d284b21dc8272863e9568167112aadccaed21a6 SHA512 39eaa5d4bc64669bc398797c69d63157a6a4539bed1c4cdc492c4fe94c9a32d58ac9ea8c06fafd75a5c36ab9d3a5c99f88990b03bcef6cccf7e0c4247330780b
diff --git a/dev-python/botocore/botocore-1.22.7.ebuild b/dev-python/botocore/botocore-1.22.7.ebuild
new file mode 100644
index 000000000000..9cd77a5ad4d0
--- /dev/null
+++ b/dev-python/botocore/botocore-1.22.7.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 7327bfef92f5..bb4f0bfdecd9 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,2 +1,3 @@
 DIST ipython-7.26.0.tar.gz 5147847 BLAKE2B c0cb45550387e47bba6ea67656bbb4561a2250bf9c39b4560b26a8a9e380061f79c5fa663f90df166af1fa49811cb59953fb367b2fea5f07d44ba3f9dae3de44 SHA512 142ff8ebddd61640e6ebff01d16b1310b6370643aa8cf4c7fd076872ad342949a1778c5ad74eccbafdc6b4d31a1849e096d75a28eafc555d629948db523b4776
 DIST ipython-7.28.0.tar.gz 5150515 BLAKE2B e69b2ca9b788d8bcc12fb1b82c2e3f198ba4cf1918c8d8d30aea9a1ee3c7cea99ba3ade8ac7171466f1ffc8771dafcf5980766ecca7b985e07890e229cd1575d SHA512 227645ab2cc698f6f7141bb3712b254d75beaf3f227065530f25f988ac76b5a741752ddfa6bb2816b625eaa4972d434f9e73dbe465654e4efc5420b5d80650cb
+DIST ipython-7.29.0.tar.gz 5151803 BLAKE2B 685bb7df39513fe262c07dbb10de4d795860bf2958c626d030bfa3e18052a98d7c9d5f0f96c0c9a5d4b9fdcfab09c492457d409f05ce522f607456ff3a4b35fd SHA512 b8e9cc07a0f77bbfaa88183546ed9d7e4a4c37e7c1704b1a3716d605a04339f986c7767f3c0920a94039eda99e75afb62a7bb43fa0cde6699a902f3b8f83a398
diff --git a/dev-python/ipython/ipython-7.29.0.ebuild b/dev-python/ipython/ipython-7.29.0.ebuild
new file mode 100644
index 000000000000..778b8541eb50
--- /dev/null
+++ b/dev-python/ipython/ipython-7.29.0.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=()
+	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
+		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
+		IPython/core/tests/test_oinspect.py::test_pinfo_docstring_if_detail_and_no_source
+		# fails due to changed argparse output
+		IPython/core/tests/test_magic_arguments.py::test_magic_arguments
+		# py3.10 API incompat, doesn't look important
+		IPython/lib/tests/test_pretty.py::test_pprint_heap_allocated_type
+	)
+	virtx epytest
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
diff --git a/dev-python/websockets/websockets-9.1-r1.ebuild b/dev-python/websockets/websockets-9.1-r1.ebuild
index 8067f57c4b1d..a24cb80f9b34 100644
--- a/dev-python/websockets/websockets-9.1-r1.ebuild
+++ b/dev-python/websockets/websockets-9.1-r1.ebuild
@@ -33,3 +33,6 @@ src_prepare() {
 
 	distutils-r1_src_prepare
 }
+
+# Be more tolerant with time-sensitive tests for slow systems.
+export WEBSOCKETS_TESTS_TIMEOUT_FACTOR=100