Updating liguros repo

13 files changed, 221 insertions, 3 deletions

diff --git a/dev-python/cmd2/Manifest b/dev-python/cmd2/Manifest
index d27baeea7cdb..0b4c2fea7706 100644
--- a/dev-python/cmd2/Manifest
+++ b/dev-python/cmd2/Manifest
@@ -1,2 +1,3 @@
 DIST cmd2-1.1.0.tar.gz 605311 BLAKE2B 0816c3975b45c4845f234a746037319213af8860ea8996b6d05e2412e26649be6770d21dab330387037f6284b1f440a29b727c1ac4fed969fc8dbb2f9ac389be SHA512 b8065ec217a588725eb1787d2aedac8c49b8b8196c12848038f91cba73f23e960fbfe5d4b8631b2a57eb1aeaa1a206683b8b71545c1171d6d3101f03fefc0f0b
 DIST cmd2-1.2.0.tar.gz 613769 BLAKE2B dbdabdd52ef26fa6fd91d4255dab1b77b0363fbfba85c4f42b3d125ab3663ef301bf267ace4617c3a391765b78778d231691cb87fb43d6d47c78d02a4a11cbc8 SHA512 2df3342a4b74a29948bba0dc11c44e37be9f2ebd78051efd4d77dd03bd3460d11857c8edc3c57baacb4b1abbc41b3504d475e0395563818032dc6946fcda6538
+DIST cmd2-1.2.1.tar.gz 623518 BLAKE2B 69aebdb6350c453001b6101988d9b0d3d96ca7970c54cd59d3aad6e01b3e7133d62b57cb44588cec786ea21818d8c5983e5bc64510e8c6f07627505f14c28651 SHA512 5f7259111ed8f5719c230c33f6131c8464f5500ba14869d26e9f52850ea619c2b97ed950774930d9e19621e98c64b50c67eaff34277cd81463b60f8dcf6f04a3
diff --git a/dev-python/cmd2/cmd2-1.2.1.ebuild b/dev-python/cmd2/cmd2-1.2.1.ebuild
new file mode 100644
index 000000000000..cdd3428887c2
--- /dev/null
+++ b/dev-python/cmd2/cmd2-1.2.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Extra features for standard library's cmd module"
+HOMEPAGE="https://github.com/python-cmd2/cmd2"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/pyperclip-1.6[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-1.6.0[${PYTHON_USEDEP}]
+	' python3_{6,7})
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest-mock[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:test_which_editor_good:_&:' tests/test_cmd2.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	# tests rely on very specific text wrapping...
+	local -x COLUMNS=80
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	pytest -vv || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/flask-sqlalchemy/Manifest b/dev-python/flask-sqlalchemy/Manifest
index 3da6695d757a..e2bb44a5f4e6 100644
--- a/dev-python/flask-sqlalchemy/Manifest
+++ b/dev-python/flask-sqlalchemy/Manifest
@@ -1,2 +1,3 @@
 DIST Flask-SQLAlchemy-2.4.1.tar.gz 128863 BLAKE2B 5ce87601a5dbeb8505144c0970eecd0bf553ad3feccd74e7de567a4fe0702575c6f7935d4812410ced17b7b98e6b8e6fcb67a589681cd82464fa4cf0dc09ba74 SHA512 a55e6fe563583e240bb594c157424fba1a8462f953fa0bb14701954bcb52d1e7bf71eec38f4037c1752ceab90e798642274de58e0f950d83e234f4c702e0b6ee
 DIST Flask-SQLAlchemy-2.4.3.tar.gz 132134 BLAKE2B fb4df0daea347021334934ec1b22b18f9c4f97b6cf07c1c74f0d1567c6f0c3e0d16909f67adef89e8236e8a53e4126f1598fb21dc6f7fa5f5e042cbe733238fb SHA512 231593d53b02c4560eeb74dca7075495eb6fb4a75a4d25257aa281401dac39ac3ab2ef0edfd76ce762332c599b9bf2d903743142056a827a3170709516e94445
+DIST Flask-SQLAlchemy-2.4.4.tar.gz 132193 BLAKE2B 044885af05463bfe377ef503baea6fe8b4a988e1f23aa6e8165ba76f85626d5b596226eabd7d69b984848149c8401b136806e8a68ed568d4cce97acbf402cbb4 SHA512 9d952a39f3d116306ae15c8f802780c987e54dbe519612a9b699bb77e8a45f272e90f994697f881283d1eaf5767d42eaef2ca017d22c08e48596d385d942b1ee
diff --git a/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.4.4.ebuild b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.4.4.ebuild
new file mode 100644
index 000000000000..5733e429063d
--- /dev/null
+++ b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.4.4.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6..9} )
+
+inherit distutils-r1
+
+MY_PN="Flask-SQLAlchemy"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="SQLAlchemy support for Flask applications"
+HOMEPAGE="https://pypi.org/project/Flask-SQLAlchemy/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/flask-0.10[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/pallets-sphinx-themes \
+	dev-python/sphinx-issues
diff --git a/dev-python/peewee/peewee-3.13.2.ebuild b/dev-python/peewee/peewee-3.13.2.ebuild
index d1d51cbabc26..e05e6b58b532 100644
--- a/dev-python/peewee/peewee-3.13.2.ebuild
+++ b/dev-python/peewee/peewee-3.13.2.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6..9} )
 PYTHON_REQ_USE="sqlite"
 
 inherit distutils-r1
diff --git a/dev-python/pypng/files/pypng-0.0.20-py39.patch b/dev-python/pypng/files/pypng-0.0.20-py39.patch
new file mode 100644
index 000000000000..e4c738ee3137
--- /dev/null
+++ b/dev-python/pypng/files/pypng-0.0.20-py39.patch
@@ -0,0 +1,34 @@
+From fe9c973c5e92f24746dfa1be8796c14a2befec4f Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Wed, 15 Jul 2020 07:54:53 +0200
+Subject: [PATCH] test_png: Use array.tobytes to fix py3.9 compatibility
+
+The deprecated array.tostring() method has been removed in Python 3.9.
+Use .tobytes() instead.
+---
+ code/test_png.py | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/code/test_png.py b/code/test_png.py
+index c858d18..447c314 100644
+--- a/code/test_png.py
++++ b/code/test_png.py
+@@ -448,13 +448,13 @@ class Test(unittest.TestCase):
+     def test_interlaced_array(self):
+         """Reading an interlaced PNG yields each row as an array."""
+         r = png.Reader(bytes=pngsuite.basi0g08)
+-        list(r.read()[2])[0].tostring
++        list(r.read()[2])[0].tobytes
+ 
+     def test_trns_array(self):
+         """A type 2 PNG with tRNS chunk yields each row
+         as an array (using asDirect)."""
+         r = png.Reader(bytes=pngsuite.tbrn2c08)
+-        list(r.asDirect()[2])[0].tostring
++        list(r.asDirect()[2])[0].tobytes
+ 
+     def test_flat(self):
+         """Test read_flat."""
+-- 
+2.27.0
+
diff --git a/dev-python/pypng/pypng-0.0.20.ebuild b/dev-python/pypng/pypng-0.0.20.ebuild
index 9bb9cf785ed9..48293ee70a3f 100644
--- a/dev-python/pypng/pypng-0.0.20.ebuild
+++ b/dev-python/pypng/pypng-0.0.20.ebuild
@@ -4,7 +4,7 @@
 EAPI=7
 
 DISTUTILS_USE_SETUPTOOLS=no
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6..9} )
 
 inherit distutils-r1
 
@@ -16,6 +16,10 @@ LICENSE="MIT"
 SLOT="0"
 KEYWORDS="amd64 arm ~arm64 x86"
 
+PATCHES=(
+	"${FILESDIR}"/${P}-py39.patch
+)
+
 python_test() {
 	"${EPYTHON}" code/test_png.py -v || die "Tests fail with ${EPYTHON}"
 }
diff --git a/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild b/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild
index 50803e75ddd8..ee466d886278 100644
--- a/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild
+++ b/dev-python/pyqrcode/pyqrcode-1.2.1-r1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6..9} )
 inherit distutils-r1
 
 # upstream doesn't do tags
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index fb59ca613c10..2339bf7e4c4c 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,4 @@
 DIST tox-3.15.0.tar.gz 291890 BLAKE2B 9c42c587332eafcfd02d2d8a42588af6253baf9f62e82eb8a8bf10da291b4868b1fe319e38a583bc67bb26ab868b8a123feccd5bd008ce618ceb46d3121c68d2 SHA512 cb21574301d953b361eb5e1d89eefe22e68ae5871036f03d5753ee97c888cadde548d62a50622dd65b3c488143bbbdf8d309bafa3b6a4807871c9e78b6fcdb9c
 DIST tox-3.15.2.tar.gz 293523 BLAKE2B a1a1c84a987d2b2e5194321405775ee3828b8e2c8dcd38c7e780a9d508b789a42f1880cffcecd68c50dfdc37008a4e9a117660fa2c732864c82af6c2eaf5a99e SHA512 9448554452c79039289d2d2c05c974f451647329701372c3e4b154a0161fa768245c0068cd5e3f1221b4b51a07be806f7c66ab9d4ef83a3e8e5964e18b9cde85
 DIST tox-3.16.1.tar.gz 294080 BLAKE2B 692ef3f498f78f239ecbb3f9ac5745462430a96bb67df7a732e5c5756d1b579c4ee8582d528d5eafddc7b19905057c01514cccaa42d7c1a442ac24cd531a656f SHA512 83fefc4b82fb33adbf2ece9a6fd6ffaf27771ac6076af5d2939dcbf68f1dd88b8edd0a105b0ec86dc7ee37b127d27ed46748af61423811c7435d0093d2e8e1eb
+DIST tox-3.17.0.tar.gz 294481 BLAKE2B a4fe4c94616d003f348b2c4a58276a93887f479a3727fac3734f998071a03cd3c8da2e3b1c3bc27f0695b9d596c6d966e6c591506ce1b6ebbb5b0826c3dc20b7 SHA512 0a04b1fde7a8f7eaa24823bba59dc25c3bc48c7159866f85131bb55c0adb61d21e8c5bf88598fbbd09de58bdc51cd740d256802549e3566565af400ef7e1e95e
diff --git a/dev-python/tox/tox-3.17.0.ebuild b/dev-python/tox/tox-3.17.0.ebuild
new file mode 100644
index 000000000000..499658c518d4
--- /dev/null
+++ b/dev-python/tox/tox-3.17.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-1.1[${PYTHON_USEDEP}]
+	' python3_{5,6,7} pypy3)
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		dev-python/pathlib2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		=dev-python/tox-${PV}-${PR}[${PYTHON_USEDEP}]
+	)"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# broken without internet
+	sed -i -e 's:test_provision_non_canonical_dep:_&:' \
+		tests/unit/session/test_provision.py || die
+	sed -i -e 's:test_provision_interrupt_child:_&:' \
+		tests/integration/test_provision_int.py || die
+	# broken with our mock version (?)
+	sed -i -e 's:test_create_KeyboardInterrupt:_&:' \
+		tests/unit/test_venv.py || die
+	# broken with Gentoo Python layout
+	sed -i -e 's:test_tox_get_python_executable:_&:' \
+		-e 's:test_find_alias_on_path:_&:' \
+		tests/unit/interpreters/test_interpreters.py || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	distutils_install_for_testing
+	pytest -vv --no-network || die "Testsuite failed under ${EPYTHON}"
+}
diff --git a/dev-python/zxcvbn/Manifest b/dev-python/zxcvbn/Manifest
new file mode 100644
index 000000000000..7309057227e1
--- /dev/null
+++ b/dev-python/zxcvbn/Manifest
@@ -0,0 +1 @@
+DIST zxcvbn-4.4.28.gh.tar.gz 9392042 BLAKE2B e3baf57df00819243f9588c8203598b14b9f03e0a232d53152584b3b74872baef7050fdf8f11f25e8a8776e2e4a7a0af15c9045f07700fe686c6cb021f794f2b SHA512 be85f976dcf685e2885edff116147cc4549f9c86dee4317b61b84dc4f36ab2c8c2f3468d5d1a55e8890693c852a09104b14360f9ce43feb3727f8fc164eb78f1
diff --git a/dev-python/zxcvbn/metadata.xml b/dev-python/zxcvbn/metadata.xml
new file mode 100644
index 000000000000..50567d15b867
--- /dev/null
+++ b/dev-python/zxcvbn/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>
diff --git a/dev-python/zxcvbn/zxcvbn-4.4.28.ebuild b/dev-python/zxcvbn/zxcvbn-4.4.28.ebuild
new file mode 100644
index 000000000000..632384ec4461
--- /dev/null
+++ b/dev-python/zxcvbn/zxcvbn-4.4.28.ebuild
@@ -0,0 +1,21 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+inherit distutils-r1
+
+DESCRIPTION="A realistic password strength estimator"
+HOMEPAGE="https://github.com/dwolfhub/zxcvbn-python"
+SRC_URI="
+	https://github.com/dwolfhub/zxcvbn-python/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+S=${WORKDIR}/zxcvbn-python-${PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+distutils_enable_tests pytest