Updating liguros repo

11 files changed, 279 insertions, 1 deletions

diff --git a/dev-python/bcrypt/bcrypt-3.2.0.ebuild b/dev-python/bcrypt/bcrypt-3.2.0.ebuild
index 4dd400574da8..9c11abbc4539 100644
--- a/dev-python/bcrypt/bcrypt-3.2.0.ebuild
+++ b/dev-python/bcrypt/bcrypt-3.2.0.ebuild
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 SLOT="0"
 LICENSE="Apache-2.0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris"
+KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris"
 
 RDEPEND="
 	$(python_gen_cond_dep '>=dev-python/cffi-1.1:=[${PYTHON_USEDEP}]' 'python*')
diff --git a/dev-python/bleach/Manifest b/dev-python/bleach/Manifest
index 495386a6fe98..95124802e073 100644
--- a/dev-python/bleach/Manifest
+++ b/dev-python/bleach/Manifest
@@ -1 +1,2 @@
 DIST bleach-3.1.5.tar.gz 177972 BLAKE2B 6033871f757247f05ee67f66b3596c7a76a9bc5105113206bc8749f9ed103fb6a7c91630540f5f17ddc17e261b24043cc2edcc2562ea7f4cf54774080854de32 SHA512 20db9ab6924a1e884107f30e1059f774b45fd169d3965a61a4ff028e3de17e30be81474d7da89d9275b2173a005c5504a9d11f0e0ca528bf36a9bf08aeed0607
+DIST bleach-3.2.0.tar.gz 178910 BLAKE2B e7e97cc367420a656086e5a0e6c1c527348a0edc23c15f5f4b5a40b3079a2fa32b71fd2d99c4db8891e1b2ed06e4ac8ab3d3f0c9a3de77d02499bf32746a9dd7 SHA512 06dd7e22204280a03e37cfc303b4de8fc8776e9ac3f7a4c2451f1ff768b68d97c6b00fa42dc275eb4404dae5e448b9385b4e6ee204fdc7e11f31207cdc3d926a
diff --git a/dev-python/bleach/bleach-3.2.0.ebuild b/dev-python/bleach/bleach-3.2.0.ebuild
new file mode 100644
index 000000000000..5856cebee01d
--- /dev/null
+++ b/dev-python/bleach/bleach-3.2.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="an easy whitelist-based HTML-sanitizing tool"
+HOMEPAGE="https://github.com/mozilla/bleach https://pypi.org/project/bleach/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1-r1[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/webencodings[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/bleach-3.1.5-py39.patch
+)
+
+src_prepare() {
+	# unbundle unpatched broken html5lib
+	rm -r bleach/_vendor || die
+	sed -i -e 's:bleach\._vendor\.::' \
+		bleach/html5lib_shim.py tests/test_clean.py || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index bb9cec36e05f..2046bf9a0358 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,3 +7,4 @@ DIST boto3-1.14.55.tar.gz 302397 BLAKE2B 61785df9bfbe0668ff7b0537bb86b119ab3a98d
 DIST boto3-1.14.57.tar.gz 334506 BLAKE2B ba422426f36c55eb78e057d886abdb9a435839b4a842bf917e3e02d2f3f80c8c94bbf524ed4f3cab53ae627a9f1aeac41a790bebb72c94f52c73486dbcd3f13b SHA512 b772ec8d1c167e37515643796a569ba4258de24b9e4aa1a5022e140fc9121fdc02472231f36b8336e75115aabafa8dbc8c5422ce2ac137f3ead1202043b1c6c0
 DIST boto3-1.14.59.tar.gz 334641 BLAKE2B 96cd0750521715f030c2668cf21b7d6e5f53ffb9bcb84bc9fc540b1bea911591880385a3bd31447f924aa24cbdce873d17241d921b87e57d109173062dd27678 SHA512 9dddad6c71bac90803402b35a316f7177c26629e7e1b3cdadc6222e890d89dce4c2941174501705da85209220fe741f788654f5db164b2d9eac26cbba7cfb0d5
 DIST boto3-1.14.61.tar.gz 334755 BLAKE2B f0c5b5e9f74abaab03789deae1bbf9c5957d5d54af5cdc0c3a21deaed4945e104abeb59305ec1c692f2bcd2e99f7806ea4bd7fb9ae6194f194d74c9eeac4bf0a SHA512 6bec490d4d976585c5a8522998a4b3538dfdfc53416844779dbede2faa7d0d45bb10a6a566a777eaccd5d630202f6217178a386fbf3de5ef3c6395cda583f413
+DIST boto3-1.14.63.tar.gz 334965 BLAKE2B 370a1d5bcc32ba6fd8f187fa56fbb3afa4aafa0692245efe024efdefb3d0a314b24873f641b3789430d6a64df70e55743a73760b8282ecaeb64116d9c27b82bc SHA512 668ec7a40d7be74268005d342b568e2d0efe0a3aafca7123c27e966fd89334dbdab04bca0a7ab216eae1f26f0506ef4ccacead49b1714a94a84c7a315e71e505
diff --git a/dev-python/boto3/boto3-1.14.63.ebuild b/dev-python/boto3/boto3-1.14.63.ebuild
new file mode 100644
index 000000000000..12584b2fba42
--- /dev/null
+++ b/dev-python/boto3/boto3-1.14.63.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index db0976623a57..e0316f816cef 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,3 +7,4 @@ DIST botocore-1.17.55.tar.gz 6781012 BLAKE2B d9dac6d32ae6226bf80c79651f0d56c1b91
 DIST botocore-1.17.57.tar.gz 6815839 BLAKE2B e135e4d0b889add8417d8a6ce97c475865859e8805077bc404010cf1c0d7da0eae27f49fc14eaffa86b0a45e5a49799a59fa6b3a7117d103976b0c1628a531db SHA512 244021f4ab9a2778917f91bcf0f26d868025e77bee0c592f81e8266721952b5ffcc3ec4fc7f1dc2b7e2b20faac8f0d4e8b8b47d72a89ff66386fc008b0781da1
 DIST botocore-1.17.59.tar.gz 6829639 BLAKE2B efacd4c875e17f187abd5c4602a82229ed2a9fd78e1987f1b540eb882d1a3ce7c23768f7f4b9dc26a678ff4ce48264f3893c0aa2a68511823f79686c21ecf82f SHA512 609eb24774384b95dd9b5bcf5931d263341fbbba90b84159c6833296c22d95c6cf8d304d6908713d9ba826858d8d226e0b5c700bb1410c3a9f7b2d679f535c40
 DIST botocore-1.17.61.tar.gz 6832886 BLAKE2B 1c63507dea98f4f4275effe190e7af1e3325ee03376676bdbab6eeca364540bd86c7253b1ab64a70d28cf2f5ae8182927c2f18ac86e0bac813d4ef11c37193c6 SHA512 606076103594fb6efee1fa79181449c0ffa37eb71b5f5c187f8046375ddf982f72741ba00a1d2311be893094b86dd9196ee33410a693727ea9502cf87332dcc0
+DIST botocore-1.17.63.tar.gz 6841028 BLAKE2B 89b2d5d520e733deaf3c4b68faa103e4227107cebd3803d1cb6e47ec0df9f7a07d72eb24836a45762ead2ce1aa381d5b1dfcc33eb9a80c5f8d021c0dbfb631c3 SHA512 e4cf3fbb4c8a5c05dc8265b67fbba0bf03dcf12d28bcd0e1dd304392614d86f061a5115f8129eefa2fa44efab17a8720b7c39c082c2908bf4e29bbefb57e92fb
diff --git a/dev-python/botocore/botocore-1.17.63.ebuild b/dev-python/botocore/botocore-1.17.63.ebuild
new file mode 100644
index 000000000000..b111030cd3da
--- /dev/null
+++ b/dev-python/botocore/botocore-1.17.63.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+	"${FILESDIR}/botocore-1.16.7-unlock-deps.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# py3.9
+	find -name '*.py' -exec \
+		sed -i -e 's:cElementTree:ElementTree:' {} + || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/cfn-python-lint/Manifest b/dev-python/cfn-python-lint/Manifest
index ef3d8bea5d84..956c1b331ef1 100644
--- a/dev-python/cfn-python-lint/Manifest
+++ b/dev-python/cfn-python-lint/Manifest
@@ -1,2 +1,3 @@
 DIST cfn-python-lint-0.30.1.tar.gz 4137425 BLAKE2B dd4f7d449236e567e7ea0fa662cbe983b6125a6cb557ee314de0e6647c5756b0be450deec7778ac69f1cec95b594c8c74a0a2f56ea229b7dc28ffb918983e6b3 SHA512 67b72973dc174e0de4980606b7886459233fca516a0587b91319127c4df0ce2647bbdc3302d68b63916654a76f4c9405c2f27cfd5e0ad737b00724e403815477
 DIST cfn-python-lint-0.35.1.tar.gz 4501826 BLAKE2B 84da0965fc198ce7b8f955a7d43f9a1c87c9688c301594abe6843509a832b4c9c5fadad1f75ac1c5b20ce2179244fd2b9681f5a92a1dbe38738a61c94f95982a SHA512 6d277048bbd7d8950ef7681c4a31cb82ccc231fb29f5083169caef69bfa4464cd87e473f40c775d798ff511a5db1dff9a17b0c08dcc800db0188e1e84990c9e4
+DIST cfn-python-lint-0.36.0.tar.gz 4879599 BLAKE2B a79a12290e20f4db1e45b29df0486d3b69f3c028f35cae8e8ba9ab5da191c1a5f7fed6bc339d24e3212faab7a05a82e859a79135847eb90b0161fe0aa7b8c995 SHA512 286c8e614ee083981105a74f09b4c75454ae6eef48812ac59852374bea5dfc0d111b006bb67c50e42fa2a1eeb54ce6f25b8bf0f06624da236344e9bbadf4ce1c
diff --git a/dev-python/cfn-python-lint/cfn-python-lint-0.36.0.ebuild b/dev-python/cfn-python-lint/cfn-python-lint-0.36.0.ebuild
new file mode 100644
index 000000000000..17c526935121
--- /dev/null
+++ b/dev-python/cfn-python-lint/cfn-python-lint-0.36.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="https://pypi.org/project/cfn-lint/ https://github.com/aws-cloudformation/cfn-python-lint"
+SRC_URI="https://github.com/aws-cloudformation/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.25.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources[${PYTHON_USEDEP}]
+	' python3_6)
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/cfn-python-lint-0.30.1-tests.patch"
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	distutils_install_for_testing
+	"${EPYTHON}" -m unittest discover -v ||
+		die "tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index b7cea49a902e..c4a474c1f66b 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1,3 +1,4 @@
 DIST nbconvert-5.6.1.tar.gz 703233 BLAKE2B e75d558aee6c66fe8e7455ecf22dbbcd2a0698380ffec80eff15aea6c70bc853daa9ab2fd1d114453bd5dfe7e75617afb9f5c1075704bfadbb59fef34bca88a9 SHA512 0c68adcb9f28ead9ec058fc2e02a9a1e6f65818709c99f7a006a59a7562b5f5ee74afe5287e41568c35542898dc1b43c4543d2386cc05a721b3f99d5cc789435
 DIST nbconvert-6.0.1.tar.gz 838950 BLAKE2B 7ccb821bd7affab3faed0c1fb139b0641f295c71109c783e9ce40c5a4c15c2d87a327ce7c802ed3cfde2fcde4c360375dd751f9592eeda102d520aee4e94f2d5 SHA512 7c782a068fc004a42cbc2e09d8d4fbce5385a8f6fb8491fa39d14df123a00bf81e6e7f11885fe39300156ecf560b92f5631537a5956e5541ea3dcf9ec5f9f365
 DIST nbconvert-6.0.2.tar.gz 847737 BLAKE2B c787840ec25661a1242bd1a4ef46ca0c022fd23385da5dc48ff8ec391ad440fc70ab841fdfd1fd0a98836a4a30592ed0f121ce94895f2a70c33899c11760e43b SHA512 faad2c4e697a0189e4b156e061f1d2a13676ef0dc7703993f0d445093d83a73618bc2529fceca094797415e7468e7f067d573556bfcf793a37956c082403d5fa
+DIST nbconvert-6.0.3.tar.gz 848214 BLAKE2B 4265486536cfe0cf220b8080374726cc68be4f15033c8248806579b1ea1f759caa667ae11738acce1ecc812c65b954be1c21db0abe69db7bfdf67533ea052c3c SHA512 55e6fc1f136f8bc3b4b662011172ac3f61354ee1afa6904b5df34a382ae96f46e13f097f6067ca5e42d3fd0049f81a8a27d7b7faf605fa948e22d6067bc971ef
diff --git a/dev-python/nbconvert/nbconvert-6.0.3.ebuild b/dev-python/nbconvert/nbconvert-6.0.3.ebuild
new file mode 100644
index 000000000000..5a5b2e03dc37
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.0.3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		media-gfx/inkscape
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local deselect=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		--deselect exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		--deselect 'tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	pytest -vv "${deselect[@]}" --pyargs nbconvert || die "Tests failed with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}