Adding metadata

19 files changed, 677 insertions, 0 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 1b1af704f3ae..1fcac0dbdc3b 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,4 +7,5 @@ DIST boto3-1.20.29.tar.gz 457663 BLAKE2B 8bb10de51a0250c3bf18b339ca6d9aa54985ebb
 DIST boto3-1.20.31.tar.gz 458553 BLAKE2B 396acd8bbc47f76a0ba65da4b83f141f253690370f6cd36fcfad8b4ba1017889bb2c4c63bbcc8e3f817307cca666593072becde30b5739f38386f764a9f2c876 SHA512 0772959c735a6002431f171b6476398a1e1096301c20b5429504ed9a9bd6e3a2b6e95392504b3ea49ef942ab6c5210a0d26a0cdde6be52bb88d642ce776576b9
 DIST boto3-1.20.32.tar.gz 459036 BLAKE2B 21aaba2f5f5db65edc3570e44082cf394429407c0431bdfc19866e530b48358909ab730ecb5b871dcbb5f4c087af43f53474a7dca6ce9ca84e78ba480f5cc819 SHA512 a50f0724f4c6ab8b0fc0b329909ff35126bbdc9c73da5927dd1259565b2e43e87c718bbf8b2dd5433e75b4d35b8094d3fc122163febbbe66b6175ecfeb81fad9
 DIST boto3-1.20.33.tar.gz 459654 BLAKE2B bf2090e6af9cad5f4e9e5178d30e109c63c403137f9656c22358bb672da7e0ca2e9f36585b5721f2a7bbb2d3d3027fb3942e055d3db78ede0b03f5b6a2e6ad78 SHA512 877c8e59686cd7ac940aa7fb1f2adc75a89e4ce5c74e7a999bebe80e80819c6f909ee8f9acca1c85a6a11f3b7a8ba39a41221ec54a8b99c412da9208a791f4b3
+DIST boto3-1.20.34.tar.gz 460169 BLAKE2B d687bb3a90da0e8cd48e551dad68754edc97689350f43879c90e8c96470dc79d389b5332d06d079dd4d26f303d9260f1a83bfc2edfa2507e3a33020e4475e8f1 SHA512 ae13db5ed516a9166c14e72e078f45c911a9c16edc2e2d95dc296de09345fb311ecad92ec7615137b01edaae254d075b74e68c1c909a79b2eb1ac2416ab5bbad
 DIST boto3-1.20.5.tar.gz 439166 BLAKE2B c140e15e497e6cdf6b4b77bb99e0a0f5ac01d5b5793f8bfb210b52bbc09e39e6fe06a957951375e0795210dc1c3b2a0afd2f498bc88e449d9e6846f2b357f016 SHA512 2823466e4851684253d4ce42a8c34e5cbdad6d04c823040fe2cebdf0cffb14d5d3f40e28d57ebec14533fab04ba74f27c25f078ddb8791b8f52d0424e11b39fc
diff --git a/dev-python/boto3/boto3-1.20.34.ebuild b/dev-python/boto3/boto3-1.20.34.ebuild
new file mode 100644
index 000000000000..01dccd8375ab
--- /dev/null
+++ b/dev-python/boto3/boto3-1.20.34.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 7ace5549cf08..79410dc555bc 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,4 +7,5 @@ DIST botocore-1.23.29.tar.gz 8705067 BLAKE2B b5c2358a263f93b4808a2527b7ce8a1bbc3
 DIST botocore-1.23.31.tar.gz 8706949 BLAKE2B 2e31bc09173a93806fe045e5217defcf17b624d6e9ff543add0eb9183c99faac40c14a8b7d71a2ec71b5983df572cadd2d098155c8c9f5abeceef80c17c4c35b SHA512 7440740c05b8f009955b6627b82f8f955d907d529923457b19f1a251b701fc7cba2dd19a77eee1fce220745d93f19f4c42f146772ecd46f3ea0c93f63047086e
 DIST botocore-1.23.32.tar.gz 8710235 BLAKE2B 278189ae1ee9887e62092344543b6431425640c90c243161cc34448f5b4ed9cce624042bd21d445150f09e695608361633554d535aaaf1850b5987111a43657d SHA512 f33c9818d3985a0334d5c2cf2f9ec9aa34834a73dfc73f8e9298e59432141f6792acecf0380cb8d607cdd12156f182ee130952390d8f0e808cca12659317b2e3
 DIST botocore-1.23.33.tar.gz 8712535 BLAKE2B 97064bfe24db14e49ff37b515549a2294ed2fbba82f36cf4d5281db27add007c8524058cb208bcf168add9e739bb2d51e7980295938ac6ff6ff603ffd0cfccee SHA512 7373a9cac5efb12898ac1665b74a5eb3693d5e5defd55bc2972bc70cbfcdf69672a8cb4b8d0a6b2bfbc59e789fedea09014ac47ba9ef6af8cc038471330850f0
+DIST botocore-1.23.34.tar.gz 8718420 BLAKE2B 67325949a37c3a3ff61e66279626c30b8f225d74137512d9a45414e1af11a18dd5fba5f0f4e64dd71c3d0bbbabf210d6e8a63901bc6deba8f16e3cfc163ebb81 SHA512 8afdf0a186f4850e8905ef1cd6660ab8ea58546cc119a47085976adc51195c0b9d524c077a3dcef6687cc5977988532932a424023dfea83eb7efd1e19b19eb95
 DIST botocore-1.23.5.tar.gz 8374467 BLAKE2B 467092e7d8aa5ccb756132669049865445a47205913964c1c944b20caaf100b1efdd1bf3af9c5416ff079b487e6d4d08ffe6208e2b352d09655cc5be21c88739 SHA512 6afca19b724f9019f21e5993ce970d605b95d31c1a4e969ec1b4080510a5a120b3fa0cfd5ade973a9203bd6b7983a3dbca2f7a03108a9167392efd60d5e2fe9b
diff --git a/dev-python/botocore/botocore-1.23.34.ebuild b/dev-python/botocore/botocore-1.23.34.ebuild
new file mode 100644
index 000000000000..34dcbcdf2d0b
--- /dev/null
+++ b/dev-python/botocore/botocore-1.23.34.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	distutils_install_for_testing --via-venv
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/flask-paginate/Manifest b/dev-python/flask-paginate/Manifest
index f8a8abdd5e85..45124a8d93f0 100644
--- a/dev-python/flask-paginate/Manifest
+++ b/dev-python/flask-paginate/Manifest
@@ -1,2 +1,3 @@
 DIST flask-paginate-2021.10.26.tar.gz 120721 BLAKE2B dd37fa131baf20540620c350bca4a17f791df57c82fabd99e644891707259d330d4225fc666d3e5c31410bc17e10531bf735ab8a01e7129641fa81a9d8fbfe82 SHA512 86a782797a9401eecbbfc25c90834ed93d7c376c3eb6bc05f19edf7ad6f174aca01de9dc3b183c0c268e2995d81984fa1568e08aae8964e429c60f01b7b23736
 DIST flask-paginate-2021.12.28.tar.gz 120846 BLAKE2B 63c14a94db4c968ef22a84b28aee2ca3e223fa0a7a32e22644b02b718ae32ea9ece9177b85c66942165e01926b26bb599dd3ae47522ba9bbf9a1c68b7a5ce567 SHA512 3ff805ad2d30aadfd1affabde0b0caccf2c3c2efb54b0997f809e13a76c6db64082d0f003ba4485a824e48d5d2792d99bab5173059ebe5a4077a1aac99b3c4ca
+DIST flask-paginate-2022.1.8.tar.gz 120847 BLAKE2B 110d6f7bb6c244378a41ab26c914898b54fb05cc00cfc6c7c3e15ed96e2163f92cc89c4ce93199091d8ed2f52301e997ebc16a71a3d802b8107249f9f832ca25 SHA512 9f2e0e50d73ac15ec2a413671a52e9dbbbb7eac8576494483441ea1287a12e2076cf649ee9df0bf3b3d2c7e13eebe4a835031ab57a2e8b2015f383d53318a0b9
diff --git a/dev-python/flask-paginate/flask-paginate-2022.1.8.ebuild b/dev-python/flask-paginate/flask-paginate-2022.1.8.ebuild
new file mode 100644
index 000000000000..1433d754b732
--- /dev/null
+++ b/dev-python/flask-paginate/flask-paginate-2022.1.8.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Pagination support for flask"
+HOMEPAGE="https://flask-paginate.readthedocs.io"
+SRC_URI="https://github.com/lixxu/flask-paginate/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest tests/tests.py
+}
diff --git a/dev-python/jsonschema/Manifest b/dev-python/jsonschema/Manifest
index ea92e20b9dee..065c8f50c16c 100644
--- a/dev-python/jsonschema/Manifest
+++ b/dev-python/jsonschema/Manifest
@@ -4,3 +4,4 @@ DIST jsonschema-4.3.0.tar.gz 311317 BLAKE2B 6ec3d2cf05923657e9875b5f51b9356a730a
 DIST jsonschema-4.3.1.tar.gz 311425 BLAKE2B e524675d64fece5f7687d62ed043ffb35e7627c6d1f213fde3e9c2f35b929fc56b998d39e84148fe24c507361114e047540fcf23606f4d77b2bdfc0454c6d529 SHA512 621093b8964ea94dadd23aab7c0bbbf5eb23ae615b569278886a4213ef7adc779fddcd75cfff87e243087f788fca180f4472cd3bafe8f2f8157e30c04b5f33e7
 DIST jsonschema-4.3.2.tar.gz 311576 BLAKE2B df6e656244b3ad963714e3a5e457971ad29455529b1e032e4ead2aa60a76ef332d31c871d6e9cc98b1a76d52e53b6586e6ef0b601d4b1b6fef8b39e2ea29acfa SHA512 a849282e6661ac28d3116754e87235a1970993bedeb4590d67605409ef875c5c26efe12a35bce7eeb624778a6d7770feda0356b4a0c05f6bc0364da9aefcaed6
 DIST jsonschema-4.3.3.tar.gz 311720 BLAKE2B 685e7712bdf87f0b6cfdc0ca6b094c90efd78acec72a6233661caddbba52e55ab78af83a24b14b9580a9eed6179302208b35ca836dce36459db65f0017805142 SHA512 f2a9e4d89a12d5d1c53666a9c95bc29adf2559438f0ab11f34abaf3f2525f525cd742ae54f2d3a732d98db92c4f45fc7611ffbc61f2ac1121377066a86db3bf9
+DIST jsonschema-4.4.0.tar.gz 313519 BLAKE2B 6339c4ac9e99b55e41c133861baacb6644e04d15e915d3199955512530c946973ca6d5348746688660ea7392d53102754dba3f3380fc8aa3a4ab284a9dcde684 SHA512 8e5c138f4debf7540e2cd131f3f208d1778927ac9036f5fa67bcf5db8c62fe1bb454c7818ee61acef64e856ea4b498ef6ab08be314a3c6b1e461e0bb44db41c7
diff --git a/dev-python/jsonschema/jsonschema-4.4.0.ebuild b/dev-python/jsonschema/jsonschema-4.4.0.ebuild
new file mode 100644
index 000000000000..c8a0c3d9b09c
--- /dev/null
+++ b/dev-python/jsonschema/jsonschema-4.4.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="An implementation of JSON-Schema validation for Python"
+HOMEPAGE="https://pypi.org/project/jsonschema/ https://github.com/Julian/jsonschema"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.18.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-1.4.0[${PYTHON_USEDEP}]
+	' pypy3 python3_8)
+"
+
+# formatter deps
+RDEPEND+="
+		dev-python/fqdn[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/isoduration[${PYTHON_USEDEP}]
+		>=dev-python/jsonpointer-1.13[${PYTHON_USEDEP}]
+		dev-python/rfc3339-validator[${PYTHON_USEDEP}]
+		dev-python/rfc3986-validator[${PYTHON_USEDEP}]
+		dev-python/rfc3987[${PYTHON_USEDEP}]
+		dev-python/uritemplate[${PYTHON_USEDEP}]
+		>=dev-python/webcolors-1.11[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/twisted[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires pip, does not make much sense for the users
+	jsonschema/tests/test_cli.py::TestCLIIntegration::test_license
+	# wtf?
+	jsonschema/tests/test_deprecations.py::TestDeprecations::test_version
+)
diff --git a/dev-python/jupyter_server/Manifest b/dev-python/jupyter_server/Manifest
index 139fa6df49c3..49c114fbf613 100644
--- a/dev-python/jupyter_server/Manifest
+++ b/dev-python/jupyter_server/Manifest
@@ -2,3 +2,4 @@ DIST jupyter_server-1.11.1.tar.gz 420035 BLAKE2B 0676b0e126752ebeaa45e2325c34fe7
 DIST jupyter_server-1.12.0.tar.gz 422318 BLAKE2B 9aa4843d02bfd918b0df13d94fc0058e6a6dee74f634dac359f7f6b4ca85e6cd4f91e8ddafb873647cd672284fb3eff087e05c3fcb6eff1621c7beb4b99030ee SHA512 28de049051852ae5d2bc10f2a0643a1441c2df3c229348e8d45e7031cc1c85a118124bc0b3bf7f101fd912ee25cd9cbf3e9b1b633fee20d70f43152e1e03e12c
 DIST jupyter_server-1.12.1.tar.gz 422410 BLAKE2B 611f17fe9804b0279c60ecc4fc1c23e6548643e4f7aa8e120580e167dc58a1f2d98ed7f07b90927bf07a71a89829d5701bd296a8f5ad3e954e4e8ee20c95bd5f SHA512 b199be8b0590c4bd14e995e6c9933f6da4d33e1796203cc157fd42b111db5ec6e860ef321d8311c30995d8aba6f1803dd0fec9148ae9a1cf427b7e38924f5357
 DIST jupyter_server-1.13.1.tar.gz 423717 BLAKE2B 9524e6648365e9c4158a8af4a4b277b4673ca320fc8e2c101ef2797ad89ebe8f93d25b1e74193ed88b06d151621a2ab9d9622cd06d67d5bea3a9ba96a95eb8e0 SHA512 e42a93930d16adb3952a0f98e3ae399a50881c32ef78205922511ea702dc24ffbeae30058fb1445897c4cf52873af0c03be16276398581a3eff52b58739ed2ba
+DIST jupyter_server-1.13.2.tar.gz 422777 BLAKE2B b263831ea27b5628c01f6c0897b213b8e97d60d234e6843817750eb41cf23cc27160841d3e65ccf210648571b8a0532c921bc9cd01ec56d78b4d1cad70cec91d SHA512 93a78a7b47c570e4bee80ef51fb0e35027caf414bfbd3c1bdf1f65d166d9756fade984070605f617912144b043c099c63812f7ba6b2be64c6524f5b8c6f24d7f
diff --git a/dev-python/jupyter_server/jupyter_server-1.13.2.ebuild b/dev-python/jupyter_server/jupyter_server-1.13.2.ebuild
new file mode 100644
index 000000000000..e7e17049d407
--- /dev/null
+++ b/dev-python/jupyter_server/jupyter_server-1.13.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/nbconvert[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	<dev-python/anyio-4[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+	)"
+
+# TODO: Package 'myst_parser'
+# distutils_enable_sphinx docs/source
+# 	dev-python/pydata-sphinx-theme
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# Defining 'pytest_plugins' in a non-top-level conftest is no longer supported:
+	mv jupyter_server/conftest.py . || die
+
+	# This fails if your terminal is zsh (and maybe other non-bash as well?)
+	sed -i \
+		-e 's:est_terminal_create_with_cwd:_&:' \
+		-e 's:test_culling:_&:' \
+		jupyter_server/tests/test_terminal.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/notebook/Manifest b/dev-python/notebook/Manifest
index ac1972ba53ae..1ee4f2627e2d 100644
--- a/dev-python/notebook/Manifest
+++ b/dev-python/notebook/Manifest
@@ -1 +1,2 @@
 DIST notebook-6.4.6.tar.gz 14342345 BLAKE2B cc9d5968d05d9f75f60f02adfb5ef35f39e4a5de027356af73c6dfb1f3aebc271e5b3bc639eb8605748abd30d43bfaab662d41b3b764c91cc545c2d1848881f4 SHA512 92b10bdc041bc0f3af1b42ad219abda37402e0fa4ea16ddcfd2ffc450cc7f49ce1d770cb477160c3fa58c387f85d22ca3f4e4c6507a5cbf7a92bc5268baf661e
+DIST notebook-6.4.7.tar.gz 14347832 BLAKE2B 3430aed18e2748005a98ba8e369d3aeda1925098ea1cb59fd6c5b4fc559a9f3ad41dc3fa655a7cce05a6be7fb44c6fe1b2a6e676a7e3933a658bc2f86a603efc SHA512 8a546360948bde566f6853ad63b38f6fbbdd5cfe8bb6b74379e3feae9aeb0f71c1bd7f1e90798cd95c0203e696d73e2797bdb73160106ae4b9ec661f65b860a0
diff --git a/dev-python/notebook/notebook-6.4.7.ebuild b/dev-python/notebook/notebook-6.4.7.ebuild
new file mode 100644
index 000000000000..e8a347e23b7b
--- /dev/null
+++ b/dev-python/notebook/notebook-6.4.7.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-5.3.4[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/nest_asyncio-1.5[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	>=dev-python/send2trash-1.8.0[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]"
+
+# sphinx 2+ seems to have a problem with its github plugin. temporarily adding
+# a version constraint.
+BDEPEND="
+	test? (
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-5.7.0-no-mathjax.patch
+)
+
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		# trash doesn't seem to work for us
+		notebook/services/contents/tests/test_contents_api.py::APITest::test_checkpoints_follow_file
+		notebook/services/contents/tests/test_contents_api.py::APITest::test_delete
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_checkpoints_follow_file
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete_dirs
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete_non_empty_dir
+		notebook/services/contents/tests/test_manager.py::TestContentsManager::test_delete
+		notebook/services/contents/tests/test_manager.py::TestContentsManagerNoAtomic::test_delete
+		# TODO
+		notebook/services/kernels/tests/test_kernels_api.py::KernelAPITest::test_connections
+		notebook/services/kernels/tests/test_kernels_api.py::AsyncKernelAPITest::test_connections
+		notebook/services/kernels/tests/test_kernels_api.py::KernelCullingTest::test_culling
+	)
+
+	# selenium tests require geckodriver
+	epytest --ignore notebook/tests/selenium ${deselect[@]/#/--deselect }
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/dev-python/pipenv/Manifest b/dev-python/pipenv/Manifest
index 621cd3ceea21..e15fa639e79d 100644
--- a/dev-python/pipenv/Manifest
+++ b/dev-python/pipenv/Manifest
@@ -1,2 +1,3 @@
 DIST pipenv-2021.11.23.tar.gz 11378116 BLAKE2B aa30c86aa3b20333d0bffc8c49761869cc9e86b69920abe5e58a0aa7ccf35a8faf6b8b29ce408c85239624a999ca4e67f4a687e1e9aa15271bea31a135acdb7d SHA512 3873a3e7de33677b63bb133e397f46030ec28a24479b38009a4c409d93277327e8f53694fa56fdb8120f9cd632e849fde6f4205e29d9f5704c8844101e8e8298
 DIST pipenv-2021.11.9.tar.gz 11652360 BLAKE2B ab7d733e0c44a8551d2b786680646f5efa9effdc6b6a74fc0b8286336c84b9795229036cc8b7179a4ee3d6c91701d82fdd2e8303c7c9a9da1e06eb78fb2a0214 SHA512 6ad44fe70d3e3f5bbdedb891c76ad1c37863e6f4215c34f2ef6aa1a35b89fb6262f8c55f7f2e71544e550d66d20567f12ce4698f9e3a899853aa49a0849c3189
+DIST pipenv-2022.1.8.tar.gz 11379235 BLAKE2B b73df14688ebe6d0c6153c64c2f3cd5106f184466061177cebfac120fc49af403a5d27919a8ff0e5a40e04a9950ab9949938c1d4c8d0c1a4df98440a3a2a2ae0 SHA512 9bad380548723172eddbbb9ebfc35a46effbd8eeeff47ad347d0ab5ae9f52e20de8dfc205dab6fb8ae8763edc488cf867a64ed443895242feb444d1bc0d9b8e0
diff --git a/dev-python/pipenv/files/pipenv-2022-1-8-remove-first-vendor-import.patch b/dev-python/pipenv/files/pipenv-2022-1-8-remove-first-vendor-import.patch
new file mode 100644
index 000000000000..a8ff7d107f9c
--- /dev/null
+++ b/dev-python/pipenv/files/pipenv-2022-1-8-remove-first-vendor-import.patch
@@ -0,0 +1,162 @@
+From eefc2db1adcfdd9afc1955c81d73dc3d32c65a57 Mon Sep 17 00:00:00 2001
+From: Oz N Tiram <oz.tiram@gmail.com>
+Date: Sun, 9 Jan 2022 23:52:06 +0100
+Subject: [PATCH] Remove vendored first
+
+While first is nice to have, it adds a lot of code in vendor.
+This patch achieves the same with less code in vendor (~80 lines less).
+---
+ pipenv/core.py              |  4 +-
+ pipenv/vendor/first.LICENSE | 19 ---------
+ pipenv/vendor/first.py      | 78 -------------------------------------
+ pipenv/vendor/vendor.txt    |  1 -
+ 4 files changed, 2 insertions(+), 100 deletions(-)
+ delete mode 100644 pipenv/vendor/first.LICENSE
+ delete mode 100644 pipenv/vendor/first.py
+
+diff --git a/pipenv/core.py b/pipenv/core.py
+index 92811f74..1c04047c 100644
+--- a/pipenv/core.py
++++ b/pipenv/core.py
+@@ -2525,7 +2525,6 @@ def do_check(
+     args=None,
+     pypi_mirror=None
+ ):
+-    from first import first
+     from pipenv.vendor.vistir.compat import JSONDecodeError
+ 
+     if not system:
+@@ -2569,7 +2568,8 @@ def do_check(
+     if not system:
+         python = project._which("python")
+     else:
+-        python = first(system_which(p) for p in ("python", "python3", "python2"))
++        interpreters = [system_which(p) for p in ("python", "python3", "python2")]
++        python = interpreters[0] if interpreters else None
+     if not python:
+         click.echo(crayons.red("The Python interpreter can't be found."), err=True)
+         sys.exit(1)
+diff --git a/pipenv/vendor/first.LICENSE b/pipenv/vendor/first.LICENSE
+deleted file mode 100644
+index a9c8c9db..00000000
+--- a/pipenv/vendor/first.LICENSE
++++ /dev/null
+@@ -1,19 +0,0 @@
+-Copyright (c) 2012 Hynek Schlawack
+-
+-Permission is hereby granted, free of charge, to any person obtaining a copy of
+-this software and associated documentation files (the "Software"), to deal in
+-the Software without restriction, including without limitation the rights to
+-use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies
+-of the Software, and to permit persons to whom the Software is furnished to do
+-so, subject to the following conditions:
+-
+-The above copyright notice and this permission notice shall be included in all
+-copies or substantial portions of the Software.
+-
+-THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+-IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+-FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+-AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+-LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+-OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+-SOFTWARE.
+diff --git a/pipenv/vendor/first.py b/pipenv/vendor/first.py
+deleted file mode 100644
+index 8cf9d2d1..00000000
+--- a/pipenv/vendor/first.py
++++ /dev/null
+@@ -1,78 +0,0 @@
+-## -*- coding: utf-8 -*-
+-
+-"""
+-first
+-=====
+-
+-first is the function you always missed in Python.
+-
+-In the simplest case, it returns the first true element from an iterable:
+-
+->>> from first import first
+->>> first([0, False, None, [], (), 42])
+-42
+-
+-Or None if there is none:
+-
+->>> from first import first
+->>> first([]) is None
+-True
+->>> first([0, False, None, [], ()]) is None
+-True
+-
+-It also supports the passing of a key argument to help selecting the first
+-match in a more advanced way.
+-
+->>> from first import first
+->>> first([1, 1, 3, 4, 5], key=lambda x: x % 2 == 0)
+-4
+-
+-:copyright: (c) 2012 by Hynek Schlawack.
+-:license: MIT, see LICENSE for more details.
+-
+-"""
+-
+-__title__ = 'first'
+-__version__ = '2.0.2'
+-__author__ = 'Hynek Schlawack'
+-__license__ = 'MIT'
+-__copyright__ = 'Copyright 2012 Hynek Schlawack'
+-
+-
+-def first(iterable, default=None, key=None):
+-    """
+-    Return first element of `iterable` that evaluates true, else return None
+-    (or an optional default value).
+-
+-    >>> first([0, False, None, [], (), 42])
+-    42
+-
+-    >>> first([0, False, None, [], ()]) is None
+-    True
+-
+-    >>> first([0, False, None, [], ()], default='ohai')
+-    'ohai'
+-
+-    >>> import re
+-    >>> m = first(re.match(regex, 'abc') for regex in ['b.*', 'a(.*)'])
+-    >>> m.group(1)
+-    'bc'
+-
+-    The optional `key` argument specifies a one-argument predicate function
+-    like that used for `filter()`.  The `key` argument, if supplied, must be
+-    in keyword form.  For example:
+-
+-    >>> first([1, 1, 3, 4, 5], key=lambda x: x % 2 == 0)
+-    4
+-
+-    """
+-    if key is None:
+-        for el in iterable:
+-            if el:
+-                return el
+-    else:
+-        for el in iterable:
+-            if key(el):
+-                return el
+-
+-    return default
+diff --git a/pipenv/vendor/vendor.txt b/pipenv/vendor/vendor.txt
+index 0530062e..3d7b39ea 100644
+--- a/pipenv/vendor/vendor.txt
++++ b/pipenv/vendor/vendor.txt
+@@ -10,7 +10,6 @@ colorama==0.4.4
+ distlib==0.3.2
+ docopt==0.6.2
+ dparse==0.5.1
+-first==2.0.2
+ funcsigs==1.0.2
+ idna==3.2
+ importlib-metadata==4.6.1
+-- 
+2.32.0
+
diff --git a/dev-python/pipenv/pipenv-2022.1.8.ebuild b/dev-python/pipenv/pipenv-2022.1.8.ebuild
new file mode 100644
index 000000000000..528964370cac
--- /dev/null
+++ b/dev-python/pipenv/pipenv-2022.1.8.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+MY_PV=${PV/_beta/b}
+DESCRIPTION="Python Development Workflow for Humans"
+HOMEPAGE="https://github.com/pypa/pipenv https://pypi.org/project/pipenv/"
+SRC_URI="https://github.com/pypa/pipenv/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${MY_PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-${PV//./-}-remove-first-vendor-import.patch"
+	)
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/cached-property[${PYTHON_USEDEP}]
+	>=dev-python/cerberus-1.3.2[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.4[${PYTHON_USEDEP}]
+	dev-python/docopt[${PYTHON_USEDEP}]
+	>=dev-python/idna-3.2[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.8.0[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.0.35[${PYTHON_USEDEP}]
+	dev-python/virtualenv-clone[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	<dev-python/tomli-2[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.7[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
+	>=dev-python/zipp-3.6.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+# IMPORTANT: The following sed command patches the vendor direcotry
+# in the pipenv source. Attempts to simply bump the version of the
+# package without checking that it works is likely to fail
+# The vendored packages should eventually all be removed
+# see: https://bugs.gentoo.org/717666
+src_prepare() {
+
+	local jobs=$(makeopts_jobs)
+	local packages=( attr cerberus cached_property colorama docopt first idna pexpect dateutil requests \
+						toml tomli urllib3 zipp )
+	for pkgName in ${packages[@]}; do
+		find ./ -type f -print0 | \
+			xargs --max-procs="${jobs}" --null \
+			sed --in-place \
+				-e 's/from pipenv.vendor import '"${pkgName}"'/import '"${pkgName}"'/g' \
+				-e 's/from pipenv.vendor.'"${pkgName}"'\(.*\) import \(\w*\)/from '"${pkgName}"'\1 import \2/g' \
+				-e 's/import pipenv.vendor.'"${pkgName}"' as '"${pkgName}"'/import '"${pkgName}"'/g' \
+				-e 's/from .vendor import '"${pkgName}"'/import '"${pkgName}"'/g'
+	done
+	assert "Failed to sed sources"
+
+	distutils-r1_src_prepare
+
+	# remove vendored versions
+	for pkgName in ${packages[@]}; do
+		 find ./pipenv/vendor/ -name "${pkgName}*" -prune -exec rm -rvf {} + || die
+		 # package names can be foo-bar, their module will be however foo_bar
+		 find ./pipenv/vendor/ -name "${pkgName/_/-}*" -prune -exec rm -rvf {} + || die
+
+	done
+
+	# not actually used by pipenv, but included in pipenv
+	rm -vR "${S}/${PN}/vendor/wheel/" || die
+}
+
+python_test() {
+	pytest -vvv -x -m "not cli and not needs_internet" tests/unit/ || die
+}
diff --git a/dev-python/pyfakefs/Manifest b/dev-python/pyfakefs/Manifest
index d3464cfda22c..76107d2d551d 100644
--- a/dev-python/pyfakefs/Manifest
+++ b/dev-python/pyfakefs/Manifest
@@ -1 +1,2 @@
 DIST pyfakefs-4.5.3.tar.gz 204661 BLAKE2B 87340d98850cad83b5288d310a5e5d9774247bb71ce7fa314243e38ec3d8e0d42f50f73da2e8c732694c35359e36286c896cb7b2703aa91443d22df95aebbe6b SHA512 0fa42a81acb565292d8a9fde220f033100a4fc07eb8d095e79ed98af415fc285d4db46dd9b891e595f599a9ab48323ff7aad4928b47a6df0d5bbf94c975f605c
+DIST pyfakefs-4.5.4.tar.gz 205086 BLAKE2B c8d9273b351ce4db66764e8972afd4d221bba7735ae2796855c1a23825fe9d678b8e8bd8b8185b37779c5fd263a2109867f261157b61db20cb56b9622cf99ae9 SHA512 419452dae9de2c046be269f7d5f5c14e9a4e14ea6d4d1a9df4a3993ef4fd350011875d4b9484f180a760974a0123bcc7460a32a85d39708837261beeee8be93f
diff --git a/dev-python/pyfakefs/pyfakefs-4.5.4.ebuild b/dev-python/pyfakefs/pyfakefs-4.5.4.ebuild
new file mode 100644
index 000000000000..f137b291d55e
--- /dev/null
+++ b/dev-python/pyfakefs/pyfakefs-4.5.4.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+DISTUTILS_IN_SOURCE_BUILD=1
+
+inherit distutils-r1
+
+DESCRIPTION="a fake file system that mocks the Python file system modules"
+HOMEPAGE="https://github.com/jmcgeheeiv/pyfakefs/ https://pypi.org/project/pyfakefs/"
+SRC_URI="https://github.com/jmcgeheeiv/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest
+
+python_test() {
+	"${EPYTHON}" -m pyfakefs.tests.all_tests -v || die "tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/python-bugzilla/Manifest b/dev-python/python-bugzilla/Manifest
index 1ea1ea9fff12..f5a926b1b17a 100644
--- a/dev-python/python-bugzilla/Manifest
+++ b/dev-python/python-bugzilla/Manifest
@@ -1 +1,2 @@
 DIST python-bugzilla-3.1.0.tar.gz 115259 BLAKE2B d3eed35aeb9778e23266fb3ce1fc477a93c09533c78e478292b90cd49668f2627d7ef47afd46973898b4d5de474399aae5e94e5cd776d5608d32325dc826c12c SHA512 8f95a60e559cc5b4576d81f37c7104d6bd4afae21986db3c5ef05c6021e601690a01ca97d67fa37e97026f0b97762594e8edd0454953e31930fa841696f65121
+DIST python-bugzilla-3.2.0.tar.gz 114279 BLAKE2B 4d2d7bfaab08dfeb4334462334f23f952b43255e656b0e39eff29bfc206529062c86c79b8c83110fbc5c3970bba40663318b65e208c1b10fb04ab6fb474eeb95 SHA512 215945a0ffd637be5567839303a738a0eef74427838bf0074a5f0ab6022306f47fc0dd5c43a3513b627fb458711f38046321ee9c2c3d43b61ffc577d6dd12375
diff --git a/dev-python/python-bugzilla/python-bugzilla-3.2.0.ebuild b/dev-python/python-bugzilla/python-bugzilla-3.2.0.ebuild
new file mode 100644
index 000000000000..6e11ca4eda96
--- /dev/null
+++ b/dev-python/python-bugzilla/python-bugzilla-3.2.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A python module for interacting with Bugzilla over XMLRPC"
+HOMEPAGE="https://github.com/python-bugzilla/python-bugzilla"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+LICENSE="GPL-2+"
+SLOT="0"
+
+RDEPEND="
+	|| (
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		sys-apps/file[python,${PYTHON_USEDEP}]
+	)
+	dev-python/requests[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest