Adding metadata

29 files changed, 387 insertions, 95 deletions

diff --git a/dev-python/cssutils/Manifest b/dev-python/cssutils/Manifest
index f49e6b30d29c..9c0cbc26e75e 100644
--- a/dev-python/cssutils/Manifest
+++ b/dev-python/cssutils/Manifest
@@ -1 +1,2 @@
 DIST cssutils-2.6.0.tar.gz 723259 BLAKE2B 6548e87c78fe6b850b98989521c27cebd4170939517edca895c2787c1367e1c6dc94308355f7dd2e1dee7194f88bd025b72c801cd9b90f8a08ab244f6a4e890e SHA512 95ce26cc4816e7750fc0f1e0c4ac60f176e3c7b3ea1871440bf937d442e0f8626f9e4c75622c0ea3a84d68ceb4b768544e9642936beb87eff1b55117ce47b311
+DIST cssutils-2.7.0.tar.gz 724282 BLAKE2B db2b56bc919d266b6f5f3c334c424748b94dc754a7734af3d09551918bff669fcc16b2da4466ebd22439b8056084126cd90c49b1282613ce2242dfdba251d4c9 SHA512 378ae1f263dcc2fc3f523e1e33977ebb5b46a16cf642aa067ea97f2293d94932dea1cddd825562041145995b6d899b8912add6055425b47c3baba97db05a2dab
diff --git a/dev-python/cssutils/cssutils-2.7.0.ebuild b/dev-python/cssutils/cssutils-2.7.0.ebuild
new file mode 100644
index 000000000000..a6189e42daba
--- /dev/null
+++ b/dev-python/cssutils/cssutils-2.7.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A CSS Cascading Style Sheets library"
+HOMEPAGE="
+	https://pypi.org/project/cssutils/
+	https://github.com/jaraco/cssutils/
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		>=dev-python/jaraco-test-5.1[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/importlib-resources[${PYTHON_USEDEP}]
+		' 3.8)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# network
+		encutils/__init__.py::encutils
+		cssutils/tests/test_parse.py::TestCSSParser::test_parseUrl
+		examples/website.py::examples.website.logging
+	)
+	local EPYTEST_IGNORE=(
+		# path mismatch with "parse" package
+		examples/parse.py
+	)
+
+	epytest
+}
diff --git a/dev-python/elasticsearch-py/elasticsearch-py-8.6.2.ebuild b/dev-python/elasticsearch-py/elasticsearch-py-8.6.2.ebuild
index bb8f46e28279..f11b11f06710 100644
--- a/dev-python/elasticsearch-py/elasticsearch-py-8.6.2.ebuild
+++ b/dev-python/elasticsearch-py/elasticsearch-py-8.6.2.ebuild
@@ -23,7 +23,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0/$(ver_cut 1)"
-KEYWORDS="amd64 x86"
+KEYWORDS="amd64 ~x86"
 
 RESTRICT="
 	!amd64? ( test )
diff --git a/dev-python/eradicate/Manifest b/dev-python/eradicate/Manifest
index 0ebf9fae31db..1a503ccb9695 100644
--- a/dev-python/eradicate/Manifest
+++ b/dev-python/eradicate/Manifest
@@ -1 +1,2 @@
 DIST eradicate-2.2.0.gh.tar.gz 8808 BLAKE2B 34d1db824f6288d5da5cdc868045d899041b219e4918f5e838c066eb4e9903c2951c7cdded56c7c5455336940c212eb3e68ae61b9e090f497c3e6ef199f71e80 SHA512 80b7dd60004a5f4279a87c692b63de1b340c68d1379d975ef660130a649acbc03a5c5d6db935c782b84bbc7c2ab50b0ada2a172eafce1945113b3bccfb8055b5
+DIST eradicate-2.3.0.gh.tar.gz 8792 BLAKE2B 586989144ca69637ea769b90a72afa68eb4392e2b467d3a97f9adfc91d45d3f5be6ea6c8f00f0aa8307b52bca7243fd12e3eaad178ad3859918d137275d447c0 SHA512 b31f59b5785aa57fa55c329bfce430e8ade5de870bbe99585ff59e68fdd33bb312e49ecd72873780e47e09f713ebbaa929bd6981bf2800f858def80a9c03a8ec
diff --git a/dev-python/eradicate/eradicate-2.3.0.ebuild b/dev-python/eradicate/eradicate-2.3.0.ebuild
new file mode 100644
index 000000000000..cd170ff51234
--- /dev/null
+++ b/dev-python/eradicate/eradicate-2.3.0.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Removes commented-out code from Python files"
+HOMEPAGE="
+	https://github.com/wemake-services/eradicate/
+	https://pypi.org/project/eradicate/
+"
+SRC_URI="
+	https://github.com/wemake-services/eradicate/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_tests unittest
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 986e97ca8b33..3adbb4f95d0a 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -4,3 +4,4 @@ DIST hypothesis-6.75.6.gh.tar.gz 9370713 BLAKE2B 93996d6ff0c109c11123ad9b653502c
 DIST hypothesis-6.75.7.gh.tar.gz 9371718 BLAKE2B 9b0c9f4589be2c81fdb79a1157fcf3815dd7f9c11e3c68e14319c10fdb7a534e90e3c1ae042889057bfdb97ae3ffcf9f0360d7fb1b17419309f31b190aa03d9e SHA512 ac4da9e837606f0d98361386e51496f21d9f53ceb0fdd9b3d14eb85456eaa3b4f7cbc7b29754b6b400093fd38b3d3c89ef74be6662f113e0eed87afbf0382ce1
 DIST hypothesis-6.75.9.gh.tar.gz 9372102 BLAKE2B 9588536fade56f4f87f54a0dfd7c911934f08aad71f31785210d99dfb8060bf9719a3bc3e9a0dcd647261a4a1927d5b7cb1cab8135dd9b97ebb321d79a23946e SHA512 29dfd1e9ff1087080a8dcd9c0c25c5e01c79839ac736d20f3eb31b1173b702e31c6b7d777c03f8f5674ec13e9bdc51aab6be8b1d20d067a30508914bcf61e8f1
 DIST hypothesis-6.76.0.gh.tar.gz 9373576 BLAKE2B ed580296f163f9808597aa3a7b2ceaf1ea43431a9049ffdba229dc0f7886c8ee42829c45c98cc8ec0aae7d1f41f455f7ffd818beb1a956498ac4d676cd72b678 SHA512 2e46762a3bcc595c92eb57e65b2c7ef07062df1c393033efd2cb6b3c774ecbbe41f672e7b6c63ca0e8afb732c0f5308dddd6908bc2f43eab5c0713a6d688d5f4
+DIST hypothesis-6.77.0.gh.tar.gz 9376438 BLAKE2B 2c80427a43481fbc837042c8481e56f1186fa9026c15902f489b1d26cda216f33df6da2025e37d8b37676047d7a8be1f0aea686ec0d2d18178d14e5e8f08f24c SHA512 17c1a0d1b00c0bd9a4373c5cafa7f58f4f6c85a85a107f4afff7064b52280a21210502c555291a580c81c1085f7c5fdd9db91391b29b2af6e476c83f4838fe1a
diff --git a/dev-python/hypothesis/hypothesis-6.77.0.ebuild b/dev-python/hypothesis/hypothesis-6.77.0.ebuild
new file mode 100644
index 000000000000..5adfa14c0a19
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.77.0.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..11} )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_IGNORE=()
+	local EPYTEST_DESELECT=(
+		# these tests can randomly fail with RecursionError when run
+		# in parallel
+		# https://github.com/HypothesisWorks/hypothesis/issues/3671
+		hypothesis-python/tests/cover/test_lookup.py::test_resolving_mutually_recursive_types
+		hypothesis-python/tests/cover/test_lookup.py::test_resolving_mutually_recursive_types_with_defaults
+	)
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				hypothesis-python/tests/cover/test_lookup.py
+				hypothesis-python/tests/cover/test_type_lookup.py
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 65804e292881..cfc9dff155da 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,3 +1,2 @@
-DIST ipykernel-6.22.0.tar.gz 151303 BLAKE2B c3567066375099d388c65b43b5b8c8059a823f4185855b6131fd90f42624a71c08d839a3c59c41cf83bb51ec07d0c0487d7bbee573eafa7e7d049dbeff8e59a8 SHA512 e109a2b771ffa40e05416bd925f26a4492c65a44a1acd8100e65ae3e779da9a0eef7222566e79cdcbed4b0fc3224fbd0722728d3fe953b16ab1a14090d0205c2
 DIST ipykernel-6.23.0.tar.gz 151969 BLAKE2B c41aac053b27a2e3618831f8d6458b21877b4510062019576fe98f921b9485fe180f2bced09c0a8ddd930af5a386a09d4d13a2ffbb78e58d71bb7a7cea1c91c1 SHA512 d852742bd858639d150864d343da23ee915c2034b8fbad7875755ea580be80b5faf553c16af65c50001f214979cd4a80c89fe08e4db7198754b554de0101a1d1
 DIST ipykernel-6.23.1.tar.gz 153370 BLAKE2B 654998d46851bcc55d3c0c9c6134f3fcf8c81c2552d5af6dcdbd791e1ac98ed223a59aafc9b7b4260345f8730d243d3c82d4e19e03935a368a0a0154de547cb0 SHA512 8f3921789c837f7c046eed4ffdaade2273b6491cfd97b9a192a256966a66d58c1ad93cbfa69a5e933e052fa35c2c7a4671a652ee9f2bb2cca5a156c79df0f14f
diff --git a/dev-python/ipykernel/ipykernel-6.22.0.ebuild b/dev-python/ipykernel/ipykernel-6.22.0.ebuild
deleted file mode 100644
index 2fa5f5e4d57f..000000000000
--- a/dev-python/ipykernel/ipykernel-6.22.0.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{7,8,9,10,11} )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1 pypi virtualx
-
-DESCRIPTION="IPython Kernel for Jupyter"
-HOMEPAGE="
-	https://github.com/ipython/ipykernel/
-	https://pypi.org/project/ipykernel/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
-	>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
-	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
-	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
-	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
-	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
-	dev-python/nest_asyncio[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	dev-python/psutil[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-20[${PYTHON_USEDEP}]
-	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
-	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
-"
-# RDEPEND seems specifically needed in BDEPEND, at least jupyter
-# bug #816486
-BDEPEND="
-	${RDEPEND}
-	test? (
-		dev-python/flaky[${PYTHON_USEDEP}]
-		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
-		dev-python/pytest-timeout[${PYTHON_USEDEP}]
-		dev-python/ipyparallel[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
-	distutils-r1_src_prepare
-}
-
-python_compile() {
-	distutils-r1_python_compile
-	# Use python3 in kernel.json configuration, bug #784764
-	sed -i -e '/python3.[0-9]\+/s//python3/' \
-		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
-}
-
-src_test() {
-	local EPYTEST_DESELECT=(
-		# TODO
-		ipykernel/tests/test_debugger.py::test_attach_debug
-		ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
-		ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
-		ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
-		ipykernel/tests/test_debugger.py::test_set_breakpoints
-		ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
-		ipykernel/tests/test_debugger.py::test_copy_to_globals
-		# hangs?
-		ipykernel/tests/test_eventloop.py::test_tk_loop
-	)
-
-	virtx distutils-r1_src_test
-}
diff --git a/dev-python/ipykernel/ipykernel-6.23.0.ebuild b/dev-python/ipykernel/ipykernel-6.23.0.ebuild
index 1fd114899109..2fa5f5e4d57f 100644
--- a/dev-python/ipykernel/ipykernel-6.23.0.ebuild
+++ b/dev-python/ipykernel/ipykernel-6.23.0.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
 	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
diff --git a/dev-python/iso8601/Manifest b/dev-python/iso8601/Manifest
index 3590dadfadb5..a7bed643d752 100644
--- a/dev-python/iso8601/Manifest
+++ b/dev-python/iso8601/Manifest
@@ -1 +1,2 @@
 DIST iso8601-1.1.0.tar.gz 12836 BLAKE2B 7860d52002008a76c1d28ae94abe5100c3ea434f8e19dcb677dfc84366e898d2d277d88e6591d663579281c4ee668e77db96fd586edbe8b027433844462071e9 SHA512 f3f9621863abcbcde467d38416391cd8c98f59b7b863845b670e11060f0f81bcf4979fadc51c19eb55a5fe44ee1af922976b11cc97bf7b2dc090a485ad9979ac
+DIST iso8601-2.0.0.tar.gz 6497 BLAKE2B 6c25a267e35afe1c0d879fd4be5f3c6e47750b4faf70f9238767e8ad901fb2da9b823dab9a3f3e26ccec843a4f993a331f6f7c616f98fd1520a5e4d16268060a SHA512 786bd2604cedeba8bfaa3ca0077057540fc898d9f942627958955406705f104c2109f20c84dfc79674178dfaf4bd0936b4e7759024c7f4b8ed130e40bbfc3c07
diff --git a/dev-python/iso8601/iso8601-2.0.0.ebuild b/dev-python/iso8601/iso8601-2.0.0.ebuild
new file mode 100644
index 000000000000..65772dcf4d3b
--- /dev/null
+++ b/dev-python/iso8601/iso8601-2.0.0.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple module to parse ISO 8601 dates"
+HOMEPAGE="
+	https://github.com/micktwomey/pyiso8601/
+	https://pypi.org/project/iso8601/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/mapbox-vector-tile/mapbox-vector-tile-2.0.1.ebuild b/dev-python/mapbox-vector-tile/mapbox-vector-tile-2.0.1.ebuild
index 954b43d4cfd2..db6a206e77fc 100644
--- a/dev-python/mapbox-vector-tile/mapbox-vector-tile-2.0.1.ebuild
+++ b/dev-python/mapbox-vector-tile/mapbox-vector-tile-2.0.1.ebuild
@@ -16,7 +16,7 @@ SRC_URI="https://github.com/tilezen/mapbox-vector-tile/archive/refs/tags/v${PV}.
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 x86"
+KEYWORDS="amd64 ~x86"
 
 RDEPEND="
 	dev-python/protobuf-python[${PYTHON_USEDEP}]
diff --git a/dev-python/pygraphviz/pygraphviz-1.10.ebuild b/dev-python/pygraphviz/pygraphviz-1.10.ebuild
index b6b0729416a4..2947ddbd711a 100644
--- a/dev-python/pygraphviz/pygraphviz-1.10.ebuild
+++ b/dev-python/pygraphviz/pygraphviz-1.10.ebuild
@@ -31,9 +31,6 @@ RDEPEND="
 BDEPEND="
 	app-arch/unzip
 	dev-lang/swig:0
-	test? (
-		dev-python/doctest-ignore-unicode[${PYTHON_USEDEP}]
-	)
 "
 
 distutils_enable_tests pytest
diff --git a/dev-python/pygraphviz/pygraphviz-1.11.ebuild b/dev-python/pygraphviz/pygraphviz-1.11.ebuild
index 34ed33d51b8a..6f16537ed551 100644
--- a/dev-python/pygraphviz/pygraphviz-1.11.ebuild
+++ b/dev-python/pygraphviz/pygraphviz-1.11.ebuild
@@ -31,9 +31,6 @@ RDEPEND="
 BDEPEND="
 	app-arch/unzip
 	dev-lang/swig:0
-	test? (
-		dev-python/doctest-ignore-unicode[${PYTHON_USEDEP}]
-	)
 "
 
 distutils_enable_tests pytest
diff --git a/dev-python/pyproj/pyproj-3.5.0.ebuild b/dev-python/pyproj/pyproj-3.5.0.ebuild
index 245d4497e9e3..8e756e601061 100644
--- a/dev-python/pyproj/pyproj-3.5.0.ebuild
+++ b/dev-python/pyproj/pyproj-3.5.0.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-linux"
+KEYWORDS="amd64 ~x86 ~amd64-linux"
 
 RDEPEND="
 	>=sci-libs/proj-9.0.0:=
diff --git a/dev-python/pyqtgraph/pyqtgraph-0.13.2.ebuild b/dev-python/pyqtgraph/pyqtgraph-0.13.2.ebuild
index f0e82630fcd7..f964918771b6 100644
--- a/dev-python/pyqtgraph/pyqtgraph-0.13.2.ebuild
+++ b/dev-python/pyqtgraph/pyqtgraph-0.13.2.ebuild
@@ -22,7 +22,7 @@ S=${WORKDIR}/${PN}-${P}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~riscv x86"
+KEYWORDS="amd64 ~arm ~riscv ~x86"
 IUSE="opengl svg"
 REQUIRED_USE="test? ( opengl svg )"
 
diff --git a/dev-python/redis/redis-4.5.5.ebuild b/dev-python/redis/redis-4.5.5.ebuild
index 30d92426ee55..f4fd62eae93f 100644
--- a/dev-python/redis/redis-4.5.5.ebuild
+++ b/dev-python/redis/redis-4.5.5.ebuild
@@ -22,7 +22,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~riscv sparc x86"
 
 RDEPEND="
 	$(python_gen_cond_dep '
diff --git a/dev-python/reportlab/Manifest b/dev-python/reportlab/Manifest
index 0bec45521e9a..dce410a5e94a 100644
--- a/dev-python/reportlab/Manifest
+++ b/dev-python/reportlab/Manifest
@@ -1,2 +1,3 @@
 DIST pfbfer-20070710.zip 677333 BLAKE2B 100214476a361a5e5d1f3da0999591345f6e3a3f8c6bc3f6a3e9eca734190c6259758a43302c6e41254d33491fe535eb7d5dd07aa9727c912424bebc31fc18df SHA512 6fd4a5d955464b10d13a7b748703450c1fe120d5ed09e8cfa1b4dfa9c183c59fe001df29433af551796b0df62544b7ddc364f9bb1bdcc2cd300434340ffcc4f2
 DIST reportlab-3.6.13.tar.gz 4035524 BLAKE2B 638b670b76b4cfb88c0a66db484f5b4d042fd935798316d02303932503e353a6035419d7ef1c4dccd8ef94b3cc2e13a576fd3cb5461fca17122a800f1140945a SHA512 059c3acf2c995ebdd3ffe005bd98640bc9c063c2fb9b3115351b9c1a4f7cfdabf4ffe61123342de2e84773005d46cf6d44410042206222df0700259e31ec7aae
+DIST reportlab-4.0.4.tar.gz 3132866 BLAKE2B eb1791b248c8c0dc194781ca09dbf181dc20f745ce2fdd3a4627ae027b21baddc0bea56c6e5eefd5905f7656c5a3a388d90310ce53a948ab0a3dbaff569f2d63 SHA512 7d79f6258672523bee50256b5b15e336801fc42f290fa2ed5ed0ab355c9f2903c9210bb935c9c00fa74174072232402247c923268ede5d61ca62493d0faa2844
diff --git a/dev-python/reportlab/metadata.xml b/dev-python/reportlab/metadata.xml
index 09fe05214a03..2cca83ef0f6c 100644
--- a/dev-python/reportlab/metadata.xml
+++ b/dev-python/reportlab/metadata.xml
@@ -33,7 +33,6 @@
   </longdescription>
  <upstream>
   <bugs-to>mailto:reportlab-users@lists2.reportlab.com</bugs-to>
-  <doc lang="en">https://www.reportlab.com/dev/docs/</doc>
  </upstream>
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/reportlab/reportlab-4.0.4.ebuild b/dev-python/reportlab/reportlab-4.0.4.ebuild
new file mode 100644
index 000000000000..7c45c6f727ca
--- /dev/null
+++ b/dev-python/reportlab/reportlab-4.0.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Tools for generating printable PDF documents from any data source"
+HOMEPAGE="
+	https://www.reportlab.com/
+	https://pypi.org/project/reportlab/
+"
+SRC_URI+="
+	https://www.reportlab.com/ftp/fonts/pfbfer-20070710.zip
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/pillow[tiff,truetype,jpeg(+),${PYTHON_USEDEP}]
+"
+BDEPEND="
+	app-arch/unzip
+"
+
+distutils_enable_sphinx docs/source
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd ${P}/src/reportlab/fonts || die
+	unpack pfbfer-20070710.zip
+}
+
+src_configure() {
+	cat > local-setup.cfg <<-EOF || die
+		[OPTIONS]
+		no-download-t1-files = 1
+	EOF
+}
+
+python_test() {
+	pushd tests >/dev/null || die
+	"${EPYTHON}" runAll.py --post-install --verbosity=2 ||
+		die "Testing failed with ${EPYTHON}"
+	popd >/dev/null || die
+}
diff --git a/dev-python/rpy/rpy-3.5.8.ebuild b/dev-python/rpy/rpy-3.5.8.ebuild
index af41efc3361c..09090d4f7f64 100644
--- a/dev-python/rpy/rpy-3.5.8.ebuild
+++ b/dev-python/rpy/rpy-3.5.8.ebuild
@@ -23,7 +23,7 @@ S="${WORKDIR}/${MY_P}"
 
 LICENSE="AGPL-3 GPL-2 LGPL-2.1 MPL-1.1"
 SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
 
 # ggplot2 is a test dep but not in ::gentoo atm
 RESTRICT="test"
diff --git a/dev-python/shapely/shapely-2.0.1.ebuild b/dev-python/shapely/shapely-2.0.1.ebuild
index 788d6e8766af..5c8c48c27b6a 100644
--- a/dev-python/shapely/shapely-2.0.1.ebuild
+++ b/dev-python/shapely/shapely-2.0.1.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~arm64 x86"
+KEYWORDS="amd64 ~arm64 ~x86"
 
 DEPEND="
 	>=sci-libs/geos-3.9
diff --git a/dev-python/symengine/symengine-0.9.2-r3.ebuild b/dev-python/symengine/symengine-0.9.2-r3.ebuild
index ce20115bf9cc..a0de6eb5f1ac 100644
--- a/dev-python/symengine/symengine-0.9.2-r3.ebuild
+++ b/dev-python/symengine/symengine-0.9.2-r3.ebuild
@@ -22,7 +22,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~riscv x86"
+KEYWORDS="amd64 ~arm ~arm64 ~riscv ~x86"
 
 BDEPEND="
 	dev-util/cmake
diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 848b8fd02bdc..55eda873b4b5 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-34.2.0.tar.gz 1141098 BLAKE2B 60d09fc0de49e63213bf23cc223cec92b53f887ff5677fd80cefac441166ef777bc8b96682847697702af26d8481192a2fe19ddbe42cd3b991cc0f16ed09176d SHA512 22cf6e5b6d60398a7a1698ad0bad02d8d16ffd815f573fb526becb9d1be64151bc6b33fb6b8b03f9c52f18565ca06cad1bf9725f2cff2c6116c88f85439b5d7e
+DIST tempest-35.0.0.tar.gz 1144022 BLAKE2B dd333ac1271ef51171ff7d06931138a6de5872a86e2ed49c4d94b37431f6f94092069eef6700e453ab6e5fc04f004f5bd040af64ea98531bf56eba5edc9394b3 SHA512 c8986e13c821c8861f0b9c1b37c71a1017cd6de480a5efdcc646b51d1c7032a236f98735d0f77240fc9ec9eb711638a12f7a4a8d67e99c76bc1f6b561c39c61d
diff --git a/dev-python/tempest/tempest-35.0.0.ebuild b/dev-python/tempest/tempest-35.0.0.ebuild
new file mode 100644
index 000000000000..56819857ad7d
--- /dev/null
+++ b/dev-python/tempest/tempest-35.0.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	eunittest -b -s tempest/tests -t .
+}
diff --git a/dev-python/websocket-client/Manifest b/dev-python/websocket-client/Manifest
index c88d7387dcc0..0ae497784f42 100644
--- a/dev-python/websocket-client/Manifest
+++ b/dev-python/websocket-client/Manifest
@@ -1,2 +1,3 @@
 DIST websocket-client-1.5.1.tar.gz 49942 BLAKE2B 7996798a5ff8c2eb1322fc7a9fa61d5cff99c71413293ce5b05f9af3581cff472350e79813ce3b393ce4fa4b7d19de956f0ad9ff6232c426be3c8adb8c91fb40 SHA512 9fce0c8de64e051b151c40a295a7f722ed7f95d19bd92ffd5cd9c64962821024e79b70d18ca7e30ca8b8707ba86be041134f13d7e2cf7bc4a4539eb22ba60895
 DIST websocket-client-1.5.2.tar.gz 50761 BLAKE2B 5b97ce1125a8ae2f95ea103a2436d8c3471bd88c9b6f631ed9cbc1e55bff3eb13e93f662f6892c65b0f035dca66f2b2a43230f228b4f174c56c0203f5e044b07 SHA512 0837dae6ea1096421482dc1882e522d9e9041d9777ef31517116592f7b537735d1d8e319e910481be4abaceda8f79855397e4dfce2c9e622d7e7b6e6577e404e
+DIST websocket-client-1.5.3.tar.gz 50887 BLAKE2B 3268b133c32be46a08208b61fc038b18a142b2e8ee87b1cfc61cd4ea814b9a389f7d72a08ab7dcb8da3a0aa144c1617b5825ce466b81f1f3c066605ad1b47d08 SHA512 6980b88166475f50d5f572bfcaa23f1203ecd1f2c06901ddd6df78d1bfff1ae54ef0a85348d6f28b580fcf405e496bdd67e898c6e4760098ba620bb69c52f39b
diff --git a/dev-python/websocket-client/websocket-client-1.5.3.ebuild b/dev-python/websocket-client/websocket-client-1.5.3.ebuild
new file mode 100644
index 000000000000..410b15670261
--- /dev/null
+++ b/dev-python/websocket-client/websocket-client-1.5.3.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="WebSocket client for python with hybi13 support"
+HOMEPAGE="
+	https://github.com/websocket-client/websocket-client/
+	https://pypi.org/project/websocket-client/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+BDEPEND="
+	test? (
+		dev-python/python-socks[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/websockets/websockets-11.0.3-r1.ebuild b/dev-python/websockets/websockets-11.0.3-r1.ebuild
index 9ebecd5f03d8..358b811bcf03 100644
--- a/dev-python/websockets/websockets-11.0.3-r1.ebuild
+++ b/dev-python/websockets/websockets-11.0.3-r1.ebuild
@@ -24,7 +24,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 IUSE="+native-extensions"
 
 distutils_enable_tests pytest