Adding metadata

6 files changed, 187 insertions, 0 deletions

diff --git a/dev-python/black/Manifest b/dev-python/black/Manifest
index 515f99ea8a9a..e6efcb89c777 100644
--- a/dev-python/black/Manifest
+++ b/dev-python/black/Manifest
@@ -1,3 +1,4 @@
 DIST black-21.10b0.tar.gz 1171813 BLAKE2B 71bf628aa3b2b0a73c53446061d07ed0074c2e136c6a4dd09feb4b7dcc2b8c8045417e2c6a049a3051bb2e8fc368037c540851384d00ec89ad943d0c8f949c40 SHA512 0e44fe6c34d75f135996bcd62768f3ea02f5ba996992f0173cd28977f6a9ed4fde975e7433439f3b724c54555867f91edcd167fc1c5273308a613a51905323c8
 DIST black-21.11b0.tar.gz 1198297 BLAKE2B 658f20ea9d61e64a34a61663ba4a0b0a5b3329803abab091679a605ca884b918aa0029f23cb02f4f0e150212ec25dad12985a7a2b3c95763f31ca7d4c823b653 SHA512 f3608008893747abbc2d47bf098d963dede57104d15312de6fd86f2f0c025da39a83043f63b29a208350f4eb44cbb7e47a1c8c38ef50414e9c8969feea2edbfc
+DIST black-21.12b0.tar.gz 1200305 BLAKE2B cd019b230d2ba1fab88075a5e14cb5de88a4ee283b53d869564f071a104d2810ca31c04db09310b99a1610bdace7d5b9b360b2a3a4810822322a4eacc8998ad8 SHA512 1f6e4eeafd653fa9db608585110f5c5067942031b2d67e630befa899d7fca3c35f52cbde8fc91c2697fb294fb16525254756ebce16e556fc139b621f738bfa22
 DIST black-21.9b0.tar.gz 1167869 BLAKE2B 31933de69cc34e23e14b0fdba33da844697816cd3917227c1a16c4d1595435d3715405f7f1df820953e83c30c3947448389a703ee662548226dfc2d278b87844 SHA512 0c8025d64ef9e5da8ad73b1f265b912bcb3d8cb00d8a426a39dd4c70505a77150e02a7f26e3d6842456eea367da9fad29d08f586b175d57d66a09cf389442ed0
diff --git a/dev-python/black/black-21.12_beta0.ebuild b/dev-python/black/black-21.12_beta0.ebuild
new file mode 100644
index 000000000000..6b869e31e898
--- /dev/null
+++ b/dev-python/black/black-21.12_beta0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 optfeature
+
+MY_PV="${PV//_beta/b}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="https://black.readthedocs.io/en/stable/ https://github.com/psf/black"
+SRC_URI="https://github.com/psf/${PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	<dev-python/pathspec-1[${PYTHON_USEDEP}]
+	<dev-python/tomli-2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' python3_{8,9})
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/aiohttp-3.7.4[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${MY_PV}
+
+src_prepare() {
+	# remove unnecessary bind that worked around broken 6.1.0/6.2.0 releases
+	sed -i -e '/setuptools_scm/s:~=:>=:' \
+		-e 's/setuptools_scm\[toml\]>=[0-9.]*/setuptools_scm[toml]/' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cp "${S}"/src/black_primer/primer.json \
+		"${BUILD_DIR}"/lib/black_primer/primer.json || die
+	distutils_install_for_testing
+	epytest -m "not python2"
+}
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" dev-python/aiohttp dev-python/aiohttp-cors
+}
diff --git a/dev-python/cattrs/Manifest b/dev-python/cattrs/Manifest
index 95b46e8d81d2..a9892b178bd0 100644
--- a/dev-python/cattrs/Manifest
+++ b/dev-python/cattrs/Manifest
@@ -1 +1,2 @@
 DIST cattrs-1.7.1.gh.tar.gz 85853 BLAKE2B 36c411ffa92eb263b85d48c81daeea1deea10d5779c6cd1f57988792ef5ec68bedc20b59620077e6500c2e41bb91e83f110467083f90219be7e2419c3880ed94 SHA512 a72370541cbec8928f9e1ae0c130c94e71d826ac522eb39062840d4b78a7f6aacd13395b677f6ff1453e327af31a71af0e5f81893f57ba33edbb53b7683835b2
+DIST cattrs-1.9.0.gh.tar.gz 102241 BLAKE2B 89cc71de97e1e63d3cfe3a4169c20e44d9fb8b85c6f939a0503d569dbf521d97ac325ead7c8bd58d4d32b6c6097a70effdf58553e334300639d6ef6c26b40bc7 SHA512 e1e4e59f802baf63cf931b3798bf39e4f18d5ab12a9aea000c2b649d34905d29ccb94f9ccdc5b2c52e48114fb9b292e59ab86da4c747243cae8a9d9ba25e768c
diff --git a/dev-python/cattrs/cattrs-1.9.0.ebuild b/dev-python/cattrs/cattrs-1.9.0.ebuild
new file mode 100644
index 000000000000..d7d58a0ff7ba
--- /dev/null
+++ b/dev-python/cattrs/cattrs-1.9.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Composable complex class support for attrs and dataclasses."
+HOMEPAGE="
+	https://pypi.org/project/cattrs/
+	https://github.com/python-attrs/cattrs/"
+SRC_URI="
+	https://github.com/python-attrs/cattrs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/immutables[${PYTHON_USEDEP}]
+	)"
+# test_preconf:
+#		dev-python/bson[${PYTHON_USEDEP}]
+#		dev-python/msgpack[${PYTHON_USEDEP}]
+#		dev-python/orjson[${PYTHON_USEDEP}]
+#		dev-python/pyyaml[${PYTHON_USEDEP}]
+#		dev-python/tomlkit[${PYTHON_USEDEP}]
+#		dev-python/ujson[${PYTHON_USEDEP}]
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--benchmark.*::' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# unpackaged deps, see above
+	epytest tests --ignore tests/test_preconf.py
+}
diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index 864a35bfccf4..c1522094bffc 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -1,3 +1,4 @@
 DIST cython-0.29.21.gh.tar.gz 2088511 BLAKE2B 7a4ddabb65a519d3c71454ac8417438a3a9c46b47489c18e7c7e82ffcb5d5f2f0c5246d0b364f8317d374c53f0c83844c73c7d2ef6b9f75f10707aaf2931ce41 SHA512 2c0c3e3fff07106eb98862f71cd5dec9ff29460cf9b9e4de74537ca5e033f7523989beb5fbdc14723beaf94a535976f75c803e791b87e017961d9694b8c37679
 DIST cython-0.29.23.gh.tar.gz 2093463 BLAKE2B c710b9bc9e05e0030dff3098857b349564fd167f7d9c47e2ef4e8897e072f67497b8ed3994f45135c21f8b2bf3a2cff016fec9a808b2bbe9712174dd0a6b1a3e SHA512 093b7a1d5c68f6e2d2b9b8adb9ac99e8967ddd0a66c0513a78e88bd55d96533dd8352b2478554fb53bf32a72d730967fb08ccb2eaa462da68f86891dceb4925a
 DIST cython-0.29.24.gh.tar.gz 2097245 BLAKE2B 9f5f2da0aed61d7fda2e14ea0669a2dd187cd053f3b82621342c7be29e26ff581b673a32e43bacd5c0df3e515f250eb23a64b1dae8911132fdca48175910a3dc SHA512 387a827f3cb7428248019744e3ed606a133d98ac882b83624d24ae0fdf8a8f2334978555d7d84e5cc4adaf715c541fef64e45bcbdda85ca33473c21f99360be8
+DIST cython-0.29.25.gh.tar.gz 2099536 BLAKE2B e07706662f860d8c807dc4a13660a05291eab9f33994a88639f565e9020c495215dbac9cbab69b7947ea82844a72706edfccb54f53dd80b5908ca703f30ee435 SHA512 6d1f0822eb6fb43372d42ebe3684df85ff430f58ff1f6d5774a2e1809d1f5ddc8827cee40cdc81bcb8b825cdf7b51262823a69ab4502fa28468cd1a1acab2283
diff --git a/dev-python/cython/cython-0.29.25.ebuild b/dev-python/cython/cython-0.29.25.ebuild
new file mode 100644
index 000000000000..3fdeb265b10a
--- /dev/null
+++ b/dev-python/cython/cython-0.29.25.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs elisp-common
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="https://cython.org https://pypi.org/project/Cython/
+	https://github.com/cython/cython"
+SRC_URI="https://github.com/cython/cython/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
+IUSE="emacs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+BDEPEND="${RDEPEND}
+	test? (
+		$(python_gen_cond_dep 'dev-python/numpy[${PYTHON_USEDEP}]' \
+			'python3*')
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.29.22-spawn-multiprocessing.patch"
+	"${FILESDIR}/${PN}-0.29.23-test_exceptions-py310.patch"
+)
+
+SITEFILE=50cython-gentoo.el
+
+distutils_enable_sphinx docs
+
+python_compile() {
+	# Python gets confused when it is in sys.path before build.
+	local -x PYTHONPATH=
+
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use emacs && elisp-compile Tools/cython-mode.el
+}
+
+python_test() {
+	tc-export CC
+	# https://github.com/cython/cython/issues/1911
+	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
+	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
+	distutils-r1_python_install_all
+
+	if use emacs; then
+		elisp-install ${PN} Tools/cython-mode.*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}